arch/arm/kernel/vmlinux.lds.S

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5
   6 #ifdef CONFIG_XIP_KERNEL
   7 #include "vmlinux-xip.lds.S"
   8 #else
   9
  10 #include <asm-generic/vmlinux.lds.h>
  11 #include <asm/cache.h>
  12 #include <asm/thread_info.h>
  13 #include <asm/memory.h>
  14 #include <asm/page.h>
  15 #ifdef CONFIG_DEBUG_RODATA
  16 #include <asm/pgtable.h>
  17 #endif
  18
  19 #define PROC_INFO                                                       \
  20         . = ALIGN(4);                                                   \
  21         VMLINUX_SYMBOL(__proc_info_begin) = .;                          \
  22         *(.proc.info.init)                                              \
  23         VMLINUX_SYMBOL(__proc_info_end) = .;
  24
  25 #define IDMAP_TEXT                                                      \
  26         ALIGN_FUNCTION();                                               \
  27         VMLINUX_SYMBOL(__idmap_text_start) = .;                         \
  28         *(.idmap.text)                                                  \
  29         VMLINUX_SYMBOL(__idmap_text_end) = .;                           \
  30         . = ALIGN(PAGE_SIZE);                                           \
  31         VMLINUX_SYMBOL(__hyp_idmap_text_start) = .;                     \
  32         *(.hyp.idmap.text)                                              \
  33         VMLINUX_SYMBOL(__hyp_idmap_text_end) = .;
  34
  35 #ifdef CONFIG_HOTPLUG_CPU
  36 #define ARM_CPU_DISCARD(x)
  37 #define ARM_CPU_KEEP(x)         x
  38 #else
  39 #define ARM_CPU_DISCARD(x)      x
  40 #define ARM_CPU_KEEP(x)
  41 #endif
  42
  43 #if (defined(CONFIG_SMP_ON_UP) && !defined(CONFIG_DEBUG_SPINLOCK)) || \
  44         defined(CONFIG_GENERIC_BUG)
  45 #define ARM_EXIT_KEEP(x)        x
  46 #define ARM_EXIT_DISCARD(x)
  47 #else
  48 #define ARM_EXIT_KEEP(x)
  49 #define ARM_EXIT_DISCARD(x)     x
  50 #endif
  51
  52 OUTPUT_ARCH(arm)
  53 ENTRY(stext)
  54
  55 #ifndef __ARMEB__
  56 jiffies = jiffies_64;
  57 #else
  58 jiffies = jiffies_64 + 4;
  59 #endif
  60
  61 SECTIONS
  62 {
  63         /*
  64          * XXX: The linker does not define how output sections are
  65          * assigned to input sections when there are multiple statements
  66          * matching the same input section name.  There is no documented
  67          * order of matching.
  68          *
  69          * unwind exit sections must be discarded before the rest of the
  70          * unwind sections get included.
  71          */
  72         /DISCARD/ : {
  73                 *(.ARM.exidx.exit.text)
  74                 *(.ARM.extab.exit.text)
  75                 ARM_CPU_DISCARD(*(.ARM.exidx.cpuexit.text))
  76                 ARM_CPU_DISCARD(*(.ARM.extab.cpuexit.text))
  77                 ARM_EXIT_DISCARD(EXIT_TEXT)
  78                 ARM_EXIT_DISCARD(EXIT_DATA)
  79                 EXIT_CALL
  80 #ifndef CONFIG_MMU
  81                 *(.text.fixup)
  82                 *(__ex_table)
  83 #endif
  84 #ifndef CONFIG_SMP_ON_UP
  85                 *(.alt.smp.init)
  86 #endif
  87                 *(.discard)
  88                 *(.discard.*)
  89         }
  90
  91         . = PAGE_OFFSET + TEXT_OFFSET;
  92         .head.text : {
  93                 _text = .;
  94                 HEAD_TEXT
  95         }
  96
  97 #ifdef CONFIG_DEBUG_RODATA
  98         . = ALIGN(1<<SECTION_SHIFT);
  99 #endif
 100
 101         .text : {                       /* Real text segment            */
 102                 _stext = .;             /* Text and read-only data      */
 103                         IDMAP_TEXT
 104                         __exception_text_start = .;
 105                         *(.exception.text)
 106                         __exception_text_end = .;
 107                         IRQENTRY_TEXT
 108                         TEXT_TEXT
 109                         SCHED_TEXT
 110                         LOCK_TEXT
 111                         KPROBES_TEXT
 112                         *(.gnu.warning)
 113                         *(.glue_7)
 114                         *(.glue_7t)
 115                 . = ALIGN(4);
 116                 *(.got)                 /* Global offset table          */
 117                         ARM_CPU_KEEP(PROC_INFO)
 118         }
 119
 120 #ifdef CONFIG_DEBUG_ALIGN_RODATA
 121         . = ALIGN(1<<SECTION_SHIFT);
 122 #endif
 123         RO_DATA(PAGE_SIZE)
 124
 125         . = ALIGN(4);
 126         __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {
 127                 __start___ex_table = .;
 128 #ifdef CONFIG_MMU
 129                 *(__ex_table)
 130 #endif
 131                 __stop___ex_table = .;
 132         }
 133
 134 #ifdef CONFIG_ARM_UNWIND
 135         /*
 136          * Stack unwinding tables
 137          */
 138         . = ALIGN(8);
 139         .ARM.unwind_idx : {
 140                 __start_unwind_idx = .;
 141                 *(.ARM.exidx*)
 142                 __stop_unwind_idx = .;
 143         }
 144         .ARM.unwind_tab : {
 145                 __start_unwind_tab = .;
 146                 *(.ARM.extab*)
 147                 __stop_unwind_tab = .;
 148         }
 149 #endif
 150
 151         NOTES
 152
 153         _etext = .;                     /* End of text and rodata section */
 154
 155 #ifdef CONFIG_DEBUG_RODATA
 156         . = ALIGN(1<<SECTION_SHIFT);
 157 #else
 158         . = ALIGN(PAGE_SIZE);
 159 #endif
 160         __init_begin = .;
 161
 162         /*
 163          * The vectors and stubs are relocatable code, and the
 164          * only thing that matters is their relative offsets
 165          */
 166         __vectors_start = .;
 167         .vectors 0 : AT(__vectors_start) {
 168                 *(.vectors)
 169         }
 170         . = __vectors_start + SIZEOF(.vectors);
 171         __vectors_end = .;
 172
 173         __stubs_start = .;
 174         .stubs 0x1000 : AT(__stubs_start) {
 175                 *(.stubs)
 176         }
 177         . = __stubs_start + SIZEOF(.stubs);
 178         __stubs_end = .;
 179
 180         INIT_TEXT_SECTION(8)
 181         .exit.text : {
 182                 ARM_EXIT_KEEP(EXIT_TEXT)
 183         }
 184         .init.proc.info : {
 185                 ARM_CPU_DISCARD(PROC_INFO)
 186         }
 187         .init.arch.info : {
 188                 __arch_info_begin = .;
 189                 *(.arch.info.init)
 190                 __arch_info_end = .;
 191         }
 192         .init.tagtable : {
 193                 __tagtable_begin = .;
 194                 *(.taglist.init)
 195                 __tagtable_end = .;
 196         }
 197 #ifdef CONFIG_SMP_ON_UP
 198         .init.smpalt : {
 199                 __smpalt_begin = .;
 200                 *(.alt.smp.init)
 201                 __smpalt_end = .;
 202         }
 203 #endif
 204         .init.pv_table : {
 205                 __pv_table_begin = .;
 206                 *(.pv_table)
 207                 __pv_table_end = .;
 208         }
 209         .init.data : {
 210                 INIT_DATA
 211                 INIT_SETUP(16)
 212                 INIT_CALLS
 213                 CON_INITCALL
 214                 SECURITY_INITCALL
 215                 INIT_RAM_FS
 216         }
 217         .exit.data : {
 218                 ARM_EXIT_KEEP(EXIT_DATA)
 219         }
 220
 221 #ifdef CONFIG_SMP
 222         PERCPU_SECTION(L1_CACHE_BYTES)
 223 #endif
 224
 225 #ifdef CONFIG_DEBUG_RODATA
 226         . = ALIGN(1<<SECTION_SHIFT);
 227 #else
 228         . = ALIGN(THREAD_SIZE);
 229 #endif
 230         __init_end = .;
 231         __data_loc = .;
 232
 233         .data : AT(__data_loc) {
 234                 _data = .;              /* address in memory */
 235                 _sdata = .;
 236
 237                 /*
 238                  * first, the init task union, aligned
 239                  * to an 8192 byte boundary.
 240                  */
 241                 INIT_TASK_DATA(THREAD_SIZE)
 242
 243                 NOSAVE_DATA
 244                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 245                 READ_MOSTLY_DATA(L1_CACHE_BYTES)
 246
 247                 /*
 248                  * and the usual data section
 249                  */
 250                 DATA_DATA
 251                 CONSTRUCTORS
 252
 253                 _edata = .;
 254         }
 255         _edata_loc = __data_loc + SIZEOF(.data);
 256
 257 #ifdef CONFIG_HAVE_TCM
 258         /*
 259          * We align everything to a page boundary so we can
 260          * free it after init has commenced and TCM contents have
 261          * been copied to its destination.
 262          */
 263         .tcm_start : {
 264                 . = ALIGN(PAGE_SIZE);
 265                 __tcm_start = .;
 266                 __itcm_start = .;
 267         }
 268
 269         /*
 270          * Link these to the ITCM RAM
 271          * Put VMA to the TCM address and LMA to the common RAM
 272          * and we'll upload the contents from RAM to TCM and free
 273          * the used RAM after that.
 274          */
 275         .text_itcm ITCM_OFFSET : AT(__itcm_start)
 276         {
 277                 __sitcm_text = .;
 278                 *(.tcm.text)
 279                 *(.tcm.rodata)
 280                 . = ALIGN(4);
 281                 __eitcm_text = .;
 282         }
 283
 284         /*
 285          * Reset the dot pointer, this is needed to create the
 286          * relative __dtcm_start below (to be used as extern in code).
 287          */
 288         . = ADDR(.tcm_start) + SIZEOF(.tcm_start) + SIZEOF(.text_itcm);
 289
 290         .dtcm_start : {
 291                 __dtcm_start = .;
 292         }
 293
 294         /* TODO: add remainder of ITCM as well, that can be used for data! */
 295         .data_dtcm DTCM_OFFSET : AT(__dtcm_start)
 296         {
 297                 . = ALIGN(4);
 298                 __sdtcm_data = .;
 299                 *(.tcm.data)
 300                 . = ALIGN(4);
 301                 __edtcm_data = .;
 302         }
 303
 304         /* Reset the dot pointer or the linker gets confused */
 305         . = ADDR(.dtcm_start) + SIZEOF(.data_dtcm);
 306
 307         /* End marker for freeing TCM copy in linked object */
 308         .tcm_end : AT(ADDR(.dtcm_start) + SIZEOF(.data_dtcm)){
 309                 . = ALIGN(PAGE_SIZE);
 310                 __tcm_end = .;
 311         }
 312 #endif
 313
 314         BSS_SECTION(0, 0, 0)
 315         _end = .;
 316
 317         STABS_DEBUG
 318 }
 319
 320 /*
 321  * These must never be empty
 322  * If you have to comment these two assert statements out, your
 323  * binutils is too old (for other reasons as well)
 324  */
 325 ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
 326 ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")
 327
 328 /*
 329  * The HYP init code can't be more than a page long,
 330  * and should not cross a page boundary.
 331  * The above comment applies as well.
 332  */
 333 ASSERT(__hyp_idmap_text_end - (__hyp_idmap_text_start & PAGE_MASK) <= PAGE_SIZE,
 334         "HYP init code too big or misaligned")
 335
 336 #endif /* CONFIG_XIP_KERNEL */