arch/arm/cpu/armv7/mx51/u-boot.lds

   1 /*
   2  * January 2004 - Changed to support H4 device
   3  * Copyright (c) 2004 Texas Instruments
   4  *
   5  * (C) Copyright 2002
   6  * Gary Jennejohn, DENX Software Engineering, <gj@denx.de>
   7  *
   8  * (C) Copyright 2009 Freescale Semiconductor, Inc.
   9  *
  10  * See file CREDITS for list of people who contributed to this
  11  * project.
  12  *
  13  * This program is free software; you can redistribute it and/or
  14  * modify it under the terms of the GNU General Public License as
  15  * published by the Free Software Foundation; either version 2 of
  16  * the License, or (at your option) any later version.
  17  *
  18  * This program is distributed in the hope that it will be useful,
  19  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  20  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21  * GNU General Public License for more details.
  22  *
  23  * You should have received a copy of the GNU General Public License
  24  * along with this program; if not, write to the Free Software
  25  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  26  * MA 02111-1307 USA
  27  */
  28
  29 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  30 OUTPUT_ARCH(arm)
  31 ENTRY(_start)
  32 SECTIONS
  33 {
  34         . = 0x00000000;
  35
  36         . = ALIGN(4);
  37         .text      :
  38         {
  39           arch/arm/cpu/armv7/start.o
  40           *(.text)
  41         }
  42
  43         . = ALIGN(4);
  44         .rodata : { *(.rodata) }
  45
  46         . = ALIGN(4);
  47         .data : {
  48                 *(.data)
  49         __datarel_start = .;
  50                 *(.data.rel)
  51         __datarelrolocal_start = .;
  52                 *(.data.rel.ro.local)
  53         __datarellocal_start = .;
  54                 *(.data.rel.local)
  55         __datarelro_start = .;
  56                 *(.data.rel.ro)
  57         }
  58
  59         __got_start = .;
  60         . = ALIGN(4);
  61         .got : { *(.got) }
  62         __got_end = .;
  63
  64         . = .;
  65         __u_boot_cmd_start = .;
  66         .u_boot_cmd : { *(.u_boot_cmd) }
  67         __u_boot_cmd_end = .;
  68
  69         . = ALIGN(4);
  70         __bss_start = .;
  71         .bss : { *(.bss) }
  72         _end = .;
  73 }