arch/arm/kernel/head.S

   1 /*
   2  *  linux/arch/arm/kernel/head.S
   3  *
   4  *  Copyright (C) 1994-2002 Russell King
   5  *  Copyright (c) 2003 ARM Limited
   6  *  All Rights Reserved
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  *  Kernel startup code for all 32-bit CPUs
  13  */
  14 #include <linux/linkage.h>
  15 #include <linux/init.h>
  16
  17 #include <asm/assembler.h>
  18 #include <asm/domain.h>
  19 #include <asm/ptrace.h>
  20 #include <asm/asm-offsets.h>
  21 #include <asm/memory.h>
  22 #include <asm/thread_info.h>
  23 #include <asm/system.h>
  24
  25 #ifdef CONFIG_DEBUG_LL
  26 #include <mach/debug-macro.S>
  27 #endif
  28
  29 /*
  30  * swapper_pg_dir is the virtual address of the initial page table.
  31  * We place the page tables 16K below KERNEL_RAM_VADDR.  Therefore, we must
  32  * make sure that KERNEL_RAM_VADDR is correctly set.  Currently, we expect
  33  * the least significant 16 bits to be 0x8000, but we could probably
  34  * relax this restriction to KERNEL_RAM_VADDR >= PAGE_OFFSET + 0x4000.
  35  */
  36 #define KERNEL_RAM_VADDR        (PAGE_OFFSET + TEXT_OFFSET)
  37 #if (KERNEL_RAM_VADDR & 0xffff) != 0x8000
  38 #error KERNEL_RAM_VADDR must start at 0xXXXX8000
  39 #endif
  40
  41         .globl  swapper_pg_dir
  42         .equ    swapper_pg_dir, KERNEL_RAM_VADDR - 0x4000
  43
  44         .macro  pgtbl, rd, phys
  45         add     \rd, \phys, #TEXT_OFFSET - 0x4000
  46         .endm
  47
  48 #ifdef CONFIG_XIP_KERNEL
  49 #define KERNEL_START    XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR)
  50 #define KERNEL_END      _edata_loc
  51 #else
  52 #define KERNEL_START    KERNEL_RAM_VADDR
  53 #define KERNEL_END      _end
  54 #endif
  55
  56 /*
  57  * Kernel startup entry point.
  58  * ---------------------------
  59  *
  60  * This is normally called from the decompressor code.  The requirements
  61  * are: MMU = off, D-cache = off, I-cache = dont care, r0 = 0,
  62  * r1 = machine nr, r2 = atags pointer.
  63  *
  64  * This code is mostly position independent, so if you link the kernel at
  65  * 0xc0008000, you call this at __pa(0xc0008000).
  66  *
  67  * See linux/arch/arm/tools/mach-types for the complete list of machine
  68  * numbers for r1.
  69  *
  70  * We're trying to keep crap to a minimum; DO NOT add any machine specific
  71  * crap here - that's what the boot loader (or in extreme, well justified
  72  * circumstances, zImage) is for.
  73  */
  74         __HEAD
  75 ENTRY(stext)
  76         setmode PSR_F_BIT | PSR_I_BIT | SVC_MODE, r9 @ ensure svc mode
  77                                                 @ and irqs disabled
  78         mrc     p15, 0, r9, c0, c0              @ get processor id
  79         bl      __lookup_processor_type         @ r5=procinfo r9=cpuid
  80         movs    r10, r5                         @ invalid processor (r5=0)?
  81  THUMB( it      eq )            @ force fixup-able long branch encoding
  82         beq     __error_p                       @ yes, error 'p'
  83
  84 #ifndef CONFIG_XIP_KERNEL
  85         adr     r3, 2f
  86         ldmia   r3, {r4, r8}
  87         sub     r4, r3, r4                      @ (PHYS_OFFSET - PAGE_OFFSET)
  88         add     r8, r8, r4                      @ PHYS_OFFSET
  89 #else
  90         ldr     r8, =PLAT_PHYS_OFFSET
  91 #endif
  92
  93         /*
  94          * r1 = machine no, r2 = atags,
  95          * r8 = phys_offset, r9 = cpuid, r10 = procinfo
  96          */
  97         bl      __vet_atags
  98 #ifdef CONFIG_SMP_ON_UP
  99         bl      __fixup_smp
 100 #endif
 101 #ifdef CONFIG_ARM_PATCH_PHYS_VIRT
 102         bl      __fixup_pv_table
 103 #endif
 104         bl      __create_page_tables
 105
 106         /*
 107          * The following calls CPU specific code in a position independent
 108          * manner.  See arch/arm/mm/proc-*.S for details.  r10 = base of
 109          * xxx_proc_info structure selected by __lookup_processor_type
 110          * above.  On return, the CPU will be ready for the MMU to be
 111          * turned on, and r0 will hold the CPU control register value.
 112          */
 113         ldr     r13, =__mmap_switched           @ address to jump to after
 114                                                 @ mmu has been enabled
 115         adr     lr, BSYM(1f)                    @ return (PIC) address
 116  ARM(   add     pc, r10, #PROCINFO_INITFUNC     )
 117  THUMB( add     r12, r10, #PROCINFO_INITFUNC    )
 118  THUMB( mov     pc, r12                         )
 119 1:      b       __enable_mmu
 120 ENDPROC(stext)
 121         .ltorg
 122 #ifndef CONFIG_XIP_KERNEL
 123 2:      .long   .
 124         .long   PAGE_OFFSET
 125 #endif
 126
 127 /*
 128  * Setup the initial page tables.  We only setup the barest
 129  * amount which are required to get the kernel running, which
 130  * generally means mapping in the kernel code.
 131  *
 132  * r8 = phys_offset, r9 = cpuid, r10 = procinfo
 133  *
 134  * Returns:
 135  *  r0, r3, r5-r7 corrupted
 136  *  r4 = physical page table address
 137  */
 138 __create_page_tables:
 139         pgtbl   r4, r8                          @ page table address
 140
 141         /*
 142          * Clear the 16K level 1 swapper page table
 143          */
 144         mov     r0, r4
 145         mov     r3, #0
 146         add     r6, r0, #0x4000
 147 1:      str     r3, [r0], #4
 148         str     r3, [r0], #4
 149         str     r3, [r0], #4
 150         str     r3, [r0], #4
 151         teq     r0, r6
 152         bne     1b
 153
 154         ldr     r7, [r10, #PROCINFO_MM_MMUFLAGS] @ mm_mmuflags
 155
 156         /*
 157          * Create identity mapping to cater for __enable_mmu.
 158          * This identity mapping will be removed by paging_init().
 159          */
 160         adr     r0, __enable_mmu_loc
 161         ldmia   r0, {r3, r5, r6}
 162         sub     r0, r0, r3                      @ virt->phys offset
 163         add     r5, r5, r0                      @ phys __enable_mmu
 164         add     r6, r6, r0                      @ phys __enable_mmu_end
 165         mov     r5, r5, lsr #20
 166         mov     r6, r6, lsr #20
 167
 168 1:      orr     r3, r7, r5, lsl #20             @ flags + kernel base
 169         str     r3, [r4, r5, lsl #2]            @ identity mapping
 170         teq     r5, r6
 171         addne   r5, r5, #1                      @ next section
 172         bne     1b
 173
 174         /*
 175          * Now setup the pagetables for our kernel direct
 176          * mapped region.
 177          */
 178         mov     r3, pc
 179         mov     r3, r3, lsr #20
 180         orr     r3, r7, r3, lsl #20
 181         add     r0, r4,  #(KERNEL_START & 0xff000000) >> 18
 182         str     r3, [r0, #(KERNEL_START & 0x00f00000) >> 18]!
 183         ldr     r6, =(KERNEL_END - 1)
 184         add     r0, r0, #4
 185         add     r6, r4, r6, lsr #18
 186 1:      cmp     r0, r6
 187         add     r3, r3, #1 << 20
 188         strls   r3, [r0], #4
 189         bls     1b
 190
 191 #ifdef CONFIG_XIP_KERNEL
 192         /*
 193          * Map some ram to cover our .data and .bss areas.
 194          */
 195         add     r3, r8, #TEXT_OFFSET
 196         orr     r3, r3, r7
 197         add     r0, r4,  #(KERNEL_RAM_VADDR & 0xff000000) >> 18
 198         str     r3, [r0, #(KERNEL_RAM_VADDR & 0x00f00000) >> 18]!
 199         ldr     r6, =(_end - 1)
 200         add     r0, r0, #4
 201         add     r6, r4, r6, lsr #18
 202 1:      cmp     r0, r6
 203         add     r3, r3, #1 << 20
 204         strls   r3, [r0], #4
 205         bls     1b
 206 #endif
 207
 208         /*
 209          * Then map first 1MB of ram in case it contains our boot params.
 210          */
 211         add     r0, r4, #PAGE_OFFSET >> 18
 212         orr     r6, r7, r8
 213         str     r6, [r0]
 214
 215 #ifdef CONFIG_DEBUG_LL
 216 #ifndef CONFIG_DEBUG_ICEDCC
 217         /*
 218          * Map in IO space for serial debugging.
 219          * This allows debug messages to be output
 220          * via a serial console before paging_init.
 221          */
 222         addruart r7, r3
 223
 224         mov     r3, r3, lsr #20
 225         mov     r3, r3, lsl #2
 226
 227         add     r0, r4, r3
 228         rsb     r3, r3, #0x4000                 @ PTRS_PER_PGD*sizeof(long)
 229         cmp     r3, #0x0800                     @ limit to 512MB
 230         movhi   r3, #0x0800
 231         add     r6, r0, r3
 232         mov     r3, r7, lsr #20
 233         ldr     r7, [r10, #PROCINFO_IO_MMUFLAGS] @ io_mmuflags
 234         orr     r3, r7, r3, lsl #20
 235 1:      str     r3, [r0], #4
 236         add     r3, r3, #1 << 20
 237         teq     r0, r6
 238         bne     1b
 239
 240 #else /* CONFIG_DEBUG_ICEDCC */
 241         /* we don't need any serial debugging mappings for ICEDCC */
 242         ldr     r7, [r10, #PROCINFO_IO_MMUFLAGS] @ io_mmuflags
 243 #endif /* !CONFIG_DEBUG_ICEDCC */
 244
 245 #if defined(CONFIG_ARCH_NETWINDER) || defined(CONFIG_ARCH_CATS)
 246         /*
 247          * If we're using the NetWinder or CATS, we also need to map
 248          * in the 16550-type serial port for the debug messages
 249          */
 250         add     r0, r4, #0xff000000 >> 18
 251         orr     r3, r7, #0x7c000000
 252         str     r3, [r0]
 253 #endif
 254 #ifdef CONFIG_ARCH_RPC
 255         /*
 256          * Map in screen at 0x02000000 & SCREEN2_BASE
 257          * Similar reasons here - for debug.  This is
 258          * only for Acorn RiscPC architectures.
 259          */
 260         add     r0, r4, #0x02000000 >> 18
 261         orr     r3, r7, #0x02000000
 262         str     r3, [r0]
 263         add     r0, r4, #0xd8000000 >> 18
 264         str     r3, [r0]
 265 #endif
 266 #endif
 267         mov     pc, lr
 268 ENDPROC(__create_page_tables)
 269         .ltorg
 270         .align
 271 __enable_mmu_loc:
 272         .long   .
 273         .long   __enable_mmu
 274         .long   __enable_mmu_end
 275
 276 #if defined(CONFIG_SMP)
 277         __CPUINIT
 278 ENTRY(secondary_startup)
 279         /*
 280          * Common entry point for secondary CPUs.
 281          *
 282          * Ensure that we're in SVC mode, and IRQs are disabled.  Lookup
 283          * the processor type - there is no need to check the machine type
 284          * as it has already been validated by the primary processor.
 285          */
 286         setmode PSR_F_BIT | PSR_I_BIT | SVC_MODE, r9
 287         mrc     p15, 0, r9, c0, c0              @ get processor id
 288         bl      __lookup_processor_type
 289         movs    r10, r5                         @ invalid processor?
 290         moveq   r0, #'p'                        @ yes, error 'p'
 291  THUMB( it      eq )            @ force fixup-able long branch encoding
 292         beq     __error_p
 293
 294         /*
 295          * Use the page tables supplied from  __cpu_up.
 296          */
 297         adr     r4, __secondary_data
 298         ldmia   r4, {r5, r7, r12}               @ address to jump to after
 299         sub     r4, r4, r5                      @ mmu has been enabled
 300         ldr     r4, [r7, r4]                    @ get secondary_data.pgdir
 301         adr     lr, BSYM(__enable_mmu)          @ return address
 302         mov     r13, r12                        @ __secondary_switched address
 303  ARM(   add     pc, r10, #PROCINFO_INITFUNC     ) @ initialise processor
 304                                                   @ (return control reg)
 305  THUMB( add     r12, r10, #PROCINFO_INITFUNC    )
 306  THUMB( mov     pc, r12                         )
 307 ENDPROC(secondary_startup)
 308
 309         /*
 310          * r6  = &secondary_data
 311          */
 312 ENTRY(__secondary_switched)
 313         ldr     sp, [r7, #4]                    @ get secondary_data.stack
 314         mov     fp, #0
 315         b       secondary_start_kernel
 316 ENDPROC(__secondary_switched)
 317
 318         .align
 319
 320         .type   __secondary_data, %object
 321 __secondary_data:
 322         .long   .
 323         .long   secondary_data
 324         .long   __secondary_switched
 325 #endif /* defined(CONFIG_SMP) */
 326
 327
 328
 329 /*
 330  * Setup common bits before finally enabling the MMU.  Essentially
 331  * this is just loading the page table pointer and domain access
 332  * registers.
 333  *
 334  *  r0  = cp#15 control register
 335  *  r1  = machine ID
 336  *  r2  = atags pointer
 337  *  r4  = page table pointer
 338  *  r9  = processor ID
 339  *  r13 = *virtual* address to jump to upon completion
 340  */
 341 __enable_mmu:
 342 #ifdef CONFIG_ALIGNMENT_TRAP
 343         orr     r0, r0, #CR_A
 344 #else
 345         bic     r0, r0, #CR_A
 346 #endif
 347 #ifdef CONFIG_CPU_DCACHE_DISABLE
 348         bic     r0, r0, #CR_C
 349 #endif
 350 #ifdef CONFIG_CPU_BPREDICT_DISABLE
 351         bic     r0, r0, #CR_Z
 352 #endif
 353 #ifdef CONFIG_CPU_ICACHE_DISABLE
 354         bic     r0, r0, #CR_I
 355 #endif
 356         mov     r5, #(domain_val(DOMAIN_USER, DOMAIN_MANAGER) | \
 357                       domain_val(DOMAIN_KERNEL, DOMAIN_MANAGER) | \
 358                       domain_val(DOMAIN_TABLE, DOMAIN_MANAGER) | \
 359                       domain_val(DOMAIN_IO, DOMAIN_CLIENT))
 360         mcr     p15, 0, r5, c3, c0, 0           @ load domain access register
 361         mcr     p15, 0, r4, c2, c0, 0           @ load page table pointer
 362         b       __turn_mmu_on
 363 ENDPROC(__enable_mmu)
 364
 365 /*
 366  * Enable the MMU.  This completely changes the structure of the visible
 367  * memory space.  You will not be able to trace execution through this.
 368  * If you have an enquiry about this, *please* check the linux-arm-kernel
 369  * mailing list archives BEFORE sending another post to the list.
 370  *
 371  *  r0  = cp#15 control register
 372  *  r1  = machine ID
 373  *  r2  = atags pointer
 374  *  r9  = processor ID
 375  *  r13 = *virtual* address to jump to upon completion
 376  *
 377  * other registers depend on the function called upon completion
 378  */
 379         .align  5
 380 __turn_mmu_on:
 381         mov     r0, r0
 382         mcr     p15, 0, r0, c1, c0, 0           @ write control reg
 383         mrc     p15, 0, r3, c0, c0, 0           @ read id reg
 384         mov     r3, r3
 385         mov     r3, r13
 386         mov     pc, r3
 387 __enable_mmu_end:
 388 ENDPROC(__turn_mmu_on)
 389
 390
 391 #ifdef CONFIG_SMP_ON_UP
 392 __fixup_smp:
 393         and     r3, r9, #0x000f0000     @ architecture version
 394         teq     r3, #0x000f0000         @ CPU ID supported?
 395         bne     __fixup_smp_on_up       @ no, assume UP
 396
 397         bic     r3, r9, #0x00ff0000
 398         bic     r3, r3, #0x0000000f     @ mask 0xff00fff0
 399         mov     r4, #0x41000000
 400         orr     r4, r4, #0x0000b000
 401         orr     r4, r4, #0x00000020     @ val 0x4100b020
 402         teq     r3, r4                  @ ARM 11MPCore?
 403         moveq   pc, lr                  @ yes, assume SMP
 404
 405         mrc     p15, 0, r0, c0, c0, 5   @ read MPIDR
 406         and     r0, r0, #0xc0000000     @ multiprocessing extensions and
 407         teq     r0, #0x80000000         @ not part of a uniprocessor system?
 408         moveq   pc, lr                  @ yes, assume SMP
 409
 410 __fixup_smp_on_up:
 411         adr     r0, 1f
 412         ldmia   r0, {r3 - r5}
 413         sub     r3, r0, r3
 414         add     r4, r4, r3
 415         add     r5, r5, r3
 416 2:      cmp     r4, r5
 417         movhs   pc, lr
 418         ldmia   r4!, {r0, r6}
 419  ARM(   str     r6, [r0, r3]    )
 420  THUMB( add     r0, r0, r3      )
 421 #ifdef __ARMEB__
 422  THUMB( mov     r6, r6, ror #16 )       @ Convert word order for big-endian.
 423 #endif
 424  THUMB( strh    r6, [r0], #2    )       @ For Thumb-2, store as two halfwords
 425  THUMB( mov     r6, r6, lsr #16 )       @ to be robust against misaligned r3.
 426  THUMB( strh    r6, [r0]        )
 427         b       2b
 428 ENDPROC(__fixup_smp)
 429
 430         .align
 431 1:      .word   .
 432         .word   __smpalt_begin
 433         .word   __smpalt_end
 434
 435         .pushsection .data
 436         .globl  smp_on_up
 437 smp_on_up:
 438         ALT_SMP(.long   1)
 439         ALT_UP(.long    0)
 440         .popsection
 441
 442 #endif
 443
 444 #ifdef CONFIG_ARM_PATCH_PHYS_VIRT
 445
 446 /* __fixup_pv_table - patch the stub instructions with the delta between
 447  * PHYS_OFFSET and PAGE_OFFSET, which is assumed to be 16MiB aligned and
 448  * can be expressed by an immediate shifter operand. The stub instruction
 449  * has a form of '(add|sub) rd, rn, #imm'.
 450  */
 451         __HEAD
 452 __fixup_pv_table:
 453         adr     r0, 1f
 454         ldmia   r0, {r3-r5, r7}
 455         sub     r3, r0, r3      @ PHYS_OFFSET - PAGE_OFFSET
 456         add     r4, r4, r3      @ adjust table start address
 457         add     r5, r5, r3      @ adjust table end address
 458         str     r8, [r7, r3]!   @ save computed PHYS_OFFSET to __pv_phys_offset
 459 #ifndef CONFIG_ARM_PATCH_PHYS_VIRT_16BIT
 460         mov     r6, r3, lsr #24 @ constant for add/sub instructions
 461         teq     r3, r6, lsl #24 @ must be 16MiB aligned
 462 #else
 463         mov     r6, r3, lsr #16 @ constant for add/sub instructions
 464         teq     r3, r6, lsl #16 @ must be 64kiB aligned
 465 #endif
 466         bne     __error
 467         str     r6, [r7, #4]    @ save to __pv_offset
 468         b       __fixup_a_pv_table
 469 ENDPROC(__fixup_pv_table)
 470
 471         .align
 472 1:      .long   .
 473         .long   __pv_table_begin
 474         .long   __pv_table_end
 475 2:      .long   __pv_phys_offset
 476
 477         .text
 478 __fixup_a_pv_table:
 479 #ifdef CONFIG_ARM_PATCH_PHYS_VIRT_16BIT
 480         and     r0, r6, #255    @ offset bits 23-16
 481         mov     r6, r6, lsr #8  @ offset bits 31-24
 482 #else
 483         mov     r0, #0          @ just in case...
 484 #endif
 485         b       3f
 486 2:      ldr     ip, [r7, r3]
 487         bic     ip, ip, #0x000000ff
 488         tst     ip, #0x400      @ rotate shift tells us LS or MS byte
 489         orrne   ip, ip, r6      @ mask in offset bits 31-24
 490         orreq   ip, ip, r0      @ mask in offset bits 23-16
 491         str     ip, [r7, r3]
 492 3:      cmp     r4, r5
 493         ldrcc   r7, [r4], #4    @ use branch for delay slot
 494         bcc     2b
 495         mov     pc, lr
 496 ENDPROC(__fixup_a_pv_table)
 497
 498 ENTRY(fixup_pv_table)
 499         stmfd   sp!, {r4 - r7, lr}
 500         ldr     r2, 2f                  @ get address of __pv_phys_offset
 501         mov     r3, #0                  @ no offset
 502         mov     r4, r0                  @ r0 = table start
 503         add     r5, r0, r1              @ r1 = table size
 504         ldr     r6, [r2, #4]            @ get __pv_offset
 505         bl      __fixup_a_pv_table
 506         ldmfd   sp!, {r4 - r7, pc}
 507 ENDPROC(fixup_pv_table)
 508
 509         .align
 510 2:      .long   __pv_phys_offset
 511
 512         .data
 513         .globl  __pv_phys_offset
 514         .type   __pv_phys_offset, %object
 515 __pv_phys_offset:
 516         .long   0
 517         .size   __pv_phys_offset, . - __pv_phys_offset
 518 __pv_offset:
 519         .long   0
 520 #endif
 521
 522 #include "head-common.S"