arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10
  11 #include <asm/unistd.h>
  12 #include <asm/ftrace.h>
  13 #include <asm/unwind.h>
  14
  15 #ifdef CONFIG_NEED_RET_TO_USER
  16 #include <mach/entry-macro.S>
  17 #else
  18         .macro  arch_ret_to_user, tmp1, tmp2
  19         .endm
  20 #endif
  21
  22 #include "entry-header.S"
  23
  24
  25         .align  5
  26 /*
  27  * This is the fast syscall return path.  We do as little as
  28  * possible here, and this includes saving r0 back into the SVC
  29  * stack.
  30  */
  31 ret_fast_syscall:
  32  UNWIND(.fnstart        )
  33  UNWIND(.cantunwind     )
  34         disable_irq                             @ disable interrupts
  35         ldr     r1, [tsk, #TI_FLAGS]
  36         tst     r1, #_TIF_WORK_MASK
  37         bne     fast_work_pending
  38 #if defined(CONFIG_IRQSOFF_TRACER)
  39         asm_trace_hardirqs_on
  40 #endif
  41
  42         /* perform architecture specific actions before user return */
  43         arch_ret_to_user r1, lr
  44
  45         restore_user_regs fast = 1, offset = S_OFF
  46  UNWIND(.fnend          )
  47
  48 /*
  49  * Ok, we need to do extra processing, enter the slow path.
  50  */
  51 fast_work_pending:
  52         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  53 work_pending:
  54         mov     r0, sp                          @ 'regs'
  55         mov     r2, why                         @ 'syscall'
  56         bl      do_work_pending
  57         cmp     r0, #0
  58         beq     no_work_pending
  59         movlt   scno, #(__NR_restart_syscall - __NR_SYSCALL_BASE)
  60         ldmia   sp, {r0 - r6}                   @ have to reload r0 - r6
  61         b       local_restart                   @ ... and off we go
  62
  63 /*
  64  * "slow" syscall return path.  "why" tells us if this was a real syscall.
  65  */
  66 ENTRY(ret_to_user)
  67 ret_slow_syscall:
  68         disable_irq                             @ disable interrupts
  69 ENTRY(ret_to_user_from_irq)
  70         ldr     r1, [tsk, #TI_FLAGS]
  71         tst     r1, #_TIF_WORK_MASK
  72         bne     work_pending
  73 no_work_pending:
  74 #if defined(CONFIG_IRQSOFF_TRACER)
  75         asm_trace_hardirqs_on
  76 #endif
  77         /* perform architecture specific actions before user return */
  78         arch_ret_to_user r1, lr
  79
  80         restore_user_regs fast = 0, offset = 0
  81 ENDPROC(ret_to_user_from_irq)
  82 ENDPROC(ret_to_user)
  83
  84 /*
  85  * This is how we return from a fork.
  86  */
  87 ENTRY(ret_from_fork)
  88         bl      schedule_tail
  89         cmp     r5, #0
  90         movne   r0, r4
  91         adrne   lr, BSYM(1f)
  92         movne   pc, r5
  93 1:      get_thread_info tsk
  94         b       ret_slow_syscall
  95 ENDPROC(ret_from_fork)
  96
  97         .equ NR_syscalls,0
  98 #define CALL(x) .equ NR_syscalls,NR_syscalls+1
  99 #include "calls.S"
 100
 101 /*
 102  * Ensure that the system call table is equal to __NR_syscalls,
 103  * which is the value the rest of the system sees
 104  */
 105 .ifne NR_syscalls - __NR_syscalls
 106 .error "__NR_syscalls is not equal to the size of the syscall table"
 107 .endif
 108
 109 #undef CALL
 110 #define CALL(x) .long x
 111
 112 #ifdef CONFIG_FUNCTION_TRACER
 113 /*
 114  * When compiling with -pg, gcc inserts a call to the mcount routine at the
 115  * start of every function.  In mcount, apart from the function's address (in
 116  * lr), we need to get hold of the function's caller's address.
 117  *
 118  * Older GCCs (pre-4.4) inserted a call to a routine called mcount like this:
 119  *
 120  *      bl      mcount
 121  *
 122  * These versions have the limitation that in order for the mcount routine to
 123  * be able to determine the function's caller's address, an APCS-style frame
 124  * pointer (which is set up with something like the code below) is required.
 125  *
 126  *      mov     ip, sp
 127  *      push    {fp, ip, lr, pc}
 128  *      sub     fp, ip, #4
 129  *
 130  * With EABI, these frame pointers are not available unless -mapcs-frame is
 131  * specified, and if building as Thumb-2, not even then.
 132  *
 133  * Newer GCCs (4.4+) solve this problem by introducing a new version of mcount,
 134  * with call sites like:
 135  *
 136  *      push    {lr}
 137  *      bl      __gnu_mcount_nc
 138  *
 139  * With these compilers, frame pointers are not necessary.
 140  *
 141  * mcount can be thought of as a function called in the middle of a subroutine
 142  * call.  As such, it needs to be transparent for both the caller and the
 143  * callee: the original lr needs to be restored when leaving mcount, and no
 144  * registers should be clobbered.  (In the __gnu_mcount_nc implementation, we
 145  * clobber the ip register.  This is OK because the ARM calling convention
 146  * allows it to be clobbered in subroutines and doesn't use it to hold
 147  * parameters.)
 148  *
 149  * When using dynamic ftrace, we patch out the mcount call by a "mov r0, r0"
 150  * for the mcount case, and a "pop {lr}" for the __gnu_mcount_nc case (see
 151  * arch/arm/kernel/ftrace.c).
 152  */
 153
 154 #ifndef CONFIG_OLD_MCOUNT
 155 #if (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 4))
 156 #error Ftrace requires CONFIG_FRAME_POINTER=y with GCC older than 4.4.0.
 157 #endif
 158 #endif
 159
 160 .macro mcount_adjust_addr rd, rn
 161         bic     \rd, \rn, #1            @ clear the Thumb bit if present
 162         sub     \rd, \rd, #MCOUNT_INSN_SIZE
 163 .endm
 164
 165 .macro __mcount suffix
 166         mcount_enter
 167         ldr     r0, =ftrace_trace_function
 168         ldr     r2, [r0]
 169         adr     r0, .Lftrace_stub
 170         cmp     r0, r2
 171         bne     1f
 172
 173 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 174         ldr     r1, =ftrace_graph_return
 175         ldr     r2, [r1]
 176         cmp     r0, r2
 177         bne     ftrace_graph_caller\suffix
 178
 179         ldr     r1, =ftrace_graph_entry
 180         ldr     r2, [r1]
 181         ldr     r0, =ftrace_graph_entry_stub
 182         cmp     r0, r2
 183         bne     ftrace_graph_caller\suffix
 184 #endif
 185
 186         mcount_exit
 187
 188 1:      mcount_get_lr   r1                      @ lr of instrumented func
 189         mcount_adjust_addr      r0, lr          @ instrumented function
 190         adr     lr, BSYM(2f)
 191         mov     pc, r2
 192 2:      mcount_exit
 193 .endm
 194
 195 .macro __ftrace_caller suffix
 196         mcount_enter
 197
 198         mcount_get_lr   r1                      @ lr of instrumented func
 199         mcount_adjust_addr      r0, lr          @ instrumented function
 200
 201         .globl ftrace_call\suffix
 202 ftrace_call\suffix:
 203         bl      ftrace_stub
 204
 205 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 206         .globl ftrace_graph_call\suffix
 207 ftrace_graph_call\suffix:
 208         mov     r0, r0
 209 #endif
 210
 211         mcount_exit
 212 .endm
 213
 214 .macro __ftrace_graph_caller
 215         sub     r0, fp, #4              @ &lr of instrumented routine (&parent)
 216 #ifdef CONFIG_DYNAMIC_FTRACE
 217         @ called from __ftrace_caller, saved in mcount_enter
 218         ldr     r1, [sp, #16]           @ instrumented routine (func)
 219         mcount_adjust_addr      r1, r1
 220 #else
 221         @ called from __mcount, untouched in lr
 222         mcount_adjust_addr      r1, lr  @ instrumented routine (func)
 223 #endif
 224         mov     r2, fp                  @ frame pointer
 225         bl      prepare_ftrace_return
 226         mcount_exit
 227 .endm
 228
 229 #ifdef CONFIG_OLD_MCOUNT
 230 /*
 231  * mcount
 232  */
 233
 234 .macro mcount_enter
 235         stmdb   sp!, {r0-r3, lr}
 236 .endm
 237
 238 .macro mcount_get_lr reg
 239         ldr     \reg, [fp, #-4]
 240 .endm
 241
 242 .macro mcount_exit
 243         ldr     lr, [fp, #-4]
 244         ldmia   sp!, {r0-r3, pc}
 245 .endm
 246
 247 ENTRY(mcount)
 248 #ifdef CONFIG_DYNAMIC_FTRACE
 249         stmdb   sp!, {lr}
 250         ldr     lr, [fp, #-4]
 251         ldmia   sp!, {pc}
 252 #else
 253         __mcount _old
 254 #endif
 255 ENDPROC(mcount)
 256
 257 #ifdef CONFIG_DYNAMIC_FTRACE
 258 ENTRY(ftrace_caller_old)
 259         __ftrace_caller _old
 260 ENDPROC(ftrace_caller_old)
 261 #endif
 262
 263 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 264 ENTRY(ftrace_graph_caller_old)
 265         __ftrace_graph_caller
 266 ENDPROC(ftrace_graph_caller_old)
 267 #endif
 268
 269 .purgem mcount_enter
 270 .purgem mcount_get_lr
 271 .purgem mcount_exit
 272 #endif
 273
 274 /*
 275  * __gnu_mcount_nc
 276  */
 277
 278 .macro mcount_enter
 279 /*
 280  * This pad compensates for the push {lr} at the call site.  Note that we are
 281  * unable to unwind through a function which does not otherwise save its lr.
 282  */
 283  UNWIND(.pad    #4)
 284         stmdb   sp!, {r0-r3, lr}
 285  UNWIND(.save   {r0-r3, lr})
 286 .endm
 287
 288 .macro mcount_get_lr reg
 289         ldr     \reg, [sp, #20]
 290 .endm
 291
 292 .macro mcount_exit
 293         ldmia   sp!, {r0-r3, ip, lr}
 294         mov     pc, ip
 295 .endm
 296
 297 ENTRY(__gnu_mcount_nc)
 298 UNWIND(.fnstart)
 299 #ifdef CONFIG_DYNAMIC_FTRACE
 300         mov     ip, lr
 301         ldmia   sp!, {lr}
 302         mov     pc, ip
 303 #else
 304         __mcount
 305 #endif
 306 UNWIND(.fnend)
 307 ENDPROC(__gnu_mcount_nc)
 308
 309 #ifdef CONFIG_DYNAMIC_FTRACE
 310 ENTRY(ftrace_caller)
 311 UNWIND(.fnstart)
 312         __ftrace_caller
 313 UNWIND(.fnend)
 314 ENDPROC(ftrace_caller)
 315 #endif
 316
 317 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 318 ENTRY(ftrace_graph_caller)
 319 UNWIND(.fnstart)
 320         __ftrace_graph_caller
 321 UNWIND(.fnend)
 322 ENDPROC(ftrace_graph_caller)
 323 #endif
 324
 325 .purgem mcount_enter
 326 .purgem mcount_get_lr
 327 .purgem mcount_exit
 328
 329 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 330         .globl return_to_handler
 331 return_to_handler:
 332         stmdb   sp!, {r0-r3}
 333         mov     r0, fp                  @ frame pointer
 334         bl      ftrace_return_to_handler
 335         mov     lr, r0                  @ r0 has real ret addr
 336         ldmia   sp!, {r0-r3}
 337         mov     pc, lr
 338 #endif
 339
 340 ENTRY(ftrace_stub)
 341 .Lftrace_stub:
 342         mov     pc, lr
 343 ENDPROC(ftrace_stub)
 344
 345 #endif /* CONFIG_FUNCTION_TRACER */
 346
 347 /*=============================================================================
 348  * SWI handler
 349  *-----------------------------------------------------------------------------
 350  */
 351
 352         .align  5
 353 ENTRY(vector_swi)
 354         sub     sp, sp, #S_FRAME_SIZE
 355         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 356  ARM(   add     r8, sp, #S_PC           )
 357  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 358  THUMB( mov     r8, sp                  )
 359  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 360         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
 361         str     lr, [sp, #S_PC]                 @ Save calling PC
 362         str     r8, [sp, #S_PSR]                @ Save CPSR
 363         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 364         zero_fp
 365
 366         /*
 367          * Get the system call number.
 368          */
 369
 370 #if defined(CONFIG_OABI_COMPAT)
 371
 372         /*
 373          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 374          * value to determine if it is an EABI or an old ABI call.
 375          */
 376 #ifdef CONFIG_ARM_THUMB
 377         tst     r8, #PSR_T_BIT
 378         movne   r10, #0                         @ no thumb OABI emulation
 379         ldreq   r10, [lr, #-4]                  @ get SWI instruction
 380 #else
 381         ldr     r10, [lr, #-4]                  @ get SWI instruction
 382 #endif
 383 #ifdef CONFIG_CPU_ENDIAN_BE8
 384         rev     r10, r10                        @ little endian instruction
 385 #endif
 386
 387 #elif defined(CONFIG_AEABI)
 388
 389         /*
 390          * Pure EABI user space always put syscall number into scno (r7).
 391          */
 392 #elif defined(CONFIG_ARM_THUMB)
 393         /* Legacy ABI only, possibly thumb mode. */
 394         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
 395         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 396         ldreq   scno, [lr, #-4]
 397
 398 #else
 399         /* Legacy ABI only. */
 400         ldr     scno, [lr, #-4]                 @ get SWI instruction
 401 #endif
 402
 403 #ifdef CONFIG_ALIGNMENT_TRAP
 404         ldr     ip, __cr_alignment
 405         ldr     ip, [ip]
 406         mcr     p15, 0, ip, c1, c0              @ update control register
 407 #endif
 408         enable_irq
 409
 410         get_thread_info tsk
 411         adr     tbl, sys_call_table             @ load syscall table pointer
 412
 413 #if defined(CONFIG_OABI_COMPAT)
 414         /*
 415          * If the swi argument is zero, this is an EABI call and we do nothing.
 416          *
 417          * If this is an old ABI call, get the syscall number into scno and
 418          * get the old ABI syscall table address.
 419          */
 420         bics    r10, r10, #0xff000000
 421         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 422         ldrne   tbl, =sys_oabi_call_table
 423 #elif !defined(CONFIG_AEABI)
 424         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 425         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 426 #endif
 427
 428 local_restart:
 429         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
 430         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 431
 432         tst     r10, #_TIF_SYSCALL_WORK         @ are we tracing syscalls?
 433         bne     __sys_trace
 434
 435         cmp     scno, #NR_syscalls              @ check upper syscall limit
 436         adr     lr, BSYM(ret_fast_syscall)      @ return address
 437         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 438
 439         add     r1, sp, #S_OFF
 440 2:      mov     why, #0                         @ no longer a real syscall
 441         cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 442         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 443         bcs     arm_syscall
 444         b       sys_ni_syscall                  @ not private func
 445 ENDPROC(vector_swi)
 446
 447         /*
 448          * This is the really slow path.  We're going to be doing
 449          * context switches, and waiting for our parent to respond.
 450          */
 451 __sys_trace:
 452         mov     r1, scno
 453         add     r0, sp, #S_OFF
 454         bl      syscall_trace_enter
 455
 456         adr     lr, BSYM(__sys_trace_return)    @ return address
 457         mov     scno, r0                        @ syscall number (possibly new)
 458         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
 459         cmp     scno, #NR_syscalls              @ check upper syscall limit
 460         ldmccia r1, {r0 - r6}                   @ have to reload r0 - r6
 461         stmccia sp, {r4, r5}                    @ and update the stack args
 462         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 463         cmp     scno, #-1                       @ skip the syscall?
 464         bne     2b
 465         add     sp, sp, #S_OFF                  @ restore stack
 466         b       ret_slow_syscall
 467
 468 __sys_trace_return:
 469         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 470         mov     r0, sp
 471         bl      syscall_trace_exit
 472         b       ret_slow_syscall
 473
 474         .align  5
 475 #ifdef CONFIG_ALIGNMENT_TRAP
 476         .type   __cr_alignment, #object
 477 __cr_alignment:
 478         .word   cr_alignment
 479 #endif
 480         .ltorg
 481
 482 /*
 483  * This is the syscall table declaration for native ABI syscalls.
 484  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 485  */
 486 #define ABI(native, compat) native
 487 #ifdef CONFIG_AEABI
 488 #define OBSOLETE(syscall) sys_ni_syscall
 489 #else
 490 #define OBSOLETE(syscall) syscall
 491 #endif
 492
 493         .type   sys_call_table, #object
 494 ENTRY(sys_call_table)
 495 #include "calls.S"
 496 #undef ABI
 497 #undef OBSOLETE
 498
 499 /*============================================================================
 500  * Special system call wrappers
 501  */
 502 @ r0 = syscall number
 503 @ r8 = syscall table
 504 sys_syscall:
 505                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 506                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 507                 cmpne   scno, #NR_syscalls      @ check range
 508                 stmloia sp, {r5, r6}            @ shuffle args
 509                 movlo   r0, r1
 510                 movlo   r1, r2
 511                 movlo   r2, r3
 512                 movlo   r3, r4
 513                 ldrlo   pc, [tbl, scno, lsl #2]
 514                 b       sys_ni_syscall
 515 ENDPROC(sys_syscall)
 516
 517 sys_sigreturn_wrapper:
 518                 add     r0, sp, #S_OFF
 519                 mov     why, #0         @ prevent syscall restart handling
 520                 b       sys_sigreturn
 521 ENDPROC(sys_sigreturn_wrapper)
 522
 523 sys_rt_sigreturn_wrapper:
 524                 add     r0, sp, #S_OFF
 525                 mov     why, #0         @ prevent syscall restart handling
 526                 b       sys_rt_sigreturn
 527 ENDPROC(sys_rt_sigreturn_wrapper)
 528
 529 sys_statfs64_wrapper:
 530                 teq     r1, #88
 531                 moveq   r1, #84
 532                 b       sys_statfs64
 533 ENDPROC(sys_statfs64_wrapper)
 534
 535 sys_fstatfs64_wrapper:
 536                 teq     r1, #88
 537                 moveq   r1, #84
 538                 b       sys_fstatfs64
 539 ENDPROC(sys_fstatfs64_wrapper)
 540
 541 /*
 542  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 543  * offset, we return EINVAL.
 544  */
 545 sys_mmap2:
 546 #if PAGE_SHIFT > 12
 547                 tst     r5, #PGOFF_MASK
 548                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
 549                 streq   r5, [sp, #4]
 550                 beq     sys_mmap_pgoff
 551                 mov     r0, #-EINVAL
 552                 mov     pc, lr
 553 #else
 554                 str     r5, [sp, #4]
 555                 b       sys_mmap_pgoff
 556 #endif
 557 ENDPROC(sys_mmap2)
 558
 559 #ifdef CONFIG_OABI_COMPAT
 560
 561 /*
 562  * These are syscalls with argument register differences
 563  */
 564
 565 sys_oabi_pread64:
 566                 stmia   sp, {r3, r4}
 567                 b       sys_pread64
 568 ENDPROC(sys_oabi_pread64)
 569
 570 sys_oabi_pwrite64:
 571                 stmia   sp, {r3, r4}
 572                 b       sys_pwrite64
 573 ENDPROC(sys_oabi_pwrite64)
 574
 575 sys_oabi_truncate64:
 576                 mov     r3, r2
 577                 mov     r2, r1
 578                 b       sys_truncate64
 579 ENDPROC(sys_oabi_truncate64)
 580
 581 sys_oabi_ftruncate64:
 582                 mov     r3, r2
 583                 mov     r2, r1
 584                 b       sys_ftruncate64
 585 ENDPROC(sys_oabi_ftruncate64)
 586
 587 sys_oabi_readahead:
 588                 str     r3, [sp]
 589                 mov     r3, r2
 590                 mov     r2, r1
 591                 b       sys_readahead
 592 ENDPROC(sys_oabi_readahead)
 593
 594 /*
 595  * Let's declare a second syscall table for old ABI binaries
 596  * using the compatibility syscall entries.
 597  */
 598 #define ABI(native, compat) compat
 599 #define OBSOLETE(syscall) syscall
 600
 601         .type   sys_oabi_call_table, #object
 602 ENTRY(sys_oabi_call_table)
 603 #include "calls.S"
 604 #undef ABI
 605 #undef OBSOLETE
 606
 607 #endif
 608