arch/powerpc/kernel/entry_64.S

   1 /*
   2  *  PowerPC version
   3  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
   4  *  Rewritten by Cort Dougan (cort@cs.nmt.edu) for PReP
   5  *    Copyright (C) 1996 Cort Dougan <cort@cs.nmt.edu>
   6  *  Adapted for Power Macintosh by Paul Mackerras.
   7  *  Low-level exception handlers and MMU support
   8  *  rewritten by Paul Mackerras.
   9  *    Copyright (C) 1996 Paul Mackerras.
  10  *  MPC8xx modifications Copyright (C) 1997 Dan Malek (dmalek@jlc.net).
  11  *
  12  *  This file contains the system call entry code, context switch
  13  *  code, and exception/interrupt return code for PowerPC.
  14  *
  15  *  This program is free software; you can redistribute it and/or
  16  *  modify it under the terms of the GNU General Public License
  17  *  as published by the Free Software Foundation; either version
  18  *  2 of the License, or (at your option) any later version.
  19  */
  20
  21 #include <linux/errno.h>
  22 #include <asm/unistd.h>
  23 #include <asm/processor.h>
  24 #include <asm/page.h>
  25 #include <asm/mmu.h>
  26 #include <asm/thread_info.h>
  27 #include <asm/ppc_asm.h>
  28 #include <asm/asm-offsets.h>
  29 #include <asm/cputable.h>
  30 #include <asm/firmware.h>
  31 #include <asm/bug.h>
  32 #include <asm/ptrace.h>
  33 #include <asm/irqflags.h>
  34 #include <asm/ftrace.h>
  35
  36 /*
  37  * System calls.
  38  */
  39         .section        ".toc","aw"
  40 .SYS_CALL_TABLE:
  41         .tc .sys_call_table[TC],.sys_call_table
  42
  43 /* This value is used to mark exception frames on the stack. */
  44 exception_marker:
  45         .tc     ID_EXC_MARKER[TC],STACK_FRAME_REGS_MARKER
  46
  47         .section        ".text"
  48         .align 7
  49
  50 #undef SHOW_SYSCALLS
  51
  52         .globl system_call_common
  53 system_call_common:
  54         andi.   r10,r12,MSR_PR
  55         mr      r10,r1
  56         addi    r1,r1,-INT_FRAME_SIZE
  57         beq-    1f
  58         ld      r1,PACAKSAVE(r13)
  59 1:      std     r10,0(r1)
  60         std     r11,_NIP(r1)
  61         std     r12,_MSR(r1)
  62         std     r0,GPR0(r1)
  63         std     r10,GPR1(r1)
  64         ACCOUNT_CPU_USER_ENTRY(r10, r11)
  65         /*
  66          * This "crclr so" clears CR0.SO, which is the error indication on
  67          * return from this system call.  There must be no cmp instruction
  68          * between it and the "mfcr r9" below, otherwise if XER.SO is set,
  69          * CR0.SO will get set, causing all system calls to appear to fail.
  70          */
  71         crclr   so
  72         std     r2,GPR2(r1)
  73         std     r3,GPR3(r1)
  74         std     r4,GPR4(r1)
  75         std     r5,GPR5(r1)
  76         std     r6,GPR6(r1)
  77         std     r7,GPR7(r1)
  78         std     r8,GPR8(r1)
  79         li      r11,0
  80         std     r11,GPR9(r1)
  81         std     r11,GPR10(r1)
  82         std     r11,GPR11(r1)
  83         std     r11,GPR12(r1)
  84         std     r9,GPR13(r1)
  85         mfcr    r9
  86         mflr    r10
  87         li      r11,0xc01
  88         std     r9,_CCR(r1)
  89         std     r10,_LINK(r1)
  90         std     r11,_TRAP(r1)
  91         mfxer   r9
  92         mfctr   r10
  93         std     r9,_XER(r1)
  94         std     r10,_CTR(r1)
  95         std     r3,ORIG_GPR3(r1)
  96         ld      r2,PACATOC(r13)
  97         addi    r9,r1,STACK_FRAME_OVERHEAD
  98         ld      r11,exception_marker@toc(r2)
  99         std     r11,-16(r9)             /* "regshere" marker */
 100 #if defined(CONFIG_VIRT_CPU_ACCOUNTING) && defined(CONFIG_PPC_SPLPAR)
 101 BEGIN_FW_FTR_SECTION
 102         beq     33f
 103         /* if from user, see if there are any DTL entries to process */
 104         ld      r10,PACALPPACAPTR(r13)  /* get ptr to VPA */
 105         ld      r11,PACA_DTL_RIDX(r13)  /* get log read index */
 106         ld      r10,LPPACA_DTLIDX(r10)  /* get log write index */
 107         cmpd    cr1,r11,r10
 108         beq+    cr1,33f
 109         bl      .accumulate_stolen_time
 110         REST_GPR(0,r1)
 111         REST_4GPRS(3,r1)
 112         REST_2GPRS(7,r1)
 113         addi    r9,r1,STACK_FRAME_OVERHEAD
 114 33:
 115 END_FW_FTR_SECTION_IFSET(FW_FEATURE_SPLPAR)
 116 #endif /* CONFIG_VIRT_CPU_ACCOUNTING && CONFIG_PPC_SPLPAR */
 117
 118         /*
 119          * A syscall should always be called with interrupts enabled
 120          * so we just unconditionally hard-enable here. When some kind
 121          * of irq tracing is used, we additionally check that condition
 122          * is correct
 123          */
 124 #if defined(CONFIG_TRACE_IRQFLAGS) && defined(CONFIG_BUG)
 125         lbz     r10,PACASOFTIRQEN(r13)
 126         xori    r10,r10,1
 127 1:      tdnei   r10,0
 128         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,BUGFLAG_WARNING
 129 #endif
 130
 131 #ifdef CONFIG_PPC_BOOK3E
 132         wrteei  1
 133 #else
 134         ld      r11,PACAKMSR(r13)
 135         ori     r11,r11,MSR_EE
 136         mtmsrd  r11,1
 137 #endif /* CONFIG_PPC_BOOK3E */
 138
 139         /* We do need to set SOFTE in the stack frame or the return
 140          * from interrupt will be painful
 141          */
 142         li      r10,1
 143         std     r10,SOFTE(r1)
 144
 145 #ifdef SHOW_SYSCALLS
 146         bl      .do_show_syscall
 147         REST_GPR(0,r1)
 148         REST_4GPRS(3,r1)
 149         REST_2GPRS(7,r1)
 150         addi    r9,r1,STACK_FRAME_OVERHEAD
 151 #endif
 152         clrrdi  r11,r1,THREAD_SHIFT
 153         ld      r10,TI_FLAGS(r11)
 154         andi.   r11,r10,_TIF_SYSCALL_T_OR_A
 155         bne-    syscall_dotrace
 156 syscall_dotrace_cont:
 157         cmpldi  0,r0,NR_syscalls
 158         bge-    syscall_enosys
 159
 160 system_call:                    /* label this so stack traces look sane */
 161 /*
 162  * Need to vector to 32 Bit or default sys_call_table here,
 163  * based on caller's run-mode / personality.
 164  */
 165         ld      r11,.SYS_CALL_TABLE@toc(2)
 166         andi.   r10,r10,_TIF_32BIT
 167         beq     15f
 168         addi    r11,r11,8       /* use 32-bit syscall entries */
 169         clrldi  r3,r3,32
 170         clrldi  r4,r4,32
 171         clrldi  r5,r5,32
 172         clrldi  r6,r6,32
 173         clrldi  r7,r7,32
 174         clrldi  r8,r8,32
 175 15:
 176         slwi    r0,r0,4
 177         ldx     r10,r11,r0      /* Fetch system call handler [ptr] */
 178         mtctr   r10
 179         bctrl                   /* Call handler */
 180
 181 syscall_exit:
 182         std     r3,RESULT(r1)
 183 #ifdef SHOW_SYSCALLS
 184         bl      .do_show_syscall_exit
 185         ld      r3,RESULT(r1)
 186 #endif
 187         clrrdi  r12,r1,THREAD_SHIFT
 188
 189         ld      r8,_MSR(r1)
 190 #ifdef CONFIG_PPC_BOOK3S
 191         /* No MSR:RI on BookE */
 192         andi.   r10,r8,MSR_RI
 193         beq-    unrecov_restore
 194 #endif
 195         /*
 196          * Disable interrupts so current_thread_info()->flags can't change,
 197          * and so that we don't get interrupted after loading SRR0/1.
 198          */
 199 #ifdef CONFIG_PPC_BOOK3E
 200         wrteei  0
 201 #else
 202         ld      r10,PACAKMSR(r13)
 203         mtmsrd  r10,1
 204 #endif /* CONFIG_PPC_BOOK3E */
 205
 206         ld      r9,TI_FLAGS(r12)
 207         li      r11,-_LAST_ERRNO
 208         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP|_TIF_USER_WORK_MASK|_TIF_PERSYSCALL_MASK)
 209         bne-    syscall_exit_work
 210         cmpld   r3,r11
 211         ld      r5,_CCR(r1)
 212         bge-    syscall_error
 213 syscall_error_cont:
 214         ld      r7,_NIP(r1)
 215 BEGIN_FTR_SECTION
 216         stdcx.  r0,0,r1                 /* to clear the reservation */
 217 END_FTR_SECTION_IFCLR(CPU_FTR_STCX_CHECKS_ADDRESS)
 218         andi.   r6,r8,MSR_PR
 219         ld      r4,_LINK(r1)
 220         /*
 221          * Clear RI before restoring r13.  If we are returning to
 222          * userspace and we take an exception after restoring r13,
 223          * we end up corrupting the userspace r13 value.
 224          */
 225 #ifdef CONFIG_PPC_BOOK3S
 226         /* No MSR:RI on BookE */
 227         li      r12,MSR_RI
 228         andc    r11,r10,r12
 229         mtmsrd  r11,1                   /* clear MSR.RI */
 230 #endif /* CONFIG_PPC_BOOK3S */
 231
 232         beq-    1f
 233         ACCOUNT_CPU_USER_EXIT(r11, r12)
 234         ld      r13,GPR13(r1)   /* only restore r13 if returning to usermode */
 235 1:      ld      r2,GPR2(r1)
 236         ld      r1,GPR1(r1)
 237         mtlr    r4
 238         mtcr    r5
 239         mtspr   SPRN_SRR0,r7
 240         mtspr   SPRN_SRR1,r8
 241         RFI
 242         b       .       /* prevent speculative execution */
 243
 244 syscall_error:
 245         oris    r5,r5,0x1000    /* Set SO bit in CR */
 246         neg     r3,r3
 247         std     r5,_CCR(r1)
 248         b       syscall_error_cont
 249
 250 /* Traced system call support */
 251 syscall_dotrace:
 252         bl      .save_nvgprs
 253         addi    r3,r1,STACK_FRAME_OVERHEAD
 254         bl      .do_syscall_trace_enter
 255         /*
 256          * Restore argument registers possibly just changed.
 257          * We use the return value of do_syscall_trace_enter
 258          * for the call number to look up in the table (r0).
 259          */
 260         mr      r0,r3
 261         ld      r3,GPR3(r1)
 262         ld      r4,GPR4(r1)
 263         ld      r5,GPR5(r1)
 264         ld      r6,GPR6(r1)
 265         ld      r7,GPR7(r1)
 266         ld      r8,GPR8(r1)
 267         addi    r9,r1,STACK_FRAME_OVERHEAD
 268         clrrdi  r10,r1,THREAD_SHIFT
 269         ld      r10,TI_FLAGS(r10)
 270         b       syscall_dotrace_cont
 271
 272 syscall_enosys:
 273         li      r3,-ENOSYS
 274         b       syscall_exit
 275
 276 syscall_exit_work:
 277         /* If TIF_RESTOREALL is set, don't scribble on either r3 or ccr.
 278          If TIF_NOERROR is set, just save r3 as it is. */
 279
 280         andi.   r0,r9,_TIF_RESTOREALL
 281         beq+    0f
 282         REST_NVGPRS(r1)
 283         b       2f
 284 0:      cmpld   r3,r11          /* r10 is -LAST_ERRNO */
 285         blt+    1f
 286         andi.   r0,r9,_TIF_NOERROR
 287         bne-    1f
 288         ld      r5,_CCR(r1)
 289         neg     r3,r3
 290         oris    r5,r5,0x1000    /* Set SO bit in CR */
 291         std     r5,_CCR(r1)
 292 1:      std     r3,GPR3(r1)
 293 2:      andi.   r0,r9,(_TIF_PERSYSCALL_MASK)
 294         beq     4f
 295
 296         /* Clear per-syscall TIF flags if any are set.  */
 297
 298         li      r11,_TIF_PERSYSCALL_MASK
 299         addi    r12,r12,TI_FLAGS
 300 3:      ldarx   r10,0,r12
 301         andc    r10,r10,r11
 302         stdcx.  r10,0,r12
 303         bne-    3b
 304         subi    r12,r12,TI_FLAGS
 305
 306 4:      /* Anything else left to do? */
 307         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP)
 308         beq     .ret_from_except_lite
 309
 310         /* Re-enable interrupts */
 311 #ifdef CONFIG_PPC_BOOK3E
 312         wrteei  1
 313 #else
 314         ld      r10,PACAKMSR(r13)
 315         ori     r10,r10,MSR_EE
 316         mtmsrd  r10,1
 317 #endif /* CONFIG_PPC_BOOK3E */
 318
 319         bl      .save_nvgprs
 320         addi    r3,r1,STACK_FRAME_OVERHEAD
 321         bl      .do_syscall_trace_leave
 322         b       .ret_from_except
 323
 324 /* Save non-volatile GPRs, if not already saved. */
 325 _GLOBAL(save_nvgprs)
 326         ld      r11,_TRAP(r1)
 327         andi.   r0,r11,1
 328         beqlr-
 329         SAVE_NVGPRS(r1)
 330         clrrdi  r0,r11,1
 331         std     r0,_TRAP(r1)
 332         blr
 333
 334
 335 /*
 336  * The sigsuspend and rt_sigsuspend system calls can call do_signal
 337  * and thus put the process into the stopped state where we might
 338  * want to examine its user state with ptrace.  Therefore we need
 339  * to save all the nonvolatile registers (r14 - r31) before calling
 340  * the C code.  Similarly, fork, vfork and clone need the full
 341  * register state on the stack so that it can be copied to the child.
 342  */
 343
 344 _GLOBAL(ppc_fork)
 345         bl      .save_nvgprs
 346         bl      .sys_fork
 347         b       syscall_exit
 348
 349 _GLOBAL(ppc_vfork)
 350         bl      .save_nvgprs
 351         bl      .sys_vfork
 352         b       syscall_exit
 353
 354 _GLOBAL(ppc_clone)
 355         bl      .save_nvgprs
 356         bl      .sys_clone
 357         b       syscall_exit
 358
 359 _GLOBAL(ppc32_swapcontext)
 360         bl      .save_nvgprs
 361         bl      .compat_sys_swapcontext
 362         b       syscall_exit
 363
 364 _GLOBAL(ppc64_swapcontext)
 365         bl      .save_nvgprs
 366         bl      .sys_swapcontext
 367         b       syscall_exit
 368
 369 _GLOBAL(ret_from_fork)
 370         bl      .schedule_tail
 371         REST_NVGPRS(r1)
 372         li      r3,0
 373         b       syscall_exit
 374
 375 /*
 376  * This routine switches between two different tasks.  The process
 377  * state of one is saved on its kernel stack.  Then the state
 378  * of the other is restored from its kernel stack.  The memory
 379  * management hardware is updated to the second process's state.
 380  * Finally, we can return to the second process, via ret_from_except.
 381  * On entry, r3 points to the THREAD for the current task, r4
 382  * points to the THREAD for the new task.
 383  *
 384  * Note: there are two ways to get to the "going out" portion
 385  * of this code; either by coming in via the entry (_switch)
 386  * or via "fork" which must set up an environment equivalent
 387  * to the "_switch" path.  If you change this you'll have to change
 388  * the fork code also.
 389  *
 390  * The code which creates the new task context is in 'copy_thread'
 391  * in arch/powerpc/kernel/process.c
 392  */
 393         .align  7
 394 _GLOBAL(_switch)
 395         mflr    r0
 396         std     r0,16(r1)
 397         stdu    r1,-SWITCH_FRAME_SIZE(r1)
 398         /* r3-r13 are caller saved -- Cort */
 399         SAVE_8GPRS(14, r1)
 400         SAVE_10GPRS(22, r1)
 401         mflr    r20             /* Return to switch caller */
 402         mfmsr   r22
 403         li      r0, MSR_FP
 404 #ifdef CONFIG_VSX
 405 BEGIN_FTR_SECTION
 406         oris    r0,r0,MSR_VSX@h /* Disable VSX */
 407 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
 408 #endif /* CONFIG_VSX */
 409 #ifdef CONFIG_ALTIVEC
 410 BEGIN_FTR_SECTION
 411         oris    r0,r0,MSR_VEC@h /* Disable altivec */
 412         mfspr   r24,SPRN_VRSAVE /* save vrsave register value */
 413         std     r24,THREAD_VRSAVE(r3)
 414 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 415 #endif /* CONFIG_ALTIVEC */
 416 #ifdef CONFIG_PPC64
 417 BEGIN_FTR_SECTION
 418         mfspr   r25,SPRN_DSCR
 419         std     r25,THREAD_DSCR(r3)
 420 END_FTR_SECTION_IFSET(CPU_FTR_DSCR)
 421 #endif
 422         and.    r0,r0,r22
 423         beq+    1f
 424         andc    r22,r22,r0
 425         MTMSRD(r22)
 426         isync
 427 1:      std     r20,_NIP(r1)
 428         mfcr    r23
 429         std     r23,_CCR(r1)
 430         std     r1,KSP(r3)      /* Set old stack pointer */
 431
 432 #ifdef CONFIG_SMP
 433         /* We need a sync somewhere here to make sure that if the
 434          * previous task gets rescheduled on another CPU, it sees all
 435          * stores it has performed on this one.
 436          */
 437         sync
 438 #endif /* CONFIG_SMP */
 439
 440         /*
 441          * If we optimise away the clear of the reservation in system
 442          * calls because we know the CPU tracks the address of the
 443          * reservation, then we need to clear it here to cover the
 444          * case that the kernel context switch path has no larx
 445          * instructions.
 446          */
 447 BEGIN_FTR_SECTION
 448         ldarx   r6,0,r1
 449 END_FTR_SECTION_IFSET(CPU_FTR_STCX_CHECKS_ADDRESS)
 450
 451         addi    r6,r4,-THREAD   /* Convert THREAD to 'current' */
 452         std     r6,PACACURRENT(r13)     /* Set new 'current' */
 453
 454         ld      r8,KSP(r4)      /* new stack pointer */
 455 #ifdef CONFIG_PPC_BOOK3S
 456 BEGIN_FTR_SECTION
 457   BEGIN_FTR_SECTION_NESTED(95)
 458         clrrdi  r6,r8,28        /* get its ESID */
 459         clrrdi  r9,r1,28        /* get current sp ESID */
 460   FTR_SECTION_ELSE_NESTED(95)
 461         clrrdi  r6,r8,40        /* get its 1T ESID */
 462         clrrdi  r9,r1,40        /* get current sp 1T ESID */
 463   ALT_MMU_FTR_SECTION_END_NESTED_IFCLR(MMU_FTR_1T_SEGMENT, 95)
 464 FTR_SECTION_ELSE
 465         b       2f
 466 ALT_MMU_FTR_SECTION_END_IFSET(MMU_FTR_SLB)
 467         clrldi. r0,r6,2         /* is new ESID c00000000? */
 468         cmpd    cr1,r6,r9       /* or is new ESID the same as current ESID? */
 469         cror    eq,4*cr1+eq,eq
 470         beq     2f              /* if yes, don't slbie it */
 471
 472         /* Bolt in the new stack SLB entry */
 473         ld      r7,KSP_VSID(r4) /* Get new stack's VSID */
 474         oris    r0,r6,(SLB_ESID_V)@h
 475         ori     r0,r0,(SLB_NUM_BOLTED-1)@l
 476 BEGIN_FTR_SECTION
 477         li      r9,MMU_SEGSIZE_1T       /* insert B field */
 478         oris    r6,r6,(MMU_SEGSIZE_1T << SLBIE_SSIZE_SHIFT)@h
 479         rldimi  r7,r9,SLB_VSID_SSIZE_SHIFT,0
 480 END_MMU_FTR_SECTION_IFSET(MMU_FTR_1T_SEGMENT)
 481
 482         /* Update the last bolted SLB.  No write barriers are needed
 483          * here, provided we only update the current CPU's SLB shadow
 484          * buffer.
 485          */
 486         ld      r9,PACA_SLBSHADOWPTR(r13)
 487         li      r12,0
 488         std     r12,SLBSHADOW_STACKESID(r9) /* Clear ESID */
 489         std     r7,SLBSHADOW_STACKVSID(r9)  /* Save VSID */
 490         std     r0,SLBSHADOW_STACKESID(r9)  /* Save ESID */
 491
 492         /* No need to check for MMU_FTR_NO_SLBIE_B here, since when
 493          * we have 1TB segments, the only CPUs known to have the errata
 494          * only support less than 1TB of system memory and we'll never
 495          * actually hit this code path.
 496          */
 497
 498         slbie   r6
 499         slbie   r6              /* Workaround POWER5 < DD2.1 issue */
 500         slbmte  r7,r0
 501         isync
 502 2:
 503 #endif /* !CONFIG_PPC_BOOK3S */
 504
 505         clrrdi  r7,r8,THREAD_SHIFT      /* base of new stack */
 506         /* Note: this uses SWITCH_FRAME_SIZE rather than INT_FRAME_SIZE
 507            because we don't need to leave the 288-byte ABI gap at the
 508            top of the kernel stack. */
 509         addi    r7,r7,THREAD_SIZE-SWITCH_FRAME_SIZE
 510
 511         mr      r1,r8           /* start using new stack pointer */
 512         std     r7,PACAKSAVE(r13)
 513
 514         ld      r6,_CCR(r1)
 515         mtcrf   0xFF,r6
 516
 517 #ifdef CONFIG_ALTIVEC
 518 BEGIN_FTR_SECTION
 519         ld      r0,THREAD_VRSAVE(r4)
 520         mtspr   SPRN_VRSAVE,r0          /* if G4, restore VRSAVE reg */
 521 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 522 #endif /* CONFIG_ALTIVEC */
 523 #ifdef CONFIG_PPC64
 524 BEGIN_FTR_SECTION
 525         ld      r0,THREAD_DSCR(r4)
 526         cmpd    r0,r25
 527         beq     1f
 528         mtspr   SPRN_DSCR,r0
 529 1:
 530 END_FTR_SECTION_IFSET(CPU_FTR_DSCR)
 531 #endif
 532
 533         /* r3-r13 are destroyed -- Cort */
 534         REST_8GPRS(14, r1)
 535         REST_10GPRS(22, r1)
 536
 537         /* convert old thread to its task_struct for return value */
 538         addi    r3,r3,-THREAD
 539         ld      r7,_NIP(r1)     /* Return to _switch caller in new task */
 540         mtlr    r7
 541         addi    r1,r1,SWITCH_FRAME_SIZE
 542         blr
 543
 544         .align  7
 545 _GLOBAL(ret_from_except)
 546         ld      r11,_TRAP(r1)
 547         andi.   r0,r11,1
 548         bne     .ret_from_except_lite
 549         REST_NVGPRS(r1)
 550
 551 _GLOBAL(ret_from_except_lite)
 552         /*
 553          * Disable interrupts so that current_thread_info()->flags
 554          * can't change between when we test it and when we return
 555          * from the interrupt.
 556          */
 557 #ifdef CONFIG_PPC_BOOK3E
 558         wrteei  0
 559 #else
 560         mfmsr   r10             /* Get current interrupt state */
 561         rldicl  r9,r10,48,1     /* clear MSR_EE */
 562         rotldi  r9,r9,16
 563         mtmsrd  r9,1            /* Update machine state */
 564 #endif /* CONFIG_PPC_BOOK3E */
 565
 566 #ifdef CONFIG_PREEMPT
 567         clrrdi  r9,r1,THREAD_SHIFT      /* current_thread_info() */
 568         li      r0,_TIF_NEED_RESCHED    /* bits to check */
 569         ld      r3,_MSR(r1)
 570         ld      r4,TI_FLAGS(r9)
 571         /* Move MSR_PR bit in r3 to _TIF_SIGPENDING position in r0 */
 572         rlwimi  r0,r3,32+TIF_SIGPENDING-MSR_PR_LG,_TIF_SIGPENDING
 573         and.    r0,r4,r0        /* check NEED_RESCHED and maybe SIGPENDING */
 574         bne     do_work
 575
 576 #else /* !CONFIG_PREEMPT */
 577         ld      r3,_MSR(r1)     /* Returning to user mode? */
 578         andi.   r3,r3,MSR_PR
 579         beq     restore         /* if not, just restore regs and return */
 580
 581         /* Check current_thread_info()->flags */
 582         clrrdi  r9,r1,THREAD_SHIFT
 583         ld      r4,TI_FLAGS(r9)
 584         andi.   r0,r4,_TIF_USER_WORK_MASK
 585         bne     do_work
 586 #endif /* !CONFIG_PREEMPT */
 587
 588 restore:
 589         ld      r5,SOFTE(r1)
 590         TRACE_AND_RESTORE_IRQ(r5);
 591
 592         /* extract EE bit and use it to restore paca->hard_enabled */
 593         ld      r3,_MSR(r1)
 594         rldicl  r4,r3,49,63             /* r0 = (r3 >> 15) & 1 */
 595         stb     r4,PACAHARDIRQEN(r13)
 596
 597 #ifdef CONFIG_PPC_BOOK3E
 598         b       .exception_return_book3e
 599 #else
 600         ld      r4,_CTR(r1)
 601         ld      r0,_LINK(r1)
 602         mtctr   r4
 603         mtlr    r0
 604         ld      r4,_XER(r1)
 605         mtspr   SPRN_XER,r4
 606
 607         REST_8GPRS(5, r1)
 608
 609         andi.   r0,r3,MSR_RI
 610         beq-    unrecov_restore
 611
 612         /*
 613          * Clear the reservation. If we know the CPU tracks the address of
 614          * the reservation then we can potentially save some cycles and use
 615          * a larx. On POWER6 and POWER7 this is significantly faster.
 616          */
 617 BEGIN_FTR_SECTION
 618         stdcx.  r0,0,r1         /* to clear the reservation */
 619 FTR_SECTION_ELSE
 620         ldarx   r4,0,r1
 621 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_STCX_CHECKS_ADDRESS)
 622
 623         /*
 624          * Clear RI before restoring r13.  If we are returning to
 625          * userspace and we take an exception after restoring r13,
 626          * we end up corrupting the userspace r13 value.
 627          */
 628         mfmsr   r4
 629         andc    r4,r4,r0        /* r0 contains MSR_RI here */
 630         mtmsrd  r4,1
 631
 632         /*
 633          * r13 is our per cpu area, only restore it if we are returning to
 634          * userspace
 635          */
 636         andi.   r0,r3,MSR_PR
 637         beq     1f
 638         ACCOUNT_CPU_USER_EXIT(r2, r4)
 639         REST_GPR(13, r1)
 640 1:
 641         mtspr   SPRN_SRR1,r3
 642
 643         ld      r2,_CCR(r1)
 644         mtcrf   0xFF,r2
 645         ld      r2,_NIP(r1)
 646         mtspr   SPRN_SRR0,r2
 647
 648         ld      r0,GPR0(r1)
 649         ld      r2,GPR2(r1)
 650         ld      r3,GPR3(r1)
 651         ld      r4,GPR4(r1)
 652         ld      r1,GPR1(r1)
 653
 654         rfid
 655         b       .       /* prevent speculative execution */
 656
 657 #endif /* CONFIG_PPC_BOOK3E */
 658
 659 do_work:
 660 #ifdef CONFIG_PREEMPT
 661         andi.   r0,r3,MSR_PR    /* Returning to user mode? */
 662         bne     user_work
 663         /* Check that preempt_count() == 0 and interrupts are enabled */
 664         lwz     r8,TI_PREEMPT(r9)
 665         cmpwi   cr1,r8,0
 666         ld      r0,SOFTE(r1)
 667         cmpdi   r0,0
 668         crandc  eq,cr1*4+eq,eq
 669         bne     restore
 670
 671         /* Here we are preempting the current task.
 672          *
 673          * Ensure interrupts are soft-disabled. We also properly mark
 674          * the PACA to reflect the fact that they are hard-disabled
 675          * and trace the change
 676          */
 677         li      r0,0
 678         stb     r0,PACASOFTIRQEN(r13)
 679         stb     r0,PACAHARDIRQEN(r13)
 680         TRACE_DISABLE_INTS
 681
 682         /* Call the scheduler with soft IRQs off */
 683 1:      bl      .preempt_schedule_irq
 684
 685         /* Hard-disable interrupts again (and update PACA) */
 686 #ifdef CONFIG_PPC_BOOK3E
 687         wrteei  0
 688 #else
 689         mfmsr   r10
 690         rldicl  r10,r10,48,1
 691         rotldi  r10,r10,16
 692         mtmsrd  r10,1
 693 #endif /* CONFIG_PPC_BOOK3E */
 694         li      r0,0
 695         stb     r0,PACAHARDIRQEN(r13)
 696
 697         /* Re-test flags and eventually loop */
 698         clrrdi  r9,r1,THREAD_SHIFT
 699         ld      r4,TI_FLAGS(r9)
 700         andi.   r0,r4,_TIF_NEED_RESCHED
 701         bne     1b
 702         b       restore
 703
 704 user_work:
 705 #endif /* CONFIG_PREEMPT */
 706
 707         /* Enable interrupts */
 708 #ifdef CONFIG_PPC_BOOK3E
 709         wrteei  1
 710 #else
 711         ori     r10,r10,MSR_EE
 712         mtmsrd  r10,1
 713 #endif /* CONFIG_PPC_BOOK3E */
 714
 715         andi.   r0,r4,_TIF_NEED_RESCHED
 716         beq     1f
 717         li      r5,1
 718         TRACE_AND_RESTORE_IRQ(r5);
 719         bl      .schedule
 720         b       .ret_from_except_lite
 721
 722 1:      bl      .save_nvgprs
 723         li      r5,1
 724         TRACE_AND_RESTORE_IRQ(r5);
 725         addi    r3,r1,STACK_FRAME_OVERHEAD
 726         bl      .do_notify_resume
 727         b       .ret_from_except
 728
 729 unrecov_restore:
 730         addi    r3,r1,STACK_FRAME_OVERHEAD
 731         bl      .unrecoverable_exception
 732         b       unrecov_restore
 733
 734 #ifdef CONFIG_PPC_RTAS
 735 /*
 736  * On CHRP, the Run-Time Abstraction Services (RTAS) have to be
 737  * called with the MMU off.
 738  *
 739  * In addition, we need to be in 32b mode, at least for now.
 740  *
 741  * Note: r3 is an input parameter to rtas, so don't trash it...
 742  */
 743 _GLOBAL(enter_rtas)
 744         mflr    r0
 745         std     r0,16(r1)
 746         stdu    r1,-RTAS_FRAME_SIZE(r1) /* Save SP and create stack space. */
 747
 748         /* Because RTAS is running in 32b mode, it clobbers the high order half
 749          * of all registers that it saves.  We therefore save those registers
 750          * RTAS might touch to the stack.  (r0, r3-r13 are caller saved)
 751          */
 752         SAVE_GPR(2, r1)                 /* Save the TOC */
 753         SAVE_GPR(13, r1)                /* Save paca */
 754         SAVE_8GPRS(14, r1)              /* Save the non-volatiles */
 755         SAVE_10GPRS(22, r1)             /* ditto */
 756
 757         mfcr    r4
 758         std     r4,_CCR(r1)
 759         mfctr   r5
 760         std     r5,_CTR(r1)
 761         mfspr   r6,SPRN_XER
 762         std     r6,_XER(r1)
 763         mfdar   r7
 764         std     r7,_DAR(r1)
 765         mfdsisr r8
 766         std     r8,_DSISR(r1)
 767
 768         /* Temporary workaround to clear CR until RTAS can be modified to
 769          * ignore all bits.
 770          */
 771         li      r0,0
 772         mtcr    r0
 773
 774 #ifdef CONFIG_BUG
 775         /* There is no way it is acceptable to get here with interrupts enabled,
 776          * check it with the asm equivalent of WARN_ON
 777          */
 778         lbz     r0,PACASOFTIRQEN(r13)
 779 1:      tdnei   r0,0
 780         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,BUGFLAG_WARNING
 781 #endif
 782
 783         /* Hard-disable interrupts */
 784         mfmsr   r6
 785         rldicl  r7,r6,48,1
 786         rotldi  r7,r7,16
 787         mtmsrd  r7,1
 788
 789         /* Unfortunately, the stack pointer and the MSR are also clobbered,
 790          * so they are saved in the PACA which allows us to restore
 791          * our original state after RTAS returns.
 792          */
 793         std     r1,PACAR1(r13)
 794         std     r6,PACASAVEDMSR(r13)
 795
 796         /* Setup our real return addr */
 797         LOAD_REG_ADDR(r4,.rtas_return_loc)
 798         clrldi  r4,r4,2                 /* convert to realmode address */
 799         mtlr    r4
 800
 801         li      r0,0
 802         ori     r0,r0,MSR_EE|MSR_SE|MSR_BE|MSR_RI
 803         andc    r0,r6,r0
 804
 805         li      r9,1
 806         rldicr  r9,r9,MSR_SF_LG,(63-MSR_SF_LG)
 807         ori     r9,r9,MSR_IR|MSR_DR|MSR_FE0|MSR_FE1|MSR_FP|MSR_RI
 808         andc    r6,r0,r9
 809         sync                            /* disable interrupts so SRR0/1 */
 810         mtmsrd  r0                      /* don't get trashed */
 811
 812         LOAD_REG_ADDR(r4, rtas)
 813         ld      r5,RTASENTRY(r4)        /* get the rtas->entry value */
 814         ld      r4,RTASBASE(r4)         /* get the rtas->base value */
 815
 816         mtspr   SPRN_SRR0,r5
 817         mtspr   SPRN_SRR1,r6
 818         rfid
 819         b       .       /* prevent speculative execution */
 820
 821 _STATIC(rtas_return_loc)
 822         /* relocation is off at this point */
 823         GET_PACA(r4)
 824         clrldi  r4,r4,2                 /* convert to realmode address */
 825
 826         bcl     20,31,$+4
 827 0:      mflr    r3
 828         ld      r3,(1f-0b)(r3)          /* get &.rtas_restore_regs */
 829
 830         mfmsr   r6
 831         li      r0,MSR_RI
 832         andc    r6,r6,r0
 833         sync
 834         mtmsrd  r6
 835
 836         ld      r1,PACAR1(r4)           /* Restore our SP */
 837         ld      r4,PACASAVEDMSR(r4)     /* Restore our MSR */
 838
 839         mtspr   SPRN_SRR0,r3
 840         mtspr   SPRN_SRR1,r4
 841         rfid
 842         b       .       /* prevent speculative execution */
 843
 844         .align  3
 845 1:      .llong  .rtas_restore_regs
 846
 847 _STATIC(rtas_restore_regs)
 848         /* relocation is on at this point */
 849         REST_GPR(2, r1)                 /* Restore the TOC */
 850         REST_GPR(13, r1)                /* Restore paca */
 851         REST_8GPRS(14, r1)              /* Restore the non-volatiles */
 852         REST_10GPRS(22, r1)             /* ditto */
 853
 854         GET_PACA(r13)
 855
 856         ld      r4,_CCR(r1)
 857         mtcr    r4
 858         ld      r5,_CTR(r1)
 859         mtctr   r5
 860         ld      r6,_XER(r1)
 861         mtspr   SPRN_XER,r6
 862         ld      r7,_DAR(r1)
 863         mtdar   r7
 864         ld      r8,_DSISR(r1)
 865         mtdsisr r8
 866
 867         addi    r1,r1,RTAS_FRAME_SIZE   /* Unstack our frame */
 868         ld      r0,16(r1)               /* get return address */
 869
 870         mtlr    r0
 871         blr                             /* return to caller */
 872
 873 #endif /* CONFIG_PPC_RTAS */
 874
 875 _GLOBAL(enter_prom)
 876         mflr    r0
 877         std     r0,16(r1)
 878         stdu    r1,-PROM_FRAME_SIZE(r1) /* Save SP and create stack space */
 879
 880         /* Because PROM is running in 32b mode, it clobbers the high order half
 881          * of all registers that it saves.  We therefore save those registers
 882          * PROM might touch to the stack.  (r0, r3-r13 are caller saved)
 883          */
 884         SAVE_GPR(2, r1)
 885         SAVE_GPR(13, r1)
 886         SAVE_8GPRS(14, r1)
 887         SAVE_10GPRS(22, r1)
 888         mfcr    r10
 889         mfmsr   r11
 890         std     r10,_CCR(r1)
 891         std     r11,_MSR(r1)
 892
 893         /* Get the PROM entrypoint */
 894         mtlr    r4
 895
 896         /* Switch MSR to 32 bits mode
 897          */
 898 #ifdef CONFIG_PPC_BOOK3E
 899         rlwinm  r11,r11,0,1,31
 900         mtmsr   r11
 901 #else /* CONFIG_PPC_BOOK3E */
 902         mfmsr   r11
 903         li      r12,1
 904         rldicr  r12,r12,MSR_SF_LG,(63-MSR_SF_LG)
 905         andc    r11,r11,r12
 906         li      r12,1
 907         rldicr  r12,r12,MSR_ISF_LG,(63-MSR_ISF_LG)
 908         andc    r11,r11,r12
 909         mtmsrd  r11
 910 #endif /* CONFIG_PPC_BOOK3E */
 911         isync
 912
 913         /* Enter PROM here... */
 914         blrl
 915
 916         /* Just make sure that r1 top 32 bits didn't get
 917          * corrupt by OF
 918          */
 919         rldicl  r1,r1,0,32
 920
 921         /* Restore the MSR (back to 64 bits) */
 922         ld      r0,_MSR(r1)
 923         MTMSRD(r0)
 924         isync
 925
 926         /* Restore other registers */
 927         REST_GPR(2, r1)
 928         REST_GPR(13, r1)
 929         REST_8GPRS(14, r1)
 930         REST_10GPRS(22, r1)
 931         ld      r4,_CCR(r1)
 932         mtcr    r4
 933
 934         addi    r1,r1,PROM_FRAME_SIZE
 935         ld      r0,16(r1)
 936         mtlr    r0
 937         blr
 938
 939 #ifdef CONFIG_FUNCTION_TRACER
 940 #ifdef CONFIG_DYNAMIC_FTRACE
 941 _GLOBAL(mcount)
 942 _GLOBAL(_mcount)
 943         blr
 944
 945 _GLOBAL(ftrace_caller)
 946         /* Taken from output of objdump from lib64/glibc */
 947         mflr    r3
 948         ld      r11, 0(r1)
 949         stdu    r1, -112(r1)
 950         std     r3, 128(r1)
 951         ld      r4, 16(r11)
 952         subi    r3, r3, MCOUNT_INSN_SIZE
 953 .globl ftrace_call
 954 ftrace_call:
 955         bl      ftrace_stub
 956         nop
 957 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 958 .globl ftrace_graph_call
 959 ftrace_graph_call:
 960         b       ftrace_graph_stub
 961 _GLOBAL(ftrace_graph_stub)
 962 #endif
 963         ld      r0, 128(r1)
 964         mtlr    r0
 965         addi    r1, r1, 112
 966 _GLOBAL(ftrace_stub)
 967         blr
 968 #else
 969 _GLOBAL(mcount)
 970         blr
 971
 972 _GLOBAL(_mcount)
 973         /* Taken from output of objdump from lib64/glibc */
 974         mflr    r3
 975         ld      r11, 0(r1)
 976         stdu    r1, -112(r1)
 977         std     r3, 128(r1)
 978         ld      r4, 16(r11)
 979
 980         subi    r3, r3, MCOUNT_INSN_SIZE
 981         LOAD_REG_ADDR(r5,ftrace_trace_function)
 982         ld      r5,0(r5)
 983         ld      r5,0(r5)
 984         mtctr   r5
 985         bctrl
 986         nop
 987
 988
 989 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 990         b       ftrace_graph_caller
 991 #endif
 992         ld      r0, 128(r1)
 993         mtlr    r0
 994         addi    r1, r1, 112
 995 _GLOBAL(ftrace_stub)
 996         blr
 997
 998 #endif /* CONFIG_DYNAMIC_FTRACE */
 999
1000 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1001 _GLOBAL(ftrace_graph_caller)
1002         /* load r4 with local address */
1003         ld      r4, 128(r1)
1004         subi    r4, r4, MCOUNT_INSN_SIZE
1005
1006         /* get the parent address */
1007         ld      r11, 112(r1)
1008         addi    r3, r11, 16
1009
1010         bl      .prepare_ftrace_return
1011         nop
1012
1013         ld      r0, 128(r1)
1014         mtlr    r0
1015         addi    r1, r1, 112
1016         blr
1017
1018 _GLOBAL(return_to_handler)
1019         /* need to save return values */
1020         std     r4,  -24(r1)
1021         std     r3,  -16(r1)
1022         std     r31, -8(r1)
1023         mr      r31, r1
1024         stdu    r1, -112(r1)
1025
1026         bl      .ftrace_return_to_handler
1027         nop
1028
1029         /* return value has real return address */
1030         mtlr    r3
1031
1032         ld      r1, 0(r1)
1033         ld      r4,  -24(r1)
1034         ld      r3,  -16(r1)
1035         ld      r31, -8(r1)
1036
1037         /* Jump back to real return address */
1038         blr
1039
1040 _GLOBAL(mod_return_to_handler)
1041         /* need to save return values */
1042         std     r4,  -32(r1)
1043         std     r3,  -24(r1)
1044         /* save TOC */
1045         std     r2,  -16(r1)
1046         std     r31, -8(r1)
1047         mr      r31, r1
1048         stdu    r1, -112(r1)
1049
1050         /*
1051          * We are in a module using the module's TOC.
1052          * Switch to our TOC to run inside the core kernel.
1053          */
1054         ld      r2, PACATOC(r13)
1055
1056         bl      .ftrace_return_to_handler
1057         nop
1058
1059         /* return value has real return address */
1060         mtlr    r3
1061
1062         ld      r1, 0(r1)
1063         ld      r4,  -32(r1)
1064         ld      r3,  -24(r1)
1065         ld      r2,  -16(r1)
1066         ld      r31, -8(r1)
1067
1068         /* Jump back to real return address */
1069         blr
1070 #endif /* CONFIG_FUNCTION_GRAPH_TRACER */
1071 #endif /* CONFIG_FUNCTION_TRACER */