arch/i386/cpu/start.S

   1 /*
   2  *  U-boot - i386 Startup Code
   3  *
   4  *  Copyright (c) 2002  Omicron Ceti AB, Daniel Engstr�m <denaiel@omicron.se>
   5  *
   6  * See file CREDITS for list of people who contributed to this
   7  * project.
   8  *
   9  * This program is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU General Public License as
  11  * published by the Free Software Foundation; either version 2 of
  12  * the License, or (at your option) any later version.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  22  * MA 02111-1307 USA
  23  */
  24
  25
  26 #include <config.h>
  27 #include <version.h>
  28 #include <asm/global_data.h>
  29
  30
  31 .section .text
  32 .code32
  33 .globl _start
  34 .type _start, @function
  35 .globl _i386boot_start
  36 _i386boot_start:
  37         /*
  38          * This is the fail safe 32-bit bootstrap entry point. The
  39          * following code is not executed from a cold-reset (actually, a
  40          * lot of it is, but from real-mode after cold reset. It is
  41          * repeated here to put the board into a state as close to cold
  42          * reset as necessary)
  43          */
  44         cli
  45         cld
  46
  47         /* Turn of cache (this might require a 486-class CPU) */
  48         movl    %cr0, %eax
  49         orl     $0x60000000, %eax
  50         movl    %eax, %cr0
  51         wbinvd
  52
  53         /* Tell 32-bit code it is being entered from an in-RAM copy */
  54         movw    $0x0000, %bx
  55 _start:
  56         /* This is the 32-bit cold-reset entry point */
  57
  58         movl    $0x18, %eax     /* Load our segement registes, the
  59                                  * gdt have already been loaded by start16.S */
  60         movw    %ax, %fs
  61         movw    %ax, %ds
  62         movw    %ax, %gs
  63         movw    %ax, %es
  64         movw    %ax, %ss
  65
  66         /* Clear the interupt vectors */
  67         lidt    blank_idt_ptr
  68
  69         /*
  70          * Skip low-level board and memory initialization if not starting
  71          * from cold-reset. This allows us to do a fail safe boot-strap
  72          * into a new build of U-Boot from a known-good boot flash
  73          */
  74         movw    $0x0001, %ax
  75         cmpw    %ax, %bx
  76         jne     mem_init_ret
  77
  78         /* We call a few functions in the board support package
  79          * since we have no stack yet we'll have to use %ebp
  80          * to store the return address */
  81
  82         /* Early platform init (setup gpio, etc ) */
  83         jmp     early_board_init
  84 .globl early_board_init_ret
  85 early_board_init_ret:
  86
  87         /* size memory */
  88         jmp     mem_init
  89 .globl mem_init_ret
  90 mem_init_ret:
  91
  92         /* fetch memory size (into %eax) */
  93         jmp     get_mem_size
  94 .globl get_mem_size_ret
  95 get_mem_size_ret:
  96
  97 #if CONFIG_SYS_SDRAM_ECC_ENABLE
  98         /* Skip ECC initialization if not starting from cold-reset */
  99         movl    %ebx, %ecx
 100         andl    $GD_FLG_COLD_BOOT, %ecx
 101         jz      init_ecc_ret
 102         jmp     init_ecc
 103
 104 .globl init_ecc_ret
 105 init_ecc_ret:
 106 #endif
 107
 108         /* Check we have enough memory for stack */
 109         movl    $CONFIG_SYS_STACK_SIZE, %ecx
 110         cmpl    %ecx, %eax
 111         jb      die
 112 mem_ok:
 113         /* Set stack pointer to upper memory limit*/
 114         movl    %eax, %esp
 115
 116         /* Test the stack */
 117         pushl   $0
 118         popl    %ecx
 119         cmpl    $0, %ecx
 120         jne     die
 121         push    $0x55aa55aa
 122         popl    %ecx
 123         cmpl    $0x55aa55aa, %ecx
 124         jne     die
 125
 126         wbinvd
 127
 128         /* Set the upper memory limit parameter */
 129         subl    $CONFIG_SYS_STACK_SIZE, %eax
 130
 131         /* Reserve space for global data */
 132         subl    $(GD_SIZE * 4), %eax
 133
 134         /* %eax points to the global data structure */
 135         movl    %esp, (GD_RAM_SIZE * 4)(%eax)
 136         movl    %ebx, (GD_FLAGS * 4)(%eax)
 137
 138         call    board_init_f    /* Enter, U-boot! */
 139
 140         /* indicate (lack of) progress */
 141         movw    $0x85, %ax
 142 die:    hlt
 143         jmp     die
 144         hlt
 145
 146 blank_idt_ptr:
 147         .word   0               /* limit */
 148         .long   0               /* base */