arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10
  11 #include <asm/unistd.h>
  12 #include <asm/ftrace.h>
  13 #include <asm/unwind.h>
  14
  15 #ifdef CONFIG_NEED_RET_TO_USER
  16 #include <mach/entry-macro.S>
  17 #else
  18         .macro  arch_ret_to_user, tmp1, tmp2
  19         .endm
  20 #endif
  21
  22 #include "entry-header.S"
  23
  24
  25         .align  5
  26 /*
  27  * This is the fast syscall return path.  We do as little as
  28  * possible here, and this includes saving r0 back into the SVC
  29  * stack.
  30  */
  31 ret_fast_syscall:
  32  UNWIND(.fnstart        )
  33  UNWIND(.cantunwind     )
  34         disable_irq                             @ disable interrupts
  35         ldr     r1, [tsk, #TI_FLAGS]
  36         tst     r1, #_TIF_WORK_MASK
  37         bne     fast_work_pending
  38 #if defined(CONFIG_IRQSOFF_TRACER)
  39         asm_trace_hardirqs_on
  40 #endif
  41
  42         /* perform architecture specific actions before user return */
  43         arch_ret_to_user r1, lr
  44
  45         restore_user_regs fast = 1, offset = S_OFF
  46  UNWIND(.fnend          )
  47
  48 /*
  49  * Ok, we need to do extra processing, enter the slow path.
  50  */
  51 fast_work_pending:
  52         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  53 work_pending:
  54         mov     r0, sp                          @ 'regs'
  55         mov     r2, why                         @ 'syscall'
  56         bl      do_work_pending
  57         cmp     r0, #0
  58         beq     no_work_pending
  59         movlt   scno, #(__NR_restart_syscall - __NR_SYSCALL_BASE)
  60         ldmia   sp, {r0 - r6}                   @ have to reload r0 - r6
  61         b       local_restart                   @ ... and off we go
  62
  63 /*
  64  * "slow" syscall return path.  "why" tells us if this was a real syscall.
  65  */
  66 ENTRY(ret_to_user)
  67 ret_slow_syscall:
  68         disable_irq                             @ disable interrupts
  69 ENTRY(ret_to_user_from_irq)
  70         ldr     r1, [tsk, #TI_FLAGS]
  71         tst     r1, #_TIF_WORK_MASK
  72         bne     work_pending
  73 no_work_pending:
  74 #if defined(CONFIG_IRQSOFF_TRACER)
  75         asm_trace_hardirqs_on
  76 #endif
  77         /* perform architecture specific actions before user return */
  78         arch_ret_to_user r1, lr
  79
  80         restore_user_regs fast = 0, offset = 0
  81 ENDPROC(ret_to_user_from_irq)
  82 ENDPROC(ret_to_user)
  83
  84 /*
  85  * This is how we return from a fork.
  86  */
  87 ENTRY(ret_from_fork)
  88         bl      schedule_tail
  89         get_thread_info tsk
  90         mov     why, #1
  91         b       ret_slow_syscall
  92 ENDPROC(ret_from_fork)
  93
  94 ENTRY(ret_from_kernel_thread)
  95  UNWIND(.fnstart)
  96  UNWIND(.cantunwind)
  97         bl      schedule_tail
  98         mov     r0, r4
  99         adr     lr, BSYM(1f)    @ kernel threads should not exit
 100         mov     pc, r5
 101 1:      bl      do_exit
 102         nop
 103  UNWIND(.fnend)
 104 ENDPROC(ret_from_kernel_thread)
 105
 106 /*
 107  * turn a kernel thread into userland process
 108  * use: ret_from_kernel_execve(struct pt_regs *normal)
 109  */
 110 ENTRY(ret_from_kernel_execve)
 111         mov     why, #0                 @ not a syscall
 112         str     why, [r0, #S_R0]        @ ... and we want 0 in ->ARM_r0 as well
 113         get_thread_info tsk             @ thread structure
 114         mov     sp, r0                  @ stack pointer just under pt_regs
 115         b       ret_slow_syscall
 116 ENDPROC(ret_from_kernel_execve)
 117
 118         .equ NR_syscalls,0
 119 #define CALL(x) .equ NR_syscalls,NR_syscalls+1
 120 #include "calls.S"
 121
 122 /*
 123  * Ensure that the system call table is equal to __NR_syscalls,
 124  * which is the value the rest of the system sees
 125  */
 126 .ifne NR_syscalls - __NR_syscalls
 127 .error "__NR_syscalls is not equal to the size of the syscall table"
 128 .endif
 129
 130 #undef CALL
 131 #define CALL(x) .long x
 132
 133 #ifdef CONFIG_FUNCTION_TRACER
 134 /*
 135  * When compiling with -pg, gcc inserts a call to the mcount routine at the
 136  * start of every function.  In mcount, apart from the function's address (in
 137  * lr), we need to get hold of the function's caller's address.
 138  *
 139  * Older GCCs (pre-4.4) inserted a call to a routine called mcount like this:
 140  *
 141  *      bl      mcount
 142  *
 143  * These versions have the limitation that in order for the mcount routine to
 144  * be able to determine the function's caller's address, an APCS-style frame
 145  * pointer (which is set up with something like the code below) is required.
 146  *
 147  *      mov     ip, sp
 148  *      push    {fp, ip, lr, pc}
 149  *      sub     fp, ip, #4
 150  *
 151  * With EABI, these frame pointers are not available unless -mapcs-frame is
 152  * specified, and if building as Thumb-2, not even then.
 153  *
 154  * Newer GCCs (4.4+) solve this problem by introducing a new version of mcount,
 155  * with call sites like:
 156  *
 157  *      push    {lr}
 158  *      bl      __gnu_mcount_nc
 159  *
 160  * With these compilers, frame pointers are not necessary.
 161  *
 162  * mcount can be thought of as a function called in the middle of a subroutine
 163  * call.  As such, it needs to be transparent for both the caller and the
 164  * callee: the original lr needs to be restored when leaving mcount, and no
 165  * registers should be clobbered.  (In the __gnu_mcount_nc implementation, we
 166  * clobber the ip register.  This is OK because the ARM calling convention
 167  * allows it to be clobbered in subroutines and doesn't use it to hold
 168  * parameters.)
 169  *
 170  * When using dynamic ftrace, we patch out the mcount call by a "mov r0, r0"
 171  * for the mcount case, and a "pop {lr}" for the __gnu_mcount_nc case (see
 172  * arch/arm/kernel/ftrace.c).
 173  */
 174
 175 #ifndef CONFIG_OLD_MCOUNT
 176 #if (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 4))
 177 #error Ftrace requires CONFIG_FRAME_POINTER=y with GCC older than 4.4.0.
 178 #endif
 179 #endif
 180
 181 .macro mcount_adjust_addr rd, rn
 182         bic     \rd, \rn, #1            @ clear the Thumb bit if present
 183         sub     \rd, \rd, #MCOUNT_INSN_SIZE
 184 .endm
 185
 186 .macro __mcount suffix
 187         mcount_enter
 188         ldr     r0, =ftrace_trace_function
 189         ldr     r2, [r0]
 190         adr     r0, .Lftrace_stub
 191         cmp     r0, r2
 192         bne     1f
 193
 194 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 195         ldr     r1, =ftrace_graph_return
 196         ldr     r2, [r1]
 197         cmp     r0, r2
 198         bne     ftrace_graph_caller\suffix
 199
 200         ldr     r1, =ftrace_graph_entry
 201         ldr     r2, [r1]
 202         ldr     r0, =ftrace_graph_entry_stub
 203         cmp     r0, r2
 204         bne     ftrace_graph_caller\suffix
 205 #endif
 206
 207         mcount_exit
 208
 209 1:      mcount_get_lr   r1                      @ lr of instrumented func
 210         mcount_adjust_addr      r0, lr          @ instrumented function
 211         adr     lr, BSYM(2f)
 212         mov     pc, r2
 213 2:      mcount_exit
 214 .endm
 215
 216 .macro __ftrace_caller suffix
 217         mcount_enter
 218
 219         mcount_get_lr   r1                      @ lr of instrumented func
 220         mcount_adjust_addr      r0, lr          @ instrumented function
 221
 222         .globl ftrace_call\suffix
 223 ftrace_call\suffix:
 224         bl      ftrace_stub
 225
 226 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 227         .globl ftrace_graph_call\suffix
 228 ftrace_graph_call\suffix:
 229         mov     r0, r0
 230 #endif
 231
 232         mcount_exit
 233 .endm
 234
 235 .macro __ftrace_graph_caller
 236         sub     r0, fp, #4              @ &lr of instrumented routine (&parent)
 237 #ifdef CONFIG_DYNAMIC_FTRACE
 238         @ called from __ftrace_caller, saved in mcount_enter
 239         ldr     r1, [sp, #16]           @ instrumented routine (func)
 240         mcount_adjust_addr      r1, r1
 241 #else
 242         @ called from __mcount, untouched in lr
 243         mcount_adjust_addr      r1, lr  @ instrumented routine (func)
 244 #endif
 245         mov     r2, fp                  @ frame pointer
 246         bl      prepare_ftrace_return
 247         mcount_exit
 248 .endm
 249
 250 #ifdef CONFIG_OLD_MCOUNT
 251 /*
 252  * mcount
 253  */
 254
 255 .macro mcount_enter
 256         stmdb   sp!, {r0-r3, lr}
 257 .endm
 258
 259 .macro mcount_get_lr reg
 260         ldr     \reg, [fp, #-4]
 261 .endm
 262
 263 .macro mcount_exit
 264         ldr     lr, [fp, #-4]
 265         ldmia   sp!, {r0-r3, pc}
 266 .endm
 267
 268 ENTRY(mcount)
 269 #ifdef CONFIG_DYNAMIC_FTRACE
 270         stmdb   sp!, {lr}
 271         ldr     lr, [fp, #-4]
 272         ldmia   sp!, {pc}
 273 #else
 274         __mcount _old
 275 #endif
 276 ENDPROC(mcount)
 277
 278 #ifdef CONFIG_DYNAMIC_FTRACE
 279 ENTRY(ftrace_caller_old)
 280         __ftrace_caller _old
 281 ENDPROC(ftrace_caller_old)
 282 #endif
 283
 284 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 285 ENTRY(ftrace_graph_caller_old)
 286         __ftrace_graph_caller
 287 ENDPROC(ftrace_graph_caller_old)
 288 #endif
 289
 290 .purgem mcount_enter
 291 .purgem mcount_get_lr
 292 .purgem mcount_exit
 293 #endif
 294
 295 /*
 296  * __gnu_mcount_nc
 297  */
 298
 299 .macro mcount_enter
 300         stmdb   sp!, {r0-r3, lr}
 301 .endm
 302
 303 .macro mcount_get_lr reg
 304         ldr     \reg, [sp, #20]
 305 .endm
 306
 307 .macro mcount_exit
 308         ldmia   sp!, {r0-r3, ip, lr}
 309         mov     pc, ip
 310 .endm
 311
 312 ENTRY(__gnu_mcount_nc)
 313 #ifdef CONFIG_DYNAMIC_FTRACE
 314         mov     ip, lr
 315         ldmia   sp!, {lr}
 316         mov     pc, ip
 317 #else
 318         __mcount
 319 #endif
 320 ENDPROC(__gnu_mcount_nc)
 321
 322 #ifdef CONFIG_DYNAMIC_FTRACE
 323 ENTRY(ftrace_caller)
 324         __ftrace_caller
 325 ENDPROC(ftrace_caller)
 326 #endif
 327
 328 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 329 ENTRY(ftrace_graph_caller)
 330         __ftrace_graph_caller
 331 ENDPROC(ftrace_graph_caller)
 332 #endif
 333
 334 .purgem mcount_enter
 335 .purgem mcount_get_lr
 336 .purgem mcount_exit
 337
 338 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 339         .globl return_to_handler
 340 return_to_handler:
 341         stmdb   sp!, {r0-r3}
 342         mov     r0, fp                  @ frame pointer
 343         bl      ftrace_return_to_handler
 344         mov     lr, r0                  @ r0 has real ret addr
 345         ldmia   sp!, {r0-r3}
 346         mov     pc, lr
 347 #endif
 348
 349 ENTRY(ftrace_stub)
 350 .Lftrace_stub:
 351         mov     pc, lr
 352 ENDPROC(ftrace_stub)
 353
 354 #endif /* CONFIG_FUNCTION_TRACER */
 355
 356 /*=============================================================================
 357  * SWI handler
 358  *-----------------------------------------------------------------------------
 359  */
 360
 361         .align  5
 362 ENTRY(vector_swi)
 363         sub     sp, sp, #S_FRAME_SIZE
 364         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 365  ARM(   add     r8, sp, #S_PC           )
 366  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 367  THUMB( mov     r8, sp                  )
 368  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 369         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
 370         str     lr, [sp, #S_PC]                 @ Save calling PC
 371         str     r8, [sp, #S_PSR]                @ Save CPSR
 372         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 373         zero_fp
 374
 375         /*
 376          * Get the system call number.
 377          */
 378
 379 #if defined(CONFIG_OABI_COMPAT)
 380
 381         /*
 382          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 383          * value to determine if it is an EABI or an old ABI call.
 384          */
 385 #ifdef CONFIG_ARM_THUMB
 386         tst     r8, #PSR_T_BIT
 387         movne   r10, #0                         @ no thumb OABI emulation
 388         ldreq   r10, [lr, #-4]                  @ get SWI instruction
 389 #else
 390         ldr     r10, [lr, #-4]                  @ get SWI instruction
 391 #endif
 392 #ifdef CONFIG_CPU_ENDIAN_BE8
 393         rev     r10, r10                        @ little endian instruction
 394 #endif
 395
 396 #elif defined(CONFIG_AEABI)
 397
 398         /*
 399          * Pure EABI user space always put syscall number into scno (r7).
 400          */
 401 #elif defined(CONFIG_ARM_THUMB)
 402         /* Legacy ABI only, possibly thumb mode. */
 403         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
 404         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 405         ldreq   scno, [lr, #-4]
 406
 407 #else
 408         /* Legacy ABI only. */
 409         ldr     scno, [lr, #-4]                 @ get SWI instruction
 410 #endif
 411
 412 #ifdef CONFIG_ALIGNMENT_TRAP
 413         ldr     ip, __cr_alignment
 414         ldr     ip, [ip]
 415         mcr     p15, 0, ip, c1, c0              @ update control register
 416 #endif
 417         enable_irq
 418
 419         get_thread_info tsk
 420         adr     tbl, sys_call_table             @ load syscall table pointer
 421
 422 #if defined(CONFIG_OABI_COMPAT)
 423         /*
 424          * If the swi argument is zero, this is an EABI call and we do nothing.
 425          *
 426          * If this is an old ABI call, get the syscall number into scno and
 427          * get the old ABI syscall table address.
 428          */
 429         bics    r10, r10, #0xff000000
 430         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 431         ldrne   tbl, =sys_oabi_call_table
 432 #elif !defined(CONFIG_AEABI)
 433         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 434         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 435 #endif
 436
 437 local_restart:
 438         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
 439         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 440
 441 #ifdef CONFIG_SECCOMP
 442         tst     r10, #_TIF_SECCOMP
 443         beq     1f
 444         mov     r0, scno
 445         bl      __secure_computing
 446         add     r0, sp, #S_R0 + S_OFF           @ pointer to regs
 447         ldmia   r0, {r0 - r3}                   @ have to reload r0 - r3
 448 1:
 449 #endif
 450
 451         tst     r10, #_TIF_SYSCALL_WORK         @ are we tracing syscalls?
 452         bne     __sys_trace
 453
 454         cmp     scno, #NR_syscalls              @ check upper syscall limit
 455         adr     lr, BSYM(ret_fast_syscall)      @ return address
 456         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 457
 458         add     r1, sp, #S_OFF
 459 2:      mov     why, #0                         @ no longer a real syscall
 460         cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 461         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 462         bcs     arm_syscall
 463         b       sys_ni_syscall                  @ not private func
 464 ENDPROC(vector_swi)
 465
 466         /*
 467          * This is the really slow path.  We're going to be doing
 468          * context switches, and waiting for our parent to respond.
 469          */
 470 __sys_trace:
 471         mov     r1, scno
 472         add     r0, sp, #S_OFF
 473         bl      syscall_trace_enter
 474
 475         adr     lr, BSYM(__sys_trace_return)    @ return address
 476         mov     scno, r0                        @ syscall number (possibly new)
 477         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
 478         cmp     scno, #NR_syscalls              @ check upper syscall limit
 479         ldmccia r1, {r0 - r6}                   @ have to reload r0 - r6
 480         stmccia sp, {r4, r5}                    @ and update the stack args
 481         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 482         b       2b
 483
 484 __sys_trace_return:
 485         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 486         mov     r1, scno
 487         mov     r0, sp
 488         bl      syscall_trace_exit
 489         b       ret_slow_syscall
 490
 491         .align  5
 492 #ifdef CONFIG_ALIGNMENT_TRAP
 493         .type   __cr_alignment, #object
 494 __cr_alignment:
 495         .word   cr_alignment
 496 #endif
 497         .ltorg
 498
 499 /*
 500  * This is the syscall table declaration for native ABI syscalls.
 501  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 502  */
 503 #define ABI(native, compat) native
 504 #ifdef CONFIG_AEABI
 505 #define OBSOLETE(syscall) sys_ni_syscall
 506 #else
 507 #define OBSOLETE(syscall) syscall
 508 #endif
 509
 510         .type   sys_call_table, #object
 511 ENTRY(sys_call_table)
 512 #include "calls.S"
 513 #undef ABI
 514 #undef OBSOLETE
 515
 516 /*============================================================================
 517  * Special system call wrappers
 518  */
 519 @ r0 = syscall number
 520 @ r8 = syscall table
 521 sys_syscall:
 522                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 523                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 524                 cmpne   scno, #NR_syscalls      @ check range
 525                 stmloia sp, {r5, r6}            @ shuffle args
 526                 movlo   r0, r1
 527                 movlo   r1, r2
 528                 movlo   r2, r3
 529                 movlo   r3, r4
 530                 ldrlo   pc, [tbl, scno, lsl #2]
 531                 b       sys_ni_syscall
 532 ENDPROC(sys_syscall)
 533
 534 sys_fork_wrapper:
 535                 add     r0, sp, #S_OFF
 536                 b       sys_fork
 537 ENDPROC(sys_fork_wrapper)
 538
 539 sys_vfork_wrapper:
 540                 add     r0, sp, #S_OFF
 541                 b       sys_vfork
 542 ENDPROC(sys_vfork_wrapper)
 543
 544 sys_clone_wrapper:
 545                 add     ip, sp, #S_OFF
 546                 str     ip, [sp, #4]
 547                 b       sys_clone
 548 ENDPROC(sys_clone_wrapper)
 549
 550 sys_sigreturn_wrapper:
 551                 add     r0, sp, #S_OFF
 552                 mov     why, #0         @ prevent syscall restart handling
 553                 b       sys_sigreturn
 554 ENDPROC(sys_sigreturn_wrapper)
 555
 556 sys_rt_sigreturn_wrapper:
 557                 add     r0, sp, #S_OFF
 558                 mov     why, #0         @ prevent syscall restart handling
 559                 b       sys_rt_sigreturn
 560 ENDPROC(sys_rt_sigreturn_wrapper)
 561
 562 sys_sigaltstack_wrapper:
 563                 ldr     r2, [sp, #S_OFF + S_SP]
 564                 b       do_sigaltstack
 565 ENDPROC(sys_sigaltstack_wrapper)
 566
 567 sys_statfs64_wrapper:
 568                 teq     r1, #88
 569                 moveq   r1, #84
 570                 b       sys_statfs64
 571 ENDPROC(sys_statfs64_wrapper)
 572
 573 sys_fstatfs64_wrapper:
 574                 teq     r1, #88
 575                 moveq   r1, #84
 576                 b       sys_fstatfs64
 577 ENDPROC(sys_fstatfs64_wrapper)
 578
 579 /*
 580  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 581  * offset, we return EINVAL.
 582  */
 583 sys_mmap2:
 584 #if PAGE_SHIFT > 12
 585                 tst     r5, #PGOFF_MASK
 586                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
 587                 streq   r5, [sp, #4]
 588                 beq     sys_mmap_pgoff
 589                 mov     r0, #-EINVAL
 590                 mov     pc, lr
 591 #else
 592                 str     r5, [sp, #4]
 593                 b       sys_mmap_pgoff
 594 #endif
 595 ENDPROC(sys_mmap2)
 596
 597 #ifdef CONFIG_OABI_COMPAT
 598
 599 /*
 600  * These are syscalls with argument register differences
 601  */
 602
 603 sys_oabi_pread64:
 604                 stmia   sp, {r3, r4}
 605                 b       sys_pread64
 606 ENDPROC(sys_oabi_pread64)
 607
 608 sys_oabi_pwrite64:
 609                 stmia   sp, {r3, r4}
 610                 b       sys_pwrite64
 611 ENDPROC(sys_oabi_pwrite64)
 612
 613 sys_oabi_truncate64:
 614                 mov     r3, r2
 615                 mov     r2, r1
 616                 b       sys_truncate64
 617 ENDPROC(sys_oabi_truncate64)
 618
 619 sys_oabi_ftruncate64:
 620                 mov     r3, r2
 621                 mov     r2, r1
 622                 b       sys_ftruncate64
 623 ENDPROC(sys_oabi_ftruncate64)
 624
 625 sys_oabi_readahead:
 626                 str     r3, [sp]
 627                 mov     r3, r2
 628                 mov     r2, r1
 629                 b       sys_readahead
 630 ENDPROC(sys_oabi_readahead)
 631
 632 /*
 633  * Let's declare a second syscall table for old ABI binaries
 634  * using the compatibility syscall entries.
 635  */
 636 #define ABI(native, compat) compat
 637 #define OBSOLETE(syscall) syscall
 638
 639         .type   sys_oabi_call_table, #object
 640 ENTRY(sys_oabi_call_table)
 641 #include "calls.S"
 642 #undef ABI
 643 #undef OBSOLETE
 644
 645 #endif
 646