arch/arm/boot/compressed/head.S

   1 /*
   2  *  linux/arch/arm/boot/compressed/head.S
   3  *
   4  *  Copyright (C) 1996-2002 Russell King
   5  *  Copyright (C) 2004 Hyok S. Choi (MPU support)
   6  *
   7  * This program is free software; you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License version 2 as
   9  * published by the Free Software Foundation.
  10  */
  11 #include <linux/linkage.h>
  12
  13 /*
  14  * Debugging stuff
  15  *
  16  * Note that these macros must not contain any code which is not
  17  * 100% relocatable.  Any attempt to do so will result in a crash.
  18  * Please select one of the following when turning on debugging.
  19  */
  20 #ifdef DEBUG
  21
  22 #if defined(CONFIG_DEBUG_ICEDCC)
  23
  24 #ifdef CONFIG_CPU_V6
  25                 .macro  loadsp, rb, tmp
  26                 .endm
  27                 .macro  writeb, ch, rb
  28                 mcr     p14, 0, \ch, c0, c5, 0
  29                 .endm
  30 #elif defined(CONFIG_CPU_V7)
  31                 .macro  loadsp, rb, tmp
  32                 .endm
  33                 .macro  writeb, ch, rb
  34 wait:           mrc     p14, 0, pc, c0, c1, 0
  35                 bcs     wait
  36                 mcr     p14, 0, \ch, c0, c5, 0
  37                 .endm
  38 #elif defined(CONFIG_CPU_XSCALE)
  39                 .macro  loadsp, rb, tmp
  40                 .endm
  41                 .macro  writeb, ch, rb
  42                 mcr     p14, 0, \ch, c8, c0, 0
  43                 .endm
  44 #else
  45                 .macro  loadsp, rb, tmp
  46                 .endm
  47                 .macro  writeb, ch, rb
  48                 mcr     p14, 0, \ch, c1, c0, 0
  49                 .endm
  50 #endif
  51
  52 #else
  53
  54 #include <mach/debug-macro.S>
  55
  56                 .macro  writeb, ch, rb
  57                 senduart \ch, \rb
  58                 .endm
  59
  60 #if defined(CONFIG_ARCH_SA1100)
  61                 .macro  loadsp, rb, tmp
  62                 mov     \rb, #0x80000000        @ physical base address
  63 #ifdef CONFIG_DEBUG_LL_SER3
  64                 add     \rb, \rb, #0x00050000   @ Ser3
  65 #else
  66                 add     \rb, \rb, #0x00010000   @ Ser1
  67 #endif
  68                 .endm
  69 #elif defined(CONFIG_ARCH_S3C2410)
  70                 .macro loadsp, rb, tmp
  71                 mov     \rb, #0x50000000
  72                 add     \rb, \rb, #0x4000 * CONFIG_S3C_LOWLEVEL_UART_PORT
  73                 .endm
  74 #else
  75                 .macro  loadsp, rb, tmp
  76                 addruart \rb, \tmp
  77                 .endm
  78 #endif
  79 #endif
  80 #endif
  81
  82                 .macro  kputc,val
  83                 mov     r0, \val
  84                 bl      putc
  85                 .endm
  86
  87                 .macro  kphex,val,len
  88                 mov     r0, \val
  89                 mov     r1, #\len
  90                 bl      phex
  91                 .endm
  92
  93                 .macro  debug_reloc_start
  94 #ifdef DEBUG
  95                 kputc   #'\n'
  96                 kphex   r6, 8           /* processor id */
  97                 kputc   #':'
  98                 kphex   r7, 8           /* architecture id */
  99 #ifdef CONFIG_CPU_CP15
 100                 kputc   #':'
 101                 mrc     p15, 0, r0, c1, c0
 102                 kphex   r0, 8           /* control reg */
 103 #endif
 104                 kputc   #'\n'
 105                 kphex   r5, 8           /* decompressed kernel start */
 106                 kputc   #'-'
 107                 kphex   r9, 8           /* decompressed kernel end  */
 108                 kputc   #'>'
 109                 kphex   r4, 8           /* kernel execution address */
 110                 kputc   #'\n'
 111 #endif
 112                 .endm
 113
 114                 .macro  debug_reloc_end
 115 #ifdef DEBUG
 116                 kphex   r5, 8           /* end of kernel */
 117                 kputc   #'\n'
 118                 mov     r0, r4
 119                 bl      memdump         /* dump 256 bytes at start of kernel */
 120 #endif
 121                 .endm
 122
 123                 .section ".start", #alloc, #execinstr
 124 /*
 125  * sort out different calling conventions
 126  */
 127                 .align
 128 start:
 129                 .type   start,#function
 130                 .rept   8
 131                 mov     r0, r0
 132                 .endr
 133
 134                 b       1f
 135                 .word   0x016f2818              @ Magic numbers to help the loader
 136                 .word   start                   @ absolute load/run zImage address
 137                 .word   _edata                  @ zImage end address
 138 1:              mov     r7, r1                  @ save architecture ID
 139                 mov     r8, r2                  @ save atags pointer
 140
 141 #ifndef __ARM_ARCH_2__
 142                 /*
 143                  * Booting from Angel - need to enter SVC mode and disable
 144                  * FIQs/IRQs (numeric definitions from angel arm.h source).
 145                  * We only do this if we were in user mode on entry.
 146                  */
 147                 mrs     r2, cpsr                @ get current mode
 148                 tst     r2, #3                  @ not user?
 149                 bne     not_angel
 150                 mov     r0, #0x17               @ angel_SWIreason_EnterSVC
 151  ARM(           swi     0x123456        )       @ angel_SWI_ARM
 152  THUMB(         svc     0xab            )       @ angel_SWI_THUMB
 153 not_angel:
 154                 mrs     r2, cpsr                @ turn off interrupts to
 155                 orr     r2, r2, #0xc0           @ prevent angel from running
 156                 msr     cpsr_c, r2
 157 #else
 158                 teqp    pc, #0x0c000003         @ turn off interrupts
 159 #endif
 160
 161                 /*
 162                  * Note that some cache flushing and other stuff may
 163                  * be needed here - is there an Angel SWI call for this?
 164                  */
 165
 166                 /*
 167                  * some architecture specific code can be inserted
 168                  * by the linker here, but it should preserve r7, r8, and r9.
 169                  */
 170
 171                 .text
 172                 adr     r0, LC0
 173                 ldmia   r0, {r1, r2, r3, r5, r6, r11, ip}
 174                 ldr     sp, [r0, #28]
 175 #ifdef CONFIG_AUTO_ZRELADDR
 176                 @ determine final kernel image address
 177                 mov     r4, pc
 178                 and     r4, r4, #0xf8000000
 179                 add     r4, r4, #TEXT_OFFSET
 180 #else
 181                 ldr     r4, =zreladdr
 182 #endif
 183                 subs    r0, r0, r1              @ calculate the delta offset
 184
 185                                                 @ if delta is zero, we are
 186                 beq     not_relocated           @ running at the address we
 187                                                 @ were linked at.
 188
 189                 /*
 190                  * We're running at a different address.  We need to fix
 191                  * up various pointers:
 192                  *   r5 - zImage base address (_start)
 193                  *   r6 - size of decompressed image
 194                  *   r11 - GOT start
 195                  *   ip - GOT end
 196                  */
 197                 add     r5, r5, r0
 198                 add     r11, r11, r0
 199                 add     ip, ip, r0
 200
 201 #ifndef CONFIG_ZBOOT_ROM
 202                 /*
 203                  * If we're running fully PIC === CONFIG_ZBOOT_ROM = n,
 204                  * we need to fix up pointers into the BSS region.
 205                  *   r2 - BSS start
 206                  *   r3 - BSS end
 207                  *   sp - stack pointer
 208                  */
 209                 add     r2, r2, r0
 210                 add     r3, r3, r0
 211                 add     sp, sp, r0
 212
 213                 /*
 214                  * Relocate all entries in the GOT table.
 215                  */
 216 1:              ldr     r1, [r11, #0]           @ relocate entries in the GOT
 217                 add     r1, r1, r0              @ table.  This fixes up the
 218                 str     r1, [r11], #4           @ C references.
 219                 cmp     r11, ip
 220                 blo     1b
 221 #else
 222
 223                 /*
 224                  * Relocate entries in the GOT table.  We only relocate
 225                  * the entries that are outside the (relocated) BSS region.
 226                  */
 227 1:              ldr     r1, [r11, #0]           @ relocate entries in the GOT
 228                 cmp     r1, r2                  @ entry < bss_start ||
 229                 cmphs   r3, r1                  @ _end < entry
 230                 addlo   r1, r1, r0              @ table.  This fixes up the
 231                 str     r1, [r11], #4           @ C references.
 232                 cmp     r11, ip
 233                 blo     1b
 234 #endif
 235
 236 not_relocated:  mov     r0, #0
 237 1:              str     r0, [r2], #4            @ clear bss
 238                 str     r0, [r2], #4
 239                 str     r0, [r2], #4
 240                 str     r0, [r2], #4
 241                 cmp     r2, r3
 242                 blo     1b
 243
 244                 /*
 245                  * The C runtime environment should now be setup
 246                  * sufficiently.  Turn the cache on, set up some
 247                  * pointers, and start decompressing.
 248                  */
 249                 bl      cache_on
 250
 251                 mov     r1, sp                  @ malloc space above stack
 252                 add     r2, sp, #0x10000        @ 64k max
 253
 254 /*
 255  * Check to see if we will overwrite ourselves.
 256  *   r4 = final kernel address
 257  *   r5 = start of this image
 258  *   r6 = size of decompressed image
 259  *   r2 = end of malloc space (and therefore this image)
 260  * We basically want:
 261  *   r4 >= r2 -> OK
 262  *   r4 + image length <= r5 -> OK
 263  */
 264                 cmp     r4, r2
 265                 bhs     wont_overwrite
 266                 add     r0, r4, r6
 267                 cmp     r0, r5
 268                 bls     wont_overwrite
 269
 270                 mov     r5, r2                  @ decompress after malloc space
 271                 mov     r0, r5
 272                 mov     r3, r7
 273                 bl      decompress_kernel
 274
 275                 add     r0, r0, #127 + 128      @ alignment + stack
 276                 bic     r0, r0, #127            @ align the kernel length
 277 /*
 278  * r0     = decompressed kernel length
 279  * r1-r3  = unused
 280  * r4     = kernel execution address
 281  * r5     = decompressed kernel start
 282  * r7     = architecture ID
 283  * r8     = atags pointer
 284  * r9-r12,r14 = corrupted
 285  */
 286                 add     r1, r5, r0              @ end of decompressed kernel
 287                 adr     r2, reloc_start
 288                 ldr     r3, LC1
 289                 add     r3, r2, r3
 290 1:              ldmia   r2!, {r9 - r12, r14}    @ copy relocation code
 291                 stmia   r1!, {r9 - r12, r14}
 292                 ldmia   r2!, {r9 - r12, r14}
 293                 stmia   r1!, {r9 - r12, r14}
 294                 cmp     r2, r3
 295                 blo     1b
 296                 mov     sp, r1
 297                 add     sp, sp, #128            @ relocate the stack
 298
 299                 bl      cache_clean_flush
 300  ARM(           add     pc, r5, r0              ) @ call relocation code
 301  THUMB(         add     r12, r5, r0             )
 302  THUMB(         mov     pc, r12                 ) @ call relocation code
 303
 304 /*
 305  * We're not in danger of overwriting ourselves.  Do this the simple way.
 306  *
 307  * r4     = kernel execution address
 308  * r7     = architecture ID
 309  */
 310 wont_overwrite: mov     r0, r4
 311                 mov     r3, r7
 312                 bl      decompress_kernel
 313                 b       call_kernel
 314
 315                 .align  2
 316                 .type   LC0, #object
 317 LC0:            .word   LC0                     @ r1
 318                 .word   __bss_start             @ r2
 319                 .word   _end                    @ r3
 320                 .word   _start                  @ r5
 321                 .word   _image_size             @ r6
 322                 .word   _got_start              @ r11
 323                 .word   _got_end                @ ip
 324                 .word   user_stack_end          @ sp
 325 LC1:            .word   reloc_end - reloc_start
 326                 .size   LC0, . - LC0
 327
 328 #ifdef CONFIG_ARCH_RPC
 329                 .globl  params
 330 params:         ldr     r0, =0x10000100         @ params_phys for RPC
 331                 mov     pc, lr
 332                 .ltorg
 333                 .align
 334 #endif
 335
 336 /*
 337  * Turn on the cache.  We need to setup some page tables so that we
 338  * can have both the I and D caches on.
 339  *
 340  * We place the page tables 16k down from the kernel execution address,
 341  * and we hope that nothing else is using it.  If we're using it, we
 342  * will go pop!
 343  *
 344  * On entry,
 345  *  r4 = kernel execution address
 346  *  r7 = architecture number
 347  *  r8 = atags pointer
 348  * On exit,
 349  *  r0, r1, r2, r3, r9, r10, r12 corrupted
 350  * This routine must preserve:
 351  *  r4, r5, r6, r7, r8
 352  */
 353                 .align  5
 354 cache_on:       mov     r3, #8                  @ cache_on function
 355                 b       call_cache_fn
 356
 357 /*
 358  * Initialize the highest priority protection region, PR7
 359  * to cover all 32bit address and cacheable and bufferable.
 360  */
 361 __armv4_mpu_cache_on:
 362                 mov     r0, #0x3f               @ 4G, the whole
 363                 mcr     p15, 0, r0, c6, c7, 0   @ PR7 Area Setting
 364                 mcr     p15, 0, r0, c6, c7, 1
 365
 366                 mov     r0, #0x80               @ PR7
 367                 mcr     p15, 0, r0, c2, c0, 0   @ D-cache on
 368                 mcr     p15, 0, r0, c2, c0, 1   @ I-cache on
 369                 mcr     p15, 0, r0, c3, c0, 0   @ write-buffer on
 370
 371                 mov     r0, #0xc000
 372                 mcr     p15, 0, r0, c5, c0, 1   @ I-access permission
 373                 mcr     p15, 0, r0, c5, c0, 0   @ D-access permission
 374
 375                 mov     r0, #0
 376                 mcr     p15, 0, r0, c7, c10, 4  @ drain write buffer
 377                 mcr     p15, 0, r0, c7, c5, 0   @ flush(inval) I-Cache
 378                 mcr     p15, 0, r0, c7, c6, 0   @ flush(inval) D-Cache
 379                 mrc     p15, 0, r0, c1, c0, 0   @ read control reg
 380                                                 @ ...I .... ..D. WC.M
 381                 orr     r0, r0, #0x002d         @ .... .... ..1. 11.1
 382                 orr     r0, r0, #0x1000         @ ...1 .... .... ....
 383
 384                 mcr     p15, 0, r0, c1, c0, 0   @ write control reg
 385
 386                 mov     r0, #0
 387                 mcr     p15, 0, r0, c7, c5, 0   @ flush(inval) I-Cache
 388                 mcr     p15, 0, r0, c7, c6, 0   @ flush(inval) D-Cache
 389                 mov     pc, lr
 390
 391 __armv3_mpu_cache_on:
 392                 mov     r0, #0x3f               @ 4G, the whole
 393                 mcr     p15, 0, r0, c6, c7, 0   @ PR7 Area Setting
 394
 395                 mov     r0, #0x80               @ PR7
 396                 mcr     p15, 0, r0, c2, c0, 0   @ cache on
 397                 mcr     p15, 0, r0, c3, c0, 0   @ write-buffer on
 398
 399                 mov     r0, #0xc000
 400                 mcr     p15, 0, r0, c5, c0, 0   @ access permission
 401
 402                 mov     r0, #0
 403                 mcr     p15, 0, r0, c7, c0, 0   @ invalidate whole cache v3
 404                 /*
 405                  * ?? ARMv3 MMU does not allow reading the control register,
 406                  * does this really work on ARMv3 MPU?
 407                  */
 408                 mrc     p15, 0, r0, c1, c0, 0   @ read control reg
 409                                                 @ .... .... .... WC.M
 410                 orr     r0, r0, #0x000d         @ .... .... .... 11.1
 411                 /* ?? this overwrites the value constructed above? */
 412                 mov     r0, #0
 413                 mcr     p15, 0, r0, c1, c0, 0   @ write control reg
 414
 415                 /* ?? invalidate for the second time? */
 416                 mcr     p15, 0, r0, c7, c0, 0   @ invalidate whole cache v3
 417                 mov     pc, lr
 418
 419 __setup_mmu:    sub     r3, r4, #16384          @ Page directory size
 420                 bic     r3, r3, #0xff           @ Align the pointer
 421                 bic     r3, r3, #0x3f00
 422 /*
 423  * Initialise the page tables, turning on the cacheable and bufferable
 424  * bits for the RAM area only.
 425  */
 426                 mov     r0, r3
 427                 mov     r9, r0, lsr #18
 428                 mov     r9, r9, lsl #18         @ start of RAM
 429                 add     r10, r9, #0x10000000    @ a reasonable RAM size
 430                 mov     r1, #0x12
 431                 orr     r1, r1, #3 << 10
 432                 add     r2, r3, #16384
 433 1:              cmp     r1, r9                  @ if virt > start of RAM
 434                 orrhs   r1, r1, #0x0c           @ set cacheable, bufferable
 435                 cmp     r1, r10                 @ if virt > end of RAM
 436                 bichs   r1, r1, #0x0c           @ clear cacheable, bufferable
 437                 str     r1, [r0], #4            @ 1:1 mapping
 438                 add     r1, r1, #1048576
 439                 teq     r0, r2
 440                 bne     1b
 441 /*
 442  * If ever we are running from Flash, then we surely want the cache
 443  * to be enabled also for our execution instance...  We map 2MB of it
 444  * so there is no map overlap problem for up to 1 MB compressed kernel.
 445  * If the execution is in RAM then we would only be duplicating the above.
 446  */
 447                 mov     r1, #0x1e
 448                 orr     r1, r1, #3 << 10
 449                 mov     r2, pc
 450                 mov     r2, r2, lsr #20
 451                 orr     r1, r1, r2, lsl #20
 452                 add     r0, r3, r2, lsl #2
 453                 str     r1, [r0], #4
 454                 add     r1, r1, #1048576
 455                 str     r1, [r0]
 456                 mov     pc, lr
 457 ENDPROC(__setup_mmu)
 458
 459 __armv4_mmu_cache_on:
 460                 mov     r12, lr
 461 #ifdef CONFIG_MMU
 462                 bl      __setup_mmu
 463                 mov     r0, #0
 464                 mcr     p15, 0, r0, c7, c10, 4  @ drain write buffer
 465                 mcr     p15, 0, r0, c8, c7, 0   @ flush I,D TLBs
 466                 mrc     p15, 0, r0, c1, c0, 0   @ read control reg
 467                 orr     r0, r0, #0x5000         @ I-cache enable, RR cache replacement
 468                 orr     r0, r0, #0x0030
 469 #ifdef CONFIG_CPU_ENDIAN_BE8
 470                 orr     r0, r0, #1 << 25        @ big-endian page tables
 471 #endif
 472                 bl      __common_mmu_cache_on
 473                 mov     r0, #0
 474                 mcr     p15, 0, r0, c8, c7, 0   @ flush I,D TLBs
 475 #endif
 476                 mov     pc, r12
 477
 478 __armv7_mmu_cache_on:
 479                 mov     r12, lr
 480 #ifdef CONFIG_MMU
 481                 mrc     p15, 0, r11, c0, c1, 4  @ read ID_MMFR0
 482                 tst     r11, #0xf               @ VMSA
 483                 blne    __setup_mmu
 484                 mov     r0, #0
 485                 mcr     p15, 0, r0, c7, c10, 4  @ drain write buffer
 486                 tst     r11, #0xf               @ VMSA
 487                 mcrne   p15, 0, r0, c8, c7, 0   @ flush I,D TLBs
 488 #endif
 489                 mrc     p15, 0, r0, c1, c0, 0   @ read control reg
 490                 orr     r0, r0, #0x5000         @ I-cache enable, RR cache replacement
 491                 orr     r0, r0, #0x003c         @ write buffer
 492 #ifdef CONFIG_MMU
 493 #ifdef CONFIG_CPU_ENDIAN_BE8
 494                 orr     r0, r0, #1 << 25        @ big-endian page tables
 495 #endif
 496                 orrne   r0, r0, #1              @ MMU enabled
 497                 movne   r1, #-1
 498                 mcrne   p15, 0, r3, c2, c0, 0   @ load page table pointer
 499                 mcrne   p15, 0, r1, c3, c0, 0   @ load domain access control
 500 #endif
 501                 mcr     p15, 0, r0, c1, c0, 0   @ load control register
 502                 mrc     p15, 0, r0, c1, c0, 0   @ and read it back
 503                 mov     r0, #0
 504                 mcr     p15, 0, r0, c7, c5, 4   @ ISB
 505                 mov     pc, r12
 506
 507 __fa526_cache_on:
 508                 mov     r12, lr
 509                 bl      __setup_mmu
 510                 mov     r0, #0
 511                 mcr     p15, 0, r0, c7, c7, 0   @ Invalidate whole cache
 512                 mcr     p15, 0, r0, c7, c10, 4  @ drain write buffer
 513                 mcr     p15, 0, r0, c8, c7, 0   @ flush UTLB
 514                 mrc     p15, 0, r0, c1, c0, 0   @ read control reg
 515                 orr     r0, r0, #0x1000         @ I-cache enable
 516                 bl      __common_mmu_cache_on
 517                 mov     r0, #0
 518                 mcr     p15, 0, r0, c8, c7, 0   @ flush UTLB
 519                 mov     pc, r12
 520
 521 __arm6_mmu_cache_on:
 522                 mov     r12, lr
 523                 bl      __setup_mmu
 524                 mov     r0, #0
 525                 mcr     p15, 0, r0, c7, c0, 0   @ invalidate whole cache v3
 526                 mcr     p15, 0, r0, c5, c0, 0   @ invalidate whole TLB v3
 527                 mov     r0, #0x30
 528                 bl      __common_mmu_cache_on
 529                 mov     r0, #0
 530                 mcr     p15, 0, r0, c5, c0, 0   @ invalidate whole TLB v3
 531                 mov     pc, r12
 532
 533 __common_mmu_cache_on:
 534 #ifndef CONFIG_THUMB2_KERNEL
 535 #ifndef DEBUG
 536                 orr     r0, r0, #0x000d         @ Write buffer, mmu
 537 #endif
 538                 mov     r1, #-1
 539                 mcr     p15, 0, r3, c2, c0, 0   @ load page table pointer
 540                 mcr     p15, 0, r1, c3, c0, 0   @ load domain access control
 541                 b       1f
 542                 .align  5                       @ cache line aligned
 543 1:              mcr     p15, 0, r0, c1, c0, 0   @ load control register
 544                 mrc     p15, 0, r0, c1, c0, 0   @ and read it back to
 545                 sub     pc, lr, r0, lsr #32     @ properly flush pipeline
 546 #endif
 547
 548 /*
 549  * All code following this line is relocatable.  It is relocated by
 550  * the above code to the end of the decompressed kernel image and
 551  * executed there.  During this time, we have no stacks.
 552  *
 553  * r0     = decompressed kernel length
 554  * r1-r3  = unused
 555  * r4     = kernel execution address
 556  * r5     = decompressed kernel start
 557  * r7     = architecture ID
 558  * r8     = atags pointer
 559  * r9-r12,r14 = corrupted
 560  */
 561                 .align  5
 562 reloc_start:    add     r9, r5, r0
 563                 sub     r9, r9, #128            @ do not copy the stack
 564                 debug_reloc_start
 565                 mov     r1, r4
 566 1:
 567                 .rept   4
 568                 ldmia   r5!, {r0, r2, r3, r10 - r12, r14}       @ relocate kernel
 569                 stmia   r1!, {r0, r2, r3, r10 - r12, r14}
 570                 .endr
 571
 572                 cmp     r5, r9
 573                 blo     1b
 574                 mov     sp, r1
 575                 add     sp, sp, #128            @ relocate the stack
 576                 debug_reloc_end
 577
 578 call_kernel:    bl      cache_clean_flush
 579                 bl      cache_off
 580                 mov     r0, #0                  @ must be zero
 581                 mov     r1, r7                  @ restore architecture number
 582                 mov     r2, r8                  @ restore atags pointer
 583                 mov     pc, r4                  @ call kernel
 584
 585 /*
 586  * Here follow the relocatable cache support functions for the
 587  * various processors.  This is a generic hook for locating an
 588  * entry and jumping to an instruction at the specified offset
 589  * from the start of the block.  Please note this is all position
 590  * independent code.
 591  *
 592  *  r1  = corrupted
 593  *  r2  = corrupted
 594  *  r3  = block offset
 595  *  r9  = corrupted
 596  *  r12 = corrupted
 597  */
 598
 599 call_cache_fn:  adr     r12, proc_types
 600 #ifdef CONFIG_CPU_CP15
 601                 mrc     p15, 0, r9, c0, c0      @ get processor ID
 602 #else
 603                 ldr     r9, =CONFIG_PROCESSOR_ID
 604 #endif
 605 1:              ldr     r1, [r12, #0]           @ get value
 606                 ldr     r2, [r12, #4]           @ get mask
 607                 eor     r1, r1, r9              @ (real ^ match)
 608                 tst     r1, r2                  @       & mask
 609  ARM(           addeq   pc, r12, r3             ) @ call cache function
 610  THUMB(         addeq   r12, r3                 )
 611  THUMB(         moveq   pc, r12                 ) @ call cache function
 612                 add     r12, r12, #4*5
 613                 b       1b
 614
 615 /*
 616  * Table for cache operations.  This is basically:
 617  *   - CPU ID match
 618  *   - CPU ID mask
 619  *   - 'cache on' method instruction
 620  *   - 'cache off' method instruction
 621  *   - 'cache flush' method instruction
 622  *
 623  * We match an entry using: ((real_id ^ match) & mask) == 0
 624  *
 625  * Writethrough caches generally only need 'on' and 'off'
 626  * methods.  Writeback caches _must_ have the flush method
 627  * defined.
 628  */
 629                 .align  2
 630                 .type   proc_types,#object
 631 proc_types:
 632                 .word   0x41560600              @ ARM6/610
 633                 .word   0xffffffe0
 634                 W(b)    __arm6_mmu_cache_off    @ works, but slow
 635                 W(b)    __arm6_mmu_cache_off
 636                 mov     pc, lr
 637  THUMB(         nop                             )
 638 @               b       __arm6_mmu_cache_on             @ untested
 639 @               b       __arm6_mmu_cache_off
 640 @               b       __armv3_mmu_cache_flush
 641
 642                 .word   0x00000000              @ old ARM ID
 643                 .word   0x0000f000
 644                 mov     pc, lr
 645  THUMB(         nop                             )
 646                 mov     pc, lr
 647  THUMB(         nop                             )
 648                 mov     pc, lr
 649  THUMB(         nop                             )
 650
 651                 .word   0x41007000              @ ARM7/710
 652                 .word   0xfff8fe00
 653                 W(b)    __arm7_mmu_cache_off
 654                 W(b)    __arm7_mmu_cache_off
 655                 mov     pc, lr
 656  THUMB(         nop                             )
 657
 658                 .word   0x41807200              @ ARM720T (writethrough)
 659                 .word   0xffffff00
 660                 W(b)    __armv4_mmu_cache_on
 661                 W(b)    __armv4_mmu_cache_off
 662                 mov     pc, lr
 663  THUMB(         nop                             )
 664
 665                 .word   0x41007400              @ ARM74x
 666                 .word   0xff00ff00
 667                 W(b)    __armv3_mpu_cache_on
 668                 W(b)    __armv3_mpu_cache_off
 669                 W(b)    __armv3_mpu_cache_flush
 670
 671                 .word   0x41009400              @ ARM94x
 672                 .word   0xff00ff00
 673                 W(b)    __armv4_mpu_cache_on
 674                 W(b)    __armv4_mpu_cache_off
 675                 W(b)    __armv4_mpu_cache_flush
 676
 677                 .word   0x00007000              @ ARM7 IDs
 678                 .word   0x0000f000
 679                 mov     pc, lr
 680  THUMB(         nop                             )
 681                 mov     pc, lr
 682  THUMB(         nop                             )
 683                 mov     pc, lr
 684  THUMB(         nop                             )
 685
 686                 @ Everything from here on will be the new ID system.
 687
 688                 .word   0x4401a100              @ sa110 / sa1100
 689                 .word   0xffffffe0
 690                 W(b)    __armv4_mmu_cache_on
 691                 W(b)    __armv4_mmu_cache_off
 692                 W(b)    __armv4_mmu_cache_flush
 693
 694                 .word   0x6901b110              @ sa1110
 695                 .word   0xfffffff0
 696                 W(b)    __armv4_mmu_cache_on
 697                 W(b)    __armv4_mmu_cache_off
 698                 W(b)    __armv4_mmu_cache_flush
 699
 700                 .word   0x56056900
 701                 .word   0xffffff00              @ PXA9xx
 702                 W(b)    __armv4_mmu_cache_on
 703                 W(b)    __armv4_mmu_cache_off
 704                 W(b)    __armv4_mmu_cache_flush
 705
 706                 .word   0x56158000              @ PXA168
 707                 .word   0xfffff000
 708                 W(b)    __armv4_mmu_cache_on
 709                 W(b)    __armv4_mmu_cache_off
 710                 W(b)    __armv5tej_mmu_cache_flush
 711
 712                 .word   0x56050000              @ Feroceon
 713                 .word   0xff0f0000
 714                 W(b)    __armv4_mmu_cache_on
 715                 W(b)    __armv4_mmu_cache_off
 716                 W(b)    __armv5tej_mmu_cache_flush
 717
 718 #ifdef CONFIG_CPU_FEROCEON_OLD_ID
 719                 /* this conflicts with the standard ARMv5TE entry */
 720                 .long   0x41009260              @ Old Feroceon
 721                 .long   0xff00fff0
 722                 b       __armv4_mmu_cache_on
 723                 b       __armv4_mmu_cache_off
 724                 b       __armv5tej_mmu_cache_flush
 725 #endif
 726
 727                 .word   0x66015261              @ FA526
 728                 .word   0xff01fff1
 729                 W(b)    __fa526_cache_on
 730                 W(b)    __armv4_mmu_cache_off
 731                 W(b)    __fa526_cache_flush
 732
 733                 @ These match on the architecture ID
 734
 735                 .word   0x00020000              @ ARMv4T
 736                 .word   0x000f0000
 737                 W(b)    __armv4_mmu_cache_on
 738                 W(b)    __armv4_mmu_cache_off
 739                 W(b)    __armv4_mmu_cache_flush
 740
 741                 .word   0x00050000              @ ARMv5TE
 742                 .word   0x000f0000
 743                 W(b)    __armv4_mmu_cache_on
 744                 W(b)    __armv4_mmu_cache_off
 745                 W(b)    __armv4_mmu_cache_flush
 746
 747                 .word   0x00060000              @ ARMv5TEJ
 748                 .word   0x000f0000
 749                 W(b)    __armv4_mmu_cache_on
 750                 W(b)    __armv4_mmu_cache_off
 751                 W(b)    __armv5tej_mmu_cache_flush
 752
 753                 .word   0x0007b000              @ ARMv6
 754                 .word   0x000ff000
 755                 W(b)    __armv4_mmu_cache_on
 756                 W(b)    __armv4_mmu_cache_off
 757                 W(b)    __armv6_mmu_cache_flush
 758
 759                 .word   0x560f5810              @ Marvell PJ4 ARMv6
 760                 .word   0xff0ffff0
 761                 W(b)    __armv4_mmu_cache_on
 762                 W(b)    __armv4_mmu_cache_off
 763                 W(b)    __armv6_mmu_cache_flush
 764
 765                 .word   0x000f0000              @ new CPU Id
 766                 .word   0x000f0000
 767                 W(b)    __armv7_mmu_cache_on
 768                 W(b)    __armv7_mmu_cache_off
 769                 W(b)    __armv7_mmu_cache_flush
 770
 771                 .word   0                       @ unrecognised type
 772                 .word   0
 773                 mov     pc, lr
 774  THUMB(         nop                             )
 775                 mov     pc, lr
 776  THUMB(         nop                             )
 777                 mov     pc, lr
 778  THUMB(         nop                             )
 779
 780                 .size   proc_types, . - proc_types
 781
 782 /*
 783  * Turn off the Cache and MMU.  ARMv3 does not support
 784  * reading the control register, but ARMv4 does.
 785  *
 786  * On exit,
 787  *  r0, r1, r2, r3, r9, r12 corrupted
 788  * This routine must preserve:
 789  *  r4, r6, r7
 790  */
 791                 .align  5
 792 cache_off:      mov     r3, #12                 @ cache_off function
 793                 b       call_cache_fn
 794
 795 __armv4_mpu_cache_off:
 796                 mrc     p15, 0, r0, c1, c0
 797                 bic     r0, r0, #0x000d
 798                 mcr     p15, 0, r0, c1, c0      @ turn MPU and cache off
 799                 mov     r0, #0
 800                 mcr     p15, 0, r0, c7, c10, 4  @ drain write buffer
 801                 mcr     p15, 0, r0, c7, c6, 0   @ flush D-Cache
 802                 mcr     p15, 0, r0, c7, c5, 0   @ flush I-Cache
 803                 mov     pc, lr
 804
 805 __armv3_mpu_cache_off:
 806                 mrc     p15, 0, r0, c1, c0
 807                 bic     r0, r0, #0x000d
 808                 mcr     p15, 0, r0, c1, c0, 0   @ turn MPU and cache off
 809                 mov     r0, #0
 810                 mcr     p15, 0, r0, c7, c0, 0   @ invalidate whole cache v3
 811                 mov     pc, lr
 812
 813 __armv4_mmu_cache_off:
 814 #ifdef CONFIG_MMU
 815                 mrc     p15, 0, r0, c1, c0
 816                 bic     r0, r0, #0x000d
 817                 mcr     p15, 0, r0, c1, c0      @ turn MMU and cache off
 818                 mov     r0, #0
 819                 mcr     p15, 0, r0, c7, c7      @ invalidate whole cache v4
 820                 mcr     p15, 0, r0, c8, c7      @ invalidate whole TLB v4
 821 #endif
 822                 mov     pc, lr
 823
 824 __armv7_mmu_cache_off:
 825                 mrc     p15, 0, r0, c1, c0
 826 #ifdef CONFIG_MMU
 827                 bic     r0, r0, #0x000d
 828 #else
 829                 bic     r0, r0, #0x000c
 830 #endif
 831                 mcr     p15, 0, r0, c1, c0      @ turn MMU and cache off
 832                 mov     r12, lr
 833                 bl      __armv7_mmu_cache_flush
 834                 mov     r0, #0
 835 #ifdef CONFIG_MMU
 836                 mcr     p15, 0, r0, c8, c7, 0   @ invalidate whole TLB
 837 #endif
 838                 mcr     p15, 0, r0, c7, c5, 6   @ invalidate BTC
 839                 mcr     p15, 0, r0, c7, c10, 4  @ DSB
 840                 mcr     p15, 0, r0, c7, c5, 4   @ ISB
 841                 mov     pc, r12
 842
 843 __arm6_mmu_cache_off:
 844                 mov     r0, #0x00000030         @ ARM6 control reg.
 845                 b       __armv3_mmu_cache_off
 846
 847 __arm7_mmu_cache_off:
 848                 mov     r0, #0x00000070         @ ARM7 control reg.
 849                 b       __armv3_mmu_cache_off
 850
 851 __armv3_mmu_cache_off:
 852                 mcr     p15, 0, r0, c1, c0, 0   @ turn MMU and cache off
 853                 mov     r0, #0
 854                 mcr     p15, 0, r0, c7, c0, 0   @ invalidate whole cache v3
 855                 mcr     p15, 0, r0, c5, c0, 0   @ invalidate whole TLB v3
 856                 mov     pc, lr
 857
 858 /*
 859  * Clean and flush the cache to maintain consistency.
 860  *
 861  * On exit,
 862  *  r1, r2, r3, r9, r10, r11, r12 corrupted
 863  * This routine must preserve:
 864  *  r0, r4, r5, r6, r7
 865  */
 866                 .align  5
 867 cache_clean_flush:
 868                 mov     r3, #16
 869                 b       call_cache_fn
 870
 871 __armv4_mpu_cache_flush:
 872                 mov     r2, #1
 873                 mov     r3, #0
 874                 mcr     p15, 0, ip, c7, c6, 0   @ invalidate D cache
 875                 mov     r1, #7 << 5             @ 8 segments
 876 1:              orr     r3, r1, #63 << 26       @ 64 entries
 877 2:              mcr     p15, 0, r3, c7, c14, 2  @ clean & invalidate D index
 878                 subs    r3, r3, #1 << 26
 879                 bcs     2b                      @ entries 63 to 0
 880                 subs    r1, r1, #1 << 5
 881                 bcs     1b                      @ segments 7 to 0
 882
 883                 teq     r2, #0
 884                 mcrne   p15, 0, ip, c7, c5, 0   @ invalidate I cache
 885                 mcr     p15, 0, ip, c7, c10, 4  @ drain WB
 886                 mov     pc, lr
 887
 888 __fa526_cache_flush:
 889                 mov     r1, #0
 890                 mcr     p15, 0, r1, c7, c14, 0  @ clean and invalidate D cache
 891                 mcr     p15, 0, r1, c7, c5, 0   @ flush I cache
 892                 mcr     p15, 0, r1, c7, c10, 4  @ drain WB
 893                 mov     pc, lr
 894
 895 __armv6_mmu_cache_flush:
 896                 mov     r1, #0
 897                 mcr     p15, 0, r1, c7, c14, 0  @ clean+invalidate D
 898                 mcr     p15, 0, r1, c7, c5, 0   @ invalidate I+BTB
 899                 mcr     p15, 0, r1, c7, c15, 0  @ clean+invalidate unified
 900                 mcr     p15, 0, r1, c7, c10, 4  @ drain WB
 901                 mov     pc, lr
 902
 903 __armv7_mmu_cache_flush:
 904                 mrc     p15, 0, r10, c0, c1, 5  @ read ID_MMFR1
 905                 tst     r10, #0xf << 16         @ hierarchical cache (ARMv7)
 906                 mov     r10, #0
 907                 beq     hierarchical
 908                 mcr     p15, 0, r10, c7, c14, 0 @ clean+invalidate D
 909                 b       iflush
 910 hierarchical:
 911                 mcr     p15, 0, r10, c7, c10, 5 @ DMB
 912                 stmfd   sp!, {r0-r7, r9-r11}
 913                 mrc     p15, 1, r0, c0, c0, 1   @ read clidr
 914                 ands    r3, r0, #0x7000000      @ extract loc from clidr
 915                 mov     r3, r3, lsr #23         @ left align loc bit field
 916                 beq     finished                @ if loc is 0, then no need to clean
 917                 mov     r10, #0                 @ start clean at cache level 0
 918 loop1:
 919                 add     r2, r10, r10, lsr #1    @ work out 3x current cache level
 920                 mov     r1, r0, lsr r2          @ extract cache type bits from clidr
 921                 and     r1, r1, #7              @ mask of the bits for current cache only
 922                 cmp     r1, #2                  @ see what cache we have at this level
 923                 blt     skip                    @ skip if no cache, or just i-cache
 924                 mcr     p15, 2, r10, c0, c0, 0  @ select current cache level in cssr
 925                 mcr     p15, 0, r10, c7, c5, 4  @ isb to sych the new cssr&csidr
 926                 mrc     p15, 1, r1, c0, c0, 0   @ read the new csidr
 927                 and     r2, r1, #7              @ extract the length of the cache lines
 928                 add     r2, r2, #4              @ add 4 (line length offset)
 929                 ldr     r4, =0x3ff
 930                 ands    r4, r4, r1, lsr #3      @ find maximum number on the way size
 931                 clz     r5, r4                  @ find bit position of way size increment
 932                 ldr     r7, =0x7fff
 933                 ands    r7, r7, r1, lsr #13     @ extract max number of the index size
 934 loop2:
 935                 mov     r9, r4                  @ create working copy of max way size
 936 loop3:
 937  ARM(           orr     r11, r10, r9, lsl r5    ) @ factor way and cache number into r11
 938  ARM(           orr     r11, r11, r7, lsl r2    ) @ factor index number into r11
 939  THUMB(         lsl     r6, r9, r5              )
 940  THUMB(         orr     r11, r10, r6            ) @ factor way and cache number into r11
 941  THUMB(         lsl     r6, r7, r2              )
 942  THUMB(         orr     r11, r11, r6            ) @ factor index number into r11
 943                 mcr     p15, 0, r11, c7, c14, 2 @ clean & invalidate by set/way
 944                 subs    r9, r9, #1              @ decrement the way
 945                 bge     loop3
 946                 subs    r7, r7, #1              @ decrement the index
 947                 bge     loop2
 948 skip:
 949                 add     r10, r10, #2            @ increment cache number
 950                 cmp     r3, r10
 951                 bgt     loop1
 952 finished:
 953                 ldmfd   sp!, {r0-r7, r9-r11}
 954                 mov     r10, #0                 @ swith back to cache level 0
 955                 mcr     p15, 2, r10, c0, c0, 0  @ select current cache level in cssr
 956 iflush:
 957                 mcr     p15, 0, r10, c7, c10, 4 @ DSB
 958                 mcr     p15, 0, r10, c7, c5, 0  @ invalidate I+BTB
 959                 mcr     p15, 0, r10, c7, c10, 4 @ DSB
 960                 mcr     p15, 0, r10, c7, c5, 4  @ ISB
 961                 mov     pc, lr
 962
 963 __armv5tej_mmu_cache_flush:
 964 1:              mrc     p15, 0, r15, c7, c14, 3 @ test,clean,invalidate D cache
 965                 bne     1b
 966                 mcr     p15, 0, r0, c7, c5, 0   @ flush I cache
 967                 mcr     p15, 0, r0, c7, c10, 4  @ drain WB
 968                 mov     pc, lr
 969
 970 __armv4_mmu_cache_flush:
 971                 mov     r2, #64*1024            @ default: 32K dcache size (*2)
 972                 mov     r11, #32                @ default: 32 byte line size
 973                 mrc     p15, 0, r3, c0, c0, 1   @ read cache type
 974                 teq     r3, r9                  @ cache ID register present?
 975                 beq     no_cache_id
 976                 mov     r1, r3, lsr #18
 977                 and     r1, r1, #7
 978                 mov     r2, #1024
 979                 mov     r2, r2, lsl r1          @ base dcache size *2
 980                 tst     r3, #1 << 14            @ test M bit
 981                 addne   r2, r2, r2, lsr #1      @ +1/2 size if M == 1
 982                 mov     r3, r3, lsr #12
 983                 and     r3, r3, #3
 984                 mov     r11, #8
 985                 mov     r11, r11, lsl r3        @ cache line size in bytes
 986 no_cache_id:
 987                 mov     r1, pc
 988                 bic     r1, r1, #63             @ align to longest cache line
 989                 add     r2, r1, r2
 990 1:
 991  ARM(           ldr     r3, [r1], r11           ) @ s/w flush D cache
 992  THUMB(         ldr     r3, [r1]                ) @ s/w flush D cache
 993  THUMB(         add     r1, r1, r11             )
 994                 teq     r1, r2
 995                 bne     1b
 996
 997                 mcr     p15, 0, r1, c7, c5, 0   @ flush I cache
 998                 mcr     p15, 0, r1, c7, c6, 0   @ flush D cache
 999                 mcr     p15, 0, r1, c7, c10, 4  @ drain WB
1000                 mov     pc, lr
1001
1002 __armv3_mmu_cache_flush:
1003 __armv3_mpu_cache_flush:
1004                 mov     r1, #0
1005                 mcr     p15, 0, r1, c7, c0, 0   @ invalidate whole cache v3
1006                 mov     pc, lr
1007
1008 /*
1009  * Various debugging routines for printing hex characters and
1010  * memory, which again must be relocatable.
1011  */
1012 #ifdef DEBUG
1013                 .align  2
1014                 .type   phexbuf,#object
1015 phexbuf:        .space  12
1016                 .size   phexbuf, . - phexbuf
1017
1018 @ phex corrupts {r0, r1, r2, r3}
1019 phex:           adr     r3, phexbuf
1020                 mov     r2, #0
1021                 strb    r2, [r3, r1]
1022 1:              subs    r1, r1, #1
1023                 movmi   r0, r3
1024                 bmi     puts
1025                 and     r2, r0, #15
1026                 mov     r0, r0, lsr #4
1027                 cmp     r2, #10
1028                 addge   r2, r2, #7
1029                 add     r2, r2, #'0'
1030                 strb    r2, [r3, r1]
1031                 b       1b
1032
1033 @ puts corrupts {r0, r1, r2, r3}
1034 puts:           loadsp  r3, r1
1035 1:              ldrb    r2, [r0], #1
1036                 teq     r2, #0
1037                 moveq   pc, lr
1038 2:              writeb  r2, r3
1039                 mov     r1, #0x00020000
1040 3:              subs    r1, r1, #1
1041                 bne     3b
1042                 teq     r2, #'\n'
1043                 moveq   r2, #'\r'
1044                 beq     2b
1045                 teq     r0, #0
1046                 bne     1b
1047                 mov     pc, lr
1048 @ putc corrupts {r0, r1, r2, r3}
1049 putc:
1050                 mov     r2, r0
1051                 mov     r0, #0
1052                 loadsp  r3, r1
1053                 b       2b
1054
1055 @ memdump corrupts {r0, r1, r2, r3, r10, r11, r12, lr}
1056 memdump:        mov     r12, r0
1057                 mov     r10, lr
1058                 mov     r11, #0
1059 2:              mov     r0, r11, lsl #2
1060                 add     r0, r0, r12
1061                 mov     r1, #8
1062                 bl      phex
1063                 mov     r0, #':'
1064                 bl      putc
1065 1:              mov     r0, #' '
1066                 bl      putc
1067                 ldr     r0, [r12, r11, lsl #2]
1068                 mov     r1, #8
1069                 bl      phex
1070                 and     r0, r11, #7
1071                 teq     r0, #3
1072                 moveq   r0, #' '
1073                 bleq    putc
1074                 and     r0, r11, #7
1075                 add     r11, r11, #1
1076                 teq     r0, #7
1077                 bne     1b
1078                 mov     r0, #'\n'
1079                 bl      putc
1080                 cmp     r11, #64
1081                 blt     2b
1082                 mov     pc, r10
1083 #endif
1084
1085                 .ltorg
1086 reloc_end:
1087
1088                 .align
1089                 .section ".stack", "aw", %nobits
1090 user_stack:     .space  4096
1091 user_stack_end: