arch/arm/cpu/arm1136/u-boot.lds

   1 /*
   2  * (C) Copyright 2009
   3  * Ilya Yanok, Emcraft Systems Ltd, <yanok@emcraft.com>
   4  *
   5  * Copyright (C) 2005-2007 Samsung Electronics
   6  * Kyungin Park <kyugnmin.park@samsung.com>
   7  *
   8  * Copyright (c) 2004 Texas Instruments
   9  *
  10  * (C) Copyright 2002
  11  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
  12  *
  13  * See file CREDITS for list of people who contributed to this
  14  * project.
  15  *
  16  * This program is free software; you can redistribute it and/or
  17  * modify it under the terms of the GNU General Public License as
  18  * published by the Free Software Foundation; either version 2 of
  19  * the License, or (at your option) any later version.
  20  *
  21  * This program is distributed in the hope that it will be useful,
  22  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  23  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24  * GNU General Public License for more details.
  25  *
  26  * You should have received a copy of the GNU General Public License
  27  * along with this program; if not, write to the Free Software
  28  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  29  * MA 02111-1307 USA
  30  */
  31
  32 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  33 OUTPUT_ARCH(arm)
  34 ENTRY(_start)
  35 SECTIONS
  36 {
  37         . = 0x00000000;
  38
  39         . = ALIGN(4);
  40         .text :
  41         {
  42                 arch/arm/cpu/arm1136/start.o    (.text)
  43                 *(.text)
  44         }
  45
  46         . = ALIGN(4);
  47         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  48
  49         . = ALIGN(4);
  50         .data : {
  51                 *(.data)
  52         __datarel_start = .;
  53                 *(.data.rel)
  54         __datarelrolocal_start = .;
  55                 *(.data.rel.ro.local)
  56         __datarellocal_start = .;
  57                 *(.data.rel.local)
  58         __datarelro_start = .;
  59                 *(.data.rel.ro)
  60         }
  61
  62         . = ALIGN(4);
  63         __rel_dyn_start = .;
  64         .rel.dyn : { *(.rel.dyn) }
  65         __rel_dyn_end = .;
  66
  67         __dynsym_start = .;
  68         .dynsym : { *(.dynsym) }
  69
  70         . = .;
  71         __u_boot_cmd_start = .;
  72         .u_boot_cmd : { *(.u_boot_cmd) }
  73         __u_boot_cmd_end = .;
  74
  75         . = ALIGN(4);
  76         __bss_start = .;
  77         .bss (NOLOAD) : { *(.bss) . = ALIGN(4); }
  78         _end = .;
  79
  80         /DISCARD/ : { *(.dynstr*) }
  81         /DISCARD/ : { *(.dynamic*) }
  82         /DISCARD/ : { *(.plt*) }
  83         /DISCARD/ : { *(.interp*) }
  84         /DISCARD/ : { *(.gnu*) }
  85 }