arch/arm64/kernel/entry.S

   1 /*
   2  * Low-level exception handling code
   3  *
   4  * Copyright (C) 2012 ARM Ltd.
   5  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   6  *              Will Deacon <will.deacon@arm.com>
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19  */
  20
  21 #include <linux/init.h>
  22 #include <linux/linkage.h>
  23
  24 #include <asm/alternative.h>
  25 #include <asm/assembler.h>
  26 #include <asm/asm-offsets.h>
  27 #include <asm/cpufeature.h>
  28 #include <asm/errno.h>
  29 #include <asm/esr.h>
  30 #include <asm/irq.h>
  31 #include <asm/thread_info.h>
  32 #include <asm/unistd.h>
  33
  34 /*
  35  * Context tracking subsystem.  Used to instrument transitions
  36  * between user and kernel mode.
  37  */
  38         .macro ct_user_exit, syscall = 0
  39 #ifdef CONFIG_CONTEXT_TRACKING
  40         bl      context_tracking_user_exit
  41         .if \syscall == 1
  42         /*
  43          * Save/restore needed during syscalls.  Restore syscall arguments from
  44          * the values already saved on stack during kernel_entry.
  45          */
  46         ldp     x0, x1, [sp]
  47         ldp     x2, x3, [sp, #S_X2]
  48         ldp     x4, x5, [sp, #S_X4]
  49         ldp     x6, x7, [sp, #S_X6]
  50         .endif
  51 #endif
  52         .endm
  53
  54         .macro ct_user_enter
  55 #ifdef CONFIG_CONTEXT_TRACKING
  56         bl      context_tracking_user_enter
  57 #endif
  58         .endm
  59
  60 /*
  61  * Bad Abort numbers
  62  *-----------------
  63  */
  64 #define BAD_SYNC        0
  65 #define BAD_IRQ         1
  66 #define BAD_FIQ         2
  67 #define BAD_ERROR       3
  68
  69         .macro  kernel_entry, el, regsize = 64
  70         sub     sp, sp, #S_FRAME_SIZE
  71         .if     \regsize == 32
  72         mov     w0, w0                          // zero upper 32 bits of x0
  73         .endif
  74         stp     x0, x1, [sp, #16 * 0]
  75         stp     x2, x3, [sp, #16 * 1]
  76         stp     x4, x5, [sp, #16 * 2]
  77         stp     x6, x7, [sp, #16 * 3]
  78         stp     x8, x9, [sp, #16 * 4]
  79         stp     x10, x11, [sp, #16 * 5]
  80         stp     x12, x13, [sp, #16 * 6]
  81         stp     x14, x15, [sp, #16 * 7]
  82         stp     x16, x17, [sp, #16 * 8]
  83         stp     x18, x19, [sp, #16 * 9]
  84         stp     x20, x21, [sp, #16 * 10]
  85         stp     x22, x23, [sp, #16 * 11]
  86         stp     x24, x25, [sp, #16 * 12]
  87         stp     x26, x27, [sp, #16 * 13]
  88         stp     x28, x29, [sp, #16 * 14]
  89
  90         .if     \el == 0
  91         mrs     x21, sp_el0
  92         mov     tsk, sp
  93         and     tsk, tsk, #~(THREAD_SIZE - 1)   // Ensure MDSCR_EL1.SS is clear,
  94         ldr     x19, [tsk, #TI_FLAGS]           // since we can unmask debug
  95         disable_step_tsk x19, x20               // exceptions when scheduling.
  96
  97         mov     x29, xzr                        // fp pointed to user-space
  98         .else
  99         add     x21, sp, #S_FRAME_SIZE
 100         .endif
 101         mrs     x22, elr_el1
 102         mrs     x23, spsr_el1
 103         stp     lr, x21, [sp, #S_LR]
 104         stp     x22, x23, [sp, #S_PC]
 105
 106         /*
 107          * Set syscallno to -1 by default (overridden later if real syscall).
 108          */
 109         .if     \el == 0
 110         mvn     x21, xzr
 111         str     x21, [sp, #S_SYSCALLNO]
 112         .endif
 113
 114         /*
 115          * Set sp_el0 to current thread_info.
 116          */
 117         .if     \el == 0
 118         msr     sp_el0, tsk
 119         .endif
 120
 121         /*
 122          * Registers that may be useful after this macro is invoked:
 123          *
 124          * x21 - aborted SP
 125          * x22 - aborted PC
 126          * x23 - aborted PSTATE
 127         */
 128         .endm
 129
 130         .macro  kernel_exit, el
 131         ldp     x21, x22, [sp, #S_PC]           // load ELR, SPSR
 132         .if     \el == 0
 133         ct_user_enter
 134         ldr     x23, [sp, #S_SP]                // load return stack pointer
 135         msr     sp_el0, x23
 136 #ifdef CONFIG_ARM64_ERRATUM_845719
 137 alternative_if_not ARM64_WORKAROUND_845719
 138         nop
 139         nop
 140 #ifdef CONFIG_PID_IN_CONTEXTIDR
 141         nop
 142 #endif
 143 alternative_else
 144         tbz     x22, #4, 1f
 145 #ifdef CONFIG_PID_IN_CONTEXTIDR
 146         mrs     x29, contextidr_el1
 147         msr     contextidr_el1, x29
 148 #else
 149         msr contextidr_el1, xzr
 150 #endif
 151 1:
 152 alternative_endif
 153 #endif
 154         .endif
 155         msr     elr_el1, x21                    // set up the return data
 156         msr     spsr_el1, x22
 157         ldp     x0, x1, [sp, #16 * 0]
 158         ldp     x2, x3, [sp, #16 * 1]
 159         ldp     x4, x5, [sp, #16 * 2]
 160         ldp     x6, x7, [sp, #16 * 3]
 161         ldp     x8, x9, [sp, #16 * 4]
 162         ldp     x10, x11, [sp, #16 * 5]
 163         ldp     x12, x13, [sp, #16 * 6]
 164         ldp     x14, x15, [sp, #16 * 7]
 165         ldp     x16, x17, [sp, #16 * 8]
 166         ldp     x18, x19, [sp, #16 * 9]
 167         ldp     x20, x21, [sp, #16 * 10]
 168         ldp     x22, x23, [sp, #16 * 11]
 169         ldp     x24, x25, [sp, #16 * 12]
 170         ldp     x26, x27, [sp, #16 * 13]
 171         ldp     x28, x29, [sp, #16 * 14]
 172         ldr     lr, [sp, #S_LR]
 173         add     sp, sp, #S_FRAME_SIZE           // restore sp
 174         eret                                    // return to kernel
 175         .endm
 176
 177         .macro  get_thread_info, rd
 178         mrs     \rd, sp_el0
 179         .endm
 180
 181         .macro  irq_stack_entry
 182         mov     x19, sp                 // preserve the original sp
 183
 184         this_cpu_ptr irq_stack, x25, x26
 185
 186         /*
 187          * Check the lowest address on irq_stack for the irq_count value,
 188          * incremented by do_softirq_own_stack if we have re-enabled irqs
 189          * while on the irq_stack.
 190          */
 191         ldr     x26, [x25]
 192         cbnz    x26, 9998f              // recursive use?
 193
 194         /* switch to the irq stack */
 195         mov     x26, #IRQ_STACK_START_SP
 196         add     x26, x25, x26
 197         mov     sp, x26
 198
 199         /*
 200          * Add a dummy stack frame, this non-standard format is fixed up
 201          * by unwind_frame()
 202          */
 203         stp     x29, x19, [sp, #-16]!
 204         mov     x29, sp
 205
 206 9998:
 207         .endm
 208
 209         /*
 210          * x19 should be preserved between irq_stack_entry and
 211          * irq_stack_exit.
 212          */
 213         .macro  irq_stack_exit
 214         mov     sp, x19
 215         .endm
 216
 217 /*
 218  * These are the registers used in the syscall handler, and allow us to
 219  * have in theory up to 7 arguments to a function - x0 to x6.
 220  *
 221  * x7 is reserved for the system call number in 32-bit mode.
 222  */
 223 sc_nr   .req    x25             // number of system calls
 224 scno    .req    x26             // syscall number
 225 stbl    .req    x27             // syscall table pointer
 226 tsk     .req    x28             // current thread_info
 227
 228 /*
 229  * Interrupt handling.
 230  */
 231         .macro  irq_handler
 232         ldr_l   x1, handle_arch_irq
 233         mov     x0, sp
 234         irq_stack_entry
 235         blr     x1
 236         irq_stack_exit
 237         .endm
 238
 239         .text
 240
 241 /*
 242  * Exception vectors.
 243  */
 244
 245         .align  11
 246 ENTRY(vectors)
 247         ventry  el1_sync_invalid                // Synchronous EL1t
 248         ventry  el1_irq_invalid                 // IRQ EL1t
 249         ventry  el1_fiq_invalid                 // FIQ EL1t
 250         ventry  el1_error_invalid               // Error EL1t
 251
 252         ventry  el1_sync                        // Synchronous EL1h
 253         ventry  el1_irq                         // IRQ EL1h
 254         ventry  el1_fiq_invalid                 // FIQ EL1h
 255         ventry  el1_error_invalid               // Error EL1h
 256
 257         ventry  el0_sync                        // Synchronous 64-bit EL0
 258         ventry  el0_irq                         // IRQ 64-bit EL0
 259         ventry  el0_fiq_invalid                 // FIQ 64-bit EL0
 260         ventry  el0_error_invalid               // Error 64-bit EL0
 261
 262 #ifdef CONFIG_COMPAT
 263         ventry  el0_sync_compat                 // Synchronous 32-bit EL0
 264         ventry  el0_irq_compat                  // IRQ 32-bit EL0
 265         ventry  el0_fiq_invalid_compat          // FIQ 32-bit EL0
 266         ventry  el0_error_invalid_compat        // Error 32-bit EL0
 267 #else
 268         ventry  el0_sync_invalid                // Synchronous 32-bit EL0
 269         ventry  el0_irq_invalid                 // IRQ 32-bit EL0
 270         ventry  el0_fiq_invalid                 // FIQ 32-bit EL0
 271         ventry  el0_error_invalid               // Error 32-bit EL0
 272 #endif
 273 END(vectors)
 274
 275 /*
 276  * Invalid mode handlers
 277  */
 278         .macro  inv_entry, el, reason, regsize = 64
 279         kernel_entry el, \regsize
 280         mov     x0, sp
 281         mov     x1, #\reason
 282         mrs     x2, esr_el1
 283         b       bad_mode
 284         .endm
 285
 286 el0_sync_invalid:
 287         inv_entry 0, BAD_SYNC
 288 ENDPROC(el0_sync_invalid)
 289
 290 el0_irq_invalid:
 291         inv_entry 0, BAD_IRQ
 292 ENDPROC(el0_irq_invalid)
 293
 294 el0_fiq_invalid:
 295         inv_entry 0, BAD_FIQ
 296 ENDPROC(el0_fiq_invalid)
 297
 298 el0_error_invalid:
 299         inv_entry 0, BAD_ERROR
 300 ENDPROC(el0_error_invalid)
 301
 302 #ifdef CONFIG_COMPAT
 303 el0_fiq_invalid_compat:
 304         inv_entry 0, BAD_FIQ, 32
 305 ENDPROC(el0_fiq_invalid_compat)
 306
 307 el0_error_invalid_compat:
 308         inv_entry 0, BAD_ERROR, 32
 309 ENDPROC(el0_error_invalid_compat)
 310 #endif
 311
 312 el1_sync_invalid:
 313         inv_entry 1, BAD_SYNC
 314 ENDPROC(el1_sync_invalid)
 315
 316 el1_irq_invalid:
 317         inv_entry 1, BAD_IRQ
 318 ENDPROC(el1_irq_invalid)
 319
 320 el1_fiq_invalid:
 321         inv_entry 1, BAD_FIQ
 322 ENDPROC(el1_fiq_invalid)
 323
 324 el1_error_invalid:
 325         inv_entry 1, BAD_ERROR
 326 ENDPROC(el1_error_invalid)
 327
 328 /*
 329  * EL1 mode handlers.
 330  */
 331         .align  6
 332 el1_sync:
 333         kernel_entry 1
 334         mrs     x1, esr_el1                     // read the syndrome register
 335         lsr     x24, x1, #ESR_ELx_EC_SHIFT      // exception class
 336         cmp     x24, #ESR_ELx_EC_DABT_CUR       // data abort in EL1
 337         b.eq    el1_da
 338         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 339         b.eq    el1_undef
 340         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 341         b.eq    el1_sp_pc
 342         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 343         b.eq    el1_sp_pc
 344         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL1
 345         b.eq    el1_undef
 346         cmp     x24, #ESR_ELx_EC_BREAKPT_CUR    // debug exception in EL1
 347         b.ge    el1_dbg
 348         b       el1_inv
 349 el1_da:
 350         /*
 351          * Data abort handling
 352          */
 353         mrs     x0, far_el1
 354         enable_dbg
 355         // re-enable interrupts if they were enabled in the aborted context
 356         tbnz    x23, #7, 1f                     // PSR_I_BIT
 357         enable_irq
 358 1:
 359         mov     x2, sp                          // struct pt_regs
 360         bl      do_mem_abort
 361
 362         // disable interrupts before pulling preserved data off the stack
 363         disable_irq
 364         kernel_exit 1
 365 el1_sp_pc:
 366         /*
 367          * Stack or PC alignment exception handling
 368          */
 369         mrs     x0, far_el1
 370         enable_dbg
 371         mov     x2, sp
 372         b       do_sp_pc_abort
 373 el1_undef:
 374         /*
 375          * Undefined instruction
 376          */
 377         enable_dbg
 378         mov     x0, sp
 379         b       do_undefinstr
 380 el1_dbg:
 381         /*
 382          * Debug exception handling
 383          */
 384         cmp     x24, #ESR_ELx_EC_BRK64          // if BRK64
 385         cinc    x24, x24, eq                    // set bit '0'
 386         tbz     x24, #0, el1_inv                // EL1 only
 387         mrs     x0, far_el1
 388         mov     x2, sp                          // struct pt_regs
 389         bl      do_debug_exception
 390         kernel_exit 1
 391 el1_inv:
 392         // TODO: add support for undefined instructions in kernel mode
 393         enable_dbg
 394         mov     x0, sp
 395         mov     x2, x1
 396         mov     x1, #BAD_SYNC
 397         b       bad_mode
 398 ENDPROC(el1_sync)
 399
 400         .align  6
 401 el1_irq:
 402         kernel_entry 1
 403         enable_dbg
 404 #ifdef CONFIG_TRACE_IRQFLAGS
 405         bl      trace_hardirqs_off
 406 #endif
 407
 408         irq_handler
 409
 410 #ifdef CONFIG_PREEMPT
 411         get_thread_info tsk
 412         ldr     w24, [tsk, #TI_PREEMPT]         // get preempt count
 413         cbnz    w24, 1f                         // preempt count != 0
 414         ldr     x0, [tsk, #TI_FLAGS]            // get flags
 415         tbz     x0, #TIF_NEED_RESCHED, 1f       // needs rescheduling?
 416         bl      el1_preempt
 417 1:
 418 #endif
 419 #ifdef CONFIG_TRACE_IRQFLAGS
 420         bl      trace_hardirqs_on
 421 #endif
 422         kernel_exit 1
 423 ENDPROC(el1_irq)
 424
 425 #ifdef CONFIG_PREEMPT
 426 el1_preempt:
 427         mov     x24, lr
 428 1:      bl      preempt_schedule_irq            // irq en/disable is done inside
 429         ldr     x0, [tsk, #TI_FLAGS]            // get new tasks TI_FLAGS
 430         tbnz    x0, #TIF_NEED_RESCHED, 1b       // needs rescheduling?
 431         ret     x24
 432 #endif
 433
 434 /*
 435  * EL0 mode handlers.
 436  */
 437         .align  6
 438 el0_sync:
 439         kernel_entry 0
 440         mrs     x25, esr_el1                    // read the syndrome register
 441         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 442         cmp     x24, #ESR_ELx_EC_SVC64          // SVC in 64-bit state
 443         b.eq    el0_svc
 444         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 445         b.eq    el0_da
 446         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 447         b.eq    el0_ia
 448         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 449         b.eq    el0_fpsimd_acc
 450         cmp     x24, #ESR_ELx_EC_FP_EXC64       // FP/ASIMD exception
 451         b.eq    el0_fpsimd_exc
 452         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 453         b.eq    el0_undef
 454         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 455         b.eq    el0_sp_pc
 456         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 457         b.eq    el0_sp_pc
 458         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 459         b.eq    el0_undef
 460         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 461         b.ge    el0_dbg
 462         b       el0_inv
 463
 464 #ifdef CONFIG_COMPAT
 465         .align  6
 466 el0_sync_compat:
 467         kernel_entry 0, 32
 468         mrs     x25, esr_el1                    // read the syndrome register
 469         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 470         cmp     x24, #ESR_ELx_EC_SVC32          // SVC in 32-bit state
 471         b.eq    el0_svc_compat
 472         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 473         b.eq    el0_da
 474         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 475         b.eq    el0_ia
 476         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 477         b.eq    el0_fpsimd_acc
 478         cmp     x24, #ESR_ELx_EC_FP_EXC32       // FP/ASIMD exception
 479         b.eq    el0_fpsimd_exc
 480         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 481         b.eq    el0_sp_pc
 482         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 483         b.eq    el0_undef
 484         cmp     x24, #ESR_ELx_EC_CP15_32        // CP15 MRC/MCR trap
 485         b.eq    el0_undef
 486         cmp     x24, #ESR_ELx_EC_CP15_64        // CP15 MRRC/MCRR trap
 487         b.eq    el0_undef
 488         cmp     x24, #ESR_ELx_EC_CP14_MR        // CP14 MRC/MCR trap
 489         b.eq    el0_undef
 490         cmp     x24, #ESR_ELx_EC_CP14_LS        // CP14 LDC/STC trap
 491         b.eq    el0_undef
 492         cmp     x24, #ESR_ELx_EC_CP14_64        // CP14 MRRC/MCRR trap
 493         b.eq    el0_undef
 494         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 495         b.ge    el0_dbg
 496         b       el0_inv
 497 el0_svc_compat:
 498         /*
 499          * AArch32 syscall handling
 500          */
 501         adrp    stbl, compat_sys_call_table     // load compat syscall table pointer
 502         uxtw    scno, w7                        // syscall number in w7 (r7)
 503         mov     sc_nr, #__NR_compat_syscalls
 504         b       el0_svc_naked
 505
 506         .align  6
 507 el0_irq_compat:
 508         kernel_entry 0, 32
 509         b       el0_irq_naked
 510 #endif
 511
 512 el0_da:
 513         /*
 514          * Data abort handling
 515          */
 516         mrs     x26, far_el1
 517         // enable interrupts before calling the main handler
 518         enable_dbg_and_irq
 519         ct_user_exit
 520         bic     x0, x26, #(0xff << 56)
 521         mov     x1, x25
 522         mov     x2, sp
 523         bl      do_mem_abort
 524         b       ret_to_user
 525 el0_ia:
 526         /*
 527          * Instruction abort handling
 528          */
 529         mrs     x26, far_el1
 530         // enable interrupts before calling the main handler
 531         enable_dbg_and_irq
 532         ct_user_exit
 533         mov     x0, x26
 534         orr     x1, x25, #1 << 24               // use reserved ISS bit for instruction aborts
 535         mov     x2, sp
 536         bl      do_mem_abort
 537         b       ret_to_user
 538 el0_fpsimd_acc:
 539         /*
 540          * Floating Point or Advanced SIMD access
 541          */
 542         enable_dbg
 543         ct_user_exit
 544         mov     x0, x25
 545         mov     x1, sp
 546         bl      do_fpsimd_acc
 547         b       ret_to_user
 548 el0_fpsimd_exc:
 549         /*
 550          * Floating Point or Advanced SIMD exception
 551          */
 552         enable_dbg
 553         ct_user_exit
 554         mov     x0, x25
 555         mov     x1, sp
 556         bl      do_fpsimd_exc
 557         b       ret_to_user
 558 el0_sp_pc:
 559         /*
 560          * Stack or PC alignment exception handling
 561          */
 562         mrs     x26, far_el1
 563         // enable interrupts before calling the main handler
 564         enable_dbg_and_irq
 565         ct_user_exit
 566         mov     x0, x26
 567         mov     x1, x25
 568         mov     x2, sp
 569         bl      do_sp_pc_abort
 570         b       ret_to_user
 571 el0_undef:
 572         /*
 573          * Undefined instruction
 574          */
 575         // enable interrupts before calling the main handler
 576         enable_dbg_and_irq
 577         ct_user_exit
 578         mov     x0, sp
 579         bl      do_undefinstr
 580         b       ret_to_user
 581 el0_dbg:
 582         /*
 583          * Debug exception handling
 584          */
 585         tbnz    x24, #0, el0_inv                // EL0 only
 586         mrs     x0, far_el1
 587         mov     x1, x25
 588         mov     x2, sp
 589         bl      do_debug_exception
 590         enable_dbg
 591         ct_user_exit
 592         b       ret_to_user
 593 el0_inv:
 594         enable_dbg
 595         ct_user_exit
 596         mov     x0, sp
 597         mov     x1, #BAD_SYNC
 598         mov     x2, x25
 599         bl      bad_mode
 600         b       ret_to_user
 601 ENDPROC(el0_sync)
 602
 603         .align  6
 604 el0_irq:
 605         kernel_entry 0
 606 el0_irq_naked:
 607         enable_dbg
 608 #ifdef CONFIG_TRACE_IRQFLAGS
 609         bl      trace_hardirqs_off
 610 #endif
 611
 612         ct_user_exit
 613         irq_handler
 614
 615 #ifdef CONFIG_TRACE_IRQFLAGS
 616         bl      trace_hardirqs_on
 617 #endif
 618         b       ret_to_user
 619 ENDPROC(el0_irq)
 620
 621 /*
 622  * Register switch for AArch64. The callee-saved registers need to be saved
 623  * and restored. On entry:
 624  *   x0 = previous task_struct (must be preserved across the switch)
 625  *   x1 = next task_struct
 626  * Previous and next are guaranteed not to be the same.
 627  *
 628  */
 629 ENTRY(cpu_switch_to)
 630         mov     x10, #THREAD_CPU_CONTEXT
 631         add     x8, x0, x10
 632         mov     x9, sp
 633         stp     x19, x20, [x8], #16             // store callee-saved registers
 634         stp     x21, x22, [x8], #16
 635         stp     x23, x24, [x8], #16
 636         stp     x25, x26, [x8], #16
 637         stp     x27, x28, [x8], #16
 638         stp     x29, x9, [x8], #16
 639         str     lr, [x8]
 640         add     x8, x1, x10
 641         ldp     x19, x20, [x8], #16             // restore callee-saved registers
 642         ldp     x21, x22, [x8], #16
 643         ldp     x23, x24, [x8], #16
 644         ldp     x25, x26, [x8], #16
 645         ldp     x27, x28, [x8], #16
 646         ldp     x29, x9, [x8], #16
 647         ldr     lr, [x8]
 648         mov     sp, x9
 649         and     x9, x9, #~(THREAD_SIZE - 1)
 650         msr     sp_el0, x9
 651         ret
 652 ENDPROC(cpu_switch_to)
 653
 654 /*
 655  * This is the fast syscall return path.  We do as little as possible here,
 656  * and this includes saving x0 back into the kernel stack.
 657  */
 658 ret_fast_syscall:
 659         disable_irq                             // disable interrupts
 660         str     x0, [sp, #S_X0]                 // returned x0
 661         ldr     x1, [tsk, #TI_FLAGS]            // re-check for syscall tracing
 662         and     x2, x1, #_TIF_SYSCALL_WORK
 663         cbnz    x2, ret_fast_syscall_trace
 664         and     x2, x1, #_TIF_WORK_MASK
 665         cbnz    x2, work_pending
 666         enable_step_tsk x1, x2
 667         kernel_exit 0
 668 ret_fast_syscall_trace:
 669         enable_irq                              // enable interrupts
 670         b       __sys_trace_return_skipped      // we already saved x0
 671
 672 /*
 673  * Ok, we need to do extra processing, enter the slow path.
 674  */
 675 work_pending:
 676         tbnz    x1, #TIF_NEED_RESCHED, work_resched
 677         /* TIF_SIGPENDING, TIF_NOTIFY_RESUME or TIF_FOREIGN_FPSTATE case */
 678         ldr     x2, [sp, #S_PSTATE]
 679         mov     x0, sp                          // 'regs'
 680         tst     x2, #PSR_MODE_MASK              // user mode regs?
 681         b.ne    no_work_pending                 // returning to kernel
 682         enable_irq                              // enable interrupts for do_notify_resume()
 683         bl      do_notify_resume
 684         b       ret_to_user
 685 work_resched:
 686 #ifdef CONFIG_TRACE_IRQFLAGS
 687         bl      trace_hardirqs_off              // the IRQs are off here, inform the tracing code
 688 #endif
 689         bl      schedule
 690
 691 /*
 692  * "slow" syscall return path.
 693  */
 694 ret_to_user:
 695         disable_irq                             // disable interrupts
 696         ldr     x1, [tsk, #TI_FLAGS]
 697         and     x2, x1, #_TIF_WORK_MASK
 698         cbnz    x2, work_pending
 699         enable_step_tsk x1, x2
 700 no_work_pending:
 701         kernel_exit 0
 702 ENDPROC(ret_to_user)
 703
 704 /*
 705  * This is how we return from a fork.
 706  */
 707 ENTRY(ret_from_fork)
 708         bl      schedule_tail
 709         cbz     x19, 1f                         // not a kernel thread
 710         mov     x0, x20
 711         blr     x19
 712 1:      get_thread_info tsk
 713         b       ret_to_user
 714 ENDPROC(ret_from_fork)
 715
 716 /*
 717  * SVC handler.
 718  */
 719         .align  6
 720 el0_svc:
 721         adrp    stbl, sys_call_table            // load syscall table pointer
 722         uxtw    scno, w8                        // syscall number in w8
 723         mov     sc_nr, #__NR_syscalls
 724 el0_svc_naked:                                  // compat entry point
 725         stp     x0, scno, [sp, #S_ORIG_X0]      // save the original x0 and syscall number
 726         enable_dbg_and_irq
 727         ct_user_exit 1
 728
 729         ldr     x16, [tsk, #TI_FLAGS]           // check for syscall hooks
 730         tst     x16, #_TIF_SYSCALL_WORK
 731         b.ne    __sys_trace
 732         cmp     scno, sc_nr                     // check upper syscall limit
 733         b.hs    ni_sys
 734         ldr     x16, [stbl, scno, lsl #3]       // address in the syscall table
 735         blr     x16                             // call sys_* routine
 736         b       ret_fast_syscall
 737 ni_sys:
 738         mov     x0, sp
 739         bl      do_ni_syscall
 740         b       ret_fast_syscall
 741 ENDPROC(el0_svc)
 742
 743         /*
 744          * This is the really slow path.  We're going to be doing context
 745          * switches, and waiting for our parent to respond.
 746          */
 747 __sys_trace:
 748         mov     w0, #-1                         // set default errno for
 749         cmp     scno, x0                        // user-issued syscall(-1)
 750         b.ne    1f
 751         mov     x0, #-ENOSYS
 752         str     x0, [sp, #S_X0]
 753 1:      mov     x0, sp
 754         bl      syscall_trace_enter
 755         cmp     w0, #-1                         // skip the syscall?
 756         b.eq    __sys_trace_return_skipped
 757         uxtw    scno, w0                        // syscall number (possibly new)
 758         mov     x1, sp                          // pointer to regs
 759         cmp     scno, sc_nr                     // check upper syscall limit
 760         b.hs    __ni_sys_trace
 761         ldp     x0, x1, [sp]                    // restore the syscall args
 762         ldp     x2, x3, [sp, #S_X2]
 763         ldp     x4, x5, [sp, #S_X4]
 764         ldp     x6, x7, [sp, #S_X6]
 765         ldr     x16, [stbl, scno, lsl #3]       // address in the syscall table
 766         blr     x16                             // call sys_* routine
 767
 768 __sys_trace_return:
 769         str     x0, [sp, #S_X0]                 // save returned x0
 770 __sys_trace_return_skipped:
 771         mov     x0, sp
 772         bl      syscall_trace_exit
 773         b       ret_to_user
 774
 775 __ni_sys_trace:
 776         mov     x0, sp
 777         bl      do_ni_syscall
 778         b       __sys_trace_return
 779
 780 /*
 781  * Special system call wrappers.
 782  */
 783 ENTRY(sys_rt_sigreturn_wrapper)
 784         mov     x0, sp
 785         b       sys_rt_sigreturn
 786 ENDPROC(sys_rt_sigreturn_wrapper)