arch/arm64/kernel/vmlinux.lds.S

   1 /*
   2  * ld script to make ARM Linux kernel
   3  * taken from the i386 version by Russell King
   4  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5  */
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/cache.h>
   9 #include <asm/kernel-pgtable.h>
  10 #include <asm/thread_info.h>
  11 #include <asm/memory.h>
  12 #include <asm/page.h>
  13 #include <asm/pgtable.h>
  14
  15 #include "image.h"
  16
  17 /* .exit.text needed in case of alternative patching */
  18 #define ARM_EXIT_KEEP(x)        x
  19 #define ARM_EXIT_DISCARD(x)
  20
  21 OUTPUT_ARCH(aarch64)
  22 ENTRY(_text)
  23
  24 jiffies = jiffies_64;
  25
  26 #define HYPERVISOR_TEXT                                 \
  27         /*                                              \
  28          * Align to 4 KB so that                        \
  29          * a) the HYP vector table is at its minimum    \
  30          *    alignment of 2048 bytes                   \
  31          * b) the HYP init code will not cross a page   \
  32          *    boundary if its size does not exceed      \
  33          *    4 KB (see related ASSERT() below)         \
  34          */                                             \
  35         . = ALIGN(SZ_4K);                               \
  36         VMLINUX_SYMBOL(__hyp_idmap_text_start) = .;     \
  37         *(.hyp.idmap.text)                              \
  38         VMLINUX_SYMBOL(__hyp_idmap_text_end) = .;       \
  39         VMLINUX_SYMBOL(__hyp_text_start) = .;           \
  40         *(.hyp.text)                                    \
  41         VMLINUX_SYMBOL(__hyp_text_end) = .;
  42
  43 #define IDMAP_TEXT                                      \
  44         . = ALIGN(SZ_4K);                               \
  45         VMLINUX_SYMBOL(__idmap_text_start) = .;         \
  46         *(.idmap.text)                                  \
  47         VMLINUX_SYMBOL(__idmap_text_end) = .;
  48
  49 /*
  50  * The size of the PE/COFF section that covers the kernel image, which
  51  * runs from stext to _edata, must be a round multiple of the PE/COFF
  52  * FileAlignment, which we set to its minimum value of 0x200. 'stext'
  53  * itself is 4 KB aligned, so padding out _edata to a 0x200 aligned
  54  * boundary should be sufficient.
  55  */
  56 PECOFF_FILE_ALIGNMENT = 0x200;
  57
  58 #ifdef CONFIG_EFI
  59 #define PECOFF_EDATA_PADDING    \
  60         .pecoff_edata_padding : { BYTE(0); . = ALIGN(PECOFF_FILE_ALIGNMENT); }
  61 #else
  62 #define PECOFF_EDATA_PADDING
  63 #endif
  64
  65 #if defined(CONFIG_DEBUG_ALIGN_RODATA)
  66 #define ALIGN_DEBUG_RO                  . = ALIGN(1<<SECTION_SHIFT);
  67 #define ALIGN_DEBUG_RO_MIN(min)         ALIGN_DEBUG_RO
  68 #elif defined(CONFIG_DEBUG_RODATA)
  69 #define ALIGN_DEBUG_RO                  . = ALIGN(1<<PAGE_SHIFT);
  70 #define ALIGN_DEBUG_RO_MIN(min)         ALIGN_DEBUG_RO
  71 #else
  72 #define ALIGN_DEBUG_RO
  73 #define ALIGN_DEBUG_RO_MIN(min)         . = ALIGN(min);
  74 #endif
  75
  76 SECTIONS
  77 {
  78         /*
  79          * XXX: The linker does not define how output sections are
  80          * assigned to input sections when there are multiple statements
  81          * matching the same input section name.  There is no documented
  82          * order of matching.
  83          */
  84         /DISCARD/ : {
  85                 ARM_EXIT_DISCARD(EXIT_TEXT)
  86                 ARM_EXIT_DISCARD(EXIT_DATA)
  87                 EXIT_CALL
  88                 *(.discard)
  89                 *(.discard.*)
  90         }
  91
  92         . = KIMAGE_VADDR + TEXT_OFFSET;
  93
  94         .head.text : {
  95                 _text = .;
  96                 HEAD_TEXT
  97         }
  98         ALIGN_DEBUG_RO_MIN(PAGE_SIZE)
  99         .text : {                       /* Real text segment            */
 100                 _stext = .;             /* Text and read-only data      */
 101                         __exception_text_start = .;
 102                         *(.exception.text)
 103                         __exception_text_end = .;
 104                         IRQENTRY_TEXT
 105                         TEXT_TEXT
 106                         SCHED_TEXT
 107                         LOCK_TEXT
 108                         HYPERVISOR_TEXT
 109                         IDMAP_TEXT
 110                         *(.fixup)
 111                         *(.gnu.warning)
 112                 . = ALIGN(16);
 113                 *(.got)                 /* Global offset table          */
 114         }
 115
 116         RO_DATA(PAGE_SIZE)
 117         EXCEPTION_TABLE(8)
 118         NOTES
 119
 120         ALIGN_DEBUG_RO_MIN(PAGE_SIZE)
 121         _etext = .;                     /* End of text and rodata section */
 122         __init_begin = .;
 123
 124         INIT_TEXT_SECTION(8)
 125         .exit.text : {
 126                 ARM_EXIT_KEEP(EXIT_TEXT)
 127         }
 128
 129         .init.data : {
 130                 INIT_DATA
 131                 INIT_SETUP(16)
 132                 INIT_CALLS
 133                 CON_INITCALL
 134                 SECURITY_INITCALL
 135                 INIT_RAM_FS
 136         }
 137         .exit.data : {
 138                 ARM_EXIT_KEEP(EXIT_DATA)
 139         }
 140
 141         PERCPU_SECTION(L1_CACHE_BYTES)
 142
 143         . = ALIGN(4);
 144         .altinstructions : {
 145                 __alt_instructions = .;
 146                 *(.altinstructions)
 147                 __alt_instructions_end = .;
 148         }
 149         .altinstr_replacement : {
 150                 *(.altinstr_replacement)
 151         }
 152
 153         . = ALIGN(PAGE_SIZE);
 154         __init_end = .;
 155
 156         _data = .;
 157         _sdata = .;
 158         RW_DATA_SECTION(L1_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
 159         PECOFF_EDATA_PADDING
 160         _edata = .;
 161
 162         BSS_SECTION(0, 0, 0)
 163
 164         . = ALIGN(PAGE_SIZE);
 165         idmap_pg_dir = .;
 166         . += IDMAP_DIR_SIZE;
 167         swapper_pg_dir = .;
 168         . += SWAPPER_DIR_SIZE;
 169
 170         _end = .;
 171
 172         STABS_DEBUG
 173
 174         HEAD_SYMBOLS
 175 }
 176
 177 /*
 178  * The HYP init code and ID map text can't be longer than a page each,
 179  * and should not cross a page boundary.
 180  */
 181 ASSERT(__hyp_idmap_text_end - (__hyp_idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
 182         "HYP init code too big or misaligned")
 183 ASSERT(__idmap_text_end - (__idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
 184         "ID map text too big or misaligned")
 185
 186 /*
 187  * If padding is applied before .head.text, virt<->phys conversions will fail.
 188  */
 189 ASSERT(_text == (KIMAGE_VADDR + TEXT_OFFSET), "HEAD is misaligned")