arch/i386/cpu/start.S

   1 /*
   2  *  U-boot - i386 Startup Code
   3  *
   4  *  Copyright (c) 2002  Omicron Ceti AB, Daniel Engström <denaiel@omicron.se>
   5  *
   6  * See file CREDITS for list of people who contributed to this
   7  * project.
   8  *
   9  * This program is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU General Public License as
  11  * published by the Free Software Foundation; either version 2 of
  12  * the License, or (at your option) any later version.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  22  * MA 02111-1307 USA
  23  */
  24
  25
  26 #include <config.h>
  27 #include <version.h>
  28
  29
  30 .section .text
  31 .code32
  32 .globl _start
  33 .type _start, @function
  34 .globl _i386boot_start
  35 _i386boot_start:
  36         /*
  37          * This is the fail safe 32-bit bootstrap entry point. The
  38          * following code is not executed from a cold-reset (actually, a
  39          * lot of it is, but from real-mode after cold reset. It is
  40          * repeated here to put the board into a state as close to cold
  41          * reset as necessary)
  42          */
  43         cli
  44         cld
  45
  46         /* Turn of cache (this might require a 486-class CPU) */
  47         movl    %cr0, %eax
  48         orl     $0x60000000,%eax
  49         movl    %eax, %cr0
  50         wbinvd
  51
  52         /* Tell 32-bit code it is being entered from an in-RAM copy */
  53         movw    $0x0000, %bx
  54 _start:
  55         /* This is the 32-bit cold-reset entry point */
  56
  57         movl    $0x18,%eax      /* Load our segement registes, the
  58                                  * gdt have already been loaded by start16.S */
  59         movw    %ax,%fs
  60         movw    %ax,%ds
  61         movw    %ax,%gs
  62         movw    %ax,%es
  63         movw    %ax,%ss
  64
  65         /* Clear the interupt vectors */
  66         lidt    blank_idt_ptr
  67
  68         /*
  69          * Skip low-level board and memory initialization if not starting
  70          * from cold-reset. This allows us to do a fail safe boot-strap
  71          * into a new build of U-Boot from a known-good boot flash
  72          */
  73         movw    $0x0001, %ax
  74         cmpw    %ax, %bx
  75         jne     mem_init_ret
  76
  77         /* We call a few functions in the board support package
  78          * since we have no stack yet we'll have to use %ebp
  79          * to store the return address */
  80
  81         /* Early platform init (setup gpio, etc ) */
  82         mov     $early_board_init_ret, %ebp
  83         jmp     early_board_init
  84 early_board_init_ret:
  85
  86         /* The __port80 entry-point should be usabe by now */
  87         /* so we try to indicate progress */
  88         movw    $0x01, %ax
  89         movl    $.progress0, %ebp
  90         jmp     show_boot_progress_asm
  91 .progress0:
  92
  93         /* size memory */
  94         mov     $mem_init_ret, %ebp
  95         jmp     mem_init
  96 mem_init_ret:
  97
  98         /* fetch memory size (into %eax) */
  99         mov     $get_mem_size_ret, %ebp
 100         jmp     get_mem_size
 101 get_mem_size_ret:
 102
 103         /* Check we have enough memory for stack */
 104         movl    $CONFIG_SYS_STACK_SIZE, %ecx
 105         cmpl    %ecx, %eax
 106         jae     mem_ok
 107
 108         /* indicate (lack of) progress */
 109         movw    $0x81, %ax
 110         movl    $.progress0a, %ebp
 111         jmp     show_boot_progress_asm
 112 .progress0a:
 113         jmp     die
 114 mem_ok:
 115         /* Set stack pointer to upper memory limit*/
 116         movl    %eax, %esp
 117
 118         /* indicate progress */
 119         movw    $0x02, %ax
 120         movl    $.progress1, %ebp
 121         jmp     show_boot_progress_asm
 122 .progress1:
 123
 124         /* Test the stack */
 125         pushl   $0
 126         popl    %eax
 127         cmpl    $0, %eax
 128         jne     no_stack
 129         push    $0x55aa55aa
 130         popl    %ebx
 131         cmpl    $0x55aa55aa, %ebx
 132         je      stack_ok
 133
 134 no_stack:
 135         /* indicate (lack of) progress */
 136         movw    $0x82, %ax
 137         movl    $.progress1a, %ebp
 138         jmp     show_boot_progress_asm
 139 .progress1a:
 140         jmp die
 141
 142
 143 stack_ok:
 144         /* indicate progress */
 145         movw    $0x03, %ax
 146         movl    $.progress2, %ebp
 147         jmp     show_boot_progress_asm
 148 .progress2:
 149
 150         wbinvd
 151
 152         /* Get upper memory limit */
 153         movl %esp, %ecx
 154         subl $CONFIG_SYS_STACK_SIZE, %ecx
 155
 156         /* Create a Stack Frame */
 157         pushl %ebp
 158         movl %esp, %ebp
 159
 160         /* stack_limit parameter */
 161         pushl   %ecx
 162         call    board_init_f    /* Enter, U-boot! */
 163
 164         /* indicate (lack of) progress */
 165         movw    $0x85, %ax
 166         movl    $.progress4a, %ebp
 167         jmp     show_boot_progress_asm
 168 .progress4a:
 169
 170 die:    hlt
 171         jmp     die
 172         hlt
 173
 174 blank_idt_ptr:
 175         .word   0               /* limit */
 176         .long   0               /* base */