arch/arm64/kernel/entry.S

   1 /*
   2  * Low-level exception handling code
   3  *
   4  * Copyright (C) 2012 ARM Ltd.
   5  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   6  *              Will Deacon <will.deacon@arm.com>
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19  */
  20
  21 #include <linux/init.h>
  22 #include <linux/linkage.h>
  23
  24 #include <asm/alternative.h>
  25 #include <asm/assembler.h>
  26 #include <asm/asm-offsets.h>
  27 #include <asm/cpufeature.h>
  28 #include <asm/errno.h>
  29 #include <asm/esr.h>
  30 #include <asm/irq.h>
  31 #include <asm/thread_info.h>
  32 #include <asm/unistd.h>
  33
  34 /*
  35  * Context tracking subsystem.  Used to instrument transitions
  36  * between user and kernel mode.
  37  */
  38         .macro ct_user_exit, syscall = 0
  39 #ifdef CONFIG_CONTEXT_TRACKING
  40         bl      context_tracking_user_exit
  41         .if \syscall == 1
  42         /*
  43          * Save/restore needed during syscalls.  Restore syscall arguments from
  44          * the values already saved on stack during kernel_entry.
  45          */
  46         ldp     x0, x1, [sp]
  47         ldp     x2, x3, [sp, #S_X2]
  48         ldp     x4, x5, [sp, #S_X4]
  49         ldp     x6, x7, [sp, #S_X6]
  50         .endif
  51 #endif
  52         .endm
  53
  54         .macro ct_user_enter
  55 #ifdef CONFIG_CONTEXT_TRACKING
  56         bl      context_tracking_user_enter
  57 #endif
  58         .endm
  59
  60 /*
  61  * Bad Abort numbers
  62  *-----------------
  63  */
  64 #define BAD_SYNC        0
  65 #define BAD_IRQ         1
  66 #define BAD_FIQ         2
  67 #define BAD_ERROR       3
  68
  69         .macro  kernel_entry, el, regsize = 64
  70         sub     sp, sp, #S_FRAME_SIZE
  71         .if     \regsize == 32
  72         mov     w0, w0                          // zero upper 32 bits of x0
  73         .endif
  74         stp     x0, x1, [sp, #16 * 0]
  75         stp     x2, x3, [sp, #16 * 1]
  76         stp     x4, x5, [sp, #16 * 2]
  77         stp     x6, x7, [sp, #16 * 3]
  78         stp     x8, x9, [sp, #16 * 4]
  79         stp     x10, x11, [sp, #16 * 5]
  80         stp     x12, x13, [sp, #16 * 6]
  81         stp     x14, x15, [sp, #16 * 7]
  82         stp     x16, x17, [sp, #16 * 8]
  83         stp     x18, x19, [sp, #16 * 9]
  84         stp     x20, x21, [sp, #16 * 10]
  85         stp     x22, x23, [sp, #16 * 11]
  86         stp     x24, x25, [sp, #16 * 12]
  87         stp     x26, x27, [sp, #16 * 13]
  88         stp     x28, x29, [sp, #16 * 14]
  89
  90         .if     \el == 0
  91         mrs     x21, sp_el0
  92         mov     tsk, sp
  93         and     tsk, tsk, #~(THREAD_SIZE - 1)   // Ensure MDSCR_EL1.SS is clear,
  94         ldr     x19, [tsk, #TI_FLAGS]           // since we can unmask debug
  95         disable_step_tsk x19, x20               // exceptions when scheduling.
  96
  97         mov     x29, xzr                        // fp pointed to user-space
  98         .else
  99         add     x21, sp, #S_FRAME_SIZE
 100         .endif
 101         mrs     x22, elr_el1
 102         mrs     x23, spsr_el1
 103         stp     lr, x21, [sp, #S_LR]
 104         stp     x22, x23, [sp, #S_PC]
 105
 106         /*
 107          * Set syscallno to -1 by default (overridden later if real syscall).
 108          */
 109         .if     \el == 0
 110         mvn     x21, xzr
 111         str     x21, [sp, #S_SYSCALLNO]
 112         .endif
 113
 114         /*
 115          * Set sp_el0 to current thread_info.
 116          */
 117         .if     \el == 0
 118         msr     sp_el0, tsk
 119         .endif
 120
 121         /*
 122          * Registers that may be useful after this macro is invoked:
 123          *
 124          * x21 - aborted SP
 125          * x22 - aborted PC
 126          * x23 - aborted PSTATE
 127         */
 128         .endm
 129
 130         .macro  kernel_exit, el
 131         ldp     x21, x22, [sp, #S_PC]           // load ELR, SPSR
 132         .if     \el == 0
 133         ct_user_enter
 134         ldr     x23, [sp, #S_SP]                // load return stack pointer
 135         msr     sp_el0, x23
 136 #ifdef CONFIG_ARM64_ERRATUM_845719
 137 alternative_if_not ARM64_WORKAROUND_845719
 138         nop
 139         nop
 140 #ifdef CONFIG_PID_IN_CONTEXTIDR
 141         nop
 142 #endif
 143 alternative_else
 144         tbz     x22, #4, 1f
 145 #ifdef CONFIG_PID_IN_CONTEXTIDR
 146         mrs     x29, contextidr_el1
 147         msr     contextidr_el1, x29
 148 #else
 149         msr contextidr_el1, xzr
 150 #endif
 151 1:
 152 alternative_endif
 153 #endif
 154         .endif
 155         msr     elr_el1, x21                    // set up the return data
 156         msr     spsr_el1, x22
 157         ldp     x0, x1, [sp, #16 * 0]
 158         ldp     x2, x3, [sp, #16 * 1]
 159         ldp     x4, x5, [sp, #16 * 2]
 160         ldp     x6, x7, [sp, #16 * 3]
 161         ldp     x8, x9, [sp, #16 * 4]
 162         ldp     x10, x11, [sp, #16 * 5]
 163         ldp     x12, x13, [sp, #16 * 6]
 164         ldp     x14, x15, [sp, #16 * 7]
 165         ldp     x16, x17, [sp, #16 * 8]
 166         ldp     x18, x19, [sp, #16 * 9]
 167         ldp     x20, x21, [sp, #16 * 10]
 168         ldp     x22, x23, [sp, #16 * 11]
 169         ldp     x24, x25, [sp, #16 * 12]
 170         ldp     x26, x27, [sp, #16 * 13]
 171         ldp     x28, x29, [sp, #16 * 14]
 172         ldr     lr, [sp, #S_LR]
 173         add     sp, sp, #S_FRAME_SIZE           // restore sp
 174         eret                                    // return to kernel
 175         .endm
 176
 177         .macro  get_thread_info, rd
 178         mrs     \rd, sp_el0
 179         .endm
 180
 181         .macro  irq_stack_entry
 182         mov     x19, sp                 // preserve the original sp
 183
 184         /*
 185          * Compare sp with the current thread_info, if the top
 186          * ~(THREAD_SIZE - 1) bits match, we are on a task stack, and
 187          * should switch to the irq stack.
 188          */
 189         and     x25, x19, #~(THREAD_SIZE - 1)
 190         cmp     x25, tsk
 191         b.ne    9998f
 192
 193         this_cpu_ptr irq_stack, x25, x26
 194         mov     x26, #IRQ_STACK_START_SP
 195         add     x26, x25, x26
 196
 197         /* switch to the irq stack */
 198         mov     sp, x26
 199
 200         /*
 201          * Add a dummy stack frame, this non-standard format is fixed up
 202          * by unwind_frame()
 203          */
 204         stp     x29, x19, [sp, #-16]!
 205         mov     x29, sp
 206
 207 9998:
 208         .endm
 209
 210         /*
 211          * x19 should be preserved between irq_stack_entry and
 212          * irq_stack_exit.
 213          */
 214         .macro  irq_stack_exit
 215         mov     sp, x19
 216         .endm
 217
 218 /*
 219  * These are the registers used in the syscall handler, and allow us to
 220  * have in theory up to 7 arguments to a function - x0 to x6.
 221  *
 222  * x7 is reserved for the system call number in 32-bit mode.
 223  */
 224 sc_nr   .req    x25             // number of system calls
 225 scno    .req    x26             // syscall number
 226 stbl    .req    x27             // syscall table pointer
 227 tsk     .req    x28             // current thread_info
 228
 229 /*
 230  * Interrupt handling.
 231  */
 232         .macro  irq_handler
 233         ldr_l   x1, handle_arch_irq
 234         mov     x0, sp
 235         irq_stack_entry
 236         blr     x1
 237         irq_stack_exit
 238         .endm
 239
 240         .text
 241
 242 /*
 243  * Exception vectors.
 244  */
 245         .pushsection ".entry.text", "ax"
 246
 247         .align  11
 248 ENTRY(vectors)
 249         ventry  el1_sync_invalid                // Synchronous EL1t
 250         ventry  el1_irq_invalid                 // IRQ EL1t
 251         ventry  el1_fiq_invalid                 // FIQ EL1t
 252         ventry  el1_error_invalid               // Error EL1t
 253
 254         ventry  el1_sync                        // Synchronous EL1h
 255         ventry  el1_irq                         // IRQ EL1h
 256         ventry  el1_fiq_invalid                 // FIQ EL1h
 257         ventry  el1_error_invalid               // Error EL1h
 258
 259         ventry  el0_sync                        // Synchronous 64-bit EL0
 260         ventry  el0_irq                         // IRQ 64-bit EL0
 261         ventry  el0_fiq_invalid                 // FIQ 64-bit EL0
 262         ventry  el0_error_invalid               // Error 64-bit EL0
 263
 264 #ifdef CONFIG_COMPAT
 265         ventry  el0_sync_compat                 // Synchronous 32-bit EL0
 266         ventry  el0_irq_compat                  // IRQ 32-bit EL0
 267         ventry  el0_fiq_invalid_compat          // FIQ 32-bit EL0
 268         ventry  el0_error_invalid_compat        // Error 32-bit EL0
 269 #else
 270         ventry  el0_sync_invalid                // Synchronous 32-bit EL0
 271         ventry  el0_irq_invalid                 // IRQ 32-bit EL0
 272         ventry  el0_fiq_invalid                 // FIQ 32-bit EL0
 273         ventry  el0_error_invalid               // Error 32-bit EL0
 274 #endif
 275 END(vectors)
 276
 277 /*
 278  * Invalid mode handlers
 279  */
 280         .macro  inv_entry, el, reason, regsize = 64
 281         kernel_entry \el, \regsize
 282         mov     x0, sp
 283         mov     x1, #\reason
 284         mrs     x2, esr_el1
 285         b       bad_mode
 286         .endm
 287
 288 el0_sync_invalid:
 289         inv_entry 0, BAD_SYNC
 290 ENDPROC(el0_sync_invalid)
 291
 292 el0_irq_invalid:
 293         inv_entry 0, BAD_IRQ
 294 ENDPROC(el0_irq_invalid)
 295
 296 el0_fiq_invalid:
 297         inv_entry 0, BAD_FIQ
 298 ENDPROC(el0_fiq_invalid)
 299
 300 el0_error_invalid:
 301         inv_entry 0, BAD_ERROR
 302 ENDPROC(el0_error_invalid)
 303
 304 #ifdef CONFIG_COMPAT
 305 el0_fiq_invalid_compat:
 306         inv_entry 0, BAD_FIQ, 32
 307 ENDPROC(el0_fiq_invalid_compat)
 308
 309 el0_error_invalid_compat:
 310         inv_entry 0, BAD_ERROR, 32
 311 ENDPROC(el0_error_invalid_compat)
 312 #endif
 313
 314 el1_sync_invalid:
 315         inv_entry 1, BAD_SYNC
 316 ENDPROC(el1_sync_invalid)
 317
 318 el1_irq_invalid:
 319         inv_entry 1, BAD_IRQ
 320 ENDPROC(el1_irq_invalid)
 321
 322 el1_fiq_invalid:
 323         inv_entry 1, BAD_FIQ
 324 ENDPROC(el1_fiq_invalid)
 325
 326 el1_error_invalid:
 327         inv_entry 1, BAD_ERROR
 328 ENDPROC(el1_error_invalid)
 329
 330 /*
 331  * EL1 mode handlers.
 332  */
 333         .align  6
 334 el1_sync:
 335         kernel_entry 1
 336         mrs     x1, esr_el1                     // read the syndrome register
 337         lsr     x24, x1, #ESR_ELx_EC_SHIFT      // exception class
 338         cmp     x24, #ESR_ELx_EC_DABT_CUR       // data abort in EL1
 339         b.eq    el1_da
 340         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 341         b.eq    el1_undef
 342         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 343         b.eq    el1_sp_pc
 344         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 345         b.eq    el1_sp_pc
 346         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL1
 347         b.eq    el1_undef
 348         cmp     x24, #ESR_ELx_EC_BREAKPT_CUR    // debug exception in EL1
 349         b.ge    el1_dbg
 350         b       el1_inv
 351 el1_da:
 352         /*
 353          * Data abort handling
 354          */
 355         mrs     x0, far_el1
 356         enable_dbg
 357         // re-enable interrupts if they were enabled in the aborted context
 358         tbnz    x23, #7, 1f                     // PSR_I_BIT
 359         enable_irq
 360 1:
 361         mov     x2, sp                          // struct pt_regs
 362         bl      do_mem_abort
 363
 364         // disable interrupts before pulling preserved data off the stack
 365         disable_irq
 366         kernel_exit 1
 367 el1_sp_pc:
 368         /*
 369          * Stack or PC alignment exception handling
 370          */
 371         mrs     x0, far_el1
 372         enable_dbg
 373         mov     x2, sp
 374         b       do_sp_pc_abort
 375 el1_undef:
 376         /*
 377          * Undefined instruction
 378          */
 379         enable_dbg
 380         mov     x0, sp
 381         b       do_undefinstr
 382 el1_dbg:
 383         /*
 384          * Debug exception handling
 385          */
 386         cmp     x24, #ESR_ELx_EC_BRK64          // if BRK64
 387         cinc    x24, x24, eq                    // set bit '0'
 388         tbz     x24, #0, el1_inv                // EL1 only
 389         mrs     x0, far_el1
 390         mov     x2, sp                          // struct pt_regs
 391         bl      do_debug_exception
 392         kernel_exit 1
 393 el1_inv:
 394         // TODO: add support for undefined instructions in kernel mode
 395         enable_dbg
 396         mov     x0, sp
 397         mov     x2, x1
 398         mov     x1, #BAD_SYNC
 399         b       bad_mode
 400 ENDPROC(el1_sync)
 401
 402         .align  6
 403 el1_irq:
 404         kernel_entry 1
 405         enable_dbg
 406 #ifdef CONFIG_TRACE_IRQFLAGS
 407         bl      trace_hardirqs_off
 408 #endif
 409
 410         get_thread_info tsk
 411         irq_handler
 412
 413 #ifdef CONFIG_PREEMPT
 414         ldr     w24, [tsk, #TI_PREEMPT]         // get preempt count
 415         cbnz    w24, 1f                         // preempt count != 0
 416         ldr     x0, [tsk, #TI_FLAGS]            // get flags
 417         tbz     x0, #TIF_NEED_RESCHED, 1f       // needs rescheduling?
 418         bl      el1_preempt
 419 1:
 420 #endif
 421 #ifdef CONFIG_TRACE_IRQFLAGS
 422         bl      trace_hardirqs_on
 423 #endif
 424         kernel_exit 1
 425 ENDPROC(el1_irq)
 426
 427 #ifdef CONFIG_PREEMPT
 428 el1_preempt:
 429         mov     x24, lr
 430 1:      bl      preempt_schedule_irq            // irq en/disable is done inside
 431         ldr     x0, [tsk, #TI_FLAGS]            // get new tasks TI_FLAGS
 432         tbnz    x0, #TIF_NEED_RESCHED, 1b       // needs rescheduling?
 433         ret     x24
 434 #endif
 435
 436 /*
 437  * EL0 mode handlers.
 438  */
 439         .align  6
 440 el0_sync:
 441         kernel_entry 0
 442         mrs     x25, esr_el1                    // read the syndrome register
 443         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 444         cmp     x24, #ESR_ELx_EC_SVC64          // SVC in 64-bit state
 445         b.eq    el0_svc
 446         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 447         b.eq    el0_da
 448         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 449         b.eq    el0_ia
 450         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 451         b.eq    el0_fpsimd_acc
 452         cmp     x24, #ESR_ELx_EC_FP_EXC64       // FP/ASIMD exception
 453         b.eq    el0_fpsimd_exc
 454         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 455         b.eq    el0_undef
 456         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 457         b.eq    el0_sp_pc
 458         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 459         b.eq    el0_sp_pc
 460         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 461         b.eq    el0_undef
 462         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 463         b.ge    el0_dbg
 464         b       el0_inv
 465
 466 #ifdef CONFIG_COMPAT
 467         .align  6
 468 el0_sync_compat:
 469         kernel_entry 0, 32
 470         mrs     x25, esr_el1                    // read the syndrome register
 471         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 472         cmp     x24, #ESR_ELx_EC_SVC32          // SVC in 32-bit state
 473         b.eq    el0_svc_compat
 474         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 475         b.eq    el0_da
 476         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 477         b.eq    el0_ia
 478         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 479         b.eq    el0_fpsimd_acc
 480         cmp     x24, #ESR_ELx_EC_FP_EXC32       // FP/ASIMD exception
 481         b.eq    el0_fpsimd_exc
 482         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 483         b.eq    el0_sp_pc
 484         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 485         b.eq    el0_undef
 486         cmp     x24, #ESR_ELx_EC_CP15_32        // CP15 MRC/MCR trap
 487         b.eq    el0_undef
 488         cmp     x24, #ESR_ELx_EC_CP15_64        // CP15 MRRC/MCRR trap
 489         b.eq    el0_undef
 490         cmp     x24, #ESR_ELx_EC_CP14_MR        // CP14 MRC/MCR trap
 491         b.eq    el0_undef
 492         cmp     x24, #ESR_ELx_EC_CP14_LS        // CP14 LDC/STC trap
 493         b.eq    el0_undef
 494         cmp     x24, #ESR_ELx_EC_CP14_64        // CP14 MRRC/MCRR trap
 495         b.eq    el0_undef
 496         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 497         b.ge    el0_dbg
 498         b       el0_inv
 499 el0_svc_compat:
 500         /*
 501          * AArch32 syscall handling
 502          */
 503         adrp    stbl, compat_sys_call_table     // load compat syscall table pointer
 504         uxtw    scno, w7                        // syscall number in w7 (r7)
 505         mov     sc_nr, #__NR_compat_syscalls
 506         b       el0_svc_naked
 507
 508         .align  6
 509 el0_irq_compat:
 510         kernel_entry 0, 32
 511         b       el0_irq_naked
 512 #endif
 513
 514 el0_da:
 515         /*
 516          * Data abort handling
 517          */
 518         mrs     x26, far_el1
 519         // enable interrupts before calling the main handler
 520         enable_dbg_and_irq
 521         ct_user_exit
 522         bic     x0, x26, #(0xff << 56)
 523         mov     x1, x25
 524         mov     x2, sp
 525         bl      do_mem_abort
 526         b       ret_to_user
 527 el0_ia:
 528         /*
 529          * Instruction abort handling
 530          */
 531         mrs     x26, far_el1
 532         // enable interrupts before calling the main handler
 533         enable_dbg_and_irq
 534         ct_user_exit
 535         mov     x0, x26
 536         orr     x1, x25, #1 << 24               // use reserved ISS bit for instruction aborts
 537         mov     x2, sp
 538         bl      do_mem_abort
 539         b       ret_to_user
 540 el0_fpsimd_acc:
 541         /*
 542          * Floating Point or Advanced SIMD access
 543          */
 544         enable_dbg
 545         ct_user_exit
 546         mov     x0, x25
 547         mov     x1, sp
 548         bl      do_fpsimd_acc
 549         b       ret_to_user
 550 el0_fpsimd_exc:
 551         /*
 552          * Floating Point or Advanced SIMD exception
 553          */
 554         enable_dbg
 555         ct_user_exit
 556         mov     x0, x25
 557         mov     x1, sp
 558         bl      do_fpsimd_exc
 559         b       ret_to_user
 560 el0_sp_pc:
 561         /*
 562          * Stack or PC alignment exception handling
 563          */
 564         mrs     x26, far_el1
 565         // enable interrupts before calling the main handler
 566         enable_dbg_and_irq
 567         ct_user_exit
 568         mov     x0, x26
 569         mov     x1, x25
 570         mov     x2, sp
 571         bl      do_sp_pc_abort
 572         b       ret_to_user
 573 el0_undef:
 574         /*
 575          * Undefined instruction
 576          */
 577         // enable interrupts before calling the main handler
 578         enable_dbg_and_irq
 579         ct_user_exit
 580         mov     x0, sp
 581         bl      do_undefinstr
 582         b       ret_to_user
 583 el0_dbg:
 584         /*
 585          * Debug exception handling
 586          */
 587         tbnz    x24, #0, el0_inv                // EL0 only
 588         mrs     x0, far_el1
 589         mov     x1, x25
 590         mov     x2, sp
 591         bl      do_debug_exception
 592         enable_dbg
 593         ct_user_exit
 594         b       ret_to_user
 595 el0_inv:
 596         enable_dbg
 597         ct_user_exit
 598         mov     x0, sp
 599         mov     x1, #BAD_SYNC
 600         mov     x2, x25
 601         bl      bad_mode
 602         b       ret_to_user
 603 ENDPROC(el0_sync)
 604
 605         .align  6
 606 el0_irq:
 607         kernel_entry 0
 608 el0_irq_naked:
 609         enable_dbg
 610 #ifdef CONFIG_TRACE_IRQFLAGS
 611         bl      trace_hardirqs_off
 612 #endif
 613
 614         ct_user_exit
 615         irq_handler
 616
 617 #ifdef CONFIG_TRACE_IRQFLAGS
 618         bl      trace_hardirqs_on
 619 #endif
 620         b       ret_to_user
 621 ENDPROC(el0_irq)
 622
 623 /*
 624  * Register switch for AArch64. The callee-saved registers need to be saved
 625  * and restored. On entry:
 626  *   x0 = previous task_struct (must be preserved across the switch)
 627  *   x1 = next task_struct
 628  * Previous and next are guaranteed not to be the same.
 629  *
 630  */
 631 ENTRY(cpu_switch_to)
 632         mov     x10, #THREAD_CPU_CONTEXT
 633         add     x8, x0, x10
 634         mov     x9, sp
 635         stp     x19, x20, [x8], #16             // store callee-saved registers
 636         stp     x21, x22, [x8], #16
 637         stp     x23, x24, [x8], #16
 638         stp     x25, x26, [x8], #16
 639         stp     x27, x28, [x8], #16
 640         stp     x29, x9, [x8], #16
 641         str     lr, [x8]
 642         add     x8, x1, x10
 643         ldp     x19, x20, [x8], #16             // restore callee-saved registers
 644         ldp     x21, x22, [x8], #16
 645         ldp     x23, x24, [x8], #16
 646         ldp     x25, x26, [x8], #16
 647         ldp     x27, x28, [x8], #16
 648         ldp     x29, x9, [x8], #16
 649         ldr     lr, [x8]
 650         mov     sp, x9
 651         and     x9, x9, #~(THREAD_SIZE - 1)
 652         msr     sp_el0, x9
 653         ret
 654 ENDPROC(cpu_switch_to)
 655
 656 /*
 657  * This is the fast syscall return path.  We do as little as possible here,
 658  * and this includes saving x0 back into the kernel stack.
 659  */
 660 ret_fast_syscall:
 661         disable_irq                             // disable interrupts
 662         str     x0, [sp, #S_X0]                 // returned x0
 663         ldr     x1, [tsk, #TI_FLAGS]            // re-check for syscall tracing
 664         and     x2, x1, #_TIF_SYSCALL_WORK
 665         cbnz    x2, ret_fast_syscall_trace
 666         and     x2, x1, #_TIF_WORK_MASK
 667         cbnz    x2, work_pending
 668         enable_step_tsk x1, x2
 669         kernel_exit 0
 670 ret_fast_syscall_trace:
 671         enable_irq                              // enable interrupts
 672         b       __sys_trace_return_skipped      // we already saved x0
 673
 674 /*
 675  * Ok, we need to do extra processing, enter the slow path.
 676  */
 677 work_pending:
 678         tbnz    x1, #TIF_NEED_RESCHED, work_resched
 679         /* TIF_SIGPENDING, TIF_NOTIFY_RESUME or TIF_FOREIGN_FPSTATE case */
 680         mov     x0, sp                          // 'regs'
 681         enable_irq                              // enable interrupts for do_notify_resume()
 682         bl      do_notify_resume
 683         b       ret_to_user
 684 work_resched:
 685 #ifdef CONFIG_TRACE_IRQFLAGS
 686         bl      trace_hardirqs_off              // the IRQs are off here, inform the tracing code
 687 #endif
 688         bl      schedule
 689
 690 /*
 691  * "slow" syscall return path.
 692  */
 693 ret_to_user:
 694         disable_irq                             // disable interrupts
 695         ldr     x1, [tsk, #TI_FLAGS]
 696         and     x2, x1, #_TIF_WORK_MASK
 697         cbnz    x2, work_pending
 698         enable_step_tsk x1, x2
 699         kernel_exit 0
 700 ENDPROC(ret_to_user)
 701
 702 /*
 703  * This is how we return from a fork.
 704  */
 705 ENTRY(ret_from_fork)
 706         bl      schedule_tail
 707         cbz     x19, 1f                         // not a kernel thread
 708         mov     x0, x20
 709         blr     x19
 710 1:      get_thread_info tsk
 711         b       ret_to_user
 712 ENDPROC(ret_from_fork)
 713
 714 /*
 715  * SVC handler.
 716  */
 717         .align  6
 718 el0_svc:
 719         adrp    stbl, sys_call_table            // load syscall table pointer
 720         uxtw    scno, w8                        // syscall number in w8
 721         mov     sc_nr, #__NR_syscalls
 722 el0_svc_naked:                                  // compat entry point
 723         stp     x0, scno, [sp, #S_ORIG_X0]      // save the original x0 and syscall number
 724         enable_dbg_and_irq
 725         ct_user_exit 1
 726
 727         ldr     x16, [tsk, #TI_FLAGS]           // check for syscall hooks
 728         tst     x16, #_TIF_SYSCALL_WORK
 729         b.ne    __sys_trace
 730         cmp     scno, sc_nr                     // check upper syscall limit
 731         b.hs    ni_sys
 732         ldr     x16, [stbl, scno, lsl #3]       // address in the syscall table
 733         blr     x16                             // call sys_* routine
 734         b       ret_fast_syscall
 735 ni_sys:
 736         mov     x0, sp
 737         bl      do_ni_syscall
 738         b       ret_fast_syscall
 739 ENDPROC(el0_svc)
 740
 741         /*
 742          * This is the really slow path.  We're going to be doing context
 743          * switches, and waiting for our parent to respond.
 744          */
 745 __sys_trace:
 746         mov     w0, #-1                         // set default errno for
 747         cmp     scno, x0                        // user-issued syscall(-1)
 748         b.ne    1f
 749         mov     x0, #-ENOSYS
 750         str     x0, [sp, #S_X0]
 751 1:      mov     x0, sp
 752         bl      syscall_trace_enter
 753         cmp     w0, #-1                         // skip the syscall?
 754         b.eq    __sys_trace_return_skipped
 755         uxtw    scno, w0                        // syscall number (possibly new)
 756         mov     x1, sp                          // pointer to regs
 757         cmp     scno, sc_nr                     // check upper syscall limit
 758         b.hs    __ni_sys_trace
 759         ldp     x0, x1, [sp]                    // restore the syscall args
 760         ldp     x2, x3, [sp, #S_X2]
 761         ldp     x4, x5, [sp, #S_X4]
 762         ldp     x6, x7, [sp, #S_X6]
 763         ldr     x16, [stbl, scno, lsl #3]       // address in the syscall table
 764         blr     x16                             // call sys_* routine
 765
 766 __sys_trace_return:
 767         str     x0, [sp, #S_X0]                 // save returned x0
 768 __sys_trace_return_skipped:
 769         mov     x0, sp
 770         bl      syscall_trace_exit
 771         b       ret_to_user
 772
 773 __ni_sys_trace:
 774         mov     x0, sp
 775         bl      do_ni_syscall
 776         b       __sys_trace_return
 777
 778         .popsection                             // .entry.text
 779
 780 /*
 781  * Special system call wrappers.
 782  */
 783 ENTRY(sys_rt_sigreturn_wrapper)
 784         mov     x0, sp
 785         b       sys_rt_sigreturn
 786 ENDPROC(sys_rt_sigreturn_wrapper)