arch/arm/mm/proc-arm922.S

   1 /*
   2  *  linux/arch/arm/mm/proc-arm922.S: MMU functions for ARM922
   3  *
   4  *  Copyright (C) 1999,2000 ARM Limited
   5  *  Copyright (C) 2000 Deep Blue Solutions Ltd.
   6  *  Copyright (C) 2001 Altera Corporation
   7  *  hacked for non-paged-MM by Hyok S. Choi, 2003.
   8  *
   9  * This program is free software; you can redistribute it and/or modify
  10  * it under the terms of the GNU General Public License as published by
  11  * the Free Software Foundation; either version 2 of the License, or
  12  * (at your option) any later version.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  22  *
  23  *
  24  * These are the low level assembler for performing cache and TLB
  25  * functions on the arm922.
  26  *
  27  *  CONFIG_CPU_ARM922_CPU_IDLE -> nohlt
  28  */
  29 #include <linux/linkage.h>
  30 #include <linux/init.h>
  31 #include <asm/assembler.h>
  32 #include <asm/hwcap.h>
  33 #include <asm/pgtable-hwdef.h>
  34 #include <asm/pgtable.h>
  35 #include <asm/page.h>
  36 #include <asm/ptrace.h>
  37 #include "proc-macros.S"
  38
  39 /*
  40  * The size of one data cache line.
  41  */
  42 #define CACHE_DLINESIZE 32
  43
  44 /*
  45  * The number of data cache segments.
  46  */
  47 #define CACHE_DSEGMENTS 4
  48
  49 /*
  50  * The number of lines in a cache segment.
  51  */
  52 #define CACHE_DENTRIES  64
  53
  54 /*
  55  * This is the size at which it becomes more efficient to
  56  * clean the whole cache, rather than using the individual
  57  * cache line maintainence instructions.  (I think this should
  58  * be 32768).
  59  */
  60 #define CACHE_DLIMIT    8192
  61
  62
  63         .text
  64 /*
  65  * cpu_arm922_proc_init()
  66  */
  67 ENTRY(cpu_arm922_proc_init)
  68         mov     pc, lr
  69
  70 /*
  71  * cpu_arm922_proc_fin()
  72  */
  73 ENTRY(cpu_arm922_proc_fin)
  74         stmfd   sp!, {lr}
  75         mov     ip, #PSR_F_BIT | PSR_I_BIT | SVC_MODE
  76         msr     cpsr_c, ip
  77 #ifndef CONFIG_CPU_DCACHE_WRITETHROUGH
  78         bl      arm922_flush_kern_cache_all
  79 #else
  80         bl      v4wt_flush_kern_cache_all
  81 #endif
  82         mrc     p15, 0, r0, c1, c0, 0           @ ctrl register
  83         bic     r0, r0, #0x1000                 @ ...i............
  84         bic     r0, r0, #0x000e                 @ ............wca.
  85         mcr     p15, 0, r0, c1, c0, 0           @ disable caches
  86         ldmfd   sp!, {pc}
  87
  88 /*
  89  * cpu_arm922_reset(loc)
  90  *
  91  * Perform a soft reset of the system.  Put the CPU into the
  92  * same state as it would be if it had been reset, and branch
  93  * to what would be the reset vector.
  94  *
  95  * loc: location to jump to for soft reset
  96  */
  97         .align  5
  98 ENTRY(cpu_arm922_reset)
  99         mov     ip, #0
 100         mcr     p15, 0, ip, c7, c7, 0           @ invalidate I,D caches
 101         mcr     p15, 0, ip, c7, c10, 4          @ drain WB
 102 #ifdef CONFIG_MMU
 103         mcr     p15, 0, ip, c8, c7, 0           @ invalidate I & D TLBs
 104 #endif
 105         mrc     p15, 0, ip, c1, c0, 0           @ ctrl register
 106         bic     ip, ip, #0x000f                 @ ............wcam
 107         bic     ip, ip, #0x1100                 @ ...i...s........
 108         mcr     p15, 0, ip, c1, c0, 0           @ ctrl register
 109         mov     pc, r0
 110
 111 /*
 112  * cpu_arm922_do_idle()
 113  */
 114         .align  5
 115 ENTRY(cpu_arm922_do_idle)
 116         mcr     p15, 0, r0, c7, c0, 4           @ Wait for interrupt
 117         mov     pc, lr
 118
 119
 120 #ifndef CONFIG_CPU_DCACHE_WRITETHROUGH
 121
 122 /*
 123  *      flush_user_cache_all()
 124  *
 125  *      Clean and invalidate all cache entries in a particular
 126  *      address space.
 127  */
 128 ENTRY(arm922_flush_user_cache_all)
 129         /* FALLTHROUGH */
 130
 131 /*
 132  *      flush_kern_cache_all()
 133  *
 134  *      Clean and invalidate the entire cache.
 135  */
 136 ENTRY(arm922_flush_kern_cache_all)
 137         mov     r2, #VM_EXEC
 138         mov     ip, #0
 139 __flush_whole_cache:
 140         mov     r1, #(CACHE_DSEGMENTS - 1) << 5 @ 8 segments
 141 1:      orr     r3, r1, #(CACHE_DENTRIES - 1) << 26 @ 64 entries
 142 2:      mcr     p15, 0, r3, c7, c14, 2          @ clean+invalidate D index
 143         subs    r3, r3, #1 << 26
 144         bcs     2b                              @ entries 63 to 0
 145         subs    r1, r1, #1 << 5
 146         bcs     1b                              @ segments 7 to 0
 147         tst     r2, #VM_EXEC
 148         mcrne   p15, 0, ip, c7, c5, 0           @ invalidate I cache
 149         mcrne   p15, 0, ip, c7, c10, 4          @ drain WB
 150         mov     pc, lr
 151
 152 /*
 153  *      flush_user_cache_range(start, end, flags)
 154  *
 155  *      Clean and invalidate a range of cache entries in the
 156  *      specified address range.
 157  *
 158  *      - start - start address (inclusive)
 159  *      - end   - end address (exclusive)
 160  *      - flags - vm_flags describing address space
 161  */
 162 ENTRY(arm922_flush_user_cache_range)
 163         mov     ip, #0
 164         sub     r3, r1, r0                      @ calculate total size
 165         cmp     r3, #CACHE_DLIMIT
 166         bhs     __flush_whole_cache
 167
 168 1:      mcr     p15, 0, r0, c7, c14, 1          @ clean+invalidate D entry
 169         tst     r2, #VM_EXEC
 170         mcrne   p15, 0, r0, c7, c5, 1           @ invalidate I entry
 171         add     r0, r0, #CACHE_DLINESIZE
 172         cmp     r0, r1
 173         blo     1b
 174         tst     r2, #VM_EXEC
 175         mcrne   p15, 0, ip, c7, c10, 4          @ drain WB
 176         mov     pc, lr
 177
 178 /*
 179  *      coherent_kern_range(start, end)
 180  *
 181  *      Ensure coherency between the Icache and the Dcache in the
 182  *      region described by start, end.  If you have non-snooping
 183  *      Harvard caches, you need to implement this function.
 184  *
 185  *      - start - virtual start address
 186  *      - end   - virtual end address
 187  */
 188 ENTRY(arm922_coherent_kern_range)
 189         /* FALLTHROUGH */
 190
 191 /*
 192  *      coherent_user_range(start, end)
 193  *
 194  *      Ensure coherency between the Icache and the Dcache in the
 195  *      region described by start, end.  If you have non-snooping
 196  *      Harvard caches, you need to implement this function.
 197  *
 198  *      - start - virtual start address
 199  *      - end   - virtual end address
 200  */
 201 ENTRY(arm922_coherent_user_range)
 202         bic     r0, r0, #CACHE_DLINESIZE - 1
 203 1:      mcr     p15, 0, r0, c7, c10, 1          @ clean D entry
 204         mcr     p15, 0, r0, c7, c5, 1           @ invalidate I entry
 205         add     r0, r0, #CACHE_DLINESIZE
 206         cmp     r0, r1
 207         blo     1b
 208         mcr     p15, 0, r0, c7, c10, 4          @ drain WB
 209         mov     pc, lr
 210
 211 /*
 212  *      flush_kern_dcache_area(void *addr, size_t size)
 213  *
 214  *      Ensure no D cache aliasing occurs, either with itself or
 215  *      the I cache
 216  *
 217  *      - addr  - kernel address
 218  *      - size  - region size
 219  */
 220 ENTRY(arm922_flush_kern_dcache_area)
 221         add     r1, r0, r1
 222 1:      mcr     p15, 0, r0, c7, c14, 1          @ clean+invalidate D entry
 223         add     r0, r0, #CACHE_DLINESIZE
 224         cmp     r0, r1
 225         blo     1b
 226         mov     r0, #0
 227         mcr     p15, 0, r0, c7, c5, 0           @ invalidate I cache
 228         mcr     p15, 0, r0, c7, c10, 4          @ drain WB
 229         mov     pc, lr
 230
 231 /*
 232  *      dma_inv_range(start, end)
 233  *
 234  *      Invalidate (discard) the specified virtual address range.
 235  *      May not write back any entries.  If 'start' or 'end'
 236  *      are not cache line aligned, those lines must be written
 237  *      back.
 238  *
 239  *      - start - virtual start address
 240  *      - end   - virtual end address
 241  *
 242  * (same as v4wb)
 243  */
 244 ENTRY(arm922_dma_inv_range)
 245         tst     r0, #CACHE_DLINESIZE - 1
 246         bic     r0, r0, #CACHE_DLINESIZE - 1
 247         mcrne   p15, 0, r0, c7, c10, 1          @ clean D entry
 248         tst     r1, #CACHE_DLINESIZE - 1
 249         mcrne   p15, 0, r1, c7, c10, 1          @ clean D entry
 250 1:      mcr     p15, 0, r0, c7, c6, 1           @ invalidate D entry
 251         add     r0, r0, #CACHE_DLINESIZE
 252         cmp     r0, r1
 253         blo     1b
 254         mcr     p15, 0, r0, c7, c10, 4          @ drain WB
 255         mov     pc, lr
 256
 257 /*
 258  *      dma_clean_range(start, end)
 259  *
 260  *      Clean the specified virtual address range.
 261  *
 262  *      - start - virtual start address
 263  *      - end   - virtual end address
 264  *
 265  * (same as v4wb)
 266  */
 267 ENTRY(arm922_dma_clean_range)
 268         bic     r0, r0, #CACHE_DLINESIZE - 1
 269 1:      mcr     p15, 0, r0, c7, c10, 1          @ clean D entry
 270         add     r0, r0, #CACHE_DLINESIZE
 271         cmp     r0, r1
 272         blo     1b
 273         mcr     p15, 0, r0, c7, c10, 4          @ drain WB
 274         mov     pc, lr
 275
 276 /*
 277  *      dma_flush_range(start, end)
 278  *
 279  *      Clean and invalidate the specified virtual address range.
 280  *
 281  *      - start - virtual start address
 282  *      - end   - virtual end address
 283  */
 284 ENTRY(arm922_dma_flush_range)
 285         bic     r0, r0, #CACHE_DLINESIZE - 1
 286 1:      mcr     p15, 0, r0, c7, c14, 1          @ clean+invalidate D entry
 287         add     r0, r0, #CACHE_DLINESIZE
 288         cmp     r0, r1
 289         blo     1b
 290         mcr     p15, 0, r0, c7, c10, 4          @ drain WB
 291         mov     pc, lr
 292
 293 /*
 294  *      dma_map_area(start, size, dir)
 295  *      - start - kernel virtual start address
 296  *      - size  - size of region
 297  *      - dir   - DMA direction
 298  */
 299 ENTRY(arm922_dma_map_area)
 300         add     r1, r1, r0
 301         cmp     r2, #DMA_TO_DEVICE
 302         beq     arm922_dma_clean_range
 303         bcs     arm922_dma_inv_range
 304         b       arm922_dma_flush_range
 305 ENDPROC(arm922_dma_map_area)
 306
 307 /*
 308  *      dma_unmap_area(start, size, dir)
 309  *      - start - kernel virtual start address
 310  *      - size  - size of region
 311  *      - dir   - DMA direction
 312  */
 313 ENTRY(arm922_dma_unmap_area)
 314         mov     pc, lr
 315 ENDPROC(arm922_dma_unmap_area)
 316
 317 ENTRY(arm922_cache_fns)
 318         .long   arm922_flush_kern_cache_all
 319         .long   arm922_flush_user_cache_all
 320         .long   arm922_flush_user_cache_range
 321         .long   arm922_coherent_kern_range
 322         .long   arm922_coherent_user_range
 323         .long   arm922_flush_kern_dcache_area
 324         .long   arm922_dma_map_area
 325         .long   arm922_dma_unmap_area
 326         .long   arm922_dma_inv_range
 327         .long   arm922_dma_clean_range
 328         .long   arm922_dma_flush_range
 329
 330 #endif
 331
 332
 333 ENTRY(cpu_arm922_dcache_clean_area)
 334 #ifndef CONFIG_CPU_DCACHE_WRITETHROUGH
 335 1:      mcr     p15, 0, r0, c7, c10, 1          @ clean D entry
 336         add     r0, r0, #CACHE_DLINESIZE
 337         subs    r1, r1, #CACHE_DLINESIZE
 338         bhi     1b
 339 #endif
 340         mov     pc, lr
 341
 342 /* =============================== PageTable ============================== */
 343
 344 /*
 345  * cpu_arm922_switch_mm(pgd)
 346  *
 347  * Set the translation base pointer to be as described by pgd.
 348  *
 349  * pgd: new page tables
 350  */
 351         .align  5
 352 ENTRY(cpu_arm922_switch_mm)
 353 #ifdef CONFIG_MMU
 354         mov     ip, #0
 355 #ifdef CONFIG_CPU_DCACHE_WRITETHROUGH
 356         mcr     p15, 0, ip, c7, c6, 0           @ invalidate D cache
 357 #else
 358 @ && 'Clean & Invalidate whole DCache'
 359 @ && Re-written to use Index Ops.
 360 @ && Uses registers r1, r3 and ip
 361
 362         mov     r1, #(CACHE_DSEGMENTS - 1) << 5 @ 4 segments
 363 1:      orr     r3, r1, #(CACHE_DENTRIES - 1) << 26 @ 64 entries
 364 2:      mcr     p15, 0, r3, c7, c14, 2          @ clean & invalidate D index
 365         subs    r3, r3, #1 << 26
 366         bcs     2b                              @ entries 63 to 0
 367         subs    r1, r1, #1 << 5
 368         bcs     1b                              @ segments 7 to 0
 369 #endif
 370         mcr     p15, 0, ip, c7, c5, 0           @ invalidate I cache
 371         mcr     p15, 0, ip, c7, c10, 4          @ drain WB
 372         mcr     p15, 0, r0, c2, c0, 0           @ load page table pointer
 373         mcr     p15, 0, ip, c8, c7, 0           @ invalidate I & D TLBs
 374 #endif
 375         mov     pc, lr
 376
 377 /*
 378  * cpu_arm922_set_pte_ext(ptep, pte, ext)
 379  *
 380  * Set a PTE and flush it out
 381  */
 382         .align  5
 383 ENTRY(cpu_arm922_set_pte_ext)
 384 #ifdef CONFIG_MMU
 385         armv3_set_pte_ext
 386         mov     r0, r0
 387         mcr     p15, 0, r0, c7, c10, 1          @ clean D entry
 388         mcr     p15, 0, r0, c7, c10, 4          @ drain WB
 389 #endif /* CONFIG_MMU */
 390         mov     pc, lr
 391
 392         __INIT
 393
 394         .type   __arm922_setup, #function
 395 __arm922_setup:
 396         mov     r0, #0
 397         mcr     p15, 0, r0, c7, c7              @ invalidate I,D caches on v4
 398         mcr     p15, 0, r0, c7, c10, 4          @ drain write buffer on v4
 399 #ifdef CONFIG_MMU
 400         mcr     p15, 0, r0, c8, c7              @ invalidate I,D TLBs on v4
 401 #endif
 402         adr     r5, arm922_crval
 403         ldmia   r5, {r5, r6}
 404         mrc     p15, 0, r0, c1, c0              @ get control register v4
 405         bic     r0, r0, r5
 406         orr     r0, r0, r6
 407         mov     pc, lr
 408         .size   __arm922_setup, . - __arm922_setup
 409
 410         /*
 411          *  R
 412          * .RVI ZFRS BLDP WCAM
 413          * ..11 0001 ..11 0101
 414          *
 415          */
 416         .type   arm922_crval, #object
 417 arm922_crval:
 418         crval   clear=0x00003f3f, mmuset=0x00003135, ucset=0x00001130
 419
 420         __INITDATA
 421
 422 /*
 423  * Purpose : Function pointers used to access above functions - all calls
 424  *           come through these
 425  */
 426         .type   arm922_processor_functions, #object
 427 arm922_processor_functions:
 428         .word   v4t_early_abort
 429         .word   legacy_pabort
 430         .word   cpu_arm922_proc_init
 431         .word   cpu_arm922_proc_fin
 432         .word   cpu_arm922_reset
 433         .word   cpu_arm922_do_idle
 434         .word   cpu_arm922_dcache_clean_area
 435         .word   cpu_arm922_switch_mm
 436         .word   cpu_arm922_set_pte_ext
 437         .size   arm922_processor_functions, . - arm922_processor_functions
 438
 439         .section ".rodata"
 440
 441         .type   cpu_arch_name, #object
 442 cpu_arch_name:
 443         .asciz  "armv4t"
 444         .size   cpu_arch_name, . - cpu_arch_name
 445
 446         .type   cpu_elf_name, #object
 447 cpu_elf_name:
 448         .asciz  "v4"
 449         .size   cpu_elf_name, . - cpu_elf_name
 450
 451         .type   cpu_arm922_name, #object
 452 cpu_arm922_name:
 453         .asciz  "ARM922T"
 454         .size   cpu_arm922_name, . - cpu_arm922_name
 455
 456         .align
 457
 458         .section ".proc.info.init", #alloc, #execinstr
 459
 460         .type   __arm922_proc_info,#object
 461 __arm922_proc_info:
 462         .long   0x41009220
 463         .long   0xff00fff0
 464         .long   PMD_TYPE_SECT | \
 465                 PMD_SECT_BUFFERABLE | \
 466                 PMD_SECT_CACHEABLE | \
 467                 PMD_BIT4 | \
 468                 PMD_SECT_AP_WRITE | \
 469                 PMD_SECT_AP_READ
 470         .long   PMD_TYPE_SECT | \
 471                 PMD_BIT4 | \
 472                 PMD_SECT_AP_WRITE | \
 473                 PMD_SECT_AP_READ
 474         b       __arm922_setup
 475         .long   cpu_arch_name
 476         .long   cpu_elf_name
 477         .long   HWCAP_SWP | HWCAP_HALF | HWCAP_THUMB
 478         .long   cpu_arm922_name
 479         .long   arm922_processor_functions
 480         .long   v4wbi_tlb_fns
 481         .long   v4wb_user_fns
 482 #ifndef CONFIG_CPU_DCACHE_WRITETHROUGH
 483         .long   arm922_cache_fns
 484 #else
 485         .long   v4wt_cache_fns
 486 #endif
 487         .size   __arm922_proc_info, . - __arm922_proc_info