arch/arm/mach-omap1/ams-delta-fiq-handler.S

   1 /*
   2  *  linux/arch/arm/mach-omap1/ams-delta-fiq-handler.S
   3  *
   4  *  Based on  linux/arch/arm/lib/floppydma.S
   5  *  Renamed and modified to work with 2.6 kernel by Matt Callow
   6  *  Copyright (C) 1995, 1996 Russell King
   7  *  Copyright (C) 2004 Pete Trapps
   8  *  Copyright (C) 2006 Matt Callow
   9  *  Copyright (C) 2010 Janusz Krzysztofik
  10  *
  11  * This program is free software; you can redistribute it and/or modify it
  12  * under the terms of the GNU General Public License version 2
  13  * as published by the Free Software Foundation.
  14  */
  15
  16 #include <linux/linkage.h>
  17
  18 #include <plat/board-ams-delta.h>
  19
  20 #include <mach/ams-delta-fiq.h>
  21
  22 #include "iomap.h"
  23
  24 /*
  25  * GPIO related definitions, copied from arch/arm/plat-omap/gpio.c.
  26  * Unfortunately, those were not placed in a separate header file.
  27  */
  28 #define OMAP1510_GPIO_BASE              0xFFFCE000
  29 #define OMAP1510_GPIO_DATA_INPUT        0x00
  30 #define OMAP1510_GPIO_DATA_OUTPUT       0x04
  31 #define OMAP1510_GPIO_DIR_CONTROL       0x08
  32 #define OMAP1510_GPIO_INT_CONTROL       0x0c
  33 #define OMAP1510_GPIO_INT_MASK          0x10
  34 #define OMAP1510_GPIO_INT_STATUS        0x14
  35 #define OMAP1510_GPIO_PIN_CONTROL       0x18
  36
  37 /* GPIO register bitmasks */
  38 #define KEYBRD_DATA_MASK                (0x1 << AMS_DELTA_GPIO_PIN_KEYBRD_DATA)
  39 #define KEYBRD_CLK_MASK                 (0x1 << AMS_DELTA_GPIO_PIN_KEYBRD_CLK)
  40 #define MODEM_IRQ_MASK                  (0x1 << AMS_DELTA_GPIO_PIN_MODEM_IRQ)
  41 #define HOOK_SWITCH_MASK                (0x1 << AMS_DELTA_GPIO_PIN_HOOK_SWITCH)
  42 #define OTHERS_MASK                     (MODEM_IRQ_MASK | HOOK_SWITCH_MASK)
  43
  44 /* IRQ handler register bitmasks */
  45 #define DEFERRED_FIQ_MASK               (0x1 << (INT_DEFERRED_FIQ % IH2_BASE))
  46 #define GPIO_BANK1_MASK                 (0x1 << INT_GPIO_BANK1)
  47
  48 /* Driver buffer byte offsets */
  49 #define BUF_MASK                        (FIQ_MASK * 4)
  50 #define BUF_STATE                       (FIQ_STATE * 4)
  51 #define BUF_KEYS_CNT                    (FIQ_KEYS_CNT * 4)
  52 #define BUF_TAIL_OFFSET                 (FIQ_TAIL_OFFSET * 4)
  53 #define BUF_HEAD_OFFSET                 (FIQ_HEAD_OFFSET * 4)
  54 #define BUF_BUF_LEN                     (FIQ_BUF_LEN * 4)
  55 #define BUF_KEY                         (FIQ_KEY * 4)
  56 #define BUF_MISSED_KEYS                 (FIQ_MISSED_KEYS * 4)
  57 #define BUF_BUFFER_START                (FIQ_BUFFER_START * 4)
  58 #define BUF_GPIO_INT_MASK               (FIQ_GPIO_INT_MASK * 4)
  59 #define BUF_KEYS_HICNT                  (FIQ_KEYS_HICNT * 4)
  60 #define BUF_IRQ_PEND                    (FIQ_IRQ_PEND * 4)
  61 #define BUF_SIR_CODE_L1                 (FIQ_SIR_CODE_L1 * 4)
  62 #define BUF_SIR_CODE_L2                 (IRQ_SIR_CODE_L2 * 4)
  63 #define BUF_CNT_INT_00                  (FIQ_CNT_INT_00 * 4)
  64 #define BUF_CNT_INT_KEY                 (FIQ_CNT_INT_KEY * 4)
  65 #define BUF_CNT_INT_MDM                 (FIQ_CNT_INT_MDM * 4)
  66 #define BUF_CNT_INT_03                  (FIQ_CNT_INT_03 * 4)
  67 #define BUF_CNT_INT_HSW                 (FIQ_CNT_INT_HSW * 4)
  68 #define BUF_CNT_INT_05                  (FIQ_CNT_INT_05 * 4)
  69 #define BUF_CNT_INT_06                  (FIQ_CNT_INT_06 * 4)
  70 #define BUF_CNT_INT_07                  (FIQ_CNT_INT_07 * 4)
  71 #define BUF_CNT_INT_08                  (FIQ_CNT_INT_08 * 4)
  72 #define BUF_CNT_INT_09                  (FIQ_CNT_INT_09 * 4)
  73 #define BUF_CNT_INT_10                  (FIQ_CNT_INT_10 * 4)
  74 #define BUF_CNT_INT_11                  (FIQ_CNT_INT_11 * 4)
  75 #define BUF_CNT_INT_12                  (FIQ_CNT_INT_12 * 4)
  76 #define BUF_CNT_INT_13                  (FIQ_CNT_INT_13 * 4)
  77 #define BUF_CNT_INT_14                  (FIQ_CNT_INT_14 * 4)
  78 #define BUF_CNT_INT_15                  (FIQ_CNT_INT_15 * 4)
  79 #define BUF_CIRC_BUFF                   (FIQ_CIRC_BUFF * 4)
  80
  81
  82 /*
  83  * Register usage
  84  * r8  - temporary
  85  * r9  - the driver buffer
  86  * r10 - temporary
  87  * r11 - interrupts mask
  88  * r12 - base pointers
  89  * r13 - interrupts status
  90  */
  91
  92         .text
  93
  94         .global qwerty_fiqin_end
  95
  96 ENTRY(qwerty_fiqin_start)
  97         @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
  98         @ FIQ intrrupt handler
  99         ldr r12, omap_ih1_base                  @ set pointer to level1 handler
 100
 101         ldr r11, [r12, #IRQ_MIR_REG_OFFSET]     @ fetch interrupts mask
 102
 103         ldr r13, [r12, #IRQ_ITR_REG_OFFSET]     @ fetch interrupts status
 104         bics r13, r13, r11                      @ clear masked - any left?
 105         beq exit                                @ none - spurious FIQ? exit
 106
 107         ldr r10, [r12, #IRQ_SIR_FIQ_REG_OFFSET] @ get requested interrupt number
 108
 109         mov r8, #2                              @ reset FIQ agreement
 110         str r8, [r12, #IRQ_CONTROL_REG_OFFSET]
 111
 112         cmp r10, #INT_GPIO_BANK1                @ is it GPIO bank interrupt?
 113         beq gpio                                @ yes - process it
 114
 115         mov r8, #1
 116         orr r8, r11, r8, lsl r10                @ mask spurious interrupt
 117         str r8, [r12, #IRQ_MIR_REG_OFFSET]
 118 exit:
 119         subs    pc, lr, #4                      @ return from FIQ
 120         @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
 121
 122
 123         @@@@@@@@@@@@@@@@@@@@@@@@@@@
 124 gpio:   @ GPIO bank interrupt handler
 125         ldr r12, omap1510_gpio_base             @ set base pointer to GPIO bank
 126
 127         ldr r11, [r12, #OMAP1510_GPIO_INT_MASK] @ fetch GPIO interrupts mask
 128 restart:
 129         ldr r13, [r12, #OMAP1510_GPIO_INT_STATUS]       @ fetch status bits
 130         bics r13, r13, r11                      @ clear masked - any left?
 131         beq exit                                @ no - spurious interrupt? exit
 132
 133         orr r11, r11, r13                       @ mask all requested interrupts
 134         str r11, [r12, #OMAP1510_GPIO_INT_MASK]
 135
 136         ands r10, r13, #KEYBRD_CLK_MASK         @ extract keyboard status - set?
 137         beq hksw                                @ no - try next source
 138
 139
 140         @@@@@@@@@@@@@@@@@@@@@@
 141         @ Keyboard clock FIQ mode interrupt handler
 142         @ r10 now contains KEYBRD_CLK_MASK, use it
 143         str r10, [r12, #OMAP1510_GPIO_INT_STATUS]       @ ack the interrupt
 144         bic r11, r11, r10                               @ unmask it
 145         str r11, [r12, #OMAP1510_GPIO_INT_MASK]
 146
 147         @ Process keyboard data
 148         ldr r8, [r12, #OMAP1510_GPIO_DATA_INPUT]        @ fetch GPIO input
 149
 150         ldr r10, [r9, #BUF_STATE]               @ fetch kbd interface state
 151         cmp r10, #0                             @ are we expecting start bit?
 152         bne data                                @ no - go to data processing
 153
 154         ands r8, r8, #KEYBRD_DATA_MASK          @ check start bit - detected?
 155         beq hksw                                @ no - try next source
 156
 157         @ r8 contains KEYBRD_DATA_MASK, use it
 158         str r8, [r9, #BUF_STATE]                @ enter data processing state
 159         @ r10 already contains 0, reuse it
 160         str r10, [r9, #BUF_KEY]                 @ clear keycode
 161         mov r10, #2                             @ reset input bit mask
 162         str r10, [r9, #BUF_MASK]
 163
 164         @ Mask other GPIO line interrupts till key done
 165         str r11, [r9, #BUF_GPIO_INT_MASK]       @ save mask for later restore
 166         mvn r11, #KEYBRD_CLK_MASK               @ prepare all except kbd mask
 167         str r11, [r12, #OMAP1510_GPIO_INT_MASK] @ store into the mask register
 168
 169         b restart                               @ restart
 170
 171 data:   ldr r10, [r9, #BUF_MASK]                @ fetch current input bit mask
 172
 173         @ r8 still contains GPIO input bits
 174         ands r8, r8, #KEYBRD_DATA_MASK          @ is keyboard data line low?
 175         ldreq r8, [r9, #BUF_KEY]                @ yes - fetch collected so far,
 176         orreq r8, r8, r10                       @ set 1 at current mask position
 177         streq r8, [r9, #BUF_KEY]                @ and save back
 178
 179         mov r10, r10, lsl #1                    @ shift mask left
 180         bics r10, r10, #0x800                   @ have we got all the bits?
 181         strne r10, [r9, #BUF_MASK]              @ not yet - store the mask
 182         bne restart                             @ and restart
 183
 184         @ r10 already contains 0, reuse it
 185         str r10, [r9, #BUF_STATE]               @ reset state to start
 186
 187         @ Key done - restore interrupt mask
 188         ldr r10, [r9, #BUF_GPIO_INT_MASK]       @ fetch saved mask
 189         and r11, r11, r10                       @ unmask all saved as unmasked
 190         str r11, [r12, #OMAP1510_GPIO_INT_MASK] @ restore into the mask register
 191
 192         @ Try appending the keycode to the circular buffer
 193         ldr r10, [r9, #BUF_KEYS_CNT]            @ get saved keystrokes count
 194         ldr r8, [r9, #BUF_BUF_LEN]              @ get buffer size
 195         cmp r10, r8                             @ is buffer full?
 196         beq hksw                                @ yes - key lost, next source
 197
 198         add r10, r10, #1                        @ incremet keystrokes counter
 199         str r10, [r9, #BUF_KEYS_CNT]
 200
 201         ldr r10, [r9, #BUF_TAIL_OFFSET]         @ get buffer tail offset
 202         @ r8 already contains buffer size
 203         cmp r10, r8                             @ end of buffer?
 204         moveq r10, #0                           @ yes - rewind to buffer start
 205
 206         ldr r12, [r9, #BUF_BUFFER_START]        @ get buffer start address
 207         add r12, r12, r10, LSL #2               @ calculate buffer tail address
 208         ldr r8, [r9, #BUF_KEY]                  @ get last keycode
 209         str r8, [r12]                           @ append it to the buffer tail
 210
 211         add r10, r10, #1                        @ increment buffer tail offset
 212         str r10, [r9, #BUF_TAIL_OFFSET]
 213
 214         ldr r10, [r9, #BUF_CNT_INT_KEY]         @ increment interrupts counter
 215         add r10, r10, #1
 216         str r10, [r9, #BUF_CNT_INT_KEY]
 217         @@@@@@@@@@@@@@@@@@@@@@@@
 218
 219
 220 hksw:   @Is hook switch interrupt requested?
 221         tst r13, #HOOK_SWITCH_MASK              @ is hook switch status bit set?
 222         beq mdm                                 @ no - try next source
 223
 224
 225         @@@@@@@@@@@@@@@@@@@@@@@@
 226         @ Hook switch interrupt FIQ mode simple handler
 227
 228         @ Don't toggle active edge, the switch always bounces
 229
 230         @ Increment hook switch interrupt counter
 231         ldr r10, [r9, #BUF_CNT_INT_HSW]
 232         add r10, r10, #1
 233         str r10, [r9, #BUF_CNT_INT_HSW]
 234         @@@@@@@@@@@@@@@@@@@@@@@@
 235
 236
 237 mdm:    @Is it a modem interrupt?
 238         tst r13, #MODEM_IRQ_MASK                @ is modem status bit set?
 239         beq irq                                 @ no - check for next interrupt
 240
 241
 242         @@@@@@@@@@@@@@@@@@@@@@@@
 243         @ Modem FIQ mode interrupt handler stub
 244
 245         @ Increment modem interrupt counter
 246         ldr r10, [r9, #BUF_CNT_INT_MDM]
 247         add r10, r10, #1
 248         str r10, [r9, #BUF_CNT_INT_MDM]
 249         @@@@@@@@@@@@@@@@@@@@@@@@
 250
 251
 252 irq:    @ Place deferred_fiq interrupt request
 253         ldr r12, deferred_fiq_ih_base           @ set pointer to IRQ handler
 254         mov r10, #DEFERRED_FIQ_MASK             @ set deferred_fiq bit
 255         str r10, [r12, #IRQ_ISR_REG_OFFSET]     @ place it in the ISR register
 256
 257         ldr r12, omap1510_gpio_base             @ set pointer back to GPIO bank
 258         b restart                               @ check for next GPIO interrupt
 259         @@@@@@@@@@@@@@@@@@@@@@@@@@@
 260
 261
 262 /*
 263  * Virtual addresses for IO
 264  */
 265 omap_ih1_base:
 266         .word OMAP1_IO_ADDRESS(OMAP_IH1_BASE)
 267 deferred_fiq_ih_base:
 268         .word OMAP1_IO_ADDRESS(DEFERRED_FIQ_IH_BASE)
 269 omap1510_gpio_base:
 270         .word OMAP1_IO_ADDRESS(OMAP1510_GPIO_BASE)
 271 qwerty_fiqin_end:
 272
 273 /*
 274  * Check the size of the FIQ,
 275  * it cannot go beyond 0xffff0200, and is copied to 0xffff001c
 276  */
 277 .if (qwerty_fiqin_end - qwerty_fiqin_start) > (0x200 - 0x1c)
 278         .err
 279 .endif