arch/powerpc/cpu/ppc4xx/start.S

   1 /*
   2  *  Copyright (C) 1998  Dan Malek <dmalek@jlc.net>
   3  *  Copyright (C) 1999  Magnus Damm <kieraypc01.p.y.kie.era.ericsson.se>
   4  *  Copyright (C) 2000,2001,2002 Wolfgang Denk <wd@denx.de>
   5  *  Copyright (C) 2007 Stefan Roese <sr@denx.de>, DENX Software Engineering
   6  *  Copyright (c) 2008 Nuovation System Designs, LLC
   7  *    Grant Erickson <gerickson@nuovations.com>
   8  *
   9  * See file CREDITS for list of people who contributed to this
  10  * project.
  11  *
  12  * This program is free software; you can redistribute it and/or
  13  * modify it under the terms of the GNU General Public License as
  14  * published by the Free Software Foundation; either version 2 of
  15  * the License, or (at your option) any later version.
  16  *
  17  * This program is distributed in the hope that it will be useful,
  18  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  19  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20  * GNU General Public License for more details.
  21  *
  22  * You should have received a copy of the GNU General Public License
  23  * along with this program; if not, write to the Free Software
  24  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  25  * MA 02111-1307 USA
  26  */
  27 /*------------------------------------------------------------------------------+
  28  *   This source code is dual-licensed.  You may use it under the terms of the
  29  *   GNU General Public License version 2, or under the license below.
  30  *
  31  *       This source code has been made available to you by IBM on an AS-IS
  32  *       basis.  Anyone receiving this source is licensed under IBM
  33  *       copyrights to use it in any way he or she deems fit, including
  34  *       copying it, modifying it, compiling it, and redistributing it either
  35  *       with or without modifications.  No license under IBM patents or
  36  *       patent applications is to be implied by the copyright license.
  37  *
  38  *       Any user of this software should understand that IBM cannot provide
  39  *       technical support for this software and will not be responsible for
  40  *       any consequences resulting from the use of this software.
  41  *
  42  *       Any person who transfers this source code or any derivative work
  43  *       must include the IBM copyright notice, this paragraph, and the
  44  *       preceding two paragraphs in the transferred software.
  45  *
  46  *       COPYRIGHT   I B M   CORPORATION 1995
  47  *       LICENSED MATERIAL  -  PROGRAM PROPERTY OF I B M
  48  *-------------------------------------------------------------------------------
  49  */
  50
  51 /*  U-Boot - Startup Code for AMCC 4xx PowerPC based Embedded Boards
  52  *
  53  *
  54  *  The processor starts at 0xfffffffc and the code is executed
  55  *  from flash/rom.
  56  *  in memory, but as long we don't jump around before relocating.
  57  *  board_init lies at a quite high address and when the cpu has
  58  *  jumped there, everything is ok.
  59  *  This works because the cpu gives the FLASH (CS0) the whole
  60  *  address space at startup, and board_init lies as a echo of
  61  *  the flash somewhere up there in the memorymap.
  62  *
  63  *  board_init will change CS0 to be positioned at the correct
  64  *  address and (s)dram will be positioned at address 0
  65  */
  66 #include <config.h>
  67 #include <asm/ppc4xx.h>
  68 #include <timestamp.h>
  69 #include <version.h>
  70
  71 #define _LINUX_CONFIG_H 1       /* avoid reading Linux autoconf.h file  */
  72
  73 #include <ppc_asm.tmpl>
  74 #include <ppc_defs.h>
  75
  76 #include <asm/cache.h>
  77 #include <asm/mmu.h>
  78 #include <asm/ppc4xx-isram.h>
  79
  80 #ifndef  CONFIG_IDENT_STRING
  81 #define  CONFIG_IDENT_STRING ""
  82 #endif
  83
  84 #ifdef CONFIG_SYS_INIT_DCACHE_CS
  85 # if (CONFIG_SYS_INIT_DCACHE_CS == 0)
  86 #  define PBxAP PB1AP
  87 #  define PBxCR PB0CR
  88 #  if (defined(CONFIG_SYS_EBC_PB0AP) && defined(CONFIG_SYS_EBC_PB0CR))
  89 #   define PBxAP_VAL CONFIG_SYS_EBC_PB0AP
  90 #   define PBxCR_VAL CONFIG_SYS_EBC_PB0CR
  91 #  endif
  92 # endif
  93 # if (CONFIG_SYS_INIT_DCACHE_CS == 1)
  94 #  define PBxAP PB1AP
  95 #  define PBxCR PB1CR
  96 #  if (defined(CONFIG_SYS_EBC_PB1AP) && defined(CONFIG_SYS_EBC_PB1CR))
  97 #   define PBxAP_VAL CONFIG_SYS_EBC_PB1AP
  98 #   define PBxCR_VAL CONFIG_SYS_EBC_PB1CR
  99 #  endif
 100 # endif
 101 # if (CONFIG_SYS_INIT_DCACHE_CS == 2)
 102 #  define PBxAP PB2AP
 103 #  define PBxCR PB2CR
 104 #  if (defined(CONFIG_SYS_EBC_PB2AP) && defined(CONFIG_SYS_EBC_PB2CR))
 105 #   define PBxAP_VAL CONFIG_SYS_EBC_PB2AP
 106 #   define PBxCR_VAL CONFIG_SYS_EBC_PB2CR
 107 #  endif
 108 # endif
 109 # if (CONFIG_SYS_INIT_DCACHE_CS == 3)
 110 #  define PBxAP PB3AP
 111 #  define PBxCR PB3CR
 112 #  if (defined(CONFIG_SYS_EBC_PB3AP) && defined(CONFIG_SYS_EBC_PB3CR))
 113 #   define PBxAP_VAL CONFIG_SYS_EBC_PB3AP
 114 #   define PBxCR_VAL CONFIG_SYS_EBC_PB3CR
 115 #  endif
 116 # endif
 117 # if (CONFIG_SYS_INIT_DCACHE_CS == 4)
 118 #  define PBxAP PB4AP
 119 #  define PBxCR PB4CR
 120 #  if (defined(CONFIG_SYS_EBC_PB4AP) && defined(CONFIG_SYS_EBC_PB4CR))
 121 #   define PBxAP_VAL CONFIG_SYS_EBC_PB4AP
 122 #   define PBxCR_VAL CONFIG_SYS_EBC_PB4CR
 123 #  endif
 124 # endif
 125 # if (CONFIG_SYS_INIT_DCACHE_CS == 5)
 126 #  define PBxAP PB5AP
 127 #  define PBxCR PB5CR
 128 #  if (defined(CONFIG_SYS_EBC_PB5AP) && defined(CONFIG_SYS_EBC_PB5CR))
 129 #   define PBxAP_VAL CONFIG_SYS_EBC_PB5AP
 130 #   define PBxCR_VAL CONFIG_SYS_EBC_PB5CR
 131 #  endif
 132 # endif
 133 # if (CONFIG_SYS_INIT_DCACHE_CS == 6)
 134 #  define PBxAP PB6AP
 135 #  define PBxCR PB6CR
 136 #  if (defined(CONFIG_SYS_EBC_PB6AP) && defined(CONFIG_SYS_EBC_PB6CR))
 137 #   define PBxAP_VAL CONFIG_SYS_EBC_PB6AP
 138 #   define PBxCR_VAL CONFIG_SYS_EBC_PB6CR
 139 #  endif
 140 # endif
 141 # if (CONFIG_SYS_INIT_DCACHE_CS == 7)
 142 #  define PBxAP PB7AP
 143 #  define PBxCR PB7CR
 144 #  if (defined(CONFIG_SYS_EBC_PB7AP) && defined(CONFIG_SYS_EBC_PB7CR))
 145 #   define PBxAP_VAL CONFIG_SYS_EBC_PB7AP
 146 #   define PBxCR_VAL CONFIG_SYS_EBC_PB7CR
 147 #  endif
 148 # endif
 149 # ifndef PBxAP_VAL
 150 #  define PBxAP_VAL     0
 151 # endif
 152 # ifndef PBxCR_VAL
 153 #  define PBxCR_VAL     0
 154 # endif
 155 /*
 156  * Memory Bank x (nothingness) initialization CONFIG_SYS_INIT_RAM_ADDR + 64 MiB
 157  * used as temporary stack pointer for the primordial stack
 158  */
 159 # ifndef CONFIG_SYS_INIT_DCACHE_PBxAR
 160 #  define CONFIG_SYS_INIT_DCACHE_PBxAR  (EBC_BXAP_BME_DISABLED                  | \
 161                                  EBC_BXAP_TWT_ENCODE(7)                 | \
 162                                  EBC_BXAP_BCE_DISABLE                   | \
 163                                  EBC_BXAP_BCT_2TRANS                    | \
 164                                  EBC_BXAP_CSN_ENCODE(0)                 | \
 165                                  EBC_BXAP_OEN_ENCODE(0)                 | \
 166                                  EBC_BXAP_WBN_ENCODE(0)                 | \
 167                                  EBC_BXAP_WBF_ENCODE(0)                 | \
 168                                  EBC_BXAP_TH_ENCODE(2)                  | \
 169                                  EBC_BXAP_RE_DISABLED                   | \
 170                                  EBC_BXAP_SOR_NONDELAYED                | \
 171                                  EBC_BXAP_BEM_WRITEONLY                 | \
 172                                  EBC_BXAP_PEN_DISABLED)
 173 # endif /* CONFIG_SYS_INIT_DCACHE_PBxAR */
 174 # ifndef CONFIG_SYS_INIT_DCACHE_PBxCR
 175 #  define CONFIG_SYS_INIT_DCACHE_PBxCR  (EBC_BXCR_BAS_ENCODE(CONFIG_SYS_INIT_RAM_ADDR)  | \
 176                                  EBC_BXCR_BS_64MB                       | \
 177                                  EBC_BXCR_BU_RW                         | \
 178                                  EBC_BXCR_BW_16BIT)
 179 # endif /* CONFIG_SYS_INIT_DCACHE_PBxCR */
 180 # ifndef CONFIG_SYS_INIT_RAM_PATTERN
 181 #  define CONFIG_SYS_INIT_RAM_PATTERN   0xDEADDEAD
 182 # endif
 183 #endif /* CONFIG_SYS_INIT_DCACHE_CS */
 184
 185 #if (defined(CONFIG_SYS_INIT_RAM_DCACHE) && (CONFIG_SYS_INIT_RAM_END > (4 << 10)))
 186 #error Only 4k of init-ram is supported - please adjust CONFIG_SYS_INIT_RAM_END!
 187 #endif
 188
 189 /*
 190  * Unless otherwise overriden, enable two 128MB cachable instruction regions
 191  * at CONFIG_SYS_SDRAM_BASE and another 128MB cacheable instruction region covering
 192  * NOR flash at CONFIG_SYS_FLASH_BASE. Disable all cacheable data regions.
 193  */
 194 #if !defined(CONFIG_SYS_FLASH_BASE)
 195 /* If not already defined, set it to the "last" 128MByte region */
 196 # define CONFIG_SYS_FLASH_BASE          0xf8000000
 197 #endif
 198 #if !defined(CONFIG_SYS_ICACHE_SACR_VALUE)
 199 # define CONFIG_SYS_ICACHE_SACR_VALUE           \
 200                 (PPC_128MB_SACR_VALUE(CONFIG_SYS_SDRAM_BASE + (  0 << 20)) | \
 201                  PPC_128MB_SACR_VALUE(CONFIG_SYS_SDRAM_BASE + (128 << 20)) | \
 202                  PPC_128MB_SACR_VALUE(CONFIG_SYS_FLASH_BASE))
 203 #endif /* !defined(CONFIG_SYS_ICACHE_SACR_VALUE) */
 204
 205 #if !defined(CONFIG_SYS_DCACHE_SACR_VALUE)
 206 # define CONFIG_SYS_DCACHE_SACR_VALUE           \
 207                 (0x00000000)
 208 #endif /* !defined(CONFIG_SYS_DCACHE_SACR_VALUE) */
 209
 210 #if !defined(CONFIG_SYS_TLB_FOR_BOOT_FLASH)
 211 #define CONFIG_SYS_TLB_FOR_BOOT_FLASH   0       /* use TLB 0 as default */
 212 #endif
 213
 214 #define function_prolog(func_name)      .text; \
 215                                         .align 2; \
 216                                         .globl func_name; \
 217                                         func_name:
 218 #define function_epilog(func_name)      .type func_name,@function; \
 219                                         .size func_name,.-func_name
 220
 221 /* We don't want the  MMU yet.
 222 */
 223 #undef  MSR_KERNEL
 224 #define MSR_KERNEL ( MSR_ME  )  /* Machine Check */
 225
 226
 227         .extern ext_bus_cntlr_init
 228 #ifdef CONFIG_NAND_U_BOOT
 229         .extern reconfig_tlb0
 230 #endif
 231
 232 /*
 233  * Set up GOT: Global Offset Table
 234  *
 235  * Use r12 to access the GOT
 236  */
 237 #if !defined(CONFIG_NAND_SPL)
 238         START_GOT
 239         GOT_ENTRY(_GOT2_TABLE_)
 240         GOT_ENTRY(_FIXUP_TABLE_)
 241
 242         GOT_ENTRY(_start)
 243         GOT_ENTRY(_start_of_vectors)
 244         GOT_ENTRY(_end_of_vectors)
 245         GOT_ENTRY(transfer_to_handler)
 246
 247         GOT_ENTRY(__init_end)
 248         GOT_ENTRY(_end)
 249         GOT_ENTRY(__bss_start)
 250         END_GOT
 251 #endif /* CONFIG_NAND_SPL */
 252
 253 #if defined(CONFIG_NAND_U_BOOT) && !defined(CONFIG_NAND_SPL)
 254         /*
 255          * NAND U-Boot image is started from offset 0
 256          */
 257         .text
 258 #if defined(CONFIG_440)
 259         bl      reconfig_tlb0
 260 #endif
 261         GET_GOT
 262         bl      cpu_init_f      /* run low-level CPU init code     (from Flash) */
 263         bl      board_init_f
 264 #endif
 265
 266 #if defined(CONFIG_SYS_RAMBOOT)
 267         /*
 268          * 4xx RAM-booting U-Boot image is started from offset 0
 269          */
 270         .text
 271         bl      _start_440
 272 #endif
 273
 274 /*
 275  * 440 Startup -- on reset only the top 4k of the effective
 276  * address space is mapped in by an entry in the instruction
 277  * and data shadow TLB. The .bootpg section is located in the
 278  * top 4k & does only what's necessary to map in the the rest
 279  * of the boot rom. Once the boot rom is mapped in we can
 280  * proceed with normal startup.
 281  *
 282  * NOTE: CS0 only covers the top 2MB of the effective address
 283  * space after reset.
 284  */
 285
 286 #if defined(CONFIG_440)
 287 #if !defined(CONFIG_NAND_SPL)
 288     .section .bootpg,"ax"
 289 #endif
 290     .globl _start_440
 291
 292 /**************************************************************************/
 293 _start_440:
 294         /*--------------------------------------------------------------------+
 295         | 440EPX BUP Change - Hardware team request
 296         +--------------------------------------------------------------------*/
 297 #if defined(CONFIG_440EPX) || defined(CONFIG_440GRX)
 298         sync
 299         nop
 300         nop
 301 #endif
 302         /*----------------------------------------------------------------+
 303         | Core bug fix.  Clear the esr
 304         +-----------------------------------------------------------------*/
 305         li      r0,0
 306         mtspr   SPRN_ESR,r0
 307         /*----------------------------------------------------------------*/
 308         /* Clear and set up some registers. */
 309         /*----------------------------------------------------------------*/
 310         iccci   r0,r0           /* NOTE: operands not used for 440 */
 311         dccci   r0,r0           /* NOTE: operands not used for 440 */
 312         sync
 313         li      r0,0
 314         mtspr   SPRN_SRR0,r0
 315         mtspr   SPRN_SRR1,r0
 316         mtspr   SPRN_CSRR0,r0
 317         mtspr   SPRN_CSRR1,r0
 318         /* NOTE: 440GX adds machine check status regs */
 319 #if defined(CONFIG_440) && !defined(CONFIG_440GP)
 320         mtspr   SPRN_MCSRR0,r0
 321         mtspr   SPRN_MCSRR1,r0
 322         mfspr   r1,SPRN_MCSR
 323         mtspr   SPRN_MCSR,r1
 324 #endif
 325
 326         /*----------------------------------------------------------------*/
 327         /* CCR0 init */
 328         /*----------------------------------------------------------------*/
 329         /* Disable store gathering & broadcast, guarantee inst/data
 330         * cache block touch, force load/store alignment
 331         * (see errata 1.12: 440_33)
 332         */
 333         lis     r1,0x0030       /* store gathering & broadcast disable */
 334         ori     r1,r1,0x6000    /* cache touch */
 335         mtspr   SPRN_CCR0,r1
 336
 337         /*----------------------------------------------------------------*/
 338         /* Initialize debug */
 339         /*----------------------------------------------------------------*/
 340         mfspr   r1,SPRN_DBCR0
 341         andis.  r1, r1, 0x8000  /* test DBCR0[EDM] bit                  */
 342         bne     skip_debug_init /* if set, don't clear debug register   */
 343         mfspr   r1,SPRN_CCR0
 344         ori     r1,r1,CCR0_DTB@l /* Disable Trace Broadcast */
 345         mtspr   SPRN_CCR0,r1
 346         mtspr   SPRN_DBCR0,r0
 347         mtspr   SPRN_DBCR1,r0
 348         mtspr   SPRN_DBCR2,r0
 349         mtspr   SPRN_IAC1,r0
 350         mtspr   SPRN_IAC2,r0
 351         mtspr   SPRN_IAC3,r0
 352         mtspr   SPRN_DAC1,r0
 353         mtspr   SPRN_DAC2,r0
 354         mtspr   SPRN_DVC1,r0
 355         mtspr   SPRN_DVC2,r0
 356
 357         mfspr   r1,SPRN_DBSR
 358         mtspr   SPRN_DBSR,r1    /* Clear all valid bits */
 359 skip_debug_init:
 360
 361 #if defined (CONFIG_440SPE)
 362         /*----------------------------------------------------------------+
 363         | Initialize Core Configuration Reg1.
 364         | a. ICDPEI: Record even parity. Normal operation.
 365         | b. ICTPEI: Record even parity. Normal operation.
 366         | c. DCTPEI: Record even parity. Normal operation.
 367         | d. DCDPEI: Record even parity. Normal operation.
 368         | e. DCUPEI: Record even parity. Normal operation.
 369         | f. DCMPEI: Record even parity. Normal operation.
 370         | g. FCOM:   Normal operation
 371         | h. MMUPEI: Record even parity. Normal operation.
 372         | i. FFF:    Flush only as much data as necessary.
 373         | j. TCS:    Timebase increments from CPU clock.
 374         +-----------------------------------------------------------------*/
 375         li      r0,0
 376         mtspr   SPRN_CCR1, r0
 377
 378         /*----------------------------------------------------------------+
 379         | Reset the timebase.
 380         | The previous write to CCR1 sets the timebase source.
 381         +-----------------------------------------------------------------*/
 382         mtspr   SPRN_TBWL, r0
 383         mtspr   SPRN_TBWU, r0
 384 #endif
 385
 386         /*----------------------------------------------------------------*/
 387         /* Setup interrupt vectors */
 388         /*----------------------------------------------------------------*/
 389         mtspr   SPRN_IVPR,r0            /* Vectors start at 0x0000_0000 */
 390         li      r1,0x0100
 391         mtspr   SPRN_IVOR0,r1   /* Critical input */
 392         li      r1,0x0200
 393         mtspr   SPRN_IVOR1,r1   /* Machine check */
 394         li      r1,0x0300
 395         mtspr   SPRN_IVOR2,r1   /* Data storage */
 396         li      r1,0x0400
 397         mtspr   SPRN_IVOR3,r1   /* Instruction storage */
 398         li      r1,0x0500
 399         mtspr   SPRN_IVOR4,r1   /* External interrupt */
 400         li      r1,0x0600
 401         mtspr   SPRN_IVOR5,r1   /* Alignment */
 402         li      r1,0x0700
 403         mtspr   SPRN_IVOR6,r1   /* Program check */
 404         li      r1,0x0800
 405         mtspr   SPRN_IVOR7,r1   /* Floating point unavailable */
 406         li      r1,0x0c00
 407         mtspr   SPRN_IVOR8,r1   /* System call */
 408         li      r1,0x0a00
 409         mtspr   SPRN_IVOR9,r1   /* Auxiliary Processor unavailable */
 410         li      r1,0x0900
 411         mtspr   SPRN_IVOR10,r1  /* Decrementer */
 412         li      r1,0x1300
 413         mtspr   SPRN_IVOR13,r1  /* Data TLB error */
 414         li      r1,0x1400
 415         mtspr   SPRN_IVOR14,r1  /* Instr TLB error */
 416         li      r1,0x2000
 417         mtspr   SPRN_IVOR15,r1  /* Debug */
 418
 419         /*----------------------------------------------------------------*/
 420         /* Configure cache regions  */
 421         /*----------------------------------------------------------------*/
 422         mtspr   SPRN_INV0,r0
 423         mtspr   SPRN_INV1,r0
 424         mtspr   SPRN_INV2,r0
 425         mtspr   SPRN_INV3,r0
 426         mtspr   SPRN_DNV0,r0
 427         mtspr   SPRN_DNV1,r0
 428         mtspr   SPRN_DNV2,r0
 429         mtspr   SPRN_DNV3,r0
 430         mtspr   SPRN_ITV0,r0
 431         mtspr   SPRN_ITV1,r0
 432         mtspr   SPRN_ITV2,r0
 433         mtspr   SPRN_ITV3,r0
 434         mtspr   SPRN_DTV0,r0
 435         mtspr   SPRN_DTV1,r0
 436         mtspr   SPRN_DTV2,r0
 437         mtspr   SPRN_DTV3,r0
 438
 439         /*----------------------------------------------------------------*/
 440         /* Cache victim limits */
 441         /*----------------------------------------------------------------*/
 442         /* floors 0, ceiling max to use the entire cache -- nothing locked
 443         */
 444         lis     r1,0x0001
 445         ori     r1,r1,0xf800
 446         mtspr   SPRN_IVLIM,r1
 447         mtspr   SPRN_DVLIM,r1
 448
 449         /*----------------------------------------------------------------+
 450         |Initialize MMUCR[STID] = 0.
 451         +-----------------------------------------------------------------*/
 452         mfspr   r0,SPRN_MMUCR
 453         addis   r1,0,0xFFFF
 454         ori     r1,r1,0xFF00
 455         and     r0,r0,r1
 456         mtspr   SPRN_MMUCR,r0
 457
 458         /*----------------------------------------------------------------*/
 459         /* Clear all TLB entries -- TID = 0, TS = 0 */
 460         /*----------------------------------------------------------------*/
 461         addis   r0,0,0x0000
 462 #ifdef CONFIG_SYS_RAMBOOT
 463         li      r4,0            /* Start with TLB #0 */
 464 #else
 465         li      r4,1            /* Start with TLB #1 */
 466 #endif
 467         li      r1,64           /* 64 TLB entries */
 468         sub     r1,r1,r4        /* calculate last TLB # */
 469         mtctr   r1
 470 rsttlb:
 471 #ifdef CONFIG_SYS_RAMBOOT
 472         tlbre   r3,r4,0         /* Read contents from TLB word #0 to get EPN */
 473         rlwinm. r3,r3,0,0xfffffc00      /* Mask EPN */
 474         beq     tlbnxt          /* Skip EPN=0 TLB, this is the SDRAM TLB */
 475 #endif
 476         tlbwe   r0,r4,0         /* Invalidate all entries (V=0)*/
 477         tlbwe   r0,r4,1
 478         tlbwe   r0,r4,2
 479 tlbnxt: addi    r4,r4,1         /* Next TLB */
 480         bdnz    rsttlb
 481
 482         /*----------------------------------------------------------------*/
 483         /* TLB entry setup -- step thru tlbtab */
 484         /*----------------------------------------------------------------*/
 485 #if defined(CONFIG_440SPE_REVA)
 486         /*----------------------------------------------------------------*/
 487         /* We have different TLB tables for revA and rev B of 440SPe */
 488         /*----------------------------------------------------------------*/
 489         mfspr   r1, PVR
 490         lis     r0,0x5342
 491         ori     r0,r0,0x1891
 492         cmpw    r7,r1,r0
 493         bne     r7,..revA
 494         bl      tlbtabB
 495         b       ..goon
 496 ..revA:
 497         bl      tlbtabA
 498 ..goon:
 499 #else
 500         bl      tlbtab          /* Get tlbtab pointer */
 501 #endif
 502         mr      r5,r0
 503         li      r1,0x003f       /* 64 TLB entries max */
 504         mtctr   r1
 505         li      r4,0            /* TLB # */
 506
 507         addi    r5,r5,-4
 508 1:
 509 #ifdef CONFIG_SYS_RAMBOOT
 510         tlbre   r3,r4,0         /* Read contents from TLB word #0 */
 511         rlwinm. r3,r3,0,0x00000200      /* Mask V (valid) bit */
 512         bne     tlbnx2          /* Skip V=1 TLB, this is the SDRAM TLB */
 513 #endif
 514         lwzu    r0,4(r5)
 515         cmpwi   r0,0
 516         beq     2f              /* 0 marks end */
 517         lwzu    r1,4(r5)
 518         lwzu    r2,4(r5)
 519         tlbwe   r0,r4,0         /* TLB Word 0 */
 520         tlbwe   r1,r4,1         /* TLB Word 1 */
 521         tlbwe   r2,r4,2         /* TLB Word 2 */
 522 tlbnx2: addi    r4,r4,1         /* Next TLB */
 523         bdnz    1b
 524
 525         /*----------------------------------------------------------------*/
 526         /* Continue from 'normal' start */
 527         /*----------------------------------------------------------------*/
 528 2:
 529         bl      3f
 530         b       _start
 531
 532 3:      li      r0,0
 533         mtspr   SPRN_SRR1,r0            /* Keep things disabled for now */
 534         mflr    r1
 535         mtspr   SPRN_SRR0,r1
 536         rfi
 537 #endif /* CONFIG_440 */
 538
 539 /*
 540  * r3 - 1st arg to board_init(): IMMP pointer
 541  * r4 - 2nd arg to board_init(): boot flag
 542  */
 543 #ifndef CONFIG_NAND_SPL
 544         .text
 545         .long   0x27051956              /* U-Boot Magic Number                  */
 546         .globl  version_string
 547 version_string:
 548         .ascii U_BOOT_VERSION
 549         .ascii " (", U_BOOT_DATE, " - ", U_BOOT_TIME, ")"
 550         .ascii CONFIG_IDENT_STRING, "\0"
 551
 552         . = EXC_OFF_SYS_RESET
 553         .globl  _start_of_vectors
 554 _start_of_vectors:
 555
 556 /* Critical input. */
 557         CRIT_EXCEPTION(0x100, CritcalInput, UnknownException)
 558
 559 #ifdef CONFIG_440
 560 /* Machine check */
 561         MCK_EXCEPTION(0x200, MachineCheck, MachineCheckException)
 562 #else
 563         CRIT_EXCEPTION(0x200, MachineCheck, MachineCheckException)
 564 #endif /* CONFIG_440 */
 565
 566 /* Data Storage exception. */
 567         STD_EXCEPTION(0x300, DataStorage, UnknownException)
 568
 569 /* Instruction Storage exception. */
 570         STD_EXCEPTION(0x400, InstStorage, UnknownException)
 571
 572 /* External Interrupt exception. */
 573         STD_EXCEPTION(0x500, ExtInterrupt, external_interrupt)
 574
 575 /* Alignment exception. */
 576         . = 0x600
 577 Alignment:
 578         EXCEPTION_PROLOG(SRR0, SRR1)
 579         mfspr   r4,DAR
 580         stw     r4,_DAR(r21)
 581         mfspr   r5,DSISR
 582         stw     r5,_DSISR(r21)
 583         addi    r3,r1,STACK_FRAME_OVERHEAD
 584         EXC_XFER_TEMPLATE(Alignment, AlignmentException, MSR_KERNEL, COPY_EE)
 585
 586 /* Program check exception */
 587         . = 0x700
 588 ProgramCheck:
 589         EXCEPTION_PROLOG(SRR0, SRR1)
 590         addi    r3,r1,STACK_FRAME_OVERHEAD
 591         EXC_XFER_TEMPLATE(ProgramCheck, ProgramCheckException,
 592                 MSR_KERNEL, COPY_EE)
 593
 594 #ifdef CONFIG_440
 595         STD_EXCEPTION(0x800, FPUnavailable, UnknownException)
 596         STD_EXCEPTION(0x900, Decrementer, DecrementerPITException)
 597         STD_EXCEPTION(0xa00, APU, UnknownException)
 598 #endif
 599         STD_EXCEPTION(0xc00, SystemCall, UnknownException)
 600
 601 #ifdef CONFIG_440
 602         STD_EXCEPTION(0x1300, DataTLBError, UnknownException)
 603         STD_EXCEPTION(0x1400, InstructionTLBError, UnknownException)
 604 #else
 605         STD_EXCEPTION(0x1000, PIT, DecrementerPITException)
 606         STD_EXCEPTION(0x1100, InstructionTLBMiss, UnknownException)
 607         STD_EXCEPTION(0x1200, DataTLBMiss, UnknownException)
 608 #endif
 609         CRIT_EXCEPTION(0x2000, DebugBreakpoint, DebugException )
 610
 611         .globl  _end_of_vectors
 612 _end_of_vectors:
 613         . = _START_OFFSET
 614 #endif
 615         .globl  _start
 616 _start:
 617
 618 /*****************************************************************************/
 619 #if defined(CONFIG_440)
 620
 621         /*----------------------------------------------------------------*/
 622         /* Clear and set up some registers. */
 623         /*----------------------------------------------------------------*/
 624         li      r0,0x0000
 625         lis     r1,0xffff
 626         mtspr   SPRN_DEC,r0                     /* prevent dec exceptions */
 627         mtspr   SPRN_TBWL,r0                    /* prevent fit & wdt exceptions */
 628         mtspr   SPRN_TBWU,r0
 629         mtspr   SPRN_TSR,r1                     /* clear all timer exception status */
 630         mtspr   SPRN_TCR,r0                     /* disable all */
 631         mtspr   SPRN_ESR,r0                     /* clear exception syndrome register */
 632         mtxer   r0                      /* clear integer exception register */
 633
 634         /*----------------------------------------------------------------*/
 635         /* Debug setup -- some (not very good) ice's need an event*/
 636         /* to establish control :-( Define CONFIG_SYS_INIT_DBCR to the dbsr */
 637         /* value you need in this case 0x8cff 0000 should do the trick */
 638         /*----------------------------------------------------------------*/
 639 #if defined(CONFIG_SYS_INIT_DBCR)
 640         lis     r1,0xffff
 641         ori     r1,r1,0xffff
 642         mtspr   SPRN_DBSR,r1                    /* Clear all status bits */
 643         lis     r0,CONFIG_SYS_INIT_DBCR@h
 644         ori     r0,r0,CONFIG_SYS_INIT_DBCR@l
 645         mtspr   SPRN_DBCR0,r0
 646         isync
 647 #endif
 648
 649         /*----------------------------------------------------------------*/
 650         /* Setup the internal SRAM */
 651         /*----------------------------------------------------------------*/
 652         li      r0,0
 653
 654 #ifdef CONFIG_SYS_INIT_RAM_DCACHE
 655         /* Clear Dcache to use as RAM */
 656         addis   r3,r0,CONFIG_SYS_INIT_RAM_ADDR@h
 657         ori     r3,r3,CONFIG_SYS_INIT_RAM_ADDR@l
 658         addis   r4,r0,CONFIG_SYS_INIT_RAM_END@h
 659         ori     r4,r4,CONFIG_SYS_INIT_RAM_END@l
 660         rlwinm. r5,r4,0,27,31
 661         rlwinm  r5,r4,27,5,31
 662         beq     ..d_ran
 663         addi    r5,r5,0x0001
 664 ..d_ran:
 665         mtctr   r5
 666 ..d_ag:
 667         dcbz    r0,r3
 668         addi    r3,r3,32
 669         bdnz    ..d_ag
 670
 671         /*
 672          * Lock the init-ram/stack in d-cache, so that other regions
 673          * may use d-cache as well
 674          * Note, that this current implementation locks exactly 4k
 675          * of d-cache, so please make sure that you don't define a
 676          * bigger init-ram area. Take a look at the lwmon5 440EPx
 677          * implementation as a reference.
 678          */
 679         msync
 680         isync
 681         /* 8. set TFLOOR/NFLOOR to 8 (-> 8*16*32 bytes locked -> 4k) */
 682         lis     r1,0x0201
 683         ori     r1,r1,0xf808
 684         mtspr   SPRN_DVLIM,r1
 685         lis     r1,0x0808
 686         ori     r1,r1,0x0808
 687         mtspr   SPRN_DNV0,r1
 688         mtspr   SPRN_DNV1,r1
 689         mtspr   SPRN_DNV2,r1
 690         mtspr   SPRN_DNV3,r1
 691         mtspr   SPRN_DTV0,r1
 692         mtspr   SPRN_DTV1,r1
 693         mtspr   SPRN_DTV2,r1
 694         mtspr   SPRN_DTV3,r1
 695         msync
 696         isync
 697 #endif /* CONFIG_SYS_INIT_RAM_DCACHE */
 698
 699         /* 440EP & 440GR are only 440er PPC's without internal SRAM */
 700 #if !defined(CONFIG_440EP) && !defined(CONFIG_440GR)
 701         /* not all PPC's have internal SRAM usable as L2-cache */
 702 #if defined(CONFIG_440GX) || \
 703     defined(CONFIG_440SP) || defined(CONFIG_440SPE) || \
 704     defined(CONFIG_460SX)
 705         mtdcr   L2_CACHE_CFG,r0         /* Ensure L2 Cache is off */
 706 #elif defined(CONFIG_460EX) || defined(CONFIG_460GT) || \
 707       defined(CONFIG_APM821XX)
 708         lis     r1, 0x0000
 709         ori     r1,r1,0x0008            /* Set L2_CACHE_CFG[RDBW]=1 */
 710         mtdcr   L2_CACHE_CFG,r1
 711 #endif
 712
 713         lis     r2,0x7fff
 714         ori     r2,r2,0xffff
 715         mfdcr   r1,ISRAM0_DPC
 716         and     r1,r1,r2                /* Disable parity check */
 717         mtdcr   ISRAM0_DPC,r1
 718         mfdcr   r1,ISRAM0_PMEG
 719         and     r1,r1,r2                /* Disable pwr mgmt */
 720         mtdcr   ISRAM0_PMEG,r1
 721
 722         lis     r1,0x8000               /* BAS = 8000_0000 */
 723 #if defined(CONFIG_440GX) || defined(CONFIG_440SP)
 724         ori     r1,r1,0x0980            /* first 64k */
 725         mtdcr   ISRAM0_SB0CR,r1
 726         lis     r1,0x8001
 727         ori     r1,r1,0x0980            /* second 64k */
 728         mtdcr   ISRAM0_SB1CR,r1
 729         lis     r1, 0x8002
 730         ori     r1,r1, 0x0980           /* third 64k */
 731         mtdcr   ISRAM0_SB2CR,r1
 732         lis     r1, 0x8003
 733         ori     r1,r1, 0x0980           /* fourth 64k */
 734         mtdcr   ISRAM0_SB3CR,r1
 735 #elif defined(CONFIG_440SPE) || defined(CONFIG_460EX) || \
 736       defined(CONFIG_460GT) || defined(CONFIG_APM821XX)
 737         lis     r1,0x0000               /* BAS = X_0000_0000 */
 738         ori     r1,r1,0x0984            /* first 64k */
 739         mtdcr   ISRAM0_SB0CR,r1
 740         lis     r1,0x0001
 741         ori     r1,r1,0x0984            /* second 64k */
 742         mtdcr   ISRAM0_SB1CR,r1
 743         lis     r1, 0x0002
 744         ori     r1,r1, 0x0984           /* third 64k */
 745         mtdcr   ISRAM0_SB2CR,r1
 746         lis     r1, 0x0003
 747         ori     r1,r1, 0x0984           /* fourth 64k */
 748         mtdcr   ISRAM0_SB3CR,r1
 749 #if defined(CONFIG_460EX) || defined(CONFIG_460GT) || \
 750     defined(CONFIG_APM821XX)
 751         lis     r2,0x7fff
 752         ori     r2,r2,0xffff
 753         mfdcr   r1,ISRAM1_DPC
 754         and     r1,r1,r2                /* Disable parity check */
 755         mtdcr   ISRAM1_DPC,r1
 756         mfdcr   r1,ISRAM1_PMEG
 757         and     r1,r1,r2                /* Disable pwr mgmt */
 758         mtdcr   ISRAM1_PMEG,r1
 759
 760         lis     r1,0x0004               /* BAS = 4_0004_0000 */
 761         ori     r1,r1,ISRAM1_SIZE       /* ocm size */
 762         mtdcr   ISRAM1_SB0CR,r1
 763 #endif
 764 #elif defined(CONFIG_460SX)
 765         lis     r1,0x0000               /* BAS = 0000_0000 */
 766         ori     r1,r1,0x0B84            /* first 128k */
 767         mtdcr   ISRAM0_SB0CR,r1
 768         lis     r1,0x0001
 769         ori     r1,r1,0x0B84            /* second 128k */
 770         mtdcr   ISRAM0_SB1CR,r1
 771         lis     r1, 0x0002
 772         ori     r1,r1, 0x0B84           /* third 128k */
 773         mtdcr   ISRAM0_SB2CR,r1
 774         lis     r1, 0x0003
 775         ori     r1,r1, 0x0B84           /* fourth 128k */
 776         mtdcr   ISRAM0_SB3CR,r1
 777 #elif defined(CONFIG_440GP)
 778         ori     r1,r1,0x0380            /* 8k rw */
 779         mtdcr   ISRAM0_SB0CR,r1
 780         mtdcr   ISRAM0_SB1CR,r0         /* Disable bank 1 */
 781 #endif
 782 #endif /* #if !defined(CONFIG_440EP) && !defined(CONFIG_440GR) */
 783
 784         /*----------------------------------------------------------------*/
 785         /* Setup the stack in internal SRAM */
 786         /*----------------------------------------------------------------*/
 787         lis     r1,CONFIG_SYS_INIT_RAM_ADDR@h
 788         ori     r1,r1,CONFIG_SYS_INIT_SP_OFFSET@l
 789         li      r0,0
 790         stwu    r0,-4(r1)
 791         stwu    r0,-4(r1)               /* Terminate call chain */
 792
 793         stwu    r1,-8(r1)               /* Save back chain and move SP */
 794         lis     r0,RESET_VECTOR@h       /* Address of reset vector */
 795         ori     r0,r0, RESET_VECTOR@l
 796         stwu    r1,-8(r1)               /* Save back chain and move SP */
 797         stw     r0,+12(r1)              /* Save return addr (underflow vect) */
 798
 799 #ifdef CONFIG_NAND_SPL
 800         bl      nand_boot_common        /* will not return */
 801 #else
 802         GET_GOT
 803
 804         bl      cpu_init_f      /* run low-level CPU init code     (from Flash) */
 805         bl      board_init_f
 806 #endif
 807
 808 #endif /* CONFIG_440 */
 809
 810 /*****************************************************************************/
 811 #ifdef CONFIG_IOP480
 812         /*----------------------------------------------------------------------- */
 813         /* Set up some machine state registers. */
 814         /*----------------------------------------------------------------------- */
 815         addi    r0,r0,0x0000            /* initialize r0 to zero */
 816         mtspr   SPRN_ESR,r0             /* clear Exception Syndrome Reg */
 817         mttcr   r0                      /* timer control register */
 818         mtexier r0                      /* disable all interrupts */
 819         addis   r4,r0,0xFFFF            /* set r4 to 0xFFFFFFFF (status in the */
 820         ori     r4,r4,0xFFFF            /* dbsr is cleared by setting bits to 1) */
 821         mtdbsr  r4                      /* clear/reset the dbsr */
 822         mtexisr r4                      /* clear all pending interrupts */
 823         addis   r4,r0,0x8000
 824         mtexier r4                      /* enable critical exceptions */
 825         addis   r4,r0,0x0000            /* assume 403GCX - enable core clk */
 826         ori     r4,r4,0x4020            /* dbling (no harm done on GA and GC */
 827         mtiocr  r4                      /* since bit not used) & DRC to latch */
 828                                         /* data bus on rising edge of CAS */
 829         /*----------------------------------------------------------------------- */
 830         /* Clear XER. */
 831         /*----------------------------------------------------------------------- */
 832         mtxer   r0
 833         /*----------------------------------------------------------------------- */
 834         /* Invalidate i-cache and d-cache TAG arrays. */
 835         /*----------------------------------------------------------------------- */
 836         addi    r3,0,1024               /* 1/4 of I-cache size, half of D-cache */
 837         addi    r4,0,1024               /* 1/4 of I-cache */
 838 ..cloop:
 839         iccci   0,r3
 840         iccci   r4,r3
 841         dccci   0,r3
 842         addic.  r3,r3,-16               /* move back one cache line */
 843         bne     ..cloop                 /* loop back to do rest until r3 = 0 */
 844
 845         /* */
 846         /* initialize IOP480 so it can read 1 MB code area for SRAM spaces */
 847         /* this requires enabling MA[17..0], by default only MA[12..0] are enabled. */
 848         /* */
 849
 850         /* first copy IOP480 register base address into r3 */
 851         addis   r3,0,0x5000             /* IOP480 register base address hi */
 852 /*      ori     r3,r3,0x0000            /  IOP480 register base address lo */
 853
 854 #ifdef CONFIG_ADCIOP
 855         /* use r4 as the working variable */
 856         /* turn on CS3 (LOCCTL.7) */
 857         lwz     r4,0x84(r3)             /* LOCTL is at offset 0x84 */
 858         andi.   r4,r4,0xff7f            /* make bit 7 = 0 -- CS3 mode */
 859         stw     r4,0x84(r3)             /* LOCTL is at offset 0x84 */
 860 #endif
 861
 862 #ifdef CONFIG_DASA_SIM
 863         /* use r4 as the working variable */
 864         /* turn on MA17 (LOCCTL.7) */
 865         lwz     r4,0x84(r3)             /* LOCTL is at offset 0x84 */
 866         ori     r4,r4,0x80              /* make bit 7 = 1 -- MA17 mode */
 867         stw     r4,0x84(r3)             /* LOCTL is at offset 0x84 */
 868 #endif
 869
 870         /* turn on MA16..13 (LCS0BRD.12 = 0) */
 871         lwz     r4,0x100(r3)            /* LCS0BRD is at offset 0x100 */
 872         andi.   r4,r4,0xefff            /* make bit 12 = 0 */
 873         stw     r4,0x100(r3)            /* LCS0BRD is at offset 0x100 */
 874
 875         /* make sure above stores all comlete before going on */
 876         sync
 877
 878         /* last thing, set local init status done bit (DEVINIT.31) */
 879         lwz     r4,0x80(r3)             /* DEVINIT is at offset 0x80 */
 880         oris    r4,r4,0x8000            /* make bit 31 = 1 */
 881         stw     r4,0x80(r3)             /* DEVINIT is at offset 0x80 */
 882
 883         /* clear all pending interrupts and disable all interrupts */
 884         li      r4,-1                   /* set p1 to 0xffffffff */
 885         stw     r4,0x1b0(r3)            /* clear all pending interrupts */
 886         stw     r4,0x1b8(r3)            /* clear all pending interrupts */
 887         li      r4,0                    /* set r4 to 0 */
 888         stw     r4,0x1b4(r3)            /* disable all interrupts */
 889         stw     r4,0x1bc(r3)            /* disable all interrupts */
 890
 891         /* make sure above stores all comlete before going on */
 892         sync
 893
 894         /* Set-up icache cacheability. */
 895         lis     r1, CONFIG_SYS_ICACHE_SACR_VALUE@h
 896         ori     r1, r1, CONFIG_SYS_ICACHE_SACR_VALUE@l
 897         mticcr  r1
 898         isync
 899
 900         /* Set-up dcache cacheability. */
 901         lis     r1, CONFIG_SYS_DCACHE_SACR_VALUE@h
 902         ori     r1, r1, CONFIG_SYS_DCACHE_SACR_VALUE@l
 903         mtdccr  r1
 904
 905         addis   r1,r0,CONFIG_SYS_INIT_RAM_ADDR@h
 906         ori     r1,r1,CONFIG_SYS_INIT_SP_OFFSET /* set up the stack to SDRAM */
 907         li      r0, 0                   /* Make room for stack frame header and */
 908         stwu    r0, -4(r1)              /* clear final stack frame so that      */
 909         stwu    r0, -4(r1)              /* stack backtraces terminate cleanly   */
 910
 911         GET_GOT                 /* initialize GOT access                        */
 912
 913         bl      board_init_f    /* run first part of init code (from Flash)     */
 914
 915 #endif  /* CONFIG_IOP480 */
 916
 917 /*****************************************************************************/
 918 #if defined(CONFIG_405GP) || defined(CONFIG_405CR) || \
 919     defined(CONFIG_405EP) || defined(CONFIG_405EZ) || \
 920     defined(CONFIG_405EX) || defined(CONFIG_405)
 921         /*----------------------------------------------------------------------- */
 922         /* Clear and set up some registers. */
 923         /*----------------------------------------------------------------------- */
 924         addi    r4,r0,0x0000
 925 #if !defined(CONFIG_405EX)
 926         mtspr   SPRN_SGR,r4
 927 #else
 928         /*
 929          * On 405EX, completely clearing the SGR leads to PPC hangup
 930          * upon PCIe configuration access. The PCIe memory regions
 931          * need to be guarded!
 932          */
 933         lis     r3,0x0000
 934         ori     r3,r3,0x7FFC
 935         mtspr   SPRN_SGR,r3
 936 #endif
 937         mtspr   SPRN_DCWR,r4
 938         mtesr   r4                      /* clear Exception Syndrome Reg */
 939         mttcr   r4                      /* clear Timer Control Reg */
 940         mtxer   r4                      /* clear Fixed-Point Exception Reg */
 941         mtevpr  r4                      /* clear Exception Vector Prefix Reg */
 942         addi    r4,r0,(0xFFFF-0x10000)          /* set r4 to 0xFFFFFFFF (status in the */
 943                                         /* dbsr is cleared by setting bits to 1) */
 944         mtdbsr  r4                      /* clear/reset the dbsr */
 945
 946         /* Invalidate the i- and d-caches. */
 947         bl      invalidate_icache
 948         bl      invalidate_dcache
 949
 950         /* Set-up icache cacheability. */
 951         lis     r4, CONFIG_SYS_ICACHE_SACR_VALUE@h
 952         ori     r4, r4, CONFIG_SYS_ICACHE_SACR_VALUE@l
 953         mticcr  r4
 954         isync
 955
 956         /* Set-up dcache cacheability. */
 957         lis     r4, CONFIG_SYS_DCACHE_SACR_VALUE@h
 958         ori     r4, r4, CONFIG_SYS_DCACHE_SACR_VALUE@l
 959         mtdccr  r4
 960
 961 #if !(defined(CONFIG_SYS_EBC_PB0AP) && defined(CONFIG_SYS_EBC_PB0CR))\
 962                                 && !defined (CONFIG_XILINX_405)
 963         /*----------------------------------------------------------------------- */
 964         /* Tune the speed and size for flash CS0  */
 965         /*----------------------------------------------------------------------- */
 966         bl      ext_bus_cntlr_init
 967 #endif
 968
 969 #if !(defined(CONFIG_SYS_INIT_DCACHE_CS) || defined(CONFIG_SYS_TEMP_STACK_OCM))
 970         /*
 971          * For boards that don't have OCM and can't use the data cache
 972          * for their primordial stack, setup stack here directly after the
 973          * SDRAM is initialized in ext_bus_cntlr_init.
 974          */
 975         lis     r1, CONFIG_SYS_INIT_RAM_ADDR@h
 976         ori     r1,r1,CONFIG_SYS_INIT_SP_OFFSET /* set up the stack in SDRAM */
 977
 978         li      r0, 0                   /* Make room for stack frame header and */
 979         stwu    r0, -4(r1)              /* clear final stack frame so that      */
 980         stwu    r0, -4(r1)              /* stack backtraces terminate cleanly   */
 981         /*
 982          * Set up a dummy frame to store reset vector as return address.
 983          * this causes stack underflow to reset board.
 984          */
 985         stwu    r1, -8(r1)              /* Save back chain and move SP */
 986         lis     r0, RESET_VECTOR@h      /* Address of reset vector */
 987         ori     r0, r0, RESET_VECTOR@l
 988         stwu    r1, -8(r1)              /* Save back chain and move SP */
 989         stw     r0, +12(r1)             /* Save return addr (underflow vect) */
 990 #endif /* !(CONFIG_SYS_INIT_DCACHE_CS   || !CONFIG_SYS_TEM_STACK_OCM) */
 991
 992 #if defined(CONFIG_405EP)
 993         /*----------------------------------------------------------------------- */
 994         /* DMA Status, clear to come up clean */
 995         /*----------------------------------------------------------------------- */
 996         addis   r3,r0, 0xFFFF           /* Clear all existing DMA status */
 997         ori     r3,r3, 0xFFFF
 998         mtdcr   DMASR, r3
 999
1000         bl      ppc405ep_init           /* do ppc405ep specific init */
1001 #endif /* CONFIG_405EP */
1002
1003 #if defined(CONFIG_SYS_OCM_DATA_ADDR) && defined(CONFIG_SYS_OCM_DATA_SIZE)
1004 #if defined(CONFIG_405EZ)
1005         /********************************************************************
1006          * Setup OCM - On Chip Memory - PPC405EZ uses OCM Controller V2
1007          *******************************************************************/
1008         /*
1009          * We can map the OCM on the PLB3, so map it at
1010          * CONFIG_SYS_OCM_DATA_ADDR + 0x8000
1011          */
1012         lis     r3,CONFIG_SYS_OCM_DATA_ADDR@h   /* OCM location */
1013         ori     r3,r3,CONFIG_SYS_OCM_DATA_ADDR@l
1014         ori     r3,r3,0x0270            /* 16K for Bank 1, R/W/Enable */
1015         mtdcr   OCM0_PLBCR1,r3          /* Set PLB Access */
1016         ori     r3,r3,0x4000            /* Add 0x4000 for bank 2 */
1017         mtdcr   OCM0_PLBCR2,r3          /* Set PLB Access */
1018         isync
1019
1020         lis     r3,CONFIG_SYS_OCM_DATA_ADDR@h   /* OCM location */
1021         ori     r3,r3,CONFIG_SYS_OCM_DATA_ADDR@l
1022         ori     r3,r3,0x0270            /* 16K for Bank 1, R/W/Enable */
1023         mtdcr   OCM0_DSRC1, r3          /* Set Data Side */
1024         mtdcr   OCM0_ISRC1, r3          /* Set Instruction Side */
1025         ori     r3,r3,0x4000            /* Add 0x4000 for bank 2 */
1026         mtdcr   OCM0_DSRC2, r3          /* Set Data Side */
1027         mtdcr   OCM0_ISRC2, r3          /* Set Instruction Side */
1028         addis   r3,0,0x0800             /* OCM Data Parity Disable - 1 Wait State */
1029         mtdcr   OCM0_DISDPC,r3
1030
1031         isync
1032 #else /* CONFIG_405EZ */
1033         /********************************************************************
1034          * Setup OCM - On Chip Memory
1035          *******************************************************************/
1036         /* Setup OCM */
1037         lis     r0, 0x7FFF
1038         ori     r0, r0, 0xFFFF
1039         mfdcr   r3, OCM0_ISCNTL         /* get instr-side IRAM config */
1040         mfdcr   r4, OCM0_DSCNTL         /* get data-side IRAM config */
1041         and     r3, r3, r0              /* disable data-side IRAM */
1042         and     r4, r4, r0              /* disable data-side IRAM */
1043         mtdcr   OCM0_ISCNTL, r3         /* set instr-side IRAM config */
1044         mtdcr   OCM0_DSCNTL, r4         /* set data-side IRAM config */
1045         isync
1046
1047         lis     r3,CONFIG_SYS_OCM_DATA_ADDR@h   /* OCM location */
1048         ori     r3,r3,CONFIG_SYS_OCM_DATA_ADDR@l
1049         mtdcr   OCM0_DSARC, r3
1050         addis   r4, 0, 0xC000           /* OCM data area enabled */
1051         mtdcr   OCM0_DSCNTL, r4
1052         isync
1053 #endif /* CONFIG_405EZ */
1054 #endif
1055
1056         /*----------------------------------------------------------------------- */
1057         /* Setup temporary stack in DCACHE or OCM if needed for SDRAM SPD. */
1058         /*----------------------------------------------------------------------- */
1059 #ifdef CONFIG_SYS_INIT_DCACHE_CS
1060         li      r4, PBxAP
1061         mtdcr   EBC0_CFGADDR, r4
1062         lis     r4, CONFIG_SYS_INIT_DCACHE_PBxAR@h
1063         ori     r4, r4, CONFIG_SYS_INIT_DCACHE_PBxAR@l
1064         mtdcr   EBC0_CFGDATA, r4
1065
1066         addi    r4, 0, PBxCR
1067         mtdcr   EBC0_CFGADDR, r4
1068         lis     r4, CONFIG_SYS_INIT_DCACHE_PBxCR@h
1069         ori     r4, r4, CONFIG_SYS_INIT_DCACHE_PBxCR@l
1070         mtdcr   EBC0_CFGDATA, r4
1071
1072         /*
1073          * Enable the data cache for the 128MB storage access control region
1074          * at CONFIG_SYS_INIT_RAM_ADDR.
1075          */
1076         mfdccr  r4
1077         oris    r4, r4, PPC_128MB_SACR_VALUE(CONFIG_SYS_INIT_RAM_ADDR)@h
1078         ori     r4, r4, PPC_128MB_SACR_VALUE(CONFIG_SYS_INIT_RAM_ADDR)@l
1079         mtdccr  r4
1080
1081         /*
1082          * Preallocate data cache lines to be used to avoid a subsequent
1083          * cache miss and an ensuing machine check exception when exceptions
1084          * are enabled.
1085          */
1086         li      r0, 0
1087
1088         lis     r3, CONFIG_SYS_INIT_RAM_ADDR@h
1089         ori     r3, r3, CONFIG_SYS_INIT_RAM_ADDR@l
1090
1091         lis     r4, CONFIG_SYS_INIT_RAM_END@h
1092         ori     r4, r4, CONFIG_SYS_INIT_RAM_END@l
1093
1094         /*
1095          * Convert the size, in bytes, to the number of cache lines/blocks
1096          * to preallocate.
1097          */
1098         clrlwi. r5, r4, (32 - L1_CACHE_SHIFT)
1099         srwi    r5, r4, L1_CACHE_SHIFT
1100         beq     ..load_counter
1101         addi    r5, r5, 0x0001
1102 ..load_counter:
1103         mtctr   r5
1104
1105         /* Preallocate the computed number of cache blocks. */
1106 ..alloc_dcache_block:
1107         dcba    r0, r3
1108         addi    r3, r3, L1_CACHE_BYTES
1109         bdnz    ..alloc_dcache_block
1110         sync
1111
1112         /*
1113          * Load the initial stack pointer and data area and convert the size,
1114          * in bytes, to the number of words to initialize to a known value.
1115          */
1116         lis     r1, CONFIG_SYS_INIT_RAM_ADDR@h
1117         ori     r1, r1, CONFIG_SYS_INIT_SP_OFFSET@l
1118
1119         lis     r4, (CONFIG_SYS_INIT_RAM_END >> 2)@h
1120         ori     r4, r4, (CONFIG_SYS_INIT_RAM_END >> 2)@l
1121         mtctr   r4
1122
1123         lis     r2, CONFIG_SYS_INIT_RAM_ADDR@h
1124         ori     r2, r2, CONFIG_SYS_INIT_RAM_END@l
1125
1126         lis     r4, CONFIG_SYS_INIT_RAM_PATTERN@h
1127         ori     r4, r4, CONFIG_SYS_INIT_RAM_PATTERN@l
1128
1129 ..stackloop:
1130         stwu    r4, -4(r2)
1131         bdnz    ..stackloop
1132
1133         /*
1134          * Make room for stack frame header and clear final stack frame so
1135          * that stack backtraces terminate cleanly.
1136          */
1137         stwu    r0, -4(r1)
1138         stwu    r0, -4(r1)
1139
1140         /*
1141          * Set up a dummy frame to store reset vector as return address.
1142          * this causes stack underflow to reset board.
1143          */
1144         stwu    r1, -8(r1)              /* Save back chain and move SP */
1145         addis   r0, 0, RESET_VECTOR@h   /* Address of reset vector */
1146         ori     r0, r0, RESET_VECTOR@l
1147         stwu    r1, -8(r1)              /* Save back chain and move SP */
1148         stw     r0, +12(r1)             /* Save return addr (underflow vect) */
1149
1150 #elif defined(CONFIG_SYS_TEMP_STACK_OCM) && \
1151         (defined(CONFIG_SYS_OCM_DATA_ADDR) && defined(CONFIG_SYS_OCM_DATA_SIZE))
1152         /*
1153          * Stack in OCM.
1154          */
1155
1156         /* Set up Stack at top of OCM */
1157         lis     r1, (CONFIG_SYS_INIT_RAM_ADDR + CONFIG_SYS_INIT_SP_OFFSET)@h
1158         ori     r1, r1, (CONFIG_SYS_INIT_RAM_ADDR + CONFIG_SYS_INIT_SP_OFFSET)@l
1159
1160         /* Set up a zeroized stack frame so that backtrace works right */
1161         li      r0, 0
1162         stwu    r0, -4(r1)
1163         stwu    r0, -4(r1)
1164
1165         /*
1166          * Set up a dummy frame to store reset vector as return address.
1167          * this causes stack underflow to reset board.
1168          */
1169         stwu    r1, -8(r1)              /* Save back chain and move SP */
1170         lis     r0, RESET_VECTOR@h      /* Address of reset vector */
1171         ori     r0, r0, RESET_VECTOR@l
1172         stwu    r1, -8(r1)              /* Save back chain and move SP */
1173         stw     r0, +12(r1)             /* Save return addr (underflow vect) */
1174 #endif /* CONFIG_SYS_INIT_DCACHE_CS */
1175
1176 #ifdef CONFIG_NAND_SPL
1177         bl      nand_boot_common        /* will not return */
1178 #else
1179         GET_GOT                 /* initialize GOT access                        */
1180
1181         bl      cpu_init_f      /* run low-level CPU init code     (from Flash) */
1182
1183         /* NEVER RETURNS! */
1184         bl      board_init_f    /* run first part of init code (from Flash)     */
1185 #endif /* CONFIG_NAND_SPL */
1186
1187 #endif  /* CONFIG_405GP || CONFIG_405CR || CONFIG_405 || CONFIG_405EP */
1188         /*----------------------------------------------------------------------- */
1189
1190
1191 #ifndef CONFIG_NAND_SPL
1192 /*
1193  * This code finishes saving the registers to the exception frame
1194  * and jumps to the appropriate handler for the exception.
1195  * Register r21 is pointer into trap frame, r1 has new stack pointer.
1196  */
1197         .globl  transfer_to_handler
1198 transfer_to_handler:
1199         stw     r22,_NIP(r21)
1200         lis     r22,MSR_POW@h
1201         andc    r23,r23,r22
1202         stw     r23,_MSR(r21)
1203         SAVE_GPR(7, r21)
1204         SAVE_4GPRS(8, r21)
1205         SAVE_8GPRS(12, r21)
1206         SAVE_8GPRS(24, r21)
1207         mflr    r23
1208         andi.   r24,r23,0x3f00          /* get vector offset */
1209         stw     r24,TRAP(r21)
1210         li      r22,0
1211         stw     r22,RESULT(r21)
1212         mtspr   SPRG2,r22               /* r1 is now kernel sp */
1213         lwz     r24,0(r23)              /* virtual address of handler */
1214         lwz     r23,4(r23)              /* where to go when done */
1215         mtspr   SRR0,r24
1216         mtspr   SRR1,r20
1217         mtlr    r23
1218         SYNC
1219         rfi                             /* jump to handler, enable MMU */
1220
1221 int_return:
1222         mfmsr   r28             /* Disable interrupts */
1223         li      r4,0
1224         ori     r4,r4,MSR_EE
1225         andc    r28,r28,r4
1226         SYNC                    /* Some chip revs need this... */
1227         mtmsr   r28
1228         SYNC
1229         lwz     r2,_CTR(r1)
1230         lwz     r0,_LINK(r1)
1231         mtctr   r2
1232         mtlr    r0
1233         lwz     r2,_XER(r1)
1234         lwz     r0,_CCR(r1)
1235         mtspr   XER,r2
1236         mtcrf   0xFF,r0
1237         REST_10GPRS(3, r1)
1238         REST_10GPRS(13, r1)
1239         REST_8GPRS(23, r1)
1240         REST_GPR(31, r1)
1241         lwz     r2,_NIP(r1)     /* Restore environment */
1242         lwz     r0,_MSR(r1)
1243         mtspr   SRR0,r2
1244         mtspr   SRR1,r0
1245         lwz     r0,GPR0(r1)
1246         lwz     r2,GPR2(r1)
1247         lwz     r1,GPR1(r1)
1248         SYNC
1249         rfi
1250
1251 crit_return:
1252         mfmsr   r28             /* Disable interrupts */
1253         li      r4,0
1254         ori     r4,r4,MSR_EE
1255         andc    r28,r28,r4
1256         SYNC                    /* Some chip revs need this... */
1257         mtmsr   r28
1258         SYNC
1259         lwz     r2,_CTR(r1)
1260         lwz     r0,_LINK(r1)
1261         mtctr   r2
1262         mtlr    r0
1263         lwz     r2,_XER(r1)
1264         lwz     r0,_CCR(r1)
1265         mtspr   XER,r2
1266         mtcrf   0xFF,r0
1267         REST_10GPRS(3, r1)
1268         REST_10GPRS(13, r1)
1269         REST_8GPRS(23, r1)
1270         REST_GPR(31, r1)
1271         lwz     r2,_NIP(r1)     /* Restore environment */
1272         lwz     r0,_MSR(r1)
1273         mtspr   SPRN_CSRR0,r2
1274         mtspr   SPRN_CSRR1,r0
1275         lwz     r0,GPR0(r1)
1276         lwz     r2,GPR2(r1)
1277         lwz     r1,GPR1(r1)
1278         SYNC
1279         rfci
1280
1281 #ifdef CONFIG_440
1282 mck_return:
1283         mfmsr   r28             /* Disable interrupts */
1284         li      r4,0
1285         ori     r4,r4,MSR_EE
1286         andc    r28,r28,r4
1287         SYNC                    /* Some chip revs need this... */
1288         mtmsr   r28
1289         SYNC
1290         lwz     r2,_CTR(r1)
1291         lwz     r0,_LINK(r1)
1292         mtctr   r2
1293         mtlr    r0
1294         lwz     r2,_XER(r1)
1295         lwz     r0,_CCR(r1)
1296         mtspr   XER,r2
1297         mtcrf   0xFF,r0
1298         REST_10GPRS(3, r1)
1299         REST_10GPRS(13, r1)
1300         REST_8GPRS(23, r1)
1301         REST_GPR(31, r1)
1302         lwz     r2,_NIP(r1)     /* Restore environment */
1303         lwz     r0,_MSR(r1)
1304         mtspr   SPRN_MCSRR0,r2
1305         mtspr   SPRN_MCSRR1,r0
1306         lwz     r0,GPR0(r1)
1307         lwz     r2,GPR2(r1)
1308         lwz     r1,GPR1(r1)
1309         SYNC
1310         rfmci
1311 #endif /* CONFIG_440 */
1312
1313
1314         .globl get_pvr
1315 get_pvr:
1316         mfspr   r3, PVR
1317         blr
1318
1319 /*------------------------------------------------------------------------------- */
1320 /* Function:     out16 */
1321 /* Description:  Output 16 bits */
1322 /*------------------------------------------------------------------------------- */
1323         .globl  out16
1324 out16:
1325         sth     r4,0x0000(r3)
1326         blr
1327
1328 /*------------------------------------------------------------------------------- */
1329 /* Function:     out16r */
1330 /* Description:  Byte reverse and output 16 bits */
1331 /*------------------------------------------------------------------------------- */
1332         .globl  out16r
1333 out16r:
1334         sthbrx  r4,r0,r3
1335         blr
1336
1337 /*------------------------------------------------------------------------------- */
1338 /* Function:     out32r */
1339 /* Description:  Byte reverse and output 32 bits */
1340 /*------------------------------------------------------------------------------- */
1341         .globl  out32r
1342 out32r:
1343         stwbrx  r4,r0,r3
1344         blr
1345
1346 /*------------------------------------------------------------------------------- */
1347 /* Function:     in16 */
1348 /* Description:  Input 16 bits */
1349 /*------------------------------------------------------------------------------- */
1350         .globl  in16
1351 in16:
1352         lhz     r3,0x0000(r3)
1353         blr
1354
1355 /*------------------------------------------------------------------------------- */
1356 /* Function:     in16r */
1357 /* Description:  Input 16 bits and byte reverse */
1358 /*------------------------------------------------------------------------------- */
1359         .globl  in16r
1360 in16r:
1361         lhbrx   r3,r0,r3
1362         blr
1363
1364 /*------------------------------------------------------------------------------- */
1365 /* Function:     in32r */
1366 /* Description:  Input 32 bits and byte reverse */
1367 /*------------------------------------------------------------------------------- */
1368         .globl  in32r
1369 in32r:
1370         lwbrx   r3,r0,r3
1371         blr
1372
1373 /*
1374  * void relocate_code (addr_sp, gd, addr_moni)
1375  *
1376  * This "function" does not return, instead it continues in RAM
1377  * after relocating the monitor code.
1378  *
1379  * r3 = Relocated stack pointer
1380  * r4 = Relocated global data pointer
1381  * r5 = Relocated text pointer
1382  */
1383         .globl  relocate_code
1384 relocate_code:
1385 #if defined(CONFIG_4xx_DCACHE) || defined(CONFIG_SYS_INIT_DCACHE_CS)
1386         /*
1387          * We need to flush the initial global data (gd_t) before the dcache
1388          * will be invalidated.
1389          */
1390
1391         /* Save registers */
1392         mr      r9, r3
1393         mr      r10, r4
1394         mr      r11, r5
1395
1396         /* Flush initial global data range */
1397         mr      r3, r4
1398         addi    r4, r4, CONFIG_SYS_GBL_DATA_SIZE@l
1399         bl      flush_dcache_range
1400
1401 #if defined(CONFIG_SYS_INIT_DCACHE_CS)
1402         /*
1403          * Undo the earlier data cache set-up for the primordial stack and
1404          * data area. First, invalidate the data cache and then disable data
1405          * cacheability for that area. Finally, restore the EBC values, if
1406          * any.
1407          */
1408
1409         /* Invalidate the primordial stack and data area in cache */
1410         lis     r3, CONFIG_SYS_INIT_RAM_ADDR@h
1411         ori     r3, r3, CONFIG_SYS_INIT_RAM_ADDR@l
1412
1413         lis     r4, CONFIG_SYS_INIT_RAM_END@h
1414         ori     r4, r4, CONFIG_SYS_INIT_RAM_END@l
1415         add     r4, r4, r3
1416
1417         bl      invalidate_dcache_range
1418
1419         /* Disable cacheability for the region */
1420         mfdccr  r3
1421         lis     r4, ~PPC_128MB_SACR_VALUE(CONFIG_SYS_INIT_RAM_ADDR)@h
1422         ori     r4, r4, ~PPC_128MB_SACR_VALUE(CONFIG_SYS_INIT_RAM_ADDR)@l
1423         and     r3, r3, r4
1424         mtdccr  r3
1425
1426         /* Restore the EBC parameters */
1427         li      r3, PBxAP
1428         mtdcr   EBC0_CFGADDR, r3
1429         lis     r3, PBxAP_VAL@h
1430         ori     r3, r3, PBxAP_VAL@l
1431         mtdcr   EBC0_CFGDATA, r3
1432
1433         li      r3, PBxCR
1434         mtdcr   EBC0_CFGADDR, r3
1435         lis     r3, PBxCR_VAL@h
1436         ori     r3, r3, PBxCR_VAL@l
1437         mtdcr   EBC0_CFGDATA, r3
1438 #endif /* defined(CONFIG_SYS_INIT_DCACHE_CS) */
1439
1440         /* Restore registers */
1441         mr      r3, r9
1442         mr      r4, r10
1443         mr      r5, r11
1444 #endif /* defined(CONFIG_4xx_DCACHE) || defined(CONFIG_SYS_INIT_DCACHE_CS) */
1445
1446 #ifdef CONFIG_SYS_INIT_RAM_DCACHE
1447         /*
1448          * Unlock the previously locked d-cache
1449          */
1450         msync
1451         isync
1452         /* set TFLOOR/NFLOOR to 0 again */
1453         lis     r6,0x0001
1454         ori     r6,r6,0xf800
1455         mtspr   SPRN_DVLIM,r6
1456         lis     r6,0x0000
1457         ori     r6,r6,0x0000
1458         mtspr   SPRN_DNV0,r6
1459         mtspr   SPRN_DNV1,r6
1460         mtspr   SPRN_DNV2,r6
1461         mtspr   SPRN_DNV3,r6
1462         mtspr   SPRN_DTV0,r6
1463         mtspr   SPRN_DTV1,r6
1464         mtspr   SPRN_DTV2,r6
1465         mtspr   SPRN_DTV3,r6
1466         msync
1467         isync
1468
1469         /* Invalidate data cache, now no longer our stack */
1470         dccci   0,0
1471         sync
1472         isync
1473 #endif /* CONFIG_SYS_INIT_RAM_DCACHE */
1474
1475         /*
1476          * On some 440er platforms the cache is enabled in the first TLB (Boot-CS)
1477          * to speed up the boot process. Now this cache needs to be disabled.
1478          */
1479 #if defined(CONFIG_440)
1480         /* Clear all potential pending exceptions */
1481         mfspr   r1,SPRN_MCSR
1482         mtspr   SPRN_MCSR,r1
1483         addi    r1,r0,CONFIG_SYS_TLB_FOR_BOOT_FLASH     /* Use defined TLB */
1484         tlbre   r0,r1,0x0002            /* Read contents */
1485         ori     r0,r0,0x0c00            /* Or in the inhibit, write through bit */
1486         tlbwe   r0,r1,0x0002            /* Save it out */
1487         sync
1488         isync
1489 #endif /* defined(CONFIG_440) */
1490         mr      r1,  r3         /* Set new stack pointer                */
1491         mr      r9,  r4         /* Save copy of Init Data pointer       */
1492         mr      r10, r5         /* Save copy of Destination Address     */
1493
1494         GET_GOT
1495         mr      r3,  r5                         /* Destination Address  */
1496         lis     r4, CONFIG_SYS_MONITOR_BASE@h           /* Source      Address  */
1497         ori     r4, r4, CONFIG_SYS_MONITOR_BASE@l
1498         lwz     r5, GOT(__init_end)
1499         sub     r5, r5, r4
1500         li      r6, L1_CACHE_BYTES              /* Cache Line Size      */
1501
1502         /*
1503          * Fix GOT pointer:
1504          *
1505          * New GOT-PTR = (old GOT-PTR - CONFIG_SYS_MONITOR_BASE) + Destination Address
1506          *
1507          * Offset:
1508          */
1509         sub     r15, r10, r4
1510
1511         /* First our own GOT */
1512         add     r12, r12, r15
1513         /* then the one used by the C code */
1514         add     r30, r30, r15
1515
1516         /*
1517          * Now relocate code
1518          */
1519
1520         cmplw   cr1,r3,r4
1521         addi    r0,r5,3
1522         srwi.   r0,r0,2
1523         beq     cr1,4f          /* In place copy is not necessary       */
1524         beq     7f              /* Protect against 0 count              */
1525         mtctr   r0
1526         bge     cr1,2f
1527
1528         la      r8,-4(r4)
1529         la      r7,-4(r3)
1530 1:      lwzu    r0,4(r8)
1531         stwu    r0,4(r7)
1532         bdnz    1b
1533         b       4f
1534
1535 2:      slwi    r0,r0,2
1536         add     r8,r4,r0
1537         add     r7,r3,r0
1538 3:      lwzu    r0,-4(r8)
1539         stwu    r0,-4(r7)
1540         bdnz    3b
1541
1542 /*
1543  * Now flush the cache: note that we must start from a cache aligned
1544  * address. Otherwise we might miss one cache line.
1545  */
1546 4:      cmpwi   r6,0
1547         add     r5,r3,r5
1548         beq     7f              /* Always flush prefetch queue in any case */
1549         subi    r0,r6,1
1550         andc    r3,r3,r0
1551         mr      r4,r3
1552 5:      dcbst   0,r4
1553         add     r4,r4,r6
1554         cmplw   r4,r5
1555         blt     5b
1556         sync                    /* Wait for all dcbst to complete on bus */
1557         mr      r4,r3
1558 6:      icbi    0,r4
1559         add     r4,r4,r6
1560         cmplw   r4,r5
1561         blt     6b
1562 7:      sync                    /* Wait for all icbi to complete on bus */
1563         isync
1564
1565 /*
1566  * We are done. Do not return, instead branch to second part of board
1567  * initialization, now running from RAM.
1568  */
1569
1570         addi    r0, r10, in_ram - _start + _START_OFFSET
1571         mtlr    r0
1572         blr                             /* NEVER RETURNS! */
1573
1574 in_ram:
1575
1576         /*
1577          * Relocation Function, r12 point to got2+0x8000
1578          *
1579          * Adjust got2 pointers, no need to check for 0, this code
1580          * already puts a few entries in the table.
1581          */
1582         li      r0,__got2_entries@sectoff@l
1583         la      r3,GOT(_GOT2_TABLE_)
1584         lwz     r11,GOT(_GOT2_TABLE_)
1585         mtctr   r0
1586         sub     r11,r3,r11
1587         addi    r3,r3,-4
1588 1:      lwzu    r0,4(r3)
1589         cmpwi   r0,0
1590         beq-    2f
1591         add     r0,r0,r11
1592         stw     r0,0(r3)
1593 2:      bdnz    1b
1594
1595         /*
1596          * Now adjust the fixups and the pointers to the fixups
1597          * in case we need to move ourselves again.
1598          */
1599         li      r0,__fixup_entries@sectoff@l
1600         lwz     r3,GOT(_FIXUP_TABLE_)
1601         cmpwi   r0,0
1602         mtctr   r0
1603         addi    r3,r3,-4
1604         beq     4f
1605 3:      lwzu    r4,4(r3)
1606         lwzux   r0,r4,r11
1607         add     r0,r0,r11
1608         stw     r10,0(r3)
1609         stw     r0,0(r4)
1610         bdnz    3b
1611 4:
1612 clear_bss:
1613         /*
1614          * Now clear BSS segment
1615          */
1616         lwz     r3,GOT(__bss_start)
1617         lwz     r4,GOT(_end)
1618
1619         cmplw   0, r3, r4
1620         beq     7f
1621
1622         li      r0, 0
1623
1624         andi.   r5, r4, 3
1625         beq     6f
1626         sub     r4, r4, r5
1627         mtctr   r5
1628         mr      r5, r4
1629 5:      stb     r0, 0(r5)
1630         addi    r5, r5, 1
1631         bdnz    5b
1632 6:
1633         stw     r0, 0(r3)
1634         addi    r3, r3, 4
1635         cmplw   0, r3, r4
1636         bne     6b
1637
1638 7:
1639         mr      r3, r9          /* Init Data pointer            */
1640         mr      r4, r10         /* Destination Address          */
1641         bl      board_init_r
1642
1643         /*
1644          * Copy exception vector code to low memory
1645          *
1646          * r3: dest_addr
1647          * r7: source address, r8: end address, r9: target address
1648          */
1649         .globl  trap_init
1650 trap_init:
1651         mflr    r4                      /* save link register           */
1652         GET_GOT
1653         lwz     r7, GOT(_start_of_vectors)
1654         lwz     r8, GOT(_end_of_vectors)
1655
1656         li      r9, 0x100               /* reset vector always at 0x100 */
1657
1658         cmplw   0, r7, r8
1659         bgelr                           /* return if r7>=r8 - just in case */
1660 1:
1661         lwz     r0, 0(r7)
1662         stw     r0, 0(r9)
1663         addi    r7, r7, 4
1664         addi    r9, r9, 4
1665         cmplw   0, r7, r8
1666         bne     1b
1667
1668         /*
1669          * relocate `hdlr' and `int_return' entries
1670          */
1671         li      r7, .L_MachineCheck - _start + _START_OFFSET
1672         li      r8, Alignment - _start + _START_OFFSET
1673 2:
1674         bl      trap_reloc
1675         addi    r7, r7, 0x100           /* next exception vector */
1676         cmplw   0, r7, r8
1677         blt     2b
1678
1679         li      r7, .L_Alignment - _start + _START_OFFSET
1680         bl      trap_reloc
1681
1682         li      r7, .L_ProgramCheck - _start + _START_OFFSET
1683         bl      trap_reloc
1684
1685 #ifdef CONFIG_440
1686         li      r7, .L_FPUnavailable - _start + _START_OFFSET
1687         bl      trap_reloc
1688
1689         li      r7, .L_Decrementer - _start + _START_OFFSET
1690         bl      trap_reloc
1691
1692         li      r7, .L_APU - _start + _START_OFFSET
1693         bl      trap_reloc
1694
1695         li      r7, .L_InstructionTLBError - _start + _START_OFFSET
1696         bl      trap_reloc
1697
1698         li      r7, .L_DataTLBError - _start + _START_OFFSET
1699         bl      trap_reloc
1700 #else /* CONFIG_440 */
1701         li      r7, .L_PIT - _start + _START_OFFSET
1702         bl      trap_reloc
1703
1704         li      r7, .L_InstructionTLBMiss - _start + _START_OFFSET
1705         bl      trap_reloc
1706
1707         li      r7, .L_DataTLBMiss - _start + _START_OFFSET
1708         bl      trap_reloc
1709 #endif /* CONFIG_440 */
1710
1711         li      r7, .L_DebugBreakpoint - _start + _START_OFFSET
1712         bl      trap_reloc
1713
1714 #if !defined(CONFIG_440)
1715         addi    r7,r0,0x1000            /* set ME bit (Machine Exceptions) */
1716         oris    r7,r7,0x0002            /* set CE bit (Critical Exceptions) */
1717         mtmsr   r7                      /* change MSR */
1718 #else
1719         bl      __440_msr_set
1720         b       __440_msr_continue
1721
1722 __440_msr_set:
1723         addi    r7,r0,0x1000            /* set ME bit (Machine Exceptions) */
1724         oris    r7,r7,0x0002            /* set CE bit (Critical Exceptions) */
1725         mtspr   SPRN_SRR1,r7
1726         mflr    r7
1727         mtspr   SPRN_SRR0,r7
1728         rfi
1729 __440_msr_continue:
1730 #endif
1731
1732         mtlr    r4                      /* restore link register        */
1733         blr
1734
1735 #if defined(CONFIG_440)
1736 /*----------------------------------------------------------------------------+
1737 | dcbz_area.
1738 +----------------------------------------------------------------------------*/
1739         function_prolog(dcbz_area)
1740         rlwinm. r5,r4,0,27,31
1741         rlwinm  r5,r4,27,5,31
1742         beq     ..d_ra2
1743         addi    r5,r5,0x0001
1744 ..d_ra2:mtctr   r5
1745 ..d_ag2:dcbz    r0,r3
1746         addi    r3,r3,32
1747         bdnz    ..d_ag2
1748         sync
1749         blr
1750         function_epilog(dcbz_area)
1751 #endif /* CONFIG_440 */
1752 #endif /* CONFIG_NAND_SPL */
1753
1754 /*------------------------------------------------------------------------------- */
1755 /* Function:     in8 */
1756 /* Description:  Input 8 bits */
1757 /*------------------------------------------------------------------------------- */
1758         .globl  in8
1759 in8:
1760         lbz     r3,0x0000(r3)
1761         blr
1762
1763 /*------------------------------------------------------------------------------- */
1764 /* Function:     out8 */
1765 /* Description:  Output 8 bits */
1766 /*------------------------------------------------------------------------------- */
1767         .globl  out8
1768 out8:
1769         stb     r4,0x0000(r3)
1770         blr
1771
1772 /*------------------------------------------------------------------------------- */
1773 /* Function:     out32 */
1774 /* Description:  Output 32 bits */
1775 /*------------------------------------------------------------------------------- */
1776         .globl  out32
1777 out32:
1778         stw     r4,0x0000(r3)
1779         blr
1780
1781 /*------------------------------------------------------------------------------- */
1782 /* Function:     in32 */
1783 /* Description:  Input 32 bits */
1784 /*------------------------------------------------------------------------------- */
1785         .globl  in32
1786 in32:
1787         lwz     3,0x0000(3)
1788         blr
1789
1790 /**************************************************************************/
1791 /* PPC405EP specific stuff                                                */
1792 /**************************************************************************/
1793 #ifdef CONFIG_405EP
1794 ppc405ep_init:
1795
1796 #ifdef CONFIG_BUBINGA
1797         /*
1798          * Initialize EBC chip selects 1 & 4 and GPIO pins (for alternate
1799          * function) to support FPGA and NVRAM accesses below.
1800          */
1801
1802         lis     r3,GPIO0_OSRH@h         /* config GPIO output select */
1803         ori     r3,r3,GPIO0_OSRH@l
1804         lis     r4,CONFIG_SYS_GPIO0_OSRH@h
1805         ori     r4,r4,CONFIG_SYS_GPIO0_OSRH@l
1806         stw     r4,0(r3)
1807         lis     r3,GPIO0_OSRL@h
1808         ori     r3,r3,GPIO0_OSRL@l
1809         lis     r4,CONFIG_SYS_GPIO0_OSRL@h
1810         ori     r4,r4,CONFIG_SYS_GPIO0_OSRL@l
1811         stw     r4,0(r3)
1812
1813         lis     r3,GPIO0_ISR1H@h        /* config GPIO input select */
1814         ori     r3,r3,GPIO0_ISR1H@l
1815         lis     r4,CONFIG_SYS_GPIO0_ISR1H@h
1816         ori     r4,r4,CONFIG_SYS_GPIO0_ISR1H@l
1817         stw     r4,0(r3)
1818         lis     r3,GPIO0_ISR1L@h
1819         ori     r3,r3,GPIO0_ISR1L@l
1820         lis     r4,CONFIG_SYS_GPIO0_ISR1L@h
1821         ori     r4,r4,CONFIG_SYS_GPIO0_ISR1L@l
1822         stw     r4,0(r3)
1823
1824         lis     r3,GPIO0_TSRH@h         /* config GPIO three-state select */
1825         ori     r3,r3,GPIO0_TSRH@l
1826         lis     r4,CONFIG_SYS_GPIO0_TSRH@h
1827         ori     r4,r4,CONFIG_SYS_GPIO0_TSRH@l
1828         stw     r4,0(r3)
1829         lis     r3,GPIO0_TSRL@h
1830         ori     r3,r3,GPIO0_TSRL@l
1831         lis     r4,CONFIG_SYS_GPIO0_TSRL@h
1832         ori     r4,r4,CONFIG_SYS_GPIO0_TSRL@l
1833         stw     r4,0(r3)
1834
1835         lis     r3,GPIO0_TCR@h          /* config GPIO driver output enables */
1836         ori     r3,r3,GPIO0_TCR@l
1837         lis     r4,CONFIG_SYS_GPIO0_TCR@h
1838         ori     r4,r4,CONFIG_SYS_GPIO0_TCR@l
1839         stw     r4,0(r3)
1840
1841         li      r3,PB1AP                /* program EBC bank 1 for RTC access */
1842         mtdcr   EBC0_CFGADDR,r3
1843         lis     r3,CONFIG_SYS_EBC_PB1AP@h
1844         ori     r3,r3,CONFIG_SYS_EBC_PB1AP@l
1845         mtdcr   EBC0_CFGDATA,r3
1846         li      r3,PB1CR
1847         mtdcr   EBC0_CFGADDR,r3
1848         lis     r3,CONFIG_SYS_EBC_PB1CR@h
1849         ori     r3,r3,CONFIG_SYS_EBC_PB1CR@l
1850         mtdcr   EBC0_CFGDATA,r3
1851
1852         li      r3,PB1AP                /* program EBC bank 1 for RTC access */
1853         mtdcr   EBC0_CFGADDR,r3
1854         lis     r3,CONFIG_SYS_EBC_PB1AP@h
1855         ori     r3,r3,CONFIG_SYS_EBC_PB1AP@l
1856         mtdcr   EBC0_CFGDATA,r3
1857         li      r3,PB1CR
1858         mtdcr   EBC0_CFGADDR,r3
1859         lis     r3,CONFIG_SYS_EBC_PB1CR@h
1860         ori     r3,r3,CONFIG_SYS_EBC_PB1CR@l
1861         mtdcr   EBC0_CFGDATA,r3
1862
1863         li      r3,PB4AP                /* program EBC bank 4 for FPGA access */
1864         mtdcr   EBC0_CFGADDR,r3
1865         lis     r3,CONFIG_SYS_EBC_PB4AP@h
1866         ori     r3,r3,CONFIG_SYS_EBC_PB4AP@l
1867         mtdcr   EBC0_CFGDATA,r3
1868         li      r3,PB4CR
1869         mtdcr   EBC0_CFGADDR,r3
1870         lis     r3,CONFIG_SYS_EBC_PB4CR@h
1871         ori     r3,r3,CONFIG_SYS_EBC_PB4CR@l
1872         mtdcr   EBC0_CFGDATA,r3
1873 #endif
1874
1875         /*
1876         !-----------------------------------------------------------------------
1877         ! Check to see if chip is in bypass mode.
1878         ! If so, write stored CPC0_PLLMR0 and CPC0_PLLMR1 values and perform a
1879         ! CPU reset   Otherwise, skip this step and keep going.
1880         ! Note:  Running BIOS in bypass mode is not supported since PLB speed
1881         !        will not be fast enough for the SDRAM (min 66MHz)
1882         !-----------------------------------------------------------------------
1883         */
1884         mfdcr   r5, CPC0_PLLMR1
1885         rlwinm  r4,r5,1,0x1             /* get system clock source (SSCS) */
1886         cmpi    cr0,0,r4,0x1
1887
1888         beq    pll_done                 /* if SSCS =b'1' then PLL has */
1889                                         /* already been set */
1890                                         /* and CPU has been reset */
1891                                         /* so skip to next section */
1892
1893 #ifdef CONFIG_BUBINGA
1894         /*
1895         !-----------------------------------------------------------------------
1896         ! Read NVRAM to get value to write in PLLMR.
1897         ! If value has not been correctly saved, write default value
1898         ! Default config values (assuming on-board 33MHz SYS_CLK) are above.
1899         ! See CPU_DEFAULT_200 and CPU_DEFAULT_266 above.
1900         !
1901         ! WARNING:  This code assumes the first three words in the nvram_t
1902         !           structure in openbios.h.  Changing the beginning of
1903         !           the structure will break this code.
1904         !
1905         !-----------------------------------------------------------------------
1906         */
1907         addis   r3,0,NVRAM_BASE@h
1908         addi    r3,r3,NVRAM_BASE@l
1909
1910         lwz     r4, 0(r3)
1911         addis   r5,0,NVRVFY1@h
1912         addi    r5,r5,NVRVFY1@l
1913         cmp     cr0,0,r4,r5             /* Compare 1st NVRAM Magic number*/
1914         bne     ..no_pllset
1915         addi    r3,r3,4
1916         lwz     r4, 0(r3)
1917         addis   r5,0,NVRVFY2@h
1918         addi    r5,r5,NVRVFY2@l
1919         cmp     cr0,0,r4,r5             /* Compare 2 NVRAM Magic number */
1920         bne     ..no_pllset
1921         addi    r3,r3,8                 /* Skip over conf_size */
1922         lwz     r4, 4(r3)               /* Load PLLMR1 value from NVRAM */
1923         lwz     r3, 0(r3)               /* Load PLLMR0 value from NVRAM */
1924         rlwinm  r5,r4,1,0x1             /* get system clock source (SSCS) */
1925         cmpi     cr0,0,r5,1             /* See if PLL is locked */
1926         beq     pll_write
1927 ..no_pllset:
1928 #endif /* CONFIG_BUBINGA */
1929
1930 #ifdef CONFIG_TAIHU
1931         mfdcr   r4, CPC0_BOOT
1932         andi.   r5, r4, CPC0_BOOT_SEP@l
1933         bne     strap_1                 /* serial eeprom present */
1934         addis   r5,0,CPLD_REG0_ADDR@h
1935         ori     r5,r5,CPLD_REG0_ADDR@l
1936         andi.   r5, r5, 0x10
1937         bne     _pci_66mhz
1938 #endif /* CONFIG_TAIHU */
1939
1940 #if defined(CONFIG_ZEUS)
1941         mfdcr   r4, CPC0_BOOT
1942         andi.   r5, r4, CPC0_BOOT_SEP@l
1943         bne     strap_1                 /* serial eeprom present */
1944         lis     r3,0x0000
1945         addi    r3,r3,0x3030
1946         lis     r4,0x8042
1947         addi    r4,r4,0x223e
1948         b       1f
1949 strap_1:
1950         mfdcr   r3, CPC0_PLLMR0
1951         mfdcr   r4, CPC0_PLLMR1
1952         b       1f
1953 #endif
1954
1955         addis   r3,0,PLLMR0_DEFAULT@h   /* PLLMR0 default value */
1956         ori     r3,r3,PLLMR0_DEFAULT@l  /* */
1957         addis   r4,0,PLLMR1_DEFAULT@h   /* PLLMR1 default value */
1958         ori     r4,r4,PLLMR1_DEFAULT@l  /* */
1959
1960 #ifdef CONFIG_TAIHU
1961         b       1f
1962 _pci_66mhz:
1963         addis   r3,0,PLLMR0_DEFAULT_PCI66@h
1964         ori     r3,r3,PLLMR0_DEFAULT_PCI66@l
1965         addis   r4,0,PLLMR1_DEFAULT_PCI66@h
1966         ori     r4,r4,PLLMR1_DEFAULT_PCI66@l
1967         b       1f
1968 strap_1:
1969         mfdcr   r3, CPC0_PLLMR0
1970         mfdcr   r4, CPC0_PLLMR1
1971 #endif /* CONFIG_TAIHU */
1972
1973 1:
1974         b       pll_write               /* Write the CPC0_PLLMR with new value */
1975
1976 pll_done:
1977         /*
1978         !-----------------------------------------------------------------------
1979         ! Clear Soft Reset Register
1980         ! This is needed to enable PCI if not booting from serial EPROM
1981         !-----------------------------------------------------------------------
1982                 */
1983         addi    r3, 0, 0x0
1984         mtdcr   CPC0_SRR, r3
1985
1986         addis    r3,0,0x0010
1987         mtctr   r3
1988 pci_wait:
1989         bdnz    pci_wait
1990
1991         blr                             /* return to main code */
1992
1993 /*
1994 !-----------------------------------------------------------------------------
1995 ! Function:     pll_write
1996 ! Description:  Updates the value of the CPC0_PLLMR according to CMOS27E documentation
1997 !               That is:
1998 !                         1.  Pll is first disabled (de-activated by putting in bypass mode)
1999 !                         2.  PLL is reset
2000 !                         3.  Clock dividers are set while PLL is held in reset and bypassed
2001 !                         4.  PLL Reset is cleared
2002 !                         5.  Wait 100us for PLL to lock
2003 !                         6.  A core reset is performed
2004 ! Input: r3 = Value to write to CPC0_PLLMR0
2005 ! Input: r4 = Value to write to CPC0_PLLMR1
2006 ! Output r3 = none
2007 !-----------------------------------------------------------------------------
2008 */
2009         .globl  pll_write
2010 pll_write:
2011         mfdcr  r5, CPC0_UCR
2012         andis. r5,r5,0xFFFF
2013         ori    r5,r5,0x0101             /* Stop the UART clocks */
2014         mtdcr  CPC0_UCR,r5              /* Before changing PLL */
2015
2016         mfdcr  r5, CPC0_PLLMR1
2017         rlwinm r5,r5,0,0x7FFFFFFF       /* Disable PLL */
2018         mtdcr   CPC0_PLLMR1,r5
2019         oris   r5,r5,0x4000             /* Set PLL Reset */
2020         mtdcr   CPC0_PLLMR1,r5
2021
2022         mtdcr   CPC0_PLLMR0,r3          /* Set clock dividers */
2023         rlwinm r5,r4,0,0x3FFFFFFF       /* Reset & Bypass new PLL dividers */
2024         oris   r5,r5,0x4000             /* Set PLL Reset */
2025         mtdcr   CPC0_PLLMR1,r5          /* Set clock dividers */
2026         rlwinm r5,r5,0,0xBFFFFFFF       /* Clear PLL Reset */
2027         mtdcr   CPC0_PLLMR1,r5
2028
2029                 /*
2030         ! Wait min of 100us for PLL to lock.
2031         ! See CMOS 27E databook for more info.
2032         ! At 200MHz, that means waiting 20,000 instructions
2033                  */
2034         addi    r3,0,20000              /* 2000 = 0x4e20 */
2035         mtctr   r3
2036 pll_wait:
2037         bdnz    pll_wait
2038
2039         oris   r5,r5,0x8000             /* Enable PLL */
2040         mtdcr   CPC0_PLLMR1,r5          /* Engage */
2041
2042         /*
2043          * Reset CPU to guarantee timings are OK
2044          * Not sure if this is needed...
2045          */
2046         addis r3,0,0x1000
2047         mtspr SPRN_DBCR0,r3             /* This will cause a CPU core reset, and */
2048                                         /* execution will continue from the poweron */
2049                                         /* vector of 0xfffffffc */
2050 #endif /* CONFIG_405EP */
2051
2052 #if defined(CONFIG_440)
2053 /*----------------------------------------------------------------------------+
2054 | mttlb3.
2055 +----------------------------------------------------------------------------*/
2056         function_prolog(mttlb3)
2057         TLBWE(4,3,2)
2058         blr
2059         function_epilog(mttlb3)
2060
2061 /*----------------------------------------------------------------------------+
2062 | mftlb3.
2063 +----------------------------------------------------------------------------*/
2064         function_prolog(mftlb3)
2065         TLBRE(3,3,2)
2066         blr
2067         function_epilog(mftlb3)
2068
2069 /*----------------------------------------------------------------------------+
2070 | mttlb2.
2071 +----------------------------------------------------------------------------*/
2072         function_prolog(mttlb2)
2073         TLBWE(4,3,1)
2074         blr
2075         function_epilog(mttlb2)
2076
2077 /*----------------------------------------------------------------------------+
2078 | mftlb2.
2079 +----------------------------------------------------------------------------*/
2080         function_prolog(mftlb2)
2081         TLBRE(3,3,1)
2082         blr
2083         function_epilog(mftlb2)
2084
2085 /*----------------------------------------------------------------------------+
2086 | mttlb1.
2087 +----------------------------------------------------------------------------*/
2088         function_prolog(mttlb1)
2089         TLBWE(4,3,0)
2090         blr
2091         function_epilog(mttlb1)
2092
2093 /*----------------------------------------------------------------------------+
2094 | mftlb1.
2095 +----------------------------------------------------------------------------*/
2096         function_prolog(mftlb1)
2097         TLBRE(3,3,0)
2098         blr
2099         function_epilog(mftlb1)
2100 #endif /* CONFIG_440 */
2101
2102 #if defined(CONFIG_NAND_SPL)
2103 /*
2104  * void nand_boot_relocate(dst, src, bytes)
2105  *
2106  * r3 = Destination address to copy code to (in SDRAM)
2107  * r4 = Source address to copy code from
2108  * r5 = size to copy in bytes
2109  */
2110 nand_boot_relocate:
2111         mr      r6,r3
2112         mr      r7,r4
2113         mflr    r8
2114
2115         /*
2116          * Copy SPL from icache into SDRAM
2117          */
2118         subi    r3,r3,4
2119         subi    r4,r4,4
2120         srwi    r5,r5,2
2121         mtctr   r5
2122 ..spl_loop:
2123         lwzu    r0,4(r4)
2124         stwu    r0,4(r3)
2125         bdnz    ..spl_loop
2126
2127         /*
2128          * Calculate "corrected" link register, so that we "continue"
2129          * in execution in destination range
2130          */
2131         sub     r3,r7,r6        /* r3 = src - dst */
2132         sub     r8,r8,r3        /* r8 = link-reg - (src - dst) */
2133         mtlr    r8
2134         blr
2135
2136 nand_boot_common:
2137         /*
2138          * First initialize SDRAM. It has to be available *before* calling
2139          * nand_boot().
2140          */
2141         lis     r3,CONFIG_SYS_SDRAM_BASE@h
2142         ori     r3,r3,CONFIG_SYS_SDRAM_BASE@l
2143         bl      initdram
2144
2145         /*
2146          * Now copy the 4k SPL code into SDRAM and continue execution
2147          * from there.
2148          */
2149         lis     r3,CONFIG_SYS_NAND_BOOT_SPL_DST@h
2150         ori     r3,r3,CONFIG_SYS_NAND_BOOT_SPL_DST@l
2151         lis     r4,CONFIG_SYS_NAND_BOOT_SPL_SRC@h
2152         ori     r4,r4,CONFIG_SYS_NAND_BOOT_SPL_SRC@l
2153         lis     r5,CONFIG_SYS_NAND_BOOT_SPL_SIZE@h
2154         ori     r5,r5,CONFIG_SYS_NAND_BOOT_SPL_SIZE@l
2155         bl      nand_boot_relocate
2156
2157         /*
2158          * We're running from SDRAM now!!!
2159          *
2160          * It is necessary for 4xx systems to relocate from running at
2161          * the original location (0xfffffxxx) to somewhere else (SDRAM
2162          * preferably). This is because CS0 needs to be reconfigured for
2163          * NAND access. And we can't reconfigure this CS when currently
2164          * "running" from it.
2165          */
2166
2167         /*
2168          * Finally call nand_boot() to load main NAND U-Boot image from
2169          * NAND and jump to it.
2170          */
2171         bl      nand_boot               /* will not return */
2172 #endif /* CONFIG_NAND_SPL */