arch/powerpc/kernel/entry_64.S

   1 /*
   2  *  PowerPC version
   3  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
   4  *  Rewritten by Cort Dougan (cort@cs.nmt.edu) for PReP
   5  *    Copyright (C) 1996 Cort Dougan <cort@cs.nmt.edu>
   6  *  Adapted for Power Macintosh by Paul Mackerras.
   7  *  Low-level exception handlers and MMU support
   8  *  rewritten by Paul Mackerras.
   9  *    Copyright (C) 1996 Paul Mackerras.
  10  *  MPC8xx modifications Copyright (C) 1997 Dan Malek (dmalek@jlc.net).
  11  *
  12  *  This file contains the system call entry code, context switch
  13  *  code, and exception/interrupt return code for PowerPC.
  14  *
  15  *  This program is free software; you can redistribute it and/or
  16  *  modify it under the terms of the GNU General Public License
  17  *  as published by the Free Software Foundation; either version
  18  *  2 of the License, or (at your option) any later version.
  19  */
  20
  21 #include <linux/errno.h>
  22 #include <asm/unistd.h>
  23 #include <asm/processor.h>
  24 #include <asm/page.h>
  25 #include <asm/mmu.h>
  26 #include <asm/thread_info.h>
  27 #include <asm/ppc_asm.h>
  28 #include <asm/asm-offsets.h>
  29 #include <asm/cputable.h>
  30 #include <asm/firmware.h>
  31 #include <asm/bug.h>
  32 #include <asm/ptrace.h>
  33 #include <asm/irqflags.h>
  34 #include <asm/ftrace.h>
  35 #include <asm/hw_irq.h>
  36
  37 /*
  38  * System calls.
  39  */
  40         .section        ".toc","aw"
  41 .SYS_CALL_TABLE:
  42         .tc .sys_call_table[TC],.sys_call_table
  43
  44 /* This value is used to mark exception frames on the stack. */
  45 exception_marker:
  46         .tc     ID_EXC_MARKER[TC],STACK_FRAME_REGS_MARKER
  47
  48         .section        ".text"
  49         .align 7
  50
  51 #undef SHOW_SYSCALLS
  52
  53         .globl system_call_common
  54 system_call_common:
  55         andi.   r10,r12,MSR_PR
  56         mr      r10,r1
  57         addi    r1,r1,-INT_FRAME_SIZE
  58         beq-    1f
  59         ld      r1,PACAKSAVE(r13)
  60 1:      std     r10,0(r1)
  61         std     r11,_NIP(r1)
  62         std     r12,_MSR(r1)
  63         std     r0,GPR0(r1)
  64         std     r10,GPR1(r1)
  65         ACCOUNT_CPU_USER_ENTRY(r10, r11)
  66         std     r2,GPR2(r1)
  67         std     r3,GPR3(r1)
  68         mfcr    r2
  69         std     r4,GPR4(r1)
  70         std     r5,GPR5(r1)
  71         std     r6,GPR6(r1)
  72         std     r7,GPR7(r1)
  73         std     r8,GPR8(r1)
  74         li      r11,0
  75         std     r11,GPR9(r1)
  76         std     r11,GPR10(r1)
  77         std     r11,GPR11(r1)
  78         std     r11,GPR12(r1)
  79         std     r11,_XER(r1)
  80         std     r11,_CTR(r1)
  81         std     r9,GPR13(r1)
  82         mflr    r10
  83         /*
  84          * This clears CR0.SO (bit 28), which is the error indication on
  85          * return from this system call.
  86          */
  87         rldimi  r2,r11,28,(63-28)
  88         li      r11,0xc01
  89         std     r10,_LINK(r1)
  90         std     r11,_TRAP(r1)
  91         std     r3,ORIG_GPR3(r1)
  92         std     r2,_CCR(r1)
  93         ld      r2,PACATOC(r13)
  94         addi    r9,r1,STACK_FRAME_OVERHEAD
  95         ld      r11,exception_marker@toc(r2)
  96         std     r11,-16(r9)             /* "regshere" marker */
  97 #if defined(CONFIG_VIRT_CPU_ACCOUNTING) && defined(CONFIG_PPC_SPLPAR)
  98 BEGIN_FW_FTR_SECTION
  99         beq     33f
 100         /* if from user, see if there are any DTL entries to process */
 101         ld      r10,PACALPPACAPTR(r13)  /* get ptr to VPA */
 102         ld      r11,PACA_DTL_RIDX(r13)  /* get log read index */
 103         ld      r10,LPPACA_DTLIDX(r10)  /* get log write index */
 104         cmpd    cr1,r11,r10
 105         beq+    cr1,33f
 106         bl      .accumulate_stolen_time
 107         REST_GPR(0,r1)
 108         REST_4GPRS(3,r1)
 109         REST_2GPRS(7,r1)
 110         addi    r9,r1,STACK_FRAME_OVERHEAD
 111 33:
 112 END_FW_FTR_SECTION_IFSET(FW_FEATURE_SPLPAR)
 113 #endif /* CONFIG_VIRT_CPU_ACCOUNTING && CONFIG_PPC_SPLPAR */
 114
 115         /*
 116          * A syscall should always be called with interrupts enabled
 117          * so we just unconditionally hard-enable here. When some kind
 118          * of irq tracing is used, we additionally check that condition
 119          * is correct
 120          */
 121 #if defined(CONFIG_TRACE_IRQFLAGS) && defined(CONFIG_BUG)
 122         lbz     r10,PACASOFTIRQEN(r13)
 123         xori    r10,r10,1
 124 1:      tdnei   r10,0
 125         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,BUGFLAG_WARNING
 126 #endif
 127
 128 #ifdef CONFIG_PPC_BOOK3E
 129         wrteei  1
 130 #else
 131         ld      r11,PACAKMSR(r13)
 132         ori     r11,r11,MSR_EE
 133         mtmsrd  r11,1
 134 #endif /* CONFIG_PPC_BOOK3E */
 135
 136         /* We do need to set SOFTE in the stack frame or the return
 137          * from interrupt will be painful
 138          */
 139         li      r10,1
 140         std     r10,SOFTE(r1)
 141
 142 #ifdef SHOW_SYSCALLS
 143         bl      .do_show_syscall
 144         REST_GPR(0,r1)
 145         REST_4GPRS(3,r1)
 146         REST_2GPRS(7,r1)
 147         addi    r9,r1,STACK_FRAME_OVERHEAD
 148 #endif
 149         CURRENT_THREAD_INFO(r11, r1)
 150         ld      r10,TI_FLAGS(r11)
 151         andi.   r11,r10,_TIF_SYSCALL_T_OR_A
 152         bne-    syscall_dotrace
 153 .Lsyscall_dotrace_cont:
 154         cmpldi  0,r0,NR_syscalls
 155         bge-    syscall_enosys
 156
 157 system_call:                    /* label this so stack traces look sane */
 158 /*
 159  * Need to vector to 32 Bit or default sys_call_table here,
 160  * based on caller's run-mode / personality.
 161  */
 162         ld      r11,.SYS_CALL_TABLE@toc(2)
 163         andi.   r10,r10,_TIF_32BIT
 164         beq     15f
 165         addi    r11,r11,8       /* use 32-bit syscall entries */
 166         clrldi  r3,r3,32
 167         clrldi  r4,r4,32
 168         clrldi  r5,r5,32
 169         clrldi  r6,r6,32
 170         clrldi  r7,r7,32
 171         clrldi  r8,r8,32
 172 15:
 173         slwi    r0,r0,4
 174         ldx     r10,r11,r0      /* Fetch system call handler [ptr] */
 175         mtctr   r10
 176         bctrl                   /* Call handler */
 177
 178 syscall_exit:
 179         std     r3,RESULT(r1)
 180 #ifdef SHOW_SYSCALLS
 181         bl      .do_show_syscall_exit
 182         ld      r3,RESULT(r1)
 183 #endif
 184         CURRENT_THREAD_INFO(r12, r1)
 185
 186         ld      r8,_MSR(r1)
 187 #ifdef CONFIG_PPC_BOOK3S
 188         /* No MSR:RI on BookE */
 189         andi.   r10,r8,MSR_RI
 190         beq-    unrecov_restore
 191 #endif
 192         /*
 193          * Disable interrupts so current_thread_info()->flags can't change,
 194          * and so that we don't get interrupted after loading SRR0/1.
 195          */
 196 #ifdef CONFIG_PPC_BOOK3E
 197         wrteei  0
 198 #else
 199         ld      r10,PACAKMSR(r13)
 200         /*
 201          * For performance reasons we clear RI the same time that we
 202          * clear EE. We only need to clear RI just before we restore r13
 203          * below, but batching it with EE saves us one expensive mtmsrd call.
 204          * We have to be careful to restore RI if we branch anywhere from
 205          * here (eg syscall_exit_work).
 206          */
 207         li      r9,MSR_RI
 208         andc    r11,r10,r9
 209         mtmsrd  r11,1
 210 #endif /* CONFIG_PPC_BOOK3E */
 211
 212         ld      r9,TI_FLAGS(r12)
 213         li      r11,-_LAST_ERRNO
 214         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP|_TIF_USER_WORK_MASK|_TIF_PERSYSCALL_MASK)
 215         bne-    syscall_exit_work
 216         cmpld   r3,r11
 217         ld      r5,_CCR(r1)
 218         bge-    syscall_error
 219 .Lsyscall_error_cont:
 220         ld      r7,_NIP(r1)
 221 BEGIN_FTR_SECTION
 222         stdcx.  r0,0,r1                 /* to clear the reservation */
 223 END_FTR_SECTION_IFCLR(CPU_FTR_STCX_CHECKS_ADDRESS)
 224         andi.   r6,r8,MSR_PR
 225         ld      r4,_LINK(r1)
 226
 227         beq-    1f
 228         ACCOUNT_CPU_USER_EXIT(r11, r12)
 229         ld      r13,GPR13(r1)   /* only restore r13 if returning to usermode */
 230 1:      ld      r2,GPR2(r1)
 231         ld      r1,GPR1(r1)
 232         mtlr    r4
 233         mtcr    r5
 234         mtspr   SPRN_SRR0,r7
 235         mtspr   SPRN_SRR1,r8
 236         RFI
 237         b       .       /* prevent speculative execution */
 238
 239 syscall_error:
 240         oris    r5,r5,0x1000    /* Set SO bit in CR */
 241         neg     r3,r3
 242         std     r5,_CCR(r1)
 243         b       .Lsyscall_error_cont
 244
 245 /* Traced system call support */
 246 syscall_dotrace:
 247         bl      .save_nvgprs
 248         addi    r3,r1,STACK_FRAME_OVERHEAD
 249         bl      .do_syscall_trace_enter
 250         /*
 251          * Restore argument registers possibly just changed.
 252          * We use the return value of do_syscall_trace_enter
 253          * for the call number to look up in the table (r0).
 254          */
 255         mr      r0,r3
 256         ld      r3,GPR3(r1)
 257         ld      r4,GPR4(r1)
 258         ld      r5,GPR5(r1)
 259         ld      r6,GPR6(r1)
 260         ld      r7,GPR7(r1)
 261         ld      r8,GPR8(r1)
 262         addi    r9,r1,STACK_FRAME_OVERHEAD
 263         CURRENT_THREAD_INFO(r10, r1)
 264         ld      r10,TI_FLAGS(r10)
 265         b       .Lsyscall_dotrace_cont
 266
 267 syscall_enosys:
 268         li      r3,-ENOSYS
 269         b       syscall_exit
 270
 271 syscall_exit_work:
 272 #ifdef CONFIG_PPC_BOOK3S
 273         mtmsrd  r10,1           /* Restore RI */
 274 #endif
 275         /* If TIF_RESTOREALL is set, don't scribble on either r3 or ccr.
 276          If TIF_NOERROR is set, just save r3 as it is. */
 277
 278         andi.   r0,r9,_TIF_RESTOREALL
 279         beq+    0f
 280         REST_NVGPRS(r1)
 281         b       2f
 282 0:      cmpld   r3,r11          /* r10 is -LAST_ERRNO */
 283         blt+    1f
 284         andi.   r0,r9,_TIF_NOERROR
 285         bne-    1f
 286         ld      r5,_CCR(r1)
 287         neg     r3,r3
 288         oris    r5,r5,0x1000    /* Set SO bit in CR */
 289         std     r5,_CCR(r1)
 290 1:      std     r3,GPR3(r1)
 291 2:      andi.   r0,r9,(_TIF_PERSYSCALL_MASK)
 292         beq     4f
 293
 294         /* Clear per-syscall TIF flags if any are set.  */
 295
 296         li      r11,_TIF_PERSYSCALL_MASK
 297         addi    r12,r12,TI_FLAGS
 298 3:      ldarx   r10,0,r12
 299         andc    r10,r10,r11
 300         stdcx.  r10,0,r12
 301         bne-    3b
 302         subi    r12,r12,TI_FLAGS
 303
 304 4:      /* Anything else left to do? */
 305         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP)
 306         beq     .ret_from_except_lite
 307
 308         /* Re-enable interrupts */
 309 #ifdef CONFIG_PPC_BOOK3E
 310         wrteei  1
 311 #else
 312         ld      r10,PACAKMSR(r13)
 313         ori     r10,r10,MSR_EE
 314         mtmsrd  r10,1
 315 #endif /* CONFIG_PPC_BOOK3E */
 316
 317         bl      .save_nvgprs
 318         addi    r3,r1,STACK_FRAME_OVERHEAD
 319         bl      .do_syscall_trace_leave
 320         b       .ret_from_except
 321
 322 /* Save non-volatile GPRs, if not already saved. */
 323 _GLOBAL(save_nvgprs)
 324         ld      r11,_TRAP(r1)
 325         andi.   r0,r11,1
 326         beqlr-
 327         SAVE_NVGPRS(r1)
 328         clrrdi  r0,r11,1
 329         std     r0,_TRAP(r1)
 330         blr
 331
 332
 333 /*
 334  * The sigsuspend and rt_sigsuspend system calls can call do_signal
 335  * and thus put the process into the stopped state where we might
 336  * want to examine its user state with ptrace.  Therefore we need
 337  * to save all the nonvolatile registers (r14 - r31) before calling
 338  * the C code.  Similarly, fork, vfork and clone need the full
 339  * register state on the stack so that it can be copied to the child.
 340  */
 341
 342 _GLOBAL(ppc_fork)
 343         bl      .save_nvgprs
 344         bl      .sys_fork
 345         b       syscall_exit
 346
 347 _GLOBAL(ppc_vfork)
 348         bl      .save_nvgprs
 349         bl      .sys_vfork
 350         b       syscall_exit
 351
 352 _GLOBAL(ppc_clone)
 353         bl      .save_nvgprs
 354         bl      .sys_clone
 355         b       syscall_exit
 356
 357 _GLOBAL(ppc32_swapcontext)
 358         bl      .save_nvgprs
 359         bl      .compat_sys_swapcontext
 360         b       syscall_exit
 361
 362 _GLOBAL(ppc64_swapcontext)
 363         bl      .save_nvgprs
 364         bl      .sys_swapcontext
 365         b       syscall_exit
 366
 367 _GLOBAL(ret_from_fork)
 368         bl      .schedule_tail
 369         REST_NVGPRS(r1)
 370         li      r3,0
 371         b       syscall_exit
 372
 373 _GLOBAL(ret_from_kernel_thread)
 374         bl      .schedule_tail
 375         REST_NVGPRS(r1)
 376         ld      r14, 0(r14)
 377         mtlr    r14
 378         mr      r3,r15
 379         blrl
 380         li      r3,0
 381         b       syscall_exit
 382
 383         .section        ".toc","aw"
 384 DSCR_DEFAULT:
 385         .tc dscr_default[TC],dscr_default
 386
 387         .section        ".text"
 388
 389 /*
 390  * This routine switches between two different tasks.  The process
 391  * state of one is saved on its kernel stack.  Then the state
 392  * of the other is restored from its kernel stack.  The memory
 393  * management hardware is updated to the second process's state.
 394  * Finally, we can return to the second process, via ret_from_except.
 395  * On entry, r3 points to the THREAD for the current task, r4
 396  * points to the THREAD for the new task.
 397  *
 398  * Note: there are two ways to get to the "going out" portion
 399  * of this code; either by coming in via the entry (_switch)
 400  * or via "fork" which must set up an environment equivalent
 401  * to the "_switch" path.  If you change this you'll have to change
 402  * the fork code also.
 403  *
 404  * The code which creates the new task context is in 'copy_thread'
 405  * in arch/powerpc/kernel/process.c
 406  */
 407         .align  7
 408 _GLOBAL(_switch)
 409         mflr    r0
 410         std     r0,16(r1)
 411         stdu    r1,-SWITCH_FRAME_SIZE(r1)
 412         /* r3-r13 are caller saved -- Cort */
 413         SAVE_8GPRS(14, r1)
 414         SAVE_10GPRS(22, r1)
 415         mflr    r20             /* Return to switch caller */
 416         mfmsr   r22
 417         li      r0, MSR_FP
 418 #ifdef CONFIG_VSX
 419 BEGIN_FTR_SECTION
 420         oris    r0,r0,MSR_VSX@h /* Disable VSX */
 421 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
 422 #endif /* CONFIG_VSX */
 423 #ifdef CONFIG_ALTIVEC
 424 BEGIN_FTR_SECTION
 425         oris    r0,r0,MSR_VEC@h /* Disable altivec */
 426         mfspr   r24,SPRN_VRSAVE /* save vrsave register value */
 427         std     r24,THREAD_VRSAVE(r3)
 428 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 429 #endif /* CONFIG_ALTIVEC */
 430 #ifdef CONFIG_PPC64
 431 BEGIN_FTR_SECTION
 432         mfspr   r25,SPRN_DSCR
 433         std     r25,THREAD_DSCR(r3)
 434 END_FTR_SECTION_IFSET(CPU_FTR_DSCR)
 435 #endif
 436         and.    r0,r0,r22
 437         beq+    1f
 438         andc    r22,r22,r0
 439         MTMSRD(r22)
 440         isync
 441 1:      std     r20,_NIP(r1)
 442         mfcr    r23
 443         std     r23,_CCR(r1)
 444         std     r1,KSP(r3)      /* Set old stack pointer */
 445
 446 #ifdef CONFIG_SMP
 447         /* We need a sync somewhere here to make sure that if the
 448          * previous task gets rescheduled on another CPU, it sees all
 449          * stores it has performed on this one.
 450          */
 451         sync
 452 #endif /* CONFIG_SMP */
 453
 454         /*
 455          * If we optimise away the clear of the reservation in system
 456          * calls because we know the CPU tracks the address of the
 457          * reservation, then we need to clear it here to cover the
 458          * case that the kernel context switch path has no larx
 459          * instructions.
 460          */
 461 BEGIN_FTR_SECTION
 462         ldarx   r6,0,r1
 463 END_FTR_SECTION_IFSET(CPU_FTR_STCX_CHECKS_ADDRESS)
 464
 465         addi    r6,r4,-THREAD   /* Convert THREAD to 'current' */
 466         std     r6,PACACURRENT(r13)     /* Set new 'current' */
 467
 468         ld      r8,KSP(r4)      /* new stack pointer */
 469 #ifdef CONFIG_PPC_BOOK3S
 470 BEGIN_FTR_SECTION
 471   BEGIN_FTR_SECTION_NESTED(95)
 472         clrrdi  r6,r8,28        /* get its ESID */
 473         clrrdi  r9,r1,28        /* get current sp ESID */
 474   FTR_SECTION_ELSE_NESTED(95)
 475         clrrdi  r6,r8,40        /* get its 1T ESID */
 476         clrrdi  r9,r1,40        /* get current sp 1T ESID */
 477   ALT_MMU_FTR_SECTION_END_NESTED_IFCLR(MMU_FTR_1T_SEGMENT, 95)
 478 FTR_SECTION_ELSE
 479         b       2f
 480 ALT_MMU_FTR_SECTION_END_IFSET(MMU_FTR_SLB)
 481         clrldi. r0,r6,2         /* is new ESID c00000000? */
 482         cmpd    cr1,r6,r9       /* or is new ESID the same as current ESID? */
 483         cror    eq,4*cr1+eq,eq
 484         beq     2f              /* if yes, don't slbie it */
 485
 486         /* Bolt in the new stack SLB entry */
 487         ld      r7,KSP_VSID(r4) /* Get new stack's VSID */
 488         oris    r0,r6,(SLB_ESID_V)@h
 489         ori     r0,r0,(SLB_NUM_BOLTED-1)@l
 490 BEGIN_FTR_SECTION
 491         li      r9,MMU_SEGSIZE_1T       /* insert B field */
 492         oris    r6,r6,(MMU_SEGSIZE_1T << SLBIE_SSIZE_SHIFT)@h
 493         rldimi  r7,r9,SLB_VSID_SSIZE_SHIFT,0
 494 END_MMU_FTR_SECTION_IFSET(MMU_FTR_1T_SEGMENT)
 495
 496         /* Update the last bolted SLB.  No write barriers are needed
 497          * here, provided we only update the current CPU's SLB shadow
 498          * buffer.
 499          */
 500         ld      r9,PACA_SLBSHADOWPTR(r13)
 501         li      r12,0
 502         std     r12,SLBSHADOW_STACKESID(r9) /* Clear ESID */
 503         std     r7,SLBSHADOW_STACKVSID(r9)  /* Save VSID */
 504         std     r0,SLBSHADOW_STACKESID(r9)  /* Save ESID */
 505
 506         /* No need to check for MMU_FTR_NO_SLBIE_B here, since when
 507          * we have 1TB segments, the only CPUs known to have the errata
 508          * only support less than 1TB of system memory and we'll never
 509          * actually hit this code path.
 510          */
 511
 512         slbie   r6
 513         slbie   r6              /* Workaround POWER5 < DD2.1 issue */
 514         slbmte  r7,r0
 515         isync
 516 2:
 517 #endif /* !CONFIG_PPC_BOOK3S */
 518
 519         CURRENT_THREAD_INFO(r7, r8)  /* base of new stack */
 520         /* Note: this uses SWITCH_FRAME_SIZE rather than INT_FRAME_SIZE
 521            because we don't need to leave the 288-byte ABI gap at the
 522            top of the kernel stack. */
 523         addi    r7,r7,THREAD_SIZE-SWITCH_FRAME_SIZE
 524
 525         mr      r1,r8           /* start using new stack pointer */
 526         std     r7,PACAKSAVE(r13)
 527
 528 #ifdef CONFIG_ALTIVEC
 529 BEGIN_FTR_SECTION
 530         ld      r0,THREAD_VRSAVE(r4)
 531         mtspr   SPRN_VRSAVE,r0          /* if G4, restore VRSAVE reg */
 532 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 533 #endif /* CONFIG_ALTIVEC */
 534 #ifdef CONFIG_PPC64
 535 BEGIN_FTR_SECTION
 536         lwz     r6,THREAD_DSCR_INHERIT(r4)
 537         ld      r7,DSCR_DEFAULT@toc(2)
 538         ld      r0,THREAD_DSCR(r4)
 539         cmpwi   r6,0
 540         bne     1f
 541         ld      r0,0(r7)
 542 1:      cmpd    r0,r25
 543         beq     2f
 544         mtspr   SPRN_DSCR,r0
 545 2:
 546 END_FTR_SECTION_IFSET(CPU_FTR_DSCR)
 547 #endif
 548
 549         ld      r6,_CCR(r1)
 550         mtcrf   0xFF,r6
 551
 552         /* r3-r13 are destroyed -- Cort */
 553         REST_8GPRS(14, r1)
 554         REST_10GPRS(22, r1)
 555
 556         /* convert old thread to its task_struct for return value */
 557         addi    r3,r3,-THREAD
 558         ld      r7,_NIP(r1)     /* Return to _switch caller in new task */
 559         mtlr    r7
 560         addi    r1,r1,SWITCH_FRAME_SIZE
 561         blr
 562
 563         .align  7
 564 _GLOBAL(ret_from_except)
 565         ld      r11,_TRAP(r1)
 566         andi.   r0,r11,1
 567         bne     .ret_from_except_lite
 568         REST_NVGPRS(r1)
 569
 570 _GLOBAL(ret_from_except_lite)
 571         /*
 572          * Disable interrupts so that current_thread_info()->flags
 573          * can't change between when we test it and when we return
 574          * from the interrupt.
 575          */
 576 #ifdef CONFIG_PPC_BOOK3E
 577         wrteei  0
 578 #else
 579         ld      r10,PACAKMSR(r13) /* Get kernel MSR without EE */
 580         mtmsrd  r10,1             /* Update machine state */
 581 #endif /* CONFIG_PPC_BOOK3E */
 582
 583         CURRENT_THREAD_INFO(r9, r1)
 584         ld      r3,_MSR(r1)
 585         ld      r4,TI_FLAGS(r9)
 586         andi.   r3,r3,MSR_PR
 587         beq     resume_kernel
 588
 589         /* Check current_thread_info()->flags */
 590         andi.   r0,r4,_TIF_USER_WORK_MASK
 591         beq     restore
 592
 593         andi.   r0,r4,_TIF_NEED_RESCHED
 594         beq     1f
 595         bl      .restore_interrupts
 596         bl      .schedule
 597         b       .ret_from_except_lite
 598
 599 1:      bl      .save_nvgprs
 600         bl      .restore_interrupts
 601         addi    r3,r1,STACK_FRAME_OVERHEAD
 602         bl      .do_notify_resume
 603         b       .ret_from_except
 604
 605 resume_kernel:
 606         /* check current_thread_info, _TIF_EMULATE_STACK_STORE */
 607         CURRENT_THREAD_INFO(r9, r1)
 608         ld      r8,TI_FLAGS(r9)
 609         andis.  r8,r8,_TIF_EMULATE_STACK_STORE@h
 610         beq+    1f
 611
 612         addi    r8,r1,INT_FRAME_SIZE    /* Get the kprobed function entry */
 613
 614         lwz     r3,GPR1(r1)
 615         subi    r3,r3,INT_FRAME_SIZE    /* dst: Allocate a trampoline exception frame */
 616         mr      r4,r1                   /* src:  current exception frame */
 617         mr      r1,r3                   /* Reroute the trampoline frame to r1 */
 618
 619         /* Copy from the original to the trampoline. */
 620         li      r5,INT_FRAME_SIZE/8     /* size: INT_FRAME_SIZE */
 621         li      r6,0                    /* start offset: 0 */
 622         mtctr   r5
 623 2:      ldx     r0,r6,r4
 624         stdx    r0,r6,r3
 625         addi    r6,r6,8
 626         bdnz    2b
 627
 628         /* Do real store operation to complete stwu */
 629         lwz     r5,GPR1(r1)
 630         std     r8,0(r5)
 631
 632         /* Clear _TIF_EMULATE_STACK_STORE flag */
 633         lis     r11,_TIF_EMULATE_STACK_STORE@h
 634         addi    r5,r9,TI_FLAGS
 635         ldarx   r4,0,r5
 636         andc    r4,r4,r11
 637         stdcx.  r4,0,r5
 638         bne-    0b
 639 1:
 640
 641 #ifdef CONFIG_PREEMPT
 642         /* Check if we need to preempt */
 643         andi.   r0,r4,_TIF_NEED_RESCHED
 644         beq+    restore
 645         /* Check that preempt_count() == 0 and interrupts are enabled */
 646         lwz     r8,TI_PREEMPT(r9)
 647         cmpwi   cr1,r8,0
 648         ld      r0,SOFTE(r1)
 649         cmpdi   r0,0
 650         crandc  eq,cr1*4+eq,eq
 651         bne     restore
 652
 653         /*
 654          * Here we are preempting the current task. We want to make
 655          * sure we are soft-disabled first
 656          */
 657         SOFT_DISABLE_INTS(r3,r4)
 658 1:      bl      .preempt_schedule_irq
 659
 660         /* Re-test flags and eventually loop */
 661         CURRENT_THREAD_INFO(r9, r1)
 662         ld      r4,TI_FLAGS(r9)
 663         andi.   r0,r4,_TIF_NEED_RESCHED
 664         bne     1b
 665 #endif /* CONFIG_PREEMPT */
 666
 667         .globl  fast_exc_return_irq
 668 fast_exc_return_irq:
 669 restore:
 670         /*
 671          * This is the main kernel exit path. First we check if we
 672          * are about to re-enable interrupts
 673          */
 674         ld      r5,SOFTE(r1)
 675         lbz     r6,PACASOFTIRQEN(r13)
 676         cmpwi   cr0,r5,0
 677         beq     restore_irq_off
 678
 679         /* We are enabling, were we already enabled ? Yes, just return */
 680         cmpwi   cr0,r6,1
 681         beq     cr0,do_restore
 682
 683         /*
 684          * We are about to soft-enable interrupts (we are hard disabled
 685          * at this point). We check if there's anything that needs to
 686          * be replayed first.
 687          */
 688         lbz     r0,PACAIRQHAPPENED(r13)
 689         cmpwi   cr0,r0,0
 690         bne-    restore_check_irq_replay
 691
 692         /*
 693          * Get here when nothing happened while soft-disabled, just
 694          * soft-enable and move-on. We will hard-enable as a side
 695          * effect of rfi
 696          */
 697 restore_no_replay:
 698         TRACE_ENABLE_INTS
 699         li      r0,1
 700         stb     r0,PACASOFTIRQEN(r13);
 701
 702         /*
 703          * Final return path. BookE is handled in a different file
 704          */
 705 do_restore:
 706 #ifdef CONFIG_PPC_BOOK3E
 707         b       .exception_return_book3e
 708 #else
 709         /*
 710          * Clear the reservation. If we know the CPU tracks the address of
 711          * the reservation then we can potentially save some cycles and use
 712          * a larx. On POWER6 and POWER7 this is significantly faster.
 713          */
 714 BEGIN_FTR_SECTION
 715         stdcx.  r0,0,r1         /* to clear the reservation */
 716 FTR_SECTION_ELSE
 717         ldarx   r4,0,r1
 718 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_STCX_CHECKS_ADDRESS)
 719
 720         /*
 721          * Some code path such as load_up_fpu or altivec return directly
 722          * here. They run entirely hard disabled and do not alter the
 723          * interrupt state. They also don't use lwarx/stwcx. and thus
 724          * are known not to leave dangling reservations.
 725          */
 726         .globl  fast_exception_return
 727 fast_exception_return:
 728         ld      r3,_MSR(r1)
 729         ld      r4,_CTR(r1)
 730         ld      r0,_LINK(r1)
 731         mtctr   r4
 732         mtlr    r0
 733         ld      r4,_XER(r1)
 734         mtspr   SPRN_XER,r4
 735
 736         REST_8GPRS(5, r1)
 737
 738         andi.   r0,r3,MSR_RI
 739         beq-    unrecov_restore
 740
 741         /*
 742          * Clear RI before restoring r13.  If we are returning to
 743          * userspace and we take an exception after restoring r13,
 744          * we end up corrupting the userspace r13 value.
 745          */
 746         ld      r4,PACAKMSR(r13) /* Get kernel MSR without EE */
 747         andc    r4,r4,r0         /* r0 contains MSR_RI here */
 748         mtmsrd  r4,1
 749
 750         /*
 751          * r13 is our per cpu area, only restore it if we are returning to
 752          * userspace the value stored in the stack frame may belong to
 753          * another CPU.
 754          */
 755         andi.   r0,r3,MSR_PR
 756         beq     1f
 757         ACCOUNT_CPU_USER_EXIT(r2, r4)
 758         REST_GPR(13, r1)
 759 1:
 760         mtspr   SPRN_SRR1,r3
 761
 762         ld      r2,_CCR(r1)
 763         mtcrf   0xFF,r2
 764         ld      r2,_NIP(r1)
 765         mtspr   SPRN_SRR0,r2
 766
 767         ld      r0,GPR0(r1)
 768         ld      r2,GPR2(r1)
 769         ld      r3,GPR3(r1)
 770         ld      r4,GPR4(r1)
 771         ld      r1,GPR1(r1)
 772
 773         rfid
 774         b       .       /* prevent speculative execution */
 775
 776 #endif /* CONFIG_PPC_BOOK3E */
 777
 778         /*
 779          * We are returning to a context with interrupts soft disabled.
 780          *
 781          * However, we may also about to hard enable, so we need to
 782          * make sure that in this case, we also clear PACA_IRQ_HARD_DIS
 783          * or that bit can get out of sync and bad things will happen
 784          */
 785 restore_irq_off:
 786         ld      r3,_MSR(r1)
 787         lbz     r7,PACAIRQHAPPENED(r13)
 788         andi.   r0,r3,MSR_EE
 789         beq     1f
 790         rlwinm  r7,r7,0,~PACA_IRQ_HARD_DIS
 791         stb     r7,PACAIRQHAPPENED(r13)
 792 1:      li      r0,0
 793         stb     r0,PACASOFTIRQEN(r13);
 794         TRACE_DISABLE_INTS
 795         b       do_restore
 796
 797         /*
 798          * Something did happen, check if a re-emit is needed
 799          * (this also clears paca->irq_happened)
 800          */
 801 restore_check_irq_replay:
 802         /* XXX: We could implement a fast path here where we check
 803          * for irq_happened being just 0x01, in which case we can
 804          * clear it and return. That means that we would potentially
 805          * miss a decrementer having wrapped all the way around.
 806          *
 807          * Still, this might be useful for things like hash_page
 808          */
 809         bl      .__check_irq_replay
 810         cmpwi   cr0,r3,0
 811         beq     restore_no_replay
 812
 813         /*
 814          * We need to re-emit an interrupt. We do so by re-using our
 815          * existing exception frame. We first change the trap value,
 816          * but we need to ensure we preserve the low nibble of it
 817          */
 818         ld      r4,_TRAP(r1)
 819         clrldi  r4,r4,60
 820         or      r4,r4,r3
 821         std     r4,_TRAP(r1)
 822
 823         /*
 824          * Then find the right handler and call it. Interrupts are
 825          * still soft-disabled and we keep them that way.
 826         */
 827         cmpwi   cr0,r3,0x500
 828         bne     1f
 829         addi    r3,r1,STACK_FRAME_OVERHEAD;
 830         bl      .do_IRQ
 831         b       .ret_from_except
 832 1:      cmpwi   cr0,r3,0x900
 833         bne     1f
 834         addi    r3,r1,STACK_FRAME_OVERHEAD;
 835         bl      .timer_interrupt
 836         b       .ret_from_except
 837 #ifdef CONFIG_PPC_BOOK3E
 838 1:      cmpwi   cr0,r3,0x280
 839         bne     1f
 840         addi    r3,r1,STACK_FRAME_OVERHEAD;
 841         bl      .doorbell_exception
 842         b       .ret_from_except
 843 #endif /* CONFIG_PPC_BOOK3E */
 844 1:      b       .ret_from_except /* What else to do here ? */
 845
 846 unrecov_restore:
 847         addi    r3,r1,STACK_FRAME_OVERHEAD
 848         bl      .unrecoverable_exception
 849         b       unrecov_restore
 850
 851 #ifdef CONFIG_PPC_RTAS
 852 /*
 853  * On CHRP, the Run-Time Abstraction Services (RTAS) have to be
 854  * called with the MMU off.
 855  *
 856  * In addition, we need to be in 32b mode, at least for now.
 857  *
 858  * Note: r3 is an input parameter to rtas, so don't trash it...
 859  */
 860 _GLOBAL(enter_rtas)
 861         mflr    r0
 862         std     r0,16(r1)
 863         stdu    r1,-RTAS_FRAME_SIZE(r1) /* Save SP and create stack space. */
 864
 865         /* Because RTAS is running in 32b mode, it clobbers the high order half
 866          * of all registers that it saves.  We therefore save those registers
 867          * RTAS might touch to the stack.  (r0, r3-r13 are caller saved)
 868          */
 869         SAVE_GPR(2, r1)                 /* Save the TOC */
 870         SAVE_GPR(13, r1)                /* Save paca */
 871         SAVE_8GPRS(14, r1)              /* Save the non-volatiles */
 872         SAVE_10GPRS(22, r1)             /* ditto */
 873
 874         mfcr    r4
 875         std     r4,_CCR(r1)
 876         mfctr   r5
 877         std     r5,_CTR(r1)
 878         mfspr   r6,SPRN_XER
 879         std     r6,_XER(r1)
 880         mfdar   r7
 881         std     r7,_DAR(r1)
 882         mfdsisr r8
 883         std     r8,_DSISR(r1)
 884
 885         /* Temporary workaround to clear CR until RTAS can be modified to
 886          * ignore all bits.
 887          */
 888         li      r0,0
 889         mtcr    r0
 890
 891 #ifdef CONFIG_BUG
 892         /* There is no way it is acceptable to get here with interrupts enabled,
 893          * check it with the asm equivalent of WARN_ON
 894          */
 895         lbz     r0,PACASOFTIRQEN(r13)
 896 1:      tdnei   r0,0
 897         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,BUGFLAG_WARNING
 898 #endif
 899
 900         /* Hard-disable interrupts */
 901         mfmsr   r6
 902         rldicl  r7,r6,48,1
 903         rotldi  r7,r7,16
 904         mtmsrd  r7,1
 905
 906         /* Unfortunately, the stack pointer and the MSR are also clobbered,
 907          * so they are saved in the PACA which allows us to restore
 908          * our original state after RTAS returns.
 909          */
 910         std     r1,PACAR1(r13)
 911         std     r6,PACASAVEDMSR(r13)
 912
 913         /* Setup our real return addr */
 914         LOAD_REG_ADDR(r4,.rtas_return_loc)
 915         clrldi  r4,r4,2                 /* convert to realmode address */
 916         mtlr    r4
 917
 918         li      r0,0
 919         ori     r0,r0,MSR_EE|MSR_SE|MSR_BE|MSR_RI
 920         andc    r0,r6,r0
 921
 922         li      r9,1
 923         rldicr  r9,r9,MSR_SF_LG,(63-MSR_SF_LG)
 924         ori     r9,r9,MSR_IR|MSR_DR|MSR_FE0|MSR_FE1|MSR_FP|MSR_RI
 925         andc    r6,r0,r9
 926         sync                            /* disable interrupts so SRR0/1 */
 927         mtmsrd  r0                      /* don't get trashed */
 928
 929         LOAD_REG_ADDR(r4, rtas)
 930         ld      r5,RTASENTRY(r4)        /* get the rtas->entry value */
 931         ld      r4,RTASBASE(r4)         /* get the rtas->base value */
 932
 933         mtspr   SPRN_SRR0,r5
 934         mtspr   SPRN_SRR1,r6
 935         rfid
 936         b       .       /* prevent speculative execution */
 937
 938 _STATIC(rtas_return_loc)
 939         /* relocation is off at this point */
 940         GET_PACA(r4)
 941         clrldi  r4,r4,2                 /* convert to realmode address */
 942
 943         bcl     20,31,$+4
 944 0:      mflr    r3
 945         ld      r3,(1f-0b)(r3)          /* get &.rtas_restore_regs */
 946
 947         mfmsr   r6
 948         li      r0,MSR_RI
 949         andc    r6,r6,r0
 950         sync
 951         mtmsrd  r6
 952
 953         ld      r1,PACAR1(r4)           /* Restore our SP */
 954         ld      r4,PACASAVEDMSR(r4)     /* Restore our MSR */
 955
 956         mtspr   SPRN_SRR0,r3
 957         mtspr   SPRN_SRR1,r4
 958         rfid
 959         b       .       /* prevent speculative execution */
 960
 961         .align  3
 962 1:      .llong  .rtas_restore_regs
 963
 964 _STATIC(rtas_restore_regs)
 965         /* relocation is on at this point */
 966         REST_GPR(2, r1)                 /* Restore the TOC */
 967         REST_GPR(13, r1)                /* Restore paca */
 968         REST_8GPRS(14, r1)              /* Restore the non-volatiles */
 969         REST_10GPRS(22, r1)             /* ditto */
 970
 971         GET_PACA(r13)
 972
 973         ld      r4,_CCR(r1)
 974         mtcr    r4
 975         ld      r5,_CTR(r1)
 976         mtctr   r5
 977         ld      r6,_XER(r1)
 978         mtspr   SPRN_XER,r6
 979         ld      r7,_DAR(r1)
 980         mtdar   r7
 981         ld      r8,_DSISR(r1)
 982         mtdsisr r8
 983
 984         addi    r1,r1,RTAS_FRAME_SIZE   /* Unstack our frame */
 985         ld      r0,16(r1)               /* get return address */
 986
 987         mtlr    r0
 988         blr                             /* return to caller */
 989
 990 #endif /* CONFIG_PPC_RTAS */
 991
 992 _GLOBAL(enter_prom)
 993         mflr    r0
 994         std     r0,16(r1)
 995         stdu    r1,-PROM_FRAME_SIZE(r1) /* Save SP and create stack space */
 996
 997         /* Because PROM is running in 32b mode, it clobbers the high order half
 998          * of all registers that it saves.  We therefore save those registers
 999          * PROM might touch to the stack.  (r0, r3-r13 are caller saved)
1000          */
1001         SAVE_GPR(2, r1)
1002         SAVE_GPR(13, r1)
1003         SAVE_8GPRS(14, r1)
1004         SAVE_10GPRS(22, r1)
1005         mfcr    r10
1006         mfmsr   r11
1007         std     r10,_CCR(r1)
1008         std     r11,_MSR(r1)
1009
1010         /* Get the PROM entrypoint */
1011         mtlr    r4
1012
1013         /* Switch MSR to 32 bits mode
1014          */
1015 #ifdef CONFIG_PPC_BOOK3E
1016         rlwinm  r11,r11,0,1,31
1017         mtmsr   r11
1018 #else /* CONFIG_PPC_BOOK3E */
1019         mfmsr   r11
1020         li      r12,1
1021         rldicr  r12,r12,MSR_SF_LG,(63-MSR_SF_LG)
1022         andc    r11,r11,r12
1023         li      r12,1
1024         rldicr  r12,r12,MSR_ISF_LG,(63-MSR_ISF_LG)
1025         andc    r11,r11,r12
1026         mtmsrd  r11
1027 #endif /* CONFIG_PPC_BOOK3E */
1028         isync
1029
1030         /* Enter PROM here... */
1031         blrl
1032
1033         /* Just make sure that r1 top 32 bits didn't get
1034          * corrupt by OF
1035          */
1036         rldicl  r1,r1,0,32
1037
1038         /* Restore the MSR (back to 64 bits) */
1039         ld      r0,_MSR(r1)
1040         MTMSRD(r0)
1041         isync
1042
1043         /* Restore other registers */
1044         REST_GPR(2, r1)
1045         REST_GPR(13, r1)
1046         REST_8GPRS(14, r1)
1047         REST_10GPRS(22, r1)
1048         ld      r4,_CCR(r1)
1049         mtcr    r4
1050
1051         addi    r1,r1,PROM_FRAME_SIZE
1052         ld      r0,16(r1)
1053         mtlr    r0
1054         blr
1055
1056 #ifdef CONFIG_FUNCTION_TRACER
1057 #ifdef CONFIG_DYNAMIC_FTRACE
1058 _GLOBAL(mcount)
1059 _GLOBAL(_mcount)
1060         blr
1061
1062 _GLOBAL(ftrace_caller)
1063         /* Taken from output of objdump from lib64/glibc */
1064         mflr    r3
1065         ld      r11, 0(r1)
1066         stdu    r1, -112(r1)
1067         std     r3, 128(r1)
1068         ld      r4, 16(r11)
1069         subi    r3, r3, MCOUNT_INSN_SIZE
1070 .globl ftrace_call
1071 ftrace_call:
1072         bl      ftrace_stub
1073         nop
1074 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1075 .globl ftrace_graph_call
1076 ftrace_graph_call:
1077         b       ftrace_graph_stub
1078 _GLOBAL(ftrace_graph_stub)
1079 #endif
1080         ld      r0, 128(r1)
1081         mtlr    r0
1082         addi    r1, r1, 112
1083 _GLOBAL(ftrace_stub)
1084         blr
1085 #else
1086 _GLOBAL(mcount)
1087         blr
1088
1089 _GLOBAL(_mcount)
1090         /* Taken from output of objdump from lib64/glibc */
1091         mflr    r3
1092         ld      r11, 0(r1)
1093         stdu    r1, -112(r1)
1094         std     r3, 128(r1)
1095         ld      r4, 16(r11)
1096
1097         subi    r3, r3, MCOUNT_INSN_SIZE
1098         LOAD_REG_ADDR(r5,ftrace_trace_function)
1099         ld      r5,0(r5)
1100         ld      r5,0(r5)
1101         mtctr   r5
1102         bctrl
1103         nop
1104
1105
1106 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1107         b       ftrace_graph_caller
1108 #endif
1109         ld      r0, 128(r1)
1110         mtlr    r0
1111         addi    r1, r1, 112
1112 _GLOBAL(ftrace_stub)
1113         blr
1114
1115 #endif /* CONFIG_DYNAMIC_FTRACE */
1116
1117 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1118 _GLOBAL(ftrace_graph_caller)
1119         /* load r4 with local address */
1120         ld      r4, 128(r1)
1121         subi    r4, r4, MCOUNT_INSN_SIZE
1122
1123         /* get the parent address */
1124         ld      r11, 112(r1)
1125         addi    r3, r11, 16
1126
1127         bl      .prepare_ftrace_return
1128         nop
1129
1130         ld      r0, 128(r1)
1131         mtlr    r0
1132         addi    r1, r1, 112
1133         blr
1134
1135 _GLOBAL(return_to_handler)
1136         /* need to save return values */
1137         std     r4,  -24(r1)
1138         std     r3,  -16(r1)
1139         std     r31, -8(r1)
1140         mr      r31, r1
1141         stdu    r1, -112(r1)
1142
1143         bl      .ftrace_return_to_handler
1144         nop
1145
1146         /* return value has real return address */
1147         mtlr    r3
1148
1149         ld      r1, 0(r1)
1150         ld      r4,  -24(r1)
1151         ld      r3,  -16(r1)
1152         ld      r31, -8(r1)
1153
1154         /* Jump back to real return address */
1155         blr
1156
1157 _GLOBAL(mod_return_to_handler)
1158         /* need to save return values */
1159         std     r4,  -32(r1)
1160         std     r3,  -24(r1)
1161         /* save TOC */
1162         std     r2,  -16(r1)
1163         std     r31, -8(r1)
1164         mr      r31, r1
1165         stdu    r1, -112(r1)
1166
1167         /*
1168          * We are in a module using the module's TOC.
1169          * Switch to our TOC to run inside the core kernel.
1170          */
1171         ld      r2, PACATOC(r13)
1172
1173         bl      .ftrace_return_to_handler
1174         nop
1175
1176         /* return value has real return address */
1177         mtlr    r3
1178
1179         ld      r1, 0(r1)
1180         ld      r4,  -32(r1)
1181         ld      r3,  -24(r1)
1182         ld      r2,  -16(r1)
1183         ld      r31, -8(r1)
1184
1185         /* Jump back to real return address */
1186         blr
1187 #endif /* CONFIG_FUNCTION_GRAPH_TRACER */
1188 #endif /* CONFIG_FUNCTION_TRACER */