arch/arm/kernel/entry-armv.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-armv.S
   3  *
   4  *  Copyright (C) 1996,1997,1998 Russell King.
   5  *  ARM700 fix by Matthew Godbolt (linux-user@willothewisp.demon.co.uk)
   6  *  nommu support by Hyok S. Choi (hyok.choi@samsung.com)
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  *  Low-level vector interface routines
  13  *
  14  *  Note:  there is a StrongARM bug in the STMIA rn, {regs}^ instruction
  15  *  that causes it to save wrong values...  Be aware!
  16  */
  17
  18 #include <asm/memory.h>
  19 #include <asm/glue.h>
  20 #include <asm/vfpmacros.h>
  21 #include <mach/entry-macro.S>
  22 #include <asm/thread_notify.h>
  23 #include <asm/unwind.h>
  24 #include <asm/unistd.h>
  25
  26 #include "entry-header.S"
  27
  28 /*
  29  * Interrupt handling.  Preserves r7, r8, r9
  30  */
  31         .macro  irq_handler
  32         get_irqnr_preamble r5, lr
  33 1:      get_irqnr_and_base r0, r6, r5, lr
  34         movne   r1, sp
  35         @
  36         @ routine called with r0 = irq number, r1 = struct pt_regs *
  37         @
  38         adrne   lr, BSYM(1b)
  39         bne     asm_do_IRQ
  40
  41 #ifdef CONFIG_SMP
  42         /*
  43          * XXX
  44          *
  45          * this macro assumes that irqstat (r6) and base (r5) are
  46          * preserved from get_irqnr_and_base above
  47          */
  48         test_for_ipi r0, r6, r5, lr
  49         movne   r0, sp
  50         adrne   lr, BSYM(1b)
  51         bne     do_IPI
  52
  53 #ifdef CONFIG_LOCAL_TIMERS
  54         test_for_ltirq r0, r6, r5, lr
  55         movne   r0, sp
  56         adrne   lr, BSYM(1b)
  57         bne     do_local_timer
  58 #endif
  59 #endif
  60
  61         .endm
  62
  63 #ifdef CONFIG_KPROBES
  64         .section        .kprobes.text,"ax",%progbits
  65 #else
  66         .text
  67 #endif
  68
  69 /*
  70  * Invalid mode handlers
  71  */
  72         .macro  inv_entry, reason
  73         sub     sp, sp, #S_FRAME_SIZE
  74  ARM(   stmib   sp, {r1 - lr}           )
  75  THUMB( stmia   sp, {r0 - r12}          )
  76  THUMB( str     sp, [sp, #S_SP]         )
  77  THUMB( str     lr, [sp, #S_LR]         )
  78         mov     r1, #\reason
  79         .endm
  80
  81 __pabt_invalid:
  82         inv_entry BAD_PREFETCH
  83         b       common_invalid
  84 ENDPROC(__pabt_invalid)
  85
  86 __dabt_invalid:
  87         inv_entry BAD_DATA
  88         b       common_invalid
  89 ENDPROC(__dabt_invalid)
  90
  91 __irq_invalid:
  92         inv_entry BAD_IRQ
  93         b       common_invalid
  94 ENDPROC(__irq_invalid)
  95
  96 __und_invalid:
  97         inv_entry BAD_UNDEFINSTR
  98
  99         @
 100         @ XXX fall through to common_invalid
 101         @
 102
 103 @
 104 @ common_invalid - generic code for failed exception (re-entrant version of handlers)
 105 @
 106 common_invalid:
 107         zero_fp
 108
 109         ldmia   r0, {r4 - r6}
 110         add     r0, sp, #S_PC           @ here for interlock avoidance
 111         mov     r7, #-1                 @  ""   ""    ""        ""
 112         str     r4, [sp]                @ save preserved r0
 113         stmia   r0, {r5 - r7}           @ lr_<exception>,
 114                                         @ cpsr_<exception>, "old_r0"
 115
 116         mov     r0, sp
 117         b       bad_mode
 118 ENDPROC(__und_invalid)
 119
 120 /*
 121  * SVC mode handlers
 122  */
 123
 124 #if defined(CONFIG_AEABI) && (__LINUX_ARM_ARCH__ >= 5)
 125 #define SPFIX(code...) code
 126 #else
 127 #define SPFIX(code...)
 128 #endif
 129
 130         .macro  svc_entry, stack_hole=0
 131  UNWIND(.fnstart                )
 132  UNWIND(.save {r0 - pc}         )
 133         sub     sp, sp, #(S_FRAME_SIZE + \stack_hole - 4)
 134 #ifdef CONFIG_THUMB2_KERNEL
 135  SPFIX( str     r0, [sp]        )       @ temporarily saved
 136  SPFIX( mov     r0, sp          )
 137  SPFIX( tst     r0, #4          )       @ test original stack alignment
 138  SPFIX( ldr     r0, [sp]        )       @ restored
 139 #else
 140  SPFIX( tst     sp, #4          )
 141 #endif
 142  SPFIX( subeq   sp, sp, #4      )
 143         stmia   sp, {r1 - r12}
 144
 145         ldmia   r0, {r1 - r3}
 146         add     r5, sp, #S_SP - 4       @ here for interlock avoidance
 147         mov     r4, #-1                 @  ""  ""      ""       ""
 148         add     r0, sp, #(S_FRAME_SIZE + \stack_hole - 4)
 149  SPFIX( addeq   r0, r0, #4      )
 150         str     r1, [sp, #-4]!          @ save the "real" r0 copied
 151                                         @ from the exception stack
 152
 153         mov     r1, lr
 154
 155         @
 156         @ We are now ready to fill in the remaining blanks on the stack:
 157         @
 158         @  r0 - sp_svc
 159         @  r1 - lr_svc
 160         @  r2 - lr_<exception>, already fixed up for correct return/restart
 161         @  r3 - spsr_<exception>
 162         @  r4 - orig_r0 (see pt_regs definition in ptrace.h)
 163         @
 164         stmia   r5, {r0 - r4}
 165         .endm
 166
 167         .align  5
 168 __dabt_svc:
 169         svc_entry
 170
 171         @
 172         @ get ready to re-enable interrupts if appropriate
 173         @
 174         mrs     r9, cpsr
 175         tst     r3, #PSR_I_BIT
 176         biceq   r9, r9, #PSR_I_BIT
 177
 178         @
 179         @ Call the processor-specific abort handler:
 180         @
 181         @  r2 - aborted context pc
 182         @  r3 - aborted context cpsr
 183         @
 184         @ The abort handler must return the aborted address in r0, and
 185         @ the fault status register in r1.  r9 must be preserved.
 186         @
 187 #ifdef MULTI_DABORT
 188         ldr     r4, .LCprocfns
 189         mov     lr, pc
 190         ldr     pc, [r4, #PROCESSOR_DABT_FUNC]
 191 #else
 192         bl      CPU_DABORT_HANDLER
 193 #endif
 194
 195         @
 196         @ set desired IRQ state, then call main handler
 197         @
 198         msr     cpsr_c, r9
 199         mov     r2, sp
 200         bl      do_DataAbort
 201
 202         @
 203         @ IRQs off again before pulling preserved data off the stack
 204         @
 205         disable_irq_notrace
 206
 207         @
 208         @ restore SPSR and restart the instruction
 209         @
 210         ldr     r2, [sp, #S_PSR]
 211         svc_exit r2                             @ return from exception
 212  UNWIND(.fnend          )
 213 ENDPROC(__dabt_svc)
 214
 215         .align  5
 216 __irq_svc:
 217         svc_entry
 218
 219 #ifdef CONFIG_TRACE_IRQFLAGS
 220         bl      trace_hardirqs_off
 221 #endif
 222 #ifdef CONFIG_PREEMPT
 223         get_thread_info tsk
 224         ldr     r8, [tsk, #TI_PREEMPT]          @ get preempt count
 225         add     r7, r8, #1                      @ increment it
 226         str     r7, [tsk, #TI_PREEMPT]
 227 #endif
 228
 229         irq_handler
 230 #ifdef CONFIG_PREEMPT
 231         str     r8, [tsk, #TI_PREEMPT]          @ restore preempt count
 232         ldr     r0, [tsk, #TI_FLAGS]            @ get flags
 233         teq     r8, #0                          @ if preempt count != 0
 234         movne   r0, #0                          @ force flags to 0
 235         tst     r0, #_TIF_NEED_RESCHED
 236         blne    svc_preempt
 237 #endif
 238         ldr     r4, [sp, #S_PSR]                @ irqs are already disabled
 239 #ifdef CONFIG_TRACE_IRQFLAGS
 240         tst     r4, #PSR_I_BIT
 241         bleq    trace_hardirqs_on
 242 #endif
 243         svc_exit r4                             @ return from exception
 244  UNWIND(.fnend          )
 245 ENDPROC(__irq_svc)
 246
 247         .ltorg
 248
 249 #ifdef CONFIG_PREEMPT
 250 svc_preempt:
 251         mov     r8, lr
 252 1:      bl      preempt_schedule_irq            @ irq en/disable is done inside
 253         ldr     r0, [tsk, #TI_FLAGS]            @ get new tasks TI_FLAGS
 254         tst     r0, #_TIF_NEED_RESCHED
 255         moveq   pc, r8                          @ go again
 256         b       1b
 257 #endif
 258
 259         .align  5
 260 __und_svc:
 261 #ifdef CONFIG_KPROBES
 262         @ If a kprobe is about to simulate a "stmdb sp..." instruction,
 263         @ it obviously needs free stack space which then will belong to
 264         @ the saved context.
 265         svc_entry 64
 266 #else
 267         svc_entry
 268 #endif
 269
 270         @
 271         @ call emulation code, which returns using r9 if it has emulated
 272         @ the instruction, or the more conventional lr if we are to treat
 273         @ this as a real undefined instruction
 274         @
 275         @  r0 - instruction
 276         @
 277 #ifndef CONFIG_THUMB2_KERNEL
 278         ldr     r0, [r2, #-4]
 279 #else
 280         ldrh    r0, [r2, #-2]                   @ Thumb instruction at LR - 2
 281         and     r9, r0, #0xf800
 282         cmp     r9, #0xe800                     @ 32-bit instruction if xx >= 0
 283         ldrhhs  r9, [r2]                        @ bottom 16 bits
 284         orrhs   r0, r9, r0, lsl #16
 285 #endif
 286         adr     r9, BSYM(1f)
 287         bl      call_fpe
 288
 289         mov     r0, sp                          @ struct pt_regs *regs
 290         bl      do_undefinstr
 291
 292         @
 293         @ IRQs off again before pulling preserved data off the stack
 294         @
 295 1:      disable_irq_notrace
 296
 297         @
 298         @ restore SPSR and restart the instruction
 299         @
 300         ldr     r2, [sp, #S_PSR]                @ Get SVC cpsr
 301         svc_exit r2                             @ return from exception
 302  UNWIND(.fnend          )
 303 ENDPROC(__und_svc)
 304
 305         .align  5
 306 __pabt_svc:
 307         svc_entry
 308
 309         @
 310         @ re-enable interrupts if appropriate
 311         @
 312         mrs     r9, cpsr
 313         tst     r3, #PSR_I_BIT
 314         biceq   r9, r9, #PSR_I_BIT
 315
 316         mov     r0, r2                  @ pass address of aborted instruction.
 317 #ifdef MULTI_PABORT
 318         ldr     r4, .LCprocfns
 319         mov     lr, pc
 320         ldr     pc, [r4, #PROCESSOR_PABT_FUNC]
 321 #else
 322         bl      CPU_PABORT_HANDLER
 323 #endif
 324         msr     cpsr_c, r9                      @ Maybe enable interrupts
 325         mov     r2, sp                          @ regs
 326         bl      do_PrefetchAbort                @ call abort handler
 327
 328         @
 329         @ IRQs off again before pulling preserved data off the stack
 330         @
 331         disable_irq_notrace
 332
 333         @
 334         @ restore SPSR and restart the instruction
 335         @
 336         ldr     r2, [sp, #S_PSR]
 337         svc_exit r2                             @ return from exception
 338  UNWIND(.fnend          )
 339 ENDPROC(__pabt_svc)
 340
 341         .align  5
 342 .LCcralign:
 343         .word   cr_alignment
 344 #ifdef MULTI_DABORT
 345 .LCprocfns:
 346         .word   processor
 347 #endif
 348 .LCfp:
 349         .word   fp_enter
 350
 351 /*
 352  * User mode handlers
 353  *
 354  * EABI note: sp_svc is always 64-bit aligned here, so should S_FRAME_SIZE
 355  */
 356
 357 #if defined(CONFIG_AEABI) && (__LINUX_ARM_ARCH__ >= 5) && (S_FRAME_SIZE & 7)
 358 #error "sizeof(struct pt_regs) must be a multiple of 8"
 359 #endif
 360
 361         .macro  usr_entry
 362  UNWIND(.fnstart        )
 363  UNWIND(.cantunwind     )       @ don't unwind the user space
 364         sub     sp, sp, #S_FRAME_SIZE
 365  ARM(   stmib   sp, {r1 - r12}  )
 366  THUMB( stmia   sp, {r0 - r12}  )
 367
 368         ldmia   r0, {r1 - r3}
 369         add     r0, sp, #S_PC           @ here for interlock avoidance
 370         mov     r4, #-1                 @  ""  ""     ""        ""
 371
 372         str     r1, [sp]                @ save the "real" r0 copied
 373                                         @ from the exception stack
 374
 375         @
 376         @ We are now ready to fill in the remaining blanks on the stack:
 377         @
 378         @  r2 - lr_<exception>, already fixed up for correct return/restart
 379         @  r3 - spsr_<exception>
 380         @  r4 - orig_r0 (see pt_regs definition in ptrace.h)
 381         @
 382         @ Also, separately save sp_usr and lr_usr
 383         @
 384         stmia   r0, {r2 - r4}
 385  ARM(   stmdb   r0, {sp, lr}^                   )
 386  THUMB( store_user_sp_lr r0, r1, S_SP - S_PC    )
 387
 388         @
 389         @ Enable the alignment trap while in kernel mode
 390         @
 391         alignment_trap r0
 392
 393         @
 394         @ Clear FP to mark the first stack frame
 395         @
 396         zero_fp
 397         .endm
 398
 399         .macro  kuser_cmpxchg_check
 400 #if __LINUX_ARM_ARCH__ < 6 && !defined(CONFIG_NEEDS_SYSCALL_FOR_CMPXCHG)
 401 #ifndef CONFIG_MMU
 402 #warning "NPTL on non MMU needs fixing"
 403 #else
 404         @ Make sure our user space atomic helper is restarted
 405         @ if it was interrupted in a critical region.  Here we
 406         @ perform a quick test inline since it should be false
 407         @ 99.9999% of the time.  The rest is done out of line.
 408         cmp     r2, #TASK_SIZE
 409         blhs    kuser_cmpxchg_fixup
 410 #endif
 411 #endif
 412         .endm
 413
 414         .align  5
 415 __dabt_usr:
 416         usr_entry
 417         kuser_cmpxchg_check
 418
 419         @
 420         @ Call the processor-specific abort handler:
 421         @
 422         @  r2 - aborted context pc
 423         @  r3 - aborted context cpsr
 424         @
 425         @ The abort handler must return the aborted address in r0, and
 426         @ the fault status register in r1.
 427         @
 428 #ifdef MULTI_DABORT
 429         ldr     r4, .LCprocfns
 430         mov     lr, pc
 431         ldr     pc, [r4, #PROCESSOR_DABT_FUNC]
 432 #else
 433         bl      CPU_DABORT_HANDLER
 434 #endif
 435
 436         @
 437         @ IRQs on, then call the main handler
 438         @
 439         enable_irq
 440         mov     r2, sp
 441         adr     lr, BSYM(ret_from_exception)
 442         b       do_DataAbort
 443  UNWIND(.fnend          )
 444 ENDPROC(__dabt_usr)
 445
 446         .align  5
 447 __irq_usr:
 448         usr_entry
 449         kuser_cmpxchg_check
 450
 451         get_thread_info tsk
 452 #ifdef CONFIG_PREEMPT
 453         ldr     r8, [tsk, #TI_PREEMPT]          @ get preempt count
 454         add     r7, r8, #1                      @ increment it
 455         str     r7, [tsk, #TI_PREEMPT]
 456 #endif
 457
 458         irq_handler
 459 #ifdef CONFIG_PREEMPT
 460         ldr     r0, [tsk, #TI_PREEMPT]
 461         str     r8, [tsk, #TI_PREEMPT]
 462         teq     r0, r7
 463  ARM(   strne   r0, [r0, -r0]   )
 464  THUMB( movne   r0, #0          )
 465  THUMB( strne   r0, [r0]        )
 466 #endif
 467
 468         mov     why, #0
 469         b       ret_to_user
 470  UNWIND(.fnend          )
 471 ENDPROC(__irq_usr)
 472
 473         .ltorg
 474
 475         .align  5
 476 __und_usr:
 477         usr_entry
 478
 479         @
 480         @ fall through to the emulation code, which returns using r9 if
 481         @ it has emulated the instruction, or the more conventional lr
 482         @ if we are to treat this as a real undefined instruction
 483         @
 484         @  r0 - instruction
 485         @
 486         adr     r9, BSYM(ret_from_exception)
 487         adr     lr, BSYM(__und_usr_unknown)
 488         tst     r3, #PSR_T_BIT                  @ Thumb mode?
 489         itet    eq                              @ explicit IT needed for the 1f label
 490         subeq   r4, r2, #4                      @ ARM instr at LR - 4
 491         subne   r4, r2, #2                      @ Thumb instr at LR - 2
 492 1:      ldreqt  r0, [r4]
 493 #ifdef CONFIG_CPU_ENDIAN_BE8
 494         reveq   r0, r0                          @ little endian instruction
 495 #endif
 496         beq     call_fpe
 497         @ Thumb instruction
 498 #if __LINUX_ARM_ARCH__ >= 7
 499 2:
 500  ARM(   ldrht   r5, [r4], #2    )
 501  THUMB( ldrht   r5, [r4]        )
 502  THUMB( add     r4, r4, #2      )
 503         and     r0, r5, #0xf800                 @ mask bits 111x x... .... ....
 504         cmp     r0, #0xe800                     @ 32bit instruction if xx != 0
 505         blo     __und_usr_unknown
 506 3:      ldrht   r0, [r4]
 507         add     r2, r2, #2                      @ r2 is PC + 2, make it PC + 4
 508         orr     r0, r0, r5, lsl #16
 509 #else
 510         b       __und_usr_unknown
 511 #endif
 512  UNWIND(.fnend          )
 513 ENDPROC(__und_usr)
 514
 515         @
 516         @ fallthrough to call_fpe
 517         @
 518
 519 /*
 520  * The out of line fixup for the ldrt above.
 521  */
 522         .pushsection .fixup, "ax"
 523 4:      mov     pc, r9
 524         .popsection
 525         .pushsection __ex_table,"a"
 526         .long   1b, 4b
 527 #if __LINUX_ARM_ARCH__ >= 7
 528         .long   2b, 4b
 529         .long   3b, 4b
 530 #endif
 531         .popsection
 532
 533 /*
 534  * Check whether the instruction is a co-processor instruction.
 535  * If yes, we need to call the relevant co-processor handler.
 536  *
 537  * Note that we don't do a full check here for the co-processor
 538  * instructions; all instructions with bit 27 set are well
 539  * defined.  The only instructions that should fault are the
 540  * co-processor instructions.  However, we have to watch out
 541  * for the ARM6/ARM7 SWI bug.
 542  *
 543  * NEON is a special case that has to be handled here. Not all
 544  * NEON instructions are co-processor instructions, so we have
 545  * to make a special case of checking for them. Plus, there's
 546  * five groups of them, so we have a table of mask/opcode pairs
 547  * to check against, and if any match then we branch off into the
 548  * NEON handler code.
 549  *
 550  * Emulators may wish to make use of the following registers:
 551  *  r0  = instruction opcode.
 552  *  r2  = PC+4
 553  *  r9  = normal "successful" return address
 554  *  r10 = this threads thread_info structure.
 555  *  lr  = unrecognised instruction return address
 556  */
 557         @
 558         @ Fall-through from Thumb-2 __und_usr
 559         @
 560 #ifdef CONFIG_NEON
 561         adr     r6, .LCneon_thumb_opcodes
 562         b       2f
 563 #endif
 564 call_fpe:
 565 #ifdef CONFIG_NEON
 566         adr     r6, .LCneon_arm_opcodes
 567 2:
 568         ldr     r7, [r6], #4                    @ mask value
 569         cmp     r7, #0                          @ end mask?
 570         beq     1f
 571         and     r8, r0, r7
 572         ldr     r7, [r6], #4                    @ opcode bits matching in mask
 573         cmp     r8, r7                          @ NEON instruction?
 574         bne     2b
 575         get_thread_info r10
 576         mov     r7, #1
 577         strb    r7, [r10, #TI_USED_CP + 10]     @ mark CP#10 as used
 578         strb    r7, [r10, #TI_USED_CP + 11]     @ mark CP#11 as used
 579         b       do_vfp                          @ let VFP handler handle this
 580 1:
 581 #endif
 582         tst     r0, #0x08000000                 @ only CDP/CPRT/LDC/STC have bit 27
 583         tstne   r0, #0x04000000                 @ bit 26 set on both ARM and Thumb-2
 584 #if defined(CONFIG_CPU_ARM610) || defined(CONFIG_CPU_ARM710)
 585         and     r8, r0, #0x0f000000             @ mask out op-code bits
 586         teqne   r8, #0x0f000000                 @ SWI (ARM6/7 bug)?
 587 #endif
 588         moveq   pc, lr
 589         get_thread_info r10                     @ get current thread
 590         and     r8, r0, #0x00000f00             @ mask out CP number
 591  THUMB( lsr     r8, r8, #8              )
 592         mov     r7, #1
 593         add     r6, r10, #TI_USED_CP
 594  ARM(   strb    r7, [r6, r8, lsr #8]    )       @ set appropriate used_cp[]
 595  THUMB( strb    r7, [r6, r8]            )       @ set appropriate used_cp[]
 596 #ifdef CONFIG_IWMMXT
 597         @ Test if we need to give access to iWMMXt coprocessors
 598         ldr     r5, [r10, #TI_FLAGS]
 599         rsbs    r7, r8, #(1 << 8)               @ CP 0 or 1 only
 600         movcss  r7, r5, lsr #(TIF_USING_IWMMXT + 1)
 601         bcs     iwmmxt_task_enable
 602 #endif
 603  ARM(   add     pc, pc, r8, lsr #6      )
 604  THUMB( lsl     r8, r8, #2              )
 605  THUMB( add     pc, r8                  )
 606         nop
 607
 608         movw_pc lr                              @ CP#0
 609         W(b)    do_fpe                          @ CP#1 (FPE)
 610         W(b)    do_fpe                          @ CP#2 (FPE)
 611         movw_pc lr                              @ CP#3
 612 #ifdef CONFIG_CRUNCH
 613         b       crunch_task_enable              @ CP#4 (MaverickCrunch)
 614         b       crunch_task_enable              @ CP#5 (MaverickCrunch)
 615         b       crunch_task_enable              @ CP#6 (MaverickCrunch)
 616 #else
 617         movw_pc lr                              @ CP#4
 618         movw_pc lr                              @ CP#5
 619         movw_pc lr                              @ CP#6
 620 #endif
 621         movw_pc lr                              @ CP#7
 622         movw_pc lr                              @ CP#8
 623         movw_pc lr                              @ CP#9
 624 #ifdef CONFIG_VFP
 625         W(b)    do_vfp                          @ CP#10 (VFP)
 626         W(b)    do_vfp                          @ CP#11 (VFP)
 627 #else
 628         movw_pc lr                              @ CP#10 (VFP)
 629         movw_pc lr                              @ CP#11 (VFP)
 630 #endif
 631         movw_pc lr                              @ CP#12
 632         movw_pc lr                              @ CP#13
 633         movw_pc lr                              @ CP#14 (Debug)
 634         movw_pc lr                              @ CP#15 (Control)
 635
 636 #ifdef CONFIG_NEON
 637         .align  6
 638
 639 .LCneon_arm_opcodes:
 640         .word   0xfe000000                      @ mask
 641         .word   0xf2000000                      @ opcode
 642
 643         .word   0xff100000                      @ mask
 644         .word   0xf4000000                      @ opcode
 645
 646         .word   0x00000000                      @ mask
 647         .word   0x00000000                      @ opcode
 648
 649 .LCneon_thumb_opcodes:
 650         .word   0xef000000                      @ mask
 651         .word   0xef000000                      @ opcode
 652
 653         .word   0xff100000                      @ mask
 654         .word   0xf9000000                      @ opcode
 655
 656         .word   0x00000000                      @ mask
 657         .word   0x00000000                      @ opcode
 658 #endif
 659
 660 do_fpe:
 661         enable_irq
 662         ldr     r4, .LCfp
 663         add     r10, r10, #TI_FPSTATE           @ r10 = workspace
 664         ldr     pc, [r4]                        @ Call FP module USR entry point
 665
 666 /*
 667  * The FP module is called with these registers set:
 668  *  r0  = instruction
 669  *  r2  = PC+4
 670  *  r9  = normal "successful" return address
 671  *  r10 = FP workspace
 672  *  lr  = unrecognised FP instruction return address
 673  */
 674
 675         .pushsection .data
 676 ENTRY(fp_enter)
 677         .word   no_fp
 678         .popsection
 679
 680 ENTRY(no_fp)
 681         mov     pc, lr
 682 ENDPROC(no_fp)
 683
 684 __und_usr_unknown:
 685         enable_irq
 686         mov     r0, sp
 687         adr     lr, BSYM(ret_from_exception)
 688         b       do_undefinstr
 689 ENDPROC(__und_usr_unknown)
 690
 691         .align  5
 692 __pabt_usr:
 693         usr_entry
 694
 695         mov     r0, r2                  @ pass address of aborted instruction.
 696 #ifdef MULTI_PABORT
 697         ldr     r4, .LCprocfns
 698         mov     lr, pc
 699         ldr     pc, [r4, #PROCESSOR_PABT_FUNC]
 700 #else
 701         bl      CPU_PABORT_HANDLER
 702 #endif
 703         enable_irq                              @ Enable interrupts
 704         mov     r2, sp                          @ regs
 705         bl      do_PrefetchAbort                @ call abort handler
 706  UNWIND(.fnend          )
 707         /* fall through */
 708 /*
 709  * This is the return code to user mode for abort handlers
 710  */
 711 ENTRY(ret_from_exception)
 712  UNWIND(.fnstart        )
 713  UNWIND(.cantunwind     )
 714         get_thread_info tsk
 715         mov     why, #0
 716         b       ret_to_user
 717  UNWIND(.fnend          )
 718 ENDPROC(__pabt_usr)
 719 ENDPROC(ret_from_exception)
 720
 721 /*
 722  * Register switch for ARMv3 and ARMv4 processors
 723  * r0 = previous task_struct, r1 = previous thread_info, r2 = next thread_info
 724  * previous and next are guaranteed not to be the same.
 725  */
 726 ENTRY(__switch_to)
 727  UNWIND(.fnstart        )
 728  UNWIND(.cantunwind     )
 729         add     ip, r1, #TI_CPU_SAVE
 730         ldr     r3, [r2, #TI_TP_VALUE]
 731  ARM(   stmia   ip!, {r4 - sl, fp, sp, lr} )    @ Store most regs on stack
 732  THUMB( stmia   ip!, {r4 - sl, fp}         )    @ Store most regs on stack
 733  THUMB( str     sp, [ip], #4               )
 734  THUMB( str     lr, [ip], #4               )
 735 #ifdef CONFIG_MMU
 736         ldr     r6, [r2, #TI_CPU_DOMAIN]
 737 #endif
 738 #if defined(CONFIG_HAS_TLS_REG)
 739         mcr     p15, 0, r3, c13, c0, 3          @ set TLS register
 740 #elif !defined(CONFIG_TLS_REG_EMUL)
 741         mov     r4, #0xffff0fff
 742         str     r3, [r4, #-15]                  @ TLS val at 0xffff0ff0
 743 #endif
 744 #if defined(CONFIG_CC_STACKPROTECTOR) && !defined(CONFIG_SMP)
 745         ldr     r7, [r2, #TI_TASK]
 746         ldr     r8, =__stack_chk_guard
 747         ldr     r7, [r7, #TSK_STACK_CANARY]
 748 #endif
 749 #ifdef CONFIG_MMU
 750         mcr     p15, 0, r6, c3, c0, 0           @ Set domain register
 751 #endif
 752         mov     r5, r0
 753         add     r4, r2, #TI_CPU_SAVE
 754         ldr     r0, =thread_notify_head
 755         mov     r1, #THREAD_NOTIFY_SWITCH
 756         bl      atomic_notifier_call_chain
 757 #if defined(CONFIG_CC_STACKPROTECTOR) && !defined(CONFIG_SMP)
 758         str     r7, [r8]
 759 #endif
 760  THUMB( mov     ip, r4                     )
 761         mov     r0, r5
 762  ARM(   ldmia   r4, {r4 - sl, fp, sp, pc}  )    @ Load all regs saved previously
 763  THUMB( ldmia   ip!, {r4 - sl, fp}         )    @ Load all regs saved previously
 764  THUMB( ldr     sp, [ip], #4               )
 765  THUMB( ldr     pc, [ip]                   )
 766  UNWIND(.fnend          )
 767 ENDPROC(__switch_to)
 768
 769         __INIT
 770
 771 /*
 772  * User helpers.
 773  *
 774  * These are segment of kernel provided user code reachable from user space
 775  * at a fixed address in kernel memory.  This is used to provide user space
 776  * with some operations which require kernel help because of unimplemented
 777  * native feature and/or instructions in many ARM CPUs. The idea is for
 778  * this code to be executed directly in user mode for best efficiency but
 779  * which is too intimate with the kernel counter part to be left to user
 780  * libraries.  In fact this code might even differ from one CPU to another
 781  * depending on the available  instruction set and restrictions like on
 782  * SMP systems.  In other words, the kernel reserves the right to change
 783  * this code as needed without warning. Only the entry points and their
 784  * results are guaranteed to be stable.
 785  *
 786  * Each segment is 32-byte aligned and will be moved to the top of the high
 787  * vector page.  New segments (if ever needed) must be added in front of
 788  * existing ones.  This mechanism should be used only for things that are
 789  * really small and justified, and not be abused freely.
 790  *
 791  * User space is expected to implement those things inline when optimizing
 792  * for a processor that has the necessary native support, but only if such
 793  * resulting binaries are already to be incompatible with earlier ARM
 794  * processors due to the use of unsupported instructions other than what
 795  * is provided here.  In other words don't make binaries unable to run on
 796  * earlier processors just for the sake of not using these kernel helpers
 797  * if your compiled code is not going to use the new instructions for other
 798  * purpose.
 799  */
 800  THUMB( .arm    )
 801
 802         .macro  usr_ret, reg
 803 #ifdef CONFIG_ARM_THUMB
 804         bx      \reg
 805 #else
 806         mov     pc, \reg
 807 #endif
 808         .endm
 809
 810         .align  5
 811         .globl  __kuser_helper_start
 812 __kuser_helper_start:
 813
 814 /*
 815  * Reference prototype:
 816  *
 817  *      void __kernel_memory_barrier(void)
 818  *
 819  * Input:
 820  *
 821  *      lr = return address
 822  *
 823  * Output:
 824  *
 825  *      none
 826  *
 827  * Clobbered:
 828  *
 829  *      none
 830  *
 831  * Definition and user space usage example:
 832  *
 833  *      typedef void (__kernel_dmb_t)(void);
 834  *      #define __kernel_dmb (*(__kernel_dmb_t *)0xffff0fa0)
 835  *
 836  * Apply any needed memory barrier to preserve consistency with data modified
 837  * manually and __kuser_cmpxchg usage.
 838  *
 839  * This could be used as follows:
 840  *
 841  * #define __kernel_dmb() \
 842  *         asm volatile ( "mov r0, #0xffff0fff; mov lr, pc; sub pc, r0, #95" \
 843  *              : : : "r0", "lr","cc" )
 844  */
 845
 846 __kuser_memory_barrier:                         @ 0xffff0fa0
 847         smp_dmb
 848         usr_ret lr
 849
 850         .align  5
 851
 852 /*
 853  * Reference prototype:
 854  *
 855  *      int __kernel_cmpxchg(int oldval, int newval, int *ptr)
 856  *
 857  * Input:
 858  *
 859  *      r0 = oldval
 860  *      r1 = newval
 861  *      r2 = ptr
 862  *      lr = return address
 863  *
 864  * Output:
 865  *
 866  *      r0 = returned value (zero or non-zero)
 867  *      C flag = set if r0 == 0, clear if r0 != 0
 868  *
 869  * Clobbered:
 870  *
 871  *      r3, ip, flags
 872  *
 873  * Definition and user space usage example:
 874  *
 875  *      typedef int (__kernel_cmpxchg_t)(int oldval, int newval, int *ptr);
 876  *      #define __kernel_cmpxchg (*(__kernel_cmpxchg_t *)0xffff0fc0)
 877  *
 878  * Atomically store newval in *ptr if *ptr is equal to oldval for user space.
 879  * Return zero if *ptr was changed or non-zero if no exchange happened.
 880  * The C flag is also set if *ptr was changed to allow for assembly
 881  * optimization in the calling code.
 882  *
 883  * Notes:
 884  *
 885  *    - This routine already includes memory barriers as needed.
 886  *
 887  * For example, a user space atomic_add implementation could look like this:
 888  *
 889  * #define atomic_add(ptr, val) \
 890  *      ({ register unsigned int *__ptr asm("r2") = (ptr); \
 891  *         register unsigned int __result asm("r1"); \
 892  *         asm volatile ( \
 893  *             "1: @ atomic_add\n\t" \
 894  *             "ldr     r0, [r2]\n\t" \
 895  *             "mov     r3, #0xffff0fff\n\t" \
 896  *             "add     lr, pc, #4\n\t" \
 897  *             "add     r1, r0, %2\n\t" \
 898  *             "add     pc, r3, #(0xffff0fc0 - 0xffff0fff)\n\t" \
 899  *             "bcc     1b" \
 900  *             : "=&r" (__result) \
 901  *             : "r" (__ptr), "rIL" (val) \
 902  *             : "r0","r3","ip","lr","cc","memory" ); \
 903  *         __result; })
 904  */
 905
 906 __kuser_cmpxchg:                                @ 0xffff0fc0
 907
 908 #if defined(CONFIG_NEEDS_SYSCALL_FOR_CMPXCHG)
 909
 910         /*
 911          * Poor you.  No fast solution possible...
 912          * The kernel itself must perform the operation.
 913          * A special ghost syscall is used for that (see traps.c).
 914          */
 915         stmfd   sp!, {r7, lr}
 916         ldr     r7, =1f                 @ it's 20 bits
 917         swi     __ARM_NR_cmpxchg
 918         ldmfd   sp!, {r7, pc}
 919 1:      .word   __ARM_NR_cmpxchg
 920
 921 #elif __LINUX_ARM_ARCH__ < 6
 922
 923 #ifdef CONFIG_MMU
 924
 925         /*
 926          * The only thing that can break atomicity in this cmpxchg
 927          * implementation is either an IRQ or a data abort exception
 928          * causing another process/thread to be scheduled in the middle
 929          * of the critical sequence.  To prevent this, code is added to
 930          * the IRQ and data abort exception handlers to set the pc back
 931          * to the beginning of the critical section if it is found to be
 932          * within that critical section (see kuser_cmpxchg_fixup).
 933          */
 934 1:      ldr     r3, [r2]                        @ load current val
 935         subs    r3, r3, r0                      @ compare with oldval
 936 2:      streq   r1, [r2]                        @ store newval if eq
 937         rsbs    r0, r3, #0                      @ set return val and C flag
 938         usr_ret lr
 939
 940         .text
 941 kuser_cmpxchg_fixup:
 942         @ Called from kuser_cmpxchg_check macro.
 943         @ r2 = address of interrupted insn (must be preserved).
 944         @ sp = saved regs. r7 and r8 are clobbered.
 945         @ 1b = first critical insn, 2b = last critical insn.
 946         @ If r2 >= 1b and r2 <= 2b then saved pc_usr is set to 1b.
 947         mov     r7, #0xffff0fff
 948         sub     r7, r7, #(0xffff0fff - (0xffff0fc0 + (1b - __kuser_cmpxchg)))
 949         subs    r8, r2, r7
 950         rsbcss  r8, r8, #(2b - 1b)
 951         strcs   r7, [sp, #S_PC]
 952         mov     pc, lr
 953         .previous
 954
 955 #else
 956 #warning "NPTL on non MMU needs fixing"
 957         mov     r0, #-1
 958         adds    r0, r0, #0
 959         usr_ret lr
 960 #endif
 961
 962 #else
 963
 964         smp_dmb
 965 1:      ldrex   r3, [r2]
 966         subs    r3, r3, r0
 967         strexeq r3, r1, [r2]
 968         teqeq   r3, #1
 969         beq     1b
 970         rsbs    r0, r3, #0
 971         /* beware -- each __kuser slot must be 8 instructions max */
 972 #ifdef CONFIG_SMP
 973         b       __kuser_memory_barrier
 974 #else
 975         usr_ret lr
 976 #endif
 977
 978 #endif
 979
 980         .align  5
 981
 982 /*
 983  * Reference prototype:
 984  *
 985  *      int __kernel_get_tls(void)
 986  *
 987  * Input:
 988  *
 989  *      lr = return address
 990  *
 991  * Output:
 992  *
 993  *      r0 = TLS value
 994  *
 995  * Clobbered:
 996  *
 997  *      none
 998  *
 999  * Definition and user space usage example:
1000  *
1001  *      typedef int (__kernel_get_tls_t)(void);
1002  *      #define __kernel_get_tls (*(__kernel_get_tls_t *)0xffff0fe0)
1003  *
1004  * Get the TLS value as previously set via the __ARM_NR_set_tls syscall.
1005  *
1006  * This could be used as follows:
1007  *
1008  * #define __kernel_get_tls() \
1009  *      ({ register unsigned int __val asm("r0"); \
1010  *         asm( "mov r0, #0xffff0fff; mov lr, pc; sub pc, r0, #31" \
1011  *              : "=r" (__val) : : "lr","cc" ); \
1012  *         __val; })
1013  */
1014
1015 __kuser_get_tls:                                @ 0xffff0fe0
1016
1017 #if !defined(CONFIG_HAS_TLS_REG) && !defined(CONFIG_TLS_REG_EMUL)
1018         ldr     r0, [pc, #(16 - 8)]             @ TLS stored at 0xffff0ff0
1019 #else
1020         mrc     p15, 0, r0, c13, c0, 3          @ read TLS register
1021 #endif
1022         usr_ret lr
1023
1024         .rep    5
1025         .word   0                       @ pad up to __kuser_helper_version
1026         .endr
1027
1028 /*
1029  * Reference declaration:
1030  *
1031  *      extern unsigned int __kernel_helper_version;
1032  *
1033  * Definition and user space usage example:
1034  *
1035  *      #define __kernel_helper_version (*(unsigned int *)0xffff0ffc)
1036  *
1037  * User space may read this to determine the curent number of helpers
1038  * available.
1039  */
1040
1041 __kuser_helper_version:                         @ 0xffff0ffc
1042         .word   ((__kuser_helper_end - __kuser_helper_start) >> 5)
1043
1044         .globl  __kuser_helper_end
1045 __kuser_helper_end:
1046
1047  THUMB( .thumb  )
1048
1049 /*
1050  * Vector stubs.
1051  *
1052  * This code is copied to 0xffff0200 so we can use branches in the
1053  * vectors, rather than ldr's.  Note that this code must not
1054  * exceed 0x300 bytes.
1055  *
1056  * Common stub entry macro:
1057  *   Enter in IRQ mode, spsr = SVC/USR CPSR, lr = SVC/USR PC
1058  *
1059  * SP points to a minimal amount of processor-private memory, the address
1060  * of which is copied into r0 for the mode specific abort handler.
1061  */
1062         .macro  vector_stub, name, mode, correction=0
1063         .align  5
1064
1065 vector_\name:
1066         .if \correction
1067         sub     lr, lr, #\correction
1068         .endif
1069
1070         @
1071         @ Save r0, lr_<exception> (parent PC) and spsr_<exception>
1072         @ (parent CPSR)
1073         @
1074         stmia   sp, {r0, lr}            @ save r0, lr
1075         mrs     lr, spsr
1076         str     lr, [sp, #8]            @ save spsr
1077
1078         @
1079         @ Prepare for SVC32 mode.  IRQs remain disabled.
1080         @
1081         mrs     r0, cpsr
1082         eor     r0, r0, #(\mode ^ SVC_MODE | PSR_ISETSTATE)
1083         msr     spsr_cxsf, r0
1084
1085         @
1086         @ the branch table must immediately follow this code
1087         @
1088         and     lr, lr, #0x0f
1089  THUMB( adr     r0, 1f                  )
1090  THUMB( ldr     lr, [r0, lr, lsl #2]    )
1091         mov     r0, sp
1092  ARM(   ldr     lr, [pc, lr, lsl #2]    )
1093         movs    pc, lr                  @ branch to handler in SVC mode
1094 ENDPROC(vector_\name)
1095
1096         .align  2
1097         @ handler addresses follow this label
1098 1:
1099         .endm
1100
1101         .globl  __stubs_start
1102 __stubs_start:
1103 /*
1104  * Interrupt dispatcher
1105  */
1106         vector_stub     irq, IRQ_MODE, 4
1107
1108         .long   __irq_usr                       @  0  (USR_26 / USR_32)
1109         .long   __irq_invalid                   @  1  (FIQ_26 / FIQ_32)
1110         .long   __irq_invalid                   @  2  (IRQ_26 / IRQ_32)
1111         .long   __irq_svc                       @  3  (SVC_26 / SVC_32)
1112         .long   __irq_invalid                   @  4
1113         .long   __irq_invalid                   @  5
1114         .long   __irq_invalid                   @  6
1115         .long   __irq_invalid                   @  7
1116         .long   __irq_invalid                   @  8
1117         .long   __irq_invalid                   @  9
1118         .long   __irq_invalid                   @  a
1119         .long   __irq_invalid                   @  b
1120         .long   __irq_invalid                   @  c
1121         .long   __irq_invalid                   @  d
1122         .long   __irq_invalid                   @  e
1123         .long   __irq_invalid                   @  f
1124
1125 /*
1126  * Data abort dispatcher
1127  * Enter in ABT mode, spsr = USR CPSR, lr = USR PC
1128  */
1129         vector_stub     dabt, ABT_MODE, 8
1130
1131         .long   __dabt_usr                      @  0  (USR_26 / USR_32)
1132         .long   __dabt_invalid                  @  1  (FIQ_26 / FIQ_32)
1133         .long   __dabt_invalid                  @  2  (IRQ_26 / IRQ_32)
1134         .long   __dabt_svc                      @  3  (SVC_26 / SVC_32)
1135         .long   __dabt_invalid                  @  4
1136         .long   __dabt_invalid                  @  5
1137         .long   __dabt_invalid                  @  6
1138         .long   __dabt_invalid                  @  7
1139         .long   __dabt_invalid                  @  8
1140         .long   __dabt_invalid                  @  9
1141         .long   __dabt_invalid                  @  a
1142         .long   __dabt_invalid                  @  b
1143         .long   __dabt_invalid                  @  c
1144         .long   __dabt_invalid                  @  d
1145         .long   __dabt_invalid                  @  e
1146         .long   __dabt_invalid                  @  f
1147
1148 /*
1149  * Prefetch abort dispatcher
1150  * Enter in ABT mode, spsr = USR CPSR, lr = USR PC
1151  */
1152         vector_stub     pabt, ABT_MODE, 4
1153
1154         .long   __pabt_usr                      @  0 (USR_26 / USR_32)
1155         .long   __pabt_invalid                  @  1 (FIQ_26 / FIQ_32)
1156         .long   __pabt_invalid                  @  2 (IRQ_26 / IRQ_32)
1157         .long   __pabt_svc                      @  3 (SVC_26 / SVC_32)
1158         .long   __pabt_invalid                  @  4
1159         .long   __pabt_invalid                  @  5
1160         .long   __pabt_invalid                  @  6
1161         .long   __pabt_invalid                  @  7
1162         .long   __pabt_invalid                  @  8
1163         .long   __pabt_invalid                  @  9
1164         .long   __pabt_invalid                  @  a
1165         .long   __pabt_invalid                  @  b
1166         .long   __pabt_invalid                  @  c
1167         .long   __pabt_invalid                  @  d
1168         .long   __pabt_invalid                  @  e
1169         .long   __pabt_invalid                  @  f
1170
1171 /*
1172  * Undef instr entry dispatcher
1173  * Enter in UND mode, spsr = SVC/USR CPSR, lr = SVC/USR PC
1174  */
1175         vector_stub     und, UND_MODE
1176
1177         .long   __und_usr                       @  0 (USR_26 / USR_32)
1178         .long   __und_invalid                   @  1 (FIQ_26 / FIQ_32)
1179         .long   __und_invalid                   @  2 (IRQ_26 / IRQ_32)
1180         .long   __und_svc                       @  3 (SVC_26 / SVC_32)
1181         .long   __und_invalid                   @  4
1182         .long   __und_invalid                   @  5
1183         .long   __und_invalid                   @  6
1184         .long   __und_invalid                   @  7
1185         .long   __und_invalid                   @  8
1186         .long   __und_invalid                   @  9
1187         .long   __und_invalid                   @  a
1188         .long   __und_invalid                   @  b
1189         .long   __und_invalid                   @  c
1190         .long   __und_invalid                   @  d
1191         .long   __und_invalid                   @  e
1192         .long   __und_invalid                   @  f
1193
1194         .align  5
1195
1196 /*=============================================================================
1197  * Undefined FIQs
1198  *-----------------------------------------------------------------------------
1199  * Enter in FIQ mode, spsr = ANY CPSR, lr = ANY PC
1200  * MUST PRESERVE SVC SPSR, but need to switch to SVC mode to show our msg.
1201  * Basically to switch modes, we *HAVE* to clobber one register...  brain
1202  * damage alert!  I don't think that we can execute any code in here in any
1203  * other mode than FIQ...  Ok you can switch to another mode, but you can't
1204  * get out of that mode without clobbering one register.
1205  */
1206 vector_fiq:
1207         disable_fiq
1208         subs    pc, lr, #4
1209
1210 /*=============================================================================
1211  * Address exception handler
1212  *-----------------------------------------------------------------------------
1213  * These aren't too critical.
1214  * (they're not supposed to happen, and won't happen in 32-bit data mode).
1215  */
1216
1217 vector_addrexcptn:
1218         b       vector_addrexcptn
1219
1220 /*
1221  * We group all the following data together to optimise
1222  * for CPUs with separate I & D caches.
1223  */
1224         .align  5
1225
1226 .LCvswi:
1227         .word   vector_swi
1228
1229         .globl  __stubs_end
1230 __stubs_end:
1231
1232         .equ    stubs_offset, __vectors_start + 0x200 - __stubs_start
1233
1234         .globl  __vectors_start
1235 __vectors_start:
1236  ARM(   swi     SYS_ERROR0      )
1237  THUMB( svc     #0              )
1238  THUMB( nop                     )
1239         W(b)    vector_und + stubs_offset
1240         W(ldr)  pc, .LCvswi + stubs_offset
1241         W(b)    vector_pabt + stubs_offset
1242         W(b)    vector_dabt + stubs_offset
1243         W(b)    vector_addrexcptn + stubs_offset
1244         W(b)    vector_irq + stubs_offset
1245         W(b)    vector_fiq + stubs_offset
1246
1247         .globl  __vectors_end
1248 __vectors_end:
1249
1250         .data
1251
1252         .globl  cr_alignment
1253         .globl  cr_no_alignment
1254 cr_alignment:
1255         .space  4
1256 cr_no_alignment:
1257         .space  4