arch/powerpc/kernel/entry_64.S

   1 /*
   2  *  PowerPC version
   3  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
   4  *  Rewritten by Cort Dougan (cort@cs.nmt.edu) for PReP
   5  *    Copyright (C) 1996 Cort Dougan <cort@cs.nmt.edu>
   6  *  Adapted for Power Macintosh by Paul Mackerras.
   7  *  Low-level exception handlers and MMU support
   8  *  rewritten by Paul Mackerras.
   9  *    Copyright (C) 1996 Paul Mackerras.
  10  *  MPC8xx modifications Copyright (C) 1997 Dan Malek (dmalek@jlc.net).
  11  *
  12  *  This file contains the system call entry code, context switch
  13  *  code, and exception/interrupt return code for PowerPC.
  14  *
  15  *  This program is free software; you can redistribute it and/or
  16  *  modify it under the terms of the GNU General Public License
  17  *  as published by the Free Software Foundation; either version
  18  *  2 of the License, or (at your option) any later version.
  19  */
  20
  21 #include <linux/errno.h>
  22 #include <asm/unistd.h>
  23 #include <asm/processor.h>
  24 #include <asm/page.h>
  25 #include <asm/mmu.h>
  26 #include <asm/thread_info.h>
  27 #include <asm/ppc_asm.h>
  28 #include <asm/asm-offsets.h>
  29 #include <asm/cputable.h>
  30 #include <asm/firmware.h>
  31 #include <asm/bug.h>
  32 #include <asm/ptrace.h>
  33 #include <asm/irqflags.h>
  34 #include <asm/ftrace.h>
  35 #include <asm/hw_irq.h>
  36
  37 /*
  38  * System calls.
  39  */
  40         .section        ".toc","aw"
  41 .SYS_CALL_TABLE:
  42         .tc .sys_call_table[TC],.sys_call_table
  43
  44 /* This value is used to mark exception frames on the stack. */
  45 exception_marker:
  46         .tc     ID_EXC_MARKER[TC],STACK_FRAME_REGS_MARKER
  47
  48         .section        ".text"
  49         .align 7
  50
  51 #undef SHOW_SYSCALLS
  52
  53         .globl system_call_common
  54 system_call_common:
  55         andi.   r10,r12,MSR_PR
  56         mr      r10,r1
  57         addi    r1,r1,-INT_FRAME_SIZE
  58         beq-    1f
  59         ld      r1,PACAKSAVE(r13)
  60 1:      std     r10,0(r1)
  61         std     r11,_NIP(r1)
  62         std     r12,_MSR(r1)
  63         std     r0,GPR0(r1)
  64         std     r10,GPR1(r1)
  65         ACCOUNT_CPU_USER_ENTRY(r10, r11)
  66         std     r2,GPR2(r1)
  67         std     r3,GPR3(r1)
  68         mfcr    r2
  69         std     r4,GPR4(r1)
  70         std     r5,GPR5(r1)
  71         std     r6,GPR6(r1)
  72         std     r7,GPR7(r1)
  73         std     r8,GPR8(r1)
  74         li      r11,0
  75         std     r11,GPR9(r1)
  76         std     r11,GPR10(r1)
  77         std     r11,GPR11(r1)
  78         std     r11,GPR12(r1)
  79         std     r11,_XER(r1)
  80         std     r11,_CTR(r1)
  81         std     r9,GPR13(r1)
  82         mflr    r10
  83         /*
  84          * This clears CR0.SO (bit 28), which is the error indication on
  85          * return from this system call.
  86          */
  87         rldimi  r2,r11,28,(63-28)
  88         li      r11,0xc01
  89         std     r10,_LINK(r1)
  90         std     r11,_TRAP(r1)
  91         std     r3,ORIG_GPR3(r1)
  92         std     r2,_CCR(r1)
  93         ld      r2,PACATOC(r13)
  94         addi    r9,r1,STACK_FRAME_OVERHEAD
  95         ld      r11,exception_marker@toc(r2)
  96         std     r11,-16(r9)             /* "regshere" marker */
  97 #if defined(CONFIG_VIRT_CPU_ACCOUNTING) && defined(CONFIG_PPC_SPLPAR)
  98 BEGIN_FW_FTR_SECTION
  99         beq     33f
 100         /* if from user, see if there are any DTL entries to process */
 101         ld      r10,PACALPPACAPTR(r13)  /* get ptr to VPA */
 102         ld      r11,PACA_DTL_RIDX(r13)  /* get log read index */
 103         ld      r10,LPPACA_DTLIDX(r10)  /* get log write index */
 104         cmpd    cr1,r11,r10
 105         beq+    cr1,33f
 106         bl      .accumulate_stolen_time
 107         REST_GPR(0,r1)
 108         REST_4GPRS(3,r1)
 109         REST_2GPRS(7,r1)
 110         addi    r9,r1,STACK_FRAME_OVERHEAD
 111 33:
 112 END_FW_FTR_SECTION_IFSET(FW_FEATURE_SPLPAR)
 113 #endif /* CONFIG_VIRT_CPU_ACCOUNTING && CONFIG_PPC_SPLPAR */
 114
 115         /*
 116          * A syscall should always be called with interrupts enabled
 117          * so we just unconditionally hard-enable here. When some kind
 118          * of irq tracing is used, we additionally check that condition
 119          * is correct
 120          */
 121 #if defined(CONFIG_TRACE_IRQFLAGS) && defined(CONFIG_BUG)
 122         lbz     r10,PACASOFTIRQEN(r13)
 123         xori    r10,r10,1
 124 1:      tdnei   r10,0
 125         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,BUGFLAG_WARNING
 126 #endif
 127
 128 #ifdef CONFIG_PPC_BOOK3E
 129         wrteei  1
 130 #else
 131         ld      r11,PACAKMSR(r13)
 132         ori     r11,r11,MSR_EE
 133         mtmsrd  r11,1
 134 #endif /* CONFIG_PPC_BOOK3E */
 135
 136         /* We do need to set SOFTE in the stack frame or the return
 137          * from interrupt will be painful
 138          */
 139         li      r10,1
 140         std     r10,SOFTE(r1)
 141
 142 #ifdef SHOW_SYSCALLS
 143         bl      .do_show_syscall
 144         REST_GPR(0,r1)
 145         REST_4GPRS(3,r1)
 146         REST_2GPRS(7,r1)
 147         addi    r9,r1,STACK_FRAME_OVERHEAD
 148 #endif
 149         CURRENT_THREAD_INFO(r11, r1)
 150         ld      r10,TI_FLAGS(r11)
 151         andi.   r11,r10,_TIF_SYSCALL_T_OR_A
 152         bne-    syscall_dotrace
 153 .Lsyscall_dotrace_cont:
 154         cmpldi  0,r0,NR_syscalls
 155         bge-    syscall_enosys
 156
 157 system_call:                    /* label this so stack traces look sane */
 158 /*
 159  * Need to vector to 32 Bit or default sys_call_table here,
 160  * based on caller's run-mode / personality.
 161  */
 162         ld      r11,.SYS_CALL_TABLE@toc(2)
 163         andi.   r10,r10,_TIF_32BIT
 164         beq     15f
 165         addi    r11,r11,8       /* use 32-bit syscall entries */
 166         clrldi  r3,r3,32
 167         clrldi  r4,r4,32
 168         clrldi  r5,r5,32
 169         clrldi  r6,r6,32
 170         clrldi  r7,r7,32
 171         clrldi  r8,r8,32
 172 15:
 173         slwi    r0,r0,4
 174         ldx     r10,r11,r0      /* Fetch system call handler [ptr] */
 175         mtctr   r10
 176         bctrl                   /* Call handler */
 177
 178 syscall_exit:
 179         std     r3,RESULT(r1)
 180 #ifdef SHOW_SYSCALLS
 181         bl      .do_show_syscall_exit
 182         ld      r3,RESULT(r1)
 183 #endif
 184         CURRENT_THREAD_INFO(r12, r1)
 185
 186         ld      r8,_MSR(r1)
 187 #ifdef CONFIG_PPC_BOOK3S
 188         /* No MSR:RI on BookE */
 189         andi.   r10,r8,MSR_RI
 190         beq-    unrecov_restore
 191 #endif
 192         /*
 193          * Disable interrupts so current_thread_info()->flags can't change,
 194          * and so that we don't get interrupted after loading SRR0/1.
 195          */
 196 #ifdef CONFIG_PPC_BOOK3E
 197         wrteei  0
 198 #else
 199         ld      r10,PACAKMSR(r13)
 200         /*
 201          * For performance reasons we clear RI the same time that we
 202          * clear EE. We only need to clear RI just before we restore r13
 203          * below, but batching it with EE saves us one expensive mtmsrd call.
 204          * We have to be careful to restore RI if we branch anywhere from
 205          * here (eg syscall_exit_work).
 206          */
 207         li      r9,MSR_RI
 208         andc    r11,r10,r9
 209         mtmsrd  r11,1
 210 #endif /* CONFIG_PPC_BOOK3E */
 211
 212         ld      r9,TI_FLAGS(r12)
 213         li      r11,-_LAST_ERRNO
 214         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP|_TIF_USER_WORK_MASK|_TIF_PERSYSCALL_MASK)
 215         bne-    syscall_exit_work
 216         cmpld   r3,r11
 217         ld      r5,_CCR(r1)
 218         bge-    syscall_error
 219 .Lsyscall_error_cont:
 220         ld      r7,_NIP(r1)
 221 BEGIN_FTR_SECTION
 222         stdcx.  r0,0,r1                 /* to clear the reservation */
 223 END_FTR_SECTION_IFCLR(CPU_FTR_STCX_CHECKS_ADDRESS)
 224         andi.   r6,r8,MSR_PR
 225         ld      r4,_LINK(r1)
 226
 227         beq-    1f
 228         ACCOUNT_CPU_USER_EXIT(r11, r12)
 229         ld      r13,GPR13(r1)   /* only restore r13 if returning to usermode */
 230 1:      ld      r2,GPR2(r1)
 231         ld      r1,GPR1(r1)
 232         mtlr    r4
 233         mtcr    r5
 234         mtspr   SPRN_SRR0,r7
 235         mtspr   SPRN_SRR1,r8
 236         RFI
 237         b       .       /* prevent speculative execution */
 238
 239 syscall_error:
 240         oris    r5,r5,0x1000    /* Set SO bit in CR */
 241         neg     r3,r3
 242         std     r5,_CCR(r1)
 243         b       .Lsyscall_error_cont
 244
 245 /* Traced system call support */
 246 syscall_dotrace:
 247         bl      .save_nvgprs
 248         addi    r3,r1,STACK_FRAME_OVERHEAD
 249         bl      .do_syscall_trace_enter
 250         /*
 251          * Restore argument registers possibly just changed.
 252          * We use the return value of do_syscall_trace_enter
 253          * for the call number to look up in the table (r0).
 254          */
 255         mr      r0,r3
 256         ld      r3,GPR3(r1)
 257         ld      r4,GPR4(r1)
 258         ld      r5,GPR5(r1)
 259         ld      r6,GPR6(r1)
 260         ld      r7,GPR7(r1)
 261         ld      r8,GPR8(r1)
 262         addi    r9,r1,STACK_FRAME_OVERHEAD
 263         CURRENT_THREAD_INFO(r10, r1)
 264         ld      r10,TI_FLAGS(r10)
 265         b       .Lsyscall_dotrace_cont
 266
 267 syscall_enosys:
 268         li      r3,-ENOSYS
 269         b       syscall_exit
 270
 271 syscall_exit_work:
 272 #ifdef CONFIG_PPC_BOOK3S
 273         mtmsrd  r10,1           /* Restore RI */
 274 #endif
 275         /* If TIF_RESTOREALL is set, don't scribble on either r3 or ccr.
 276          If TIF_NOERROR is set, just save r3 as it is. */
 277
 278         andi.   r0,r9,_TIF_RESTOREALL
 279         beq+    0f
 280         REST_NVGPRS(r1)
 281         b       2f
 282 0:      cmpld   r3,r11          /* r10 is -LAST_ERRNO */
 283         blt+    1f
 284         andi.   r0,r9,_TIF_NOERROR
 285         bne-    1f
 286         ld      r5,_CCR(r1)
 287         neg     r3,r3
 288         oris    r5,r5,0x1000    /* Set SO bit in CR */
 289         std     r5,_CCR(r1)
 290 1:      std     r3,GPR3(r1)
 291 2:      andi.   r0,r9,(_TIF_PERSYSCALL_MASK)
 292         beq     4f
 293
 294         /* Clear per-syscall TIF flags if any are set.  */
 295
 296         li      r11,_TIF_PERSYSCALL_MASK
 297         addi    r12,r12,TI_FLAGS
 298 3:      ldarx   r10,0,r12
 299         andc    r10,r10,r11
 300         stdcx.  r10,0,r12
 301         bne-    3b
 302         subi    r12,r12,TI_FLAGS
 303
 304 4:      /* Anything else left to do? */
 305         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP)
 306         beq     .ret_from_except_lite
 307
 308         /* Re-enable interrupts */
 309 #ifdef CONFIG_PPC_BOOK3E
 310         wrteei  1
 311 #else
 312         ld      r10,PACAKMSR(r13)
 313         ori     r10,r10,MSR_EE
 314         mtmsrd  r10,1
 315 #endif /* CONFIG_PPC_BOOK3E */
 316
 317         bl      .save_nvgprs
 318         addi    r3,r1,STACK_FRAME_OVERHEAD
 319         bl      .do_syscall_trace_leave
 320         b       .ret_from_except
 321
 322 /* Save non-volatile GPRs, if not already saved. */
 323 _GLOBAL(save_nvgprs)
 324         ld      r11,_TRAP(r1)
 325         andi.   r0,r11,1
 326         beqlr-
 327         SAVE_NVGPRS(r1)
 328         clrrdi  r0,r11,1
 329         std     r0,_TRAP(r1)
 330         blr
 331
 332
 333 /*
 334  * The sigsuspend and rt_sigsuspend system calls can call do_signal
 335  * and thus put the process into the stopped state where we might
 336  * want to examine its user state with ptrace.  Therefore we need
 337  * to save all the nonvolatile registers (r14 - r31) before calling
 338  * the C code.  Similarly, fork, vfork and clone need the full
 339  * register state on the stack so that it can be copied to the child.
 340  */
 341
 342 _GLOBAL(ppc_fork)
 343         bl      .save_nvgprs
 344         bl      .sys_fork
 345         b       syscall_exit
 346
 347 _GLOBAL(ppc_vfork)
 348         bl      .save_nvgprs
 349         bl      .sys_vfork
 350         b       syscall_exit
 351
 352 _GLOBAL(ppc_clone)
 353         bl      .save_nvgprs
 354         bl      .sys_clone
 355         b       syscall_exit
 356
 357 _GLOBAL(ppc32_swapcontext)
 358         bl      .save_nvgprs
 359         bl      .compat_sys_swapcontext
 360         b       syscall_exit
 361
 362 _GLOBAL(ppc64_swapcontext)
 363         bl      .save_nvgprs
 364         bl      .sys_swapcontext
 365         b       syscall_exit
 366
 367 _GLOBAL(ret_from_fork)
 368         bl      .schedule_tail
 369         REST_NVGPRS(r1)
 370         li      r3,0
 371         b       syscall_exit
 372
 373 _GLOBAL(ret_from_kernel_thread)
 374         bl      .schedule_tail
 375         REST_NVGPRS(r1)
 376         REST_GPR(2,r1)
 377         mtlr    r14
 378         mr      r3,r15
 379         blrl
 380         li      r3,0
 381         b       .do_exit        # no return
 382
 383 _GLOBAL(__ret_from_kernel_execve)
 384         addi    r1,r3,-STACK_FRAME_OVERHEAD
 385         li      r10,1
 386         std     r10,SOFTE(r1)
 387         b       syscall_exit
 388
 389         .section        ".toc","aw"
 390 DSCR_DEFAULT:
 391         .tc dscr_default[TC],dscr_default
 392
 393         .section        ".text"
 394
 395 /*
 396  * This routine switches between two different tasks.  The process
 397  * state of one is saved on its kernel stack.  Then the state
 398  * of the other is restored from its kernel stack.  The memory
 399  * management hardware is updated to the second process's state.
 400  * Finally, we can return to the second process, via ret_from_except.
 401  * On entry, r3 points to the THREAD for the current task, r4
 402  * points to the THREAD for the new task.
 403  *
 404  * Note: there are two ways to get to the "going out" portion
 405  * of this code; either by coming in via the entry (_switch)
 406  * or via "fork" which must set up an environment equivalent
 407  * to the "_switch" path.  If you change this you'll have to change
 408  * the fork code also.
 409  *
 410  * The code which creates the new task context is in 'copy_thread'
 411  * in arch/powerpc/kernel/process.c
 412  */
 413         .align  7
 414 _GLOBAL(_switch)
 415         mflr    r0
 416         std     r0,16(r1)
 417         stdu    r1,-SWITCH_FRAME_SIZE(r1)
 418         /* r3-r13 are caller saved -- Cort */
 419         SAVE_8GPRS(14, r1)
 420         SAVE_10GPRS(22, r1)
 421         mflr    r20             /* Return to switch caller */
 422         mfmsr   r22
 423         li      r0, MSR_FP
 424 #ifdef CONFIG_VSX
 425 BEGIN_FTR_SECTION
 426         oris    r0,r0,MSR_VSX@h /* Disable VSX */
 427 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
 428 #endif /* CONFIG_VSX */
 429 #ifdef CONFIG_ALTIVEC
 430 BEGIN_FTR_SECTION
 431         oris    r0,r0,MSR_VEC@h /* Disable altivec */
 432         mfspr   r24,SPRN_VRSAVE /* save vrsave register value */
 433         std     r24,THREAD_VRSAVE(r3)
 434 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 435 #endif /* CONFIG_ALTIVEC */
 436 #ifdef CONFIG_PPC64
 437 BEGIN_FTR_SECTION
 438         mfspr   r25,SPRN_DSCR
 439         std     r25,THREAD_DSCR(r3)
 440 END_FTR_SECTION_IFSET(CPU_FTR_DSCR)
 441 #endif
 442         and.    r0,r0,r22
 443         beq+    1f
 444         andc    r22,r22,r0
 445         MTMSRD(r22)
 446         isync
 447 1:      std     r20,_NIP(r1)
 448         mfcr    r23
 449         std     r23,_CCR(r1)
 450         std     r1,KSP(r3)      /* Set old stack pointer */
 451
 452 #ifdef CONFIG_SMP
 453         /* We need a sync somewhere here to make sure that if the
 454          * previous task gets rescheduled on another CPU, it sees all
 455          * stores it has performed on this one.
 456          */
 457         sync
 458 #endif /* CONFIG_SMP */
 459
 460         /*
 461          * If we optimise away the clear of the reservation in system
 462          * calls because we know the CPU tracks the address of the
 463          * reservation, then we need to clear it here to cover the
 464          * case that the kernel context switch path has no larx
 465          * instructions.
 466          */
 467 BEGIN_FTR_SECTION
 468         ldarx   r6,0,r1
 469 END_FTR_SECTION_IFSET(CPU_FTR_STCX_CHECKS_ADDRESS)
 470
 471         addi    r6,r4,-THREAD   /* Convert THREAD to 'current' */
 472         std     r6,PACACURRENT(r13)     /* Set new 'current' */
 473
 474         ld      r8,KSP(r4)      /* new stack pointer */
 475 #ifdef CONFIG_PPC_BOOK3S
 476 BEGIN_FTR_SECTION
 477   BEGIN_FTR_SECTION_NESTED(95)
 478         clrrdi  r6,r8,28        /* get its ESID */
 479         clrrdi  r9,r1,28        /* get current sp ESID */
 480   FTR_SECTION_ELSE_NESTED(95)
 481         clrrdi  r6,r8,40        /* get its 1T ESID */
 482         clrrdi  r9,r1,40        /* get current sp 1T ESID */
 483   ALT_MMU_FTR_SECTION_END_NESTED_IFCLR(MMU_FTR_1T_SEGMENT, 95)
 484 FTR_SECTION_ELSE
 485         b       2f
 486 ALT_MMU_FTR_SECTION_END_IFSET(MMU_FTR_SLB)
 487         clrldi. r0,r6,2         /* is new ESID c00000000? */
 488         cmpd    cr1,r6,r9       /* or is new ESID the same as current ESID? */
 489         cror    eq,4*cr1+eq,eq
 490         beq     2f              /* if yes, don't slbie it */
 491
 492         /* Bolt in the new stack SLB entry */
 493         ld      r7,KSP_VSID(r4) /* Get new stack's VSID */
 494         oris    r0,r6,(SLB_ESID_V)@h
 495         ori     r0,r0,(SLB_NUM_BOLTED-1)@l
 496 BEGIN_FTR_SECTION
 497         li      r9,MMU_SEGSIZE_1T       /* insert B field */
 498         oris    r6,r6,(MMU_SEGSIZE_1T << SLBIE_SSIZE_SHIFT)@h
 499         rldimi  r7,r9,SLB_VSID_SSIZE_SHIFT,0
 500 END_MMU_FTR_SECTION_IFSET(MMU_FTR_1T_SEGMENT)
 501
 502         /* Update the last bolted SLB.  No write barriers are needed
 503          * here, provided we only update the current CPU's SLB shadow
 504          * buffer.
 505          */
 506         ld      r9,PACA_SLBSHADOWPTR(r13)
 507         li      r12,0
 508         std     r12,SLBSHADOW_STACKESID(r9) /* Clear ESID */
 509         std     r7,SLBSHADOW_STACKVSID(r9)  /* Save VSID */
 510         std     r0,SLBSHADOW_STACKESID(r9)  /* Save ESID */
 511
 512         /* No need to check for MMU_FTR_NO_SLBIE_B here, since when
 513          * we have 1TB segments, the only CPUs known to have the errata
 514          * only support less than 1TB of system memory and we'll never
 515          * actually hit this code path.
 516          */
 517
 518         slbie   r6
 519         slbie   r6              /* Workaround POWER5 < DD2.1 issue */
 520         slbmte  r7,r0
 521         isync
 522 2:
 523 #endif /* !CONFIG_PPC_BOOK3S */
 524
 525         CURRENT_THREAD_INFO(r7, r8)  /* base of new stack */
 526         /* Note: this uses SWITCH_FRAME_SIZE rather than INT_FRAME_SIZE
 527            because we don't need to leave the 288-byte ABI gap at the
 528            top of the kernel stack. */
 529         addi    r7,r7,THREAD_SIZE-SWITCH_FRAME_SIZE
 530
 531         mr      r1,r8           /* start using new stack pointer */
 532         std     r7,PACAKSAVE(r13)
 533
 534 #ifdef CONFIG_ALTIVEC
 535 BEGIN_FTR_SECTION
 536         ld      r0,THREAD_VRSAVE(r4)
 537         mtspr   SPRN_VRSAVE,r0          /* if G4, restore VRSAVE reg */
 538 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 539 #endif /* CONFIG_ALTIVEC */
 540 #ifdef CONFIG_PPC64
 541 BEGIN_FTR_SECTION
 542         lwz     r6,THREAD_DSCR_INHERIT(r4)
 543         ld      r7,DSCR_DEFAULT@toc(2)
 544         ld      r0,THREAD_DSCR(r4)
 545         cmpwi   r6,0
 546         bne     1f
 547         ld      r0,0(r7)
 548 1:      cmpd    r0,r25
 549         beq     2f
 550         mtspr   SPRN_DSCR,r0
 551 2:
 552 END_FTR_SECTION_IFSET(CPU_FTR_DSCR)
 553 #endif
 554
 555         ld      r6,_CCR(r1)
 556         mtcrf   0xFF,r6
 557
 558         /* r3-r13 are destroyed -- Cort */
 559         REST_8GPRS(14, r1)
 560         REST_10GPRS(22, r1)
 561
 562         /* convert old thread to its task_struct for return value */
 563         addi    r3,r3,-THREAD
 564         ld      r7,_NIP(r1)     /* Return to _switch caller in new task */
 565         mtlr    r7
 566         addi    r1,r1,SWITCH_FRAME_SIZE
 567         blr
 568
 569         .align  7
 570 _GLOBAL(ret_from_except)
 571         ld      r11,_TRAP(r1)
 572         andi.   r0,r11,1
 573         bne     .ret_from_except_lite
 574         REST_NVGPRS(r1)
 575
 576 _GLOBAL(ret_from_except_lite)
 577         /*
 578          * Disable interrupts so that current_thread_info()->flags
 579          * can't change between when we test it and when we return
 580          * from the interrupt.
 581          */
 582 #ifdef CONFIG_PPC_BOOK3E
 583         wrteei  0
 584 #else
 585         ld      r10,PACAKMSR(r13) /* Get kernel MSR without EE */
 586         mtmsrd  r10,1             /* Update machine state */
 587 #endif /* CONFIG_PPC_BOOK3E */
 588
 589         CURRENT_THREAD_INFO(r9, r1)
 590         ld      r3,_MSR(r1)
 591         ld      r4,TI_FLAGS(r9)
 592         andi.   r3,r3,MSR_PR
 593         beq     resume_kernel
 594
 595         /* Check current_thread_info()->flags */
 596         andi.   r0,r4,_TIF_USER_WORK_MASK
 597         beq     restore
 598
 599         andi.   r0,r4,_TIF_NEED_RESCHED
 600         beq     1f
 601         bl      .restore_interrupts
 602         bl      .schedule
 603         b       .ret_from_except_lite
 604
 605 1:      bl      .save_nvgprs
 606         bl      .restore_interrupts
 607         addi    r3,r1,STACK_FRAME_OVERHEAD
 608         bl      .do_notify_resume
 609         b       .ret_from_except
 610
 611 resume_kernel:
 612         /* check current_thread_info, _TIF_EMULATE_STACK_STORE */
 613         CURRENT_THREAD_INFO(r9, r1)
 614         ld      r8,TI_FLAGS(r9)
 615         andis.  r8,r8,_TIF_EMULATE_STACK_STORE@h
 616         beq+    1f
 617
 618         addi    r8,r1,INT_FRAME_SIZE    /* Get the kprobed function entry */
 619
 620         lwz     r3,GPR1(r1)
 621         subi    r3,r3,INT_FRAME_SIZE    /* dst: Allocate a trampoline exception frame */
 622         mr      r4,r1                   /* src:  current exception frame */
 623         mr      r1,r3                   /* Reroute the trampoline frame to r1 */
 624
 625         /* Copy from the original to the trampoline. */
 626         li      r5,INT_FRAME_SIZE/8     /* size: INT_FRAME_SIZE */
 627         li      r6,0                    /* start offset: 0 */
 628         mtctr   r5
 629 2:      ldx     r0,r6,r4
 630         stdx    r0,r6,r3
 631         addi    r6,r6,8
 632         bdnz    2b
 633
 634         /* Do real store operation to complete stwu */
 635         lwz     r5,GPR1(r1)
 636         std     r8,0(r5)
 637
 638         /* Clear _TIF_EMULATE_STACK_STORE flag */
 639         lis     r11,_TIF_EMULATE_STACK_STORE@h
 640         addi    r5,r9,TI_FLAGS
 641         ldarx   r4,0,r5
 642         andc    r4,r4,r11
 643         stdcx.  r4,0,r5
 644         bne-    0b
 645 1:
 646
 647 #ifdef CONFIG_PREEMPT
 648         /* Check if we need to preempt */
 649         andi.   r0,r4,_TIF_NEED_RESCHED
 650         beq+    restore
 651         /* Check that preempt_count() == 0 and interrupts are enabled */
 652         lwz     r8,TI_PREEMPT(r9)
 653         cmpwi   cr1,r8,0
 654         ld      r0,SOFTE(r1)
 655         cmpdi   r0,0
 656         crandc  eq,cr1*4+eq,eq
 657         bne     restore
 658
 659         /*
 660          * Here we are preempting the current task. We want to make
 661          * sure we are soft-disabled first
 662          */
 663         SOFT_DISABLE_INTS(r3,r4)
 664 1:      bl      .preempt_schedule_irq
 665
 666         /* Re-test flags and eventually loop */
 667         CURRENT_THREAD_INFO(r9, r1)
 668         ld      r4,TI_FLAGS(r9)
 669         andi.   r0,r4,_TIF_NEED_RESCHED
 670         bne     1b
 671 #endif /* CONFIG_PREEMPT */
 672
 673         .globl  fast_exc_return_irq
 674 fast_exc_return_irq:
 675 restore:
 676         /*
 677          * This is the main kernel exit path. First we check if we
 678          * are about to re-enable interrupts
 679          */
 680         ld      r5,SOFTE(r1)
 681         lbz     r6,PACASOFTIRQEN(r13)
 682         cmpwi   cr0,r5,0
 683         beq     restore_irq_off
 684
 685         /* We are enabling, were we already enabled ? Yes, just return */
 686         cmpwi   cr0,r6,1
 687         beq     cr0,do_restore
 688
 689         /*
 690          * We are about to soft-enable interrupts (we are hard disabled
 691          * at this point). We check if there's anything that needs to
 692          * be replayed first.
 693          */
 694         lbz     r0,PACAIRQHAPPENED(r13)
 695         cmpwi   cr0,r0,0
 696         bne-    restore_check_irq_replay
 697
 698         /*
 699          * Get here when nothing happened while soft-disabled, just
 700          * soft-enable and move-on. We will hard-enable as a side
 701          * effect of rfi
 702          */
 703 restore_no_replay:
 704         TRACE_ENABLE_INTS
 705         li      r0,1
 706         stb     r0,PACASOFTIRQEN(r13);
 707
 708         /*
 709          * Final return path. BookE is handled in a different file
 710          */
 711 do_restore:
 712 #ifdef CONFIG_PPC_BOOK3E
 713         b       .exception_return_book3e
 714 #else
 715         /*
 716          * Clear the reservation. If we know the CPU tracks the address of
 717          * the reservation then we can potentially save some cycles and use
 718          * a larx. On POWER6 and POWER7 this is significantly faster.
 719          */
 720 BEGIN_FTR_SECTION
 721         stdcx.  r0,0,r1         /* to clear the reservation */
 722 FTR_SECTION_ELSE
 723         ldarx   r4,0,r1
 724 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_STCX_CHECKS_ADDRESS)
 725
 726         /*
 727          * Some code path such as load_up_fpu or altivec return directly
 728          * here. They run entirely hard disabled and do not alter the
 729          * interrupt state. They also don't use lwarx/stwcx. and thus
 730          * are known not to leave dangling reservations.
 731          */
 732         .globl  fast_exception_return
 733 fast_exception_return:
 734         ld      r3,_MSR(r1)
 735         ld      r4,_CTR(r1)
 736         ld      r0,_LINK(r1)
 737         mtctr   r4
 738         mtlr    r0
 739         ld      r4,_XER(r1)
 740         mtspr   SPRN_XER,r4
 741
 742         REST_8GPRS(5, r1)
 743
 744         andi.   r0,r3,MSR_RI
 745         beq-    unrecov_restore
 746
 747         /*
 748          * Clear RI before restoring r13.  If we are returning to
 749          * userspace and we take an exception after restoring r13,
 750          * we end up corrupting the userspace r13 value.
 751          */
 752         ld      r4,PACAKMSR(r13) /* Get kernel MSR without EE */
 753         andc    r4,r4,r0         /* r0 contains MSR_RI here */
 754         mtmsrd  r4,1
 755
 756         /*
 757          * r13 is our per cpu area, only restore it if we are returning to
 758          * userspace the value stored in the stack frame may belong to
 759          * another CPU.
 760          */
 761         andi.   r0,r3,MSR_PR
 762         beq     1f
 763         ACCOUNT_CPU_USER_EXIT(r2, r4)
 764         REST_GPR(13, r1)
 765 1:
 766         mtspr   SPRN_SRR1,r3
 767
 768         ld      r2,_CCR(r1)
 769         mtcrf   0xFF,r2
 770         ld      r2,_NIP(r1)
 771         mtspr   SPRN_SRR0,r2
 772
 773         ld      r0,GPR0(r1)
 774         ld      r2,GPR2(r1)
 775         ld      r3,GPR3(r1)
 776         ld      r4,GPR4(r1)
 777         ld      r1,GPR1(r1)
 778
 779         rfid
 780         b       .       /* prevent speculative execution */
 781
 782 #endif /* CONFIG_PPC_BOOK3E */
 783
 784         /*
 785          * We are returning to a context with interrupts soft disabled.
 786          *
 787          * However, we may also about to hard enable, so we need to
 788          * make sure that in this case, we also clear PACA_IRQ_HARD_DIS
 789          * or that bit can get out of sync and bad things will happen
 790          */
 791 restore_irq_off:
 792         ld      r3,_MSR(r1)
 793         lbz     r7,PACAIRQHAPPENED(r13)
 794         andi.   r0,r3,MSR_EE
 795         beq     1f
 796         rlwinm  r7,r7,0,~PACA_IRQ_HARD_DIS
 797         stb     r7,PACAIRQHAPPENED(r13)
 798 1:      li      r0,0
 799         stb     r0,PACASOFTIRQEN(r13);
 800         TRACE_DISABLE_INTS
 801         b       do_restore
 802
 803         /*
 804          * Something did happen, check if a re-emit is needed
 805          * (this also clears paca->irq_happened)
 806          */
 807 restore_check_irq_replay:
 808         /* XXX: We could implement a fast path here where we check
 809          * for irq_happened being just 0x01, in which case we can
 810          * clear it and return. That means that we would potentially
 811          * miss a decrementer having wrapped all the way around.
 812          *
 813          * Still, this might be useful for things like hash_page
 814          */
 815         bl      .__check_irq_replay
 816         cmpwi   cr0,r3,0
 817         beq     restore_no_replay
 818
 819         /*
 820          * We need to re-emit an interrupt. We do so by re-using our
 821          * existing exception frame. We first change the trap value,
 822          * but we need to ensure we preserve the low nibble of it
 823          */
 824         ld      r4,_TRAP(r1)
 825         clrldi  r4,r4,60
 826         or      r4,r4,r3
 827         std     r4,_TRAP(r1)
 828
 829         /*
 830          * Then find the right handler and call it. Interrupts are
 831          * still soft-disabled and we keep them that way.
 832         */
 833         cmpwi   cr0,r3,0x500
 834         bne     1f
 835         addi    r3,r1,STACK_FRAME_OVERHEAD;
 836         bl      .do_IRQ
 837         b       .ret_from_except
 838 1:      cmpwi   cr0,r3,0x900
 839         bne     1f
 840         addi    r3,r1,STACK_FRAME_OVERHEAD;
 841         bl      .timer_interrupt
 842         b       .ret_from_except
 843 #ifdef CONFIG_PPC_BOOK3E
 844 1:      cmpwi   cr0,r3,0x280
 845         bne     1f
 846         addi    r3,r1,STACK_FRAME_OVERHEAD;
 847         bl      .doorbell_exception
 848         b       .ret_from_except
 849 #endif /* CONFIG_PPC_BOOK3E */
 850 1:      b       .ret_from_except /* What else to do here ? */
 851
 852 unrecov_restore:
 853         addi    r3,r1,STACK_FRAME_OVERHEAD
 854         bl      .unrecoverable_exception
 855         b       unrecov_restore
 856
 857 #ifdef CONFIG_PPC_RTAS
 858 /*
 859  * On CHRP, the Run-Time Abstraction Services (RTAS) have to be
 860  * called with the MMU off.
 861  *
 862  * In addition, we need to be in 32b mode, at least for now.
 863  *
 864  * Note: r3 is an input parameter to rtas, so don't trash it...
 865  */
 866 _GLOBAL(enter_rtas)
 867         mflr    r0
 868         std     r0,16(r1)
 869         stdu    r1,-RTAS_FRAME_SIZE(r1) /* Save SP and create stack space. */
 870
 871         /* Because RTAS is running in 32b mode, it clobbers the high order half
 872          * of all registers that it saves.  We therefore save those registers
 873          * RTAS might touch to the stack.  (r0, r3-r13 are caller saved)
 874          */
 875         SAVE_GPR(2, r1)                 /* Save the TOC */
 876         SAVE_GPR(13, r1)                /* Save paca */
 877         SAVE_8GPRS(14, r1)              /* Save the non-volatiles */
 878         SAVE_10GPRS(22, r1)             /* ditto */
 879
 880         mfcr    r4
 881         std     r4,_CCR(r1)
 882         mfctr   r5
 883         std     r5,_CTR(r1)
 884         mfspr   r6,SPRN_XER
 885         std     r6,_XER(r1)
 886         mfdar   r7
 887         std     r7,_DAR(r1)
 888         mfdsisr r8
 889         std     r8,_DSISR(r1)
 890
 891         /* Temporary workaround to clear CR until RTAS can be modified to
 892          * ignore all bits.
 893          */
 894         li      r0,0
 895         mtcr    r0
 896
 897 #ifdef CONFIG_BUG
 898         /* There is no way it is acceptable to get here with interrupts enabled,
 899          * check it with the asm equivalent of WARN_ON
 900          */
 901         lbz     r0,PACASOFTIRQEN(r13)
 902 1:      tdnei   r0,0
 903         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,BUGFLAG_WARNING
 904 #endif
 905
 906         /* Hard-disable interrupts */
 907         mfmsr   r6
 908         rldicl  r7,r6,48,1
 909         rotldi  r7,r7,16
 910         mtmsrd  r7,1
 911
 912         /* Unfortunately, the stack pointer and the MSR are also clobbered,
 913          * so they are saved in the PACA which allows us to restore
 914          * our original state after RTAS returns.
 915          */
 916         std     r1,PACAR1(r13)
 917         std     r6,PACASAVEDMSR(r13)
 918
 919         /* Setup our real return addr */
 920         LOAD_REG_ADDR(r4,.rtas_return_loc)
 921         clrldi  r4,r4,2                 /* convert to realmode address */
 922         mtlr    r4
 923
 924         li      r0,0
 925         ori     r0,r0,MSR_EE|MSR_SE|MSR_BE|MSR_RI
 926         andc    r0,r6,r0
 927
 928         li      r9,1
 929         rldicr  r9,r9,MSR_SF_LG,(63-MSR_SF_LG)
 930         ori     r9,r9,MSR_IR|MSR_DR|MSR_FE0|MSR_FE1|MSR_FP|MSR_RI
 931         andc    r6,r0,r9
 932         sync                            /* disable interrupts so SRR0/1 */
 933         mtmsrd  r0                      /* don't get trashed */
 934
 935         LOAD_REG_ADDR(r4, rtas)
 936         ld      r5,RTASENTRY(r4)        /* get the rtas->entry value */
 937         ld      r4,RTASBASE(r4)         /* get the rtas->base value */
 938
 939         mtspr   SPRN_SRR0,r5
 940         mtspr   SPRN_SRR1,r6
 941         rfid
 942         b       .       /* prevent speculative execution */
 943
 944 _STATIC(rtas_return_loc)
 945         /* relocation is off at this point */
 946         GET_PACA(r4)
 947         clrldi  r4,r4,2                 /* convert to realmode address */
 948
 949         bcl     20,31,$+4
 950 0:      mflr    r3
 951         ld      r3,(1f-0b)(r3)          /* get &.rtas_restore_regs */
 952
 953         mfmsr   r6
 954         li      r0,MSR_RI
 955         andc    r6,r6,r0
 956         sync
 957         mtmsrd  r6
 958
 959         ld      r1,PACAR1(r4)           /* Restore our SP */
 960         ld      r4,PACASAVEDMSR(r4)     /* Restore our MSR */
 961
 962         mtspr   SPRN_SRR0,r3
 963         mtspr   SPRN_SRR1,r4
 964         rfid
 965         b       .       /* prevent speculative execution */
 966
 967         .align  3
 968 1:      .llong  .rtas_restore_regs
 969
 970 _STATIC(rtas_restore_regs)
 971         /* relocation is on at this point */
 972         REST_GPR(2, r1)                 /* Restore the TOC */
 973         REST_GPR(13, r1)                /* Restore paca */
 974         REST_8GPRS(14, r1)              /* Restore the non-volatiles */
 975         REST_10GPRS(22, r1)             /* ditto */
 976
 977         GET_PACA(r13)
 978
 979         ld      r4,_CCR(r1)
 980         mtcr    r4
 981         ld      r5,_CTR(r1)
 982         mtctr   r5
 983         ld      r6,_XER(r1)
 984         mtspr   SPRN_XER,r6
 985         ld      r7,_DAR(r1)
 986         mtdar   r7
 987         ld      r8,_DSISR(r1)
 988         mtdsisr r8
 989
 990         addi    r1,r1,RTAS_FRAME_SIZE   /* Unstack our frame */
 991         ld      r0,16(r1)               /* get return address */
 992
 993         mtlr    r0
 994         blr                             /* return to caller */
 995
 996 #endif /* CONFIG_PPC_RTAS */
 997
 998 _GLOBAL(enter_prom)
 999         mflr    r0
1000         std     r0,16(r1)
1001         stdu    r1,-PROM_FRAME_SIZE(r1) /* Save SP and create stack space */
1002
1003         /* Because PROM is running in 32b mode, it clobbers the high order half
1004          * of all registers that it saves.  We therefore save those registers
1005          * PROM might touch to the stack.  (r0, r3-r13 are caller saved)
1006          */
1007         SAVE_GPR(2, r1)
1008         SAVE_GPR(13, r1)
1009         SAVE_8GPRS(14, r1)
1010         SAVE_10GPRS(22, r1)
1011         mfcr    r10
1012         mfmsr   r11
1013         std     r10,_CCR(r1)
1014         std     r11,_MSR(r1)
1015
1016         /* Get the PROM entrypoint */
1017         mtlr    r4
1018
1019         /* Switch MSR to 32 bits mode
1020          */
1021 #ifdef CONFIG_PPC_BOOK3E
1022         rlwinm  r11,r11,0,1,31
1023         mtmsr   r11
1024 #else /* CONFIG_PPC_BOOK3E */
1025         mfmsr   r11
1026         li      r12,1
1027         rldicr  r12,r12,MSR_SF_LG,(63-MSR_SF_LG)
1028         andc    r11,r11,r12
1029         li      r12,1
1030         rldicr  r12,r12,MSR_ISF_LG,(63-MSR_ISF_LG)
1031         andc    r11,r11,r12
1032         mtmsrd  r11
1033 #endif /* CONFIG_PPC_BOOK3E */
1034         isync
1035
1036         /* Enter PROM here... */
1037         blrl
1038
1039         /* Just make sure that r1 top 32 bits didn't get
1040          * corrupt by OF
1041          */
1042         rldicl  r1,r1,0,32
1043
1044         /* Restore the MSR (back to 64 bits) */
1045         ld      r0,_MSR(r1)
1046         MTMSRD(r0)
1047         isync
1048
1049         /* Restore other registers */
1050         REST_GPR(2, r1)
1051         REST_GPR(13, r1)
1052         REST_8GPRS(14, r1)
1053         REST_10GPRS(22, r1)
1054         ld      r4,_CCR(r1)
1055         mtcr    r4
1056
1057         addi    r1,r1,PROM_FRAME_SIZE
1058         ld      r0,16(r1)
1059         mtlr    r0
1060         blr
1061
1062 #ifdef CONFIG_FUNCTION_TRACER
1063 #ifdef CONFIG_DYNAMIC_FTRACE
1064 _GLOBAL(mcount)
1065 _GLOBAL(_mcount)
1066         blr
1067
1068 _GLOBAL(ftrace_caller)
1069         /* Taken from output of objdump from lib64/glibc */
1070         mflr    r3
1071         ld      r11, 0(r1)
1072         stdu    r1, -112(r1)
1073         std     r3, 128(r1)
1074         ld      r4, 16(r11)
1075         subi    r3, r3, MCOUNT_INSN_SIZE
1076 .globl ftrace_call
1077 ftrace_call:
1078         bl      ftrace_stub
1079         nop
1080 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1081 .globl ftrace_graph_call
1082 ftrace_graph_call:
1083         b       ftrace_graph_stub
1084 _GLOBAL(ftrace_graph_stub)
1085 #endif
1086         ld      r0, 128(r1)
1087         mtlr    r0
1088         addi    r1, r1, 112
1089 _GLOBAL(ftrace_stub)
1090         blr
1091 #else
1092 _GLOBAL(mcount)
1093         blr
1094
1095 _GLOBAL(_mcount)
1096         /* Taken from output of objdump from lib64/glibc */
1097         mflr    r3
1098         ld      r11, 0(r1)
1099         stdu    r1, -112(r1)
1100         std     r3, 128(r1)
1101         ld      r4, 16(r11)
1102
1103         subi    r3, r3, MCOUNT_INSN_SIZE
1104         LOAD_REG_ADDR(r5,ftrace_trace_function)
1105         ld      r5,0(r5)
1106         ld      r5,0(r5)
1107         mtctr   r5
1108         bctrl
1109         nop
1110
1111
1112 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1113         b       ftrace_graph_caller
1114 #endif
1115         ld      r0, 128(r1)
1116         mtlr    r0
1117         addi    r1, r1, 112
1118 _GLOBAL(ftrace_stub)
1119         blr
1120
1121 #endif /* CONFIG_DYNAMIC_FTRACE */
1122
1123 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1124 _GLOBAL(ftrace_graph_caller)
1125         /* load r4 with local address */
1126         ld      r4, 128(r1)
1127         subi    r4, r4, MCOUNT_INSN_SIZE
1128
1129         /* get the parent address */
1130         ld      r11, 112(r1)
1131         addi    r3, r11, 16
1132
1133         bl      .prepare_ftrace_return
1134         nop
1135
1136         ld      r0, 128(r1)
1137         mtlr    r0
1138         addi    r1, r1, 112
1139         blr
1140
1141 _GLOBAL(return_to_handler)
1142         /* need to save return values */
1143         std     r4,  -24(r1)
1144         std     r3,  -16(r1)
1145         std     r31, -8(r1)
1146         mr      r31, r1
1147         stdu    r1, -112(r1)
1148
1149         bl      .ftrace_return_to_handler
1150         nop
1151
1152         /* return value has real return address */
1153         mtlr    r3
1154
1155         ld      r1, 0(r1)
1156         ld      r4,  -24(r1)
1157         ld      r3,  -16(r1)
1158         ld      r31, -8(r1)
1159
1160         /* Jump back to real return address */
1161         blr
1162
1163 _GLOBAL(mod_return_to_handler)
1164         /* need to save return values */
1165         std     r4,  -32(r1)
1166         std     r3,  -24(r1)
1167         /* save TOC */
1168         std     r2,  -16(r1)
1169         std     r31, -8(r1)
1170         mr      r31, r1
1171         stdu    r1, -112(r1)
1172
1173         /*
1174          * We are in a module using the module's TOC.
1175          * Switch to our TOC to run inside the core kernel.
1176          */
1177         ld      r2, PACATOC(r13)
1178
1179         bl      .ftrace_return_to_handler
1180         nop
1181
1182         /* return value has real return address */
1183         mtlr    r3
1184
1185         ld      r1, 0(r1)
1186         ld      r4,  -32(r1)
1187         ld      r3,  -24(r1)
1188         ld      r2,  -16(r1)
1189         ld      r31, -8(r1)
1190
1191         /* Jump back to real return address */
1192         blr
1193 #endif /* CONFIG_FUNCTION_GRAPH_TRACER */
1194 #endif /* CONFIG_FUNCTION_TRACER */