arch/powerpc/kernel/tm.S

   1 /*
   2  * Transactional memory support routines to reclaim and recheckpoint
   3  * transactional process state.
   4  *
   5  * Copyright 2012 Matt Evans & Michael Neuling, IBM Corporation.
   6  */
   7
   8 #include <asm/asm-offsets.h>
   9 #include <asm/ppc_asm.h>
  10 #include <asm/ppc-opcode.h>
  11 #include <asm/ptrace.h>
  12 #include <asm/reg.h>
  13 #include <asm/bug.h>
  14
  15 #ifdef CONFIG_VSX
  16 /* See fpu.S, this is borrowed from there */
  17 #define __SAVE_32FPRS_VSRS(n,c,base)            \
  18 BEGIN_FTR_SECTION                               \
  19         b       2f;                             \
  20 END_FTR_SECTION_IFSET(CPU_FTR_VSX);             \
  21         SAVE_32FPRS(n,base);                    \
  22         b       3f;                             \
  23 2:      SAVE_32VSRS(n,c,base);                  \
  24 3:
  25 #define __REST_32FPRS_VSRS(n,c,base)            \
  26 BEGIN_FTR_SECTION                               \
  27         b       2f;                             \
  28 END_FTR_SECTION_IFSET(CPU_FTR_VSX);             \
  29         REST_32FPRS(n,base);                    \
  30         b       3f;                             \
  31 2:      REST_32VSRS(n,c,base);                  \
  32 3:
  33 #else
  34 #define __SAVE_32FPRS_VSRS(n,c,base)    SAVE_32FPRS(n, base)
  35 #define __REST_32FPRS_VSRS(n,c,base)    REST_32FPRS(n, base)
  36 #endif
  37 #define SAVE_32FPRS_VSRS(n,c,base) \
  38         __SAVE_32FPRS_VSRS(n,__REG_##c,__REG_##base)
  39 #define REST_32FPRS_VSRS(n,c,base) \
  40         __REST_32FPRS_VSRS(n,__REG_##c,__REG_##base)
  41
  42 /* Stack frame offsets for local variables. */
  43 #define TM_FRAME_L0     TM_FRAME_SIZE-16
  44 #define TM_FRAME_L1     TM_FRAME_SIZE-8
  45 #define STACK_PARAM(x)  (48+((x)*8))
  46
  47
  48 /* In order to access the TM SPRs, TM must be enabled.  So, do so: */
  49 _GLOBAL(tm_enable)
  50         mfmsr   r4
  51         li      r3, MSR_TM >> 32
  52         sldi    r3, r3, 32
  53         and.    r0, r4, r3
  54         bne     1f
  55         or      r4, r4, r3
  56         mtmsrd  r4
  57 1:      blr
  58
  59 _GLOBAL(tm_save_sprs)
  60         mfspr   r0, SPRN_TFHAR
  61         std     r0, THREAD_TM_TFHAR(r3)
  62         mfspr   r0, SPRN_TEXASR
  63         std     r0, THREAD_TM_TEXASR(r3)
  64         mfspr   r0, SPRN_TFIAR
  65         std     r0, THREAD_TM_TFIAR(r3)
  66         blr
  67
  68 _GLOBAL(tm_restore_sprs)
  69         ld      r0, THREAD_TM_TFHAR(r3)
  70         mtspr   SPRN_TFHAR, r0
  71         ld      r0, THREAD_TM_TEXASR(r3)
  72         mtspr   SPRN_TEXASR, r0
  73         ld      r0, THREAD_TM_TFIAR(r3)
  74         mtspr   SPRN_TFIAR, r0
  75         blr
  76
  77         /* Passed an 8-bit failure cause as first argument. */
  78 _GLOBAL(tm_abort)
  79         TABORT(R3)
  80         blr
  81
  82         .section        ".toc","aw"
  83 DSCR_DEFAULT:
  84         .tc dscr_default[TC],dscr_default
  85
  86         .section        ".text"
  87
  88 /* void tm_reclaim(struct thread_struct *thread,
  89  *                 unsigned long orig_msr,
  90  *                 uint8_t cause)
  91  *
  92  *      - Performs a full reclaim.  This destroys outstanding
  93  *        transactions and updates thread->regs.tm_ckpt_* with the
  94  *        original checkpointed state.  Note that thread->regs is
  95  *        unchanged.
  96  *      - FP regs are written back to thread->transact_fpr before
  97  *        reclaiming.  These are the transactional (current) versions.
  98  *
  99  * Purpose is to both abort transactions of, and preserve the state of,
 100  * a transactions at a context switch. We preserve/restore both sets of process
 101  * state to restore them when the thread's scheduled again.  We continue in
 102  * userland as though nothing happened, but when the transaction is resumed
 103  * they will abort back to the checkpointed state we save out here.
 104  *
 105  * Call with IRQs off, stacks get all out of sync for some periods in here!
 106  */
 107 _GLOBAL(tm_reclaim)
 108         mfcr    r6
 109         mflr    r0
 110         stw     r6, 8(r1)
 111         std     r0, 16(r1)
 112         std     r2, 40(r1)
 113         stdu    r1, -TM_FRAME_SIZE(r1)
 114
 115         /* We've a struct pt_regs at [r1+STACK_FRAME_OVERHEAD]. */
 116
 117         std     r3, STACK_PARAM(0)(r1)
 118         SAVE_NVGPRS(r1)
 119
 120         /* We need to setup MSR for VSX register save instructions.  Here we
 121          * also clear the MSR RI since when we do the treclaim, we won't have a
 122          * valid kernel pointer for a while.  We clear RI here as it avoids
 123          * adding another mtmsr closer to the treclaim.  This makes the region
 124          * maked as non-recoverable wider than it needs to be but it saves on
 125          * inserting another mtmsrd later.
 126          */
 127         mfmsr   r14
 128         mr      r15, r14
 129         ori     r15, r15, MSR_FP
 130         li      r16, MSR_RI
 131         ori     r16, r16, MSR_EE /* IRQs hard off */
 132         andc    r15, r15, r16
 133         oris    r15, r15, MSR_VEC@h
 134 #ifdef CONFIG_VSX
 135         BEGIN_FTR_SECTION
 136         oris    r15,r15, MSR_VSX@h
 137         END_FTR_SECTION_IFSET(CPU_FTR_VSX)
 138 #endif
 139         mtmsrd  r15
 140         std     r14, TM_FRAME_L0(r1)
 141
 142         /* Stash the stack pointer away for use after reclaim */
 143         std     r1, PACAR1(r13)
 144
 145         /* ******************** FPR/VR/VSRs ************
 146          * Before reclaiming, capture the current/transactional FPR/VR
 147         * versions /if used/.
 148          *
 149          * (If VSX used, FP and VMX are implied.  Or, we don't need to look
 150          * at MSR.VSX as copying FP regs if .FP, vector regs if .VMX covers it.)
 151          *
 152          * We're passed the thread's MSR as parameter 2.
 153          *
 154          * We enabled VEC/FP/VSX in the msr above, so we can execute these
 155          * instructions!
 156          */
 157         andis.          r0, r4, MSR_VEC@h
 158         beq     dont_backup_vec
 159
 160         addi    r7, r3, THREAD_TRANSACT_VRSTATE
 161         SAVE_32VRS(0, r6, r7)   /* r6 scratch, r7 transact vr state */
 162         mfvscr  vr0
 163         li      r6, VRSTATE_VSCR
 164         stvx    vr0, r7, r6
 165 dont_backup_vec:
 166         mfspr   r0, SPRN_VRSAVE
 167         std     r0, THREAD_TRANSACT_VRSAVE(r3)
 168
 169         andi.   r0, r4, MSR_FP
 170         beq     dont_backup_fp
 171
 172         addi    r7, r3, THREAD_TRANSACT_FPSTATE
 173         SAVE_32FPRS_VSRS(0, R6, R7)     /* r6 scratch, r7 transact fp state */
 174
 175         mffs    fr0
 176         stfd    fr0,FPSTATE_FPSCR(r7)
 177
 178 dont_backup_fp:
 179         /* Do sanity check on MSR to make sure we are suspended */
 180         li      r7, (MSR_TS_S)@higher
 181         srdi    r6, r14, 32
 182         and     r6, r6, r7
 183 1:      tdeqi   r6, 0
 184         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,0
 185
 186         /* The moment we treclaim, ALL of our GPRs will switch
 187          * to user register state.  (FPRs, CCR etc. also!)
 188          * Use an sprg and a tm_scratch in the PACA to shuffle.
 189          */
 190         TRECLAIM(R5)                            /* Cause in r5 */
 191
 192         /* ******************** GPRs ******************** */
 193         /* Stash the checkpointed r13 away in the scratch SPR and get the real
 194          *  paca
 195          */
 196         SET_SCRATCH0(r13)
 197         GET_PACA(r13)
 198
 199         /* Stash the checkpointed r1 away in paca tm_scratch and get the real
 200          * stack pointer back
 201          */
 202         std     r1, PACATMSCRATCH(r13)
 203         ld      r1, PACAR1(r13)
 204
 205         /* Store the PPR in r11 and reset to decent value */
 206         std     r11, GPR11(r1)                  /* Temporary stash */
 207         mfspr   r11, SPRN_PPR
 208         HMT_MEDIUM
 209
 210         /* Now get some more GPRS free */
 211         std     r7, GPR7(r1)                    /* Temporary stash */
 212         std     r12, GPR12(r1)                  /* ''   ''    ''   */
 213         ld      r12, STACK_PARAM(0)(r1)         /* Param 0, thread_struct * */
 214
 215         std     r11, THREAD_TM_PPR(r12)         /* Store PPR and free r11 */
 216
 217         addi    r7, r12, PT_CKPT_REGS           /* Thread's ckpt_regs */
 218
 219         /* Make r7 look like an exception frame so that we
 220          * can use the neat GPRx(n) macros.  r7 is NOT a pt_regs ptr!
 221          */
 222         subi    r7, r7, STACK_FRAME_OVERHEAD
 223
 224         /* Sync the userland GPRs 2-12, 14-31 to thread->regs: */
 225         SAVE_GPR(0, r7)                         /* user r0 */
 226         SAVE_GPR(2, r7)                 /* user r2 */
 227         SAVE_4GPRS(3, r7)                       /* user r3-r6 */
 228         SAVE_GPR(8, r7)                         /* user r8 */
 229         SAVE_GPR(9, r7)                         /* user r9 */
 230         SAVE_GPR(10, r7)                        /* user r10 */
 231         ld      r3, PACATMSCRATCH(r13)          /* user r1 */
 232         ld      r4, GPR7(r1)                    /* user r7 */
 233         ld      r5, GPR11(r1)                   /* user r11 */
 234         ld      r6, GPR12(r1)                   /* user r12 */
 235         GET_SCRATCH0(8)                         /* user r13 */
 236         std     r3, GPR1(r7)
 237         std     r4, GPR7(r7)
 238         std     r5, GPR11(r7)
 239         std     r6, GPR12(r7)
 240         std     r8, GPR13(r7)
 241
 242         SAVE_NVGPRS(r7)                         /* user r14-r31 */
 243
 244         /* ******************** NIP ******************** */
 245         mfspr   r3, SPRN_TFHAR
 246         std     r3, _NIP(r7)                    /* Returns to failhandler */
 247         /* The checkpointed NIP is ignored when rescheduling/rechkpting,
 248          * but is used in signal return to 'wind back' to the abort handler.
 249          */
 250
 251         /* ******************** CR,LR,CCR,MSR ********** */
 252         mfctr   r3
 253         mflr    r4
 254         mfcr    r5
 255         mfxer   r6
 256
 257         std     r3, _CTR(r7)
 258         std     r4, _LINK(r7)
 259         std     r5, _CCR(r7)
 260         std     r6, _XER(r7)
 261
 262
 263         /* ******************** TAR, DSCR ********** */
 264         mfspr   r3, SPRN_TAR
 265         mfspr   r4, SPRN_DSCR
 266
 267         std     r3, THREAD_TM_TAR(r12)
 268         std     r4, THREAD_TM_DSCR(r12)
 269
 270         /* MSR and flags:  We don't change CRs, and we don't need to alter
 271          * MSR.
 272          */
 273
 274         /* TM regs, incl TEXASR -- these live in thread_struct.  Note they've
 275          * been updated by the treclaim, to explain to userland the failure
 276          * cause (aborted).
 277          */
 278         mfspr   r0, SPRN_TEXASR
 279         mfspr   r3, SPRN_TFHAR
 280         mfspr   r4, SPRN_TFIAR
 281         std     r0, THREAD_TM_TEXASR(r12)
 282         std     r3, THREAD_TM_TFHAR(r12)
 283         std     r4, THREAD_TM_TFIAR(r12)
 284
 285         /* AMR is checkpointed too, but is unsupported by Linux. */
 286
 287         /* Restore original MSR/IRQ state & clear TM mode */
 288         ld      r14, TM_FRAME_L0(r1)            /* Orig MSR */
 289         li      r15, 0
 290         rldimi  r14, r15, MSR_TS_LG, (63-MSR_TS_LG)-1
 291         mtmsrd  r14
 292
 293         REST_NVGPRS(r1)
 294
 295         addi    r1, r1, TM_FRAME_SIZE
 296         lwz     r4, 8(r1)
 297         ld      r0, 16(r1)
 298         mtcr    r4
 299         mtlr    r0
 300         ld      r2, 40(r1)
 301
 302         /* Load system default DSCR */
 303         ld      r4, DSCR_DEFAULT@toc(r2)
 304         ld      r0, 0(r4)
 305         mtspr   SPRN_DSCR, r0
 306
 307         blr
 308
 309
 310         /* void tm_recheckpoint(struct thread_struct *thread,
 311          *                      unsigned long orig_msr)
 312          *      - Restore the checkpointed register state saved by tm_reclaim
 313          *        when we switch_to a process.
 314          *
 315          *      Call with IRQs off, stacks get all out of sync for
 316          *      some periods in here!
 317          */
 318 _GLOBAL(__tm_recheckpoint)
 319         mfcr    r5
 320         mflr    r0
 321         stw     r5, 8(r1)
 322         std     r0, 16(r1)
 323         std     r2, 40(r1)
 324         stdu    r1, -TM_FRAME_SIZE(r1)
 325
 326         /* We've a struct pt_regs at [r1+STACK_FRAME_OVERHEAD].
 327          * This is used for backing up the NVGPRs:
 328          */
 329         SAVE_NVGPRS(r1)
 330
 331         /* Load complete register state from ts_ckpt* registers */
 332
 333         addi    r7, r3, PT_CKPT_REGS            /* Thread's ckpt_regs */
 334
 335         /* Make r7 look like an exception frame so that we
 336          * can use the neat GPRx(n) macros.  r7 is now NOT a pt_regs ptr!
 337          */
 338         subi    r7, r7, STACK_FRAME_OVERHEAD
 339
 340         SET_SCRATCH0(r1)
 341
 342         mfmsr   r6
 343         /* R4 = original MSR to indicate whether thread used FP/Vector etc. */
 344
 345         /* Enable FP/vec in MSR if necessary! */
 346         lis     r5, MSR_VEC@h
 347         ori     r5, r5, MSR_FP
 348         and.    r5, r4, r5
 349         beq     restore_gprs                    /* if neither, skip both */
 350
 351 #ifdef CONFIG_VSX
 352         BEGIN_FTR_SECTION
 353         oris    r5, r5, MSR_VSX@h
 354         END_FTR_SECTION_IFSET(CPU_FTR_VSX)
 355 #endif
 356         or      r5, r6, r5                      /* Set MSR.FP+.VSX/.VEC */
 357         mtmsr   r5
 358
 359 #ifdef CONFIG_ALTIVEC
 360         /* FP and VEC registers:  These are recheckpointed from thread.fpr[]
 361          * and thread.vr[] respectively.  The thread.transact_fpr[] version
 362          * is more modern, and will be loaded subsequently by any FPUnavailable
 363          * trap.
 364          */
 365         andis.  r0, r4, MSR_VEC@h
 366         beq     dont_restore_vec
 367
 368         addi    r8, r3, THREAD_VRSTATE
 369         li      r5, VRSTATE_VSCR
 370         lvx     vr0, r8, r5
 371         mtvscr  vr0
 372         REST_32VRS(0, r5, r8)                   /* r5 scratch, r8 ptr */
 373 dont_restore_vec:
 374         ld      r5, THREAD_VRSAVE(r3)
 375         mtspr   SPRN_VRSAVE, r5
 376 #endif
 377
 378         andi.   r0, r4, MSR_FP
 379         beq     dont_restore_fp
 380
 381         addi    r8, r3, THREAD_FPSTATE
 382         lfd     fr0, FPSTATE_FPSCR(r8)
 383         MTFSF_L(fr0)
 384         REST_32FPRS_VSRS(0, R4, R8)
 385
 386 dont_restore_fp:
 387         mtmsr   r6                              /* FP/Vec off again! */
 388
 389 restore_gprs:
 390
 391         /* ******************** CR,LR,CCR,MSR ********** */
 392         ld      r4, _CTR(r7)
 393         ld      r5, _LINK(r7)
 394         ld      r8, _XER(r7)
 395
 396         mtctr   r4
 397         mtlr    r5
 398         mtxer   r8
 399
 400         /* ******************** TAR ******************** */
 401         ld      r4, THREAD_TM_TAR(r3)
 402         mtspr   SPRN_TAR,       r4
 403
 404         /* Load up the PPR and DSCR in GPRs only at this stage */
 405         ld      r5, THREAD_TM_DSCR(r3)
 406         ld      r6, THREAD_TM_PPR(r3)
 407
 408         /* Clear the MSR RI since we are about to change R1.  EE is already off
 409          */
 410         li      r4, 0
 411         mtmsrd  r4, 1
 412
 413         REST_GPR(0, r7)                         /* GPR0 */
 414         REST_2GPRS(2, r7)                       /* GPR2-3 */
 415         REST_GPR(4, r7)                         /* GPR4 */
 416         REST_4GPRS(8, r7)                       /* GPR8-11 */
 417         REST_2GPRS(12, r7)                      /* GPR12-13 */
 418
 419         REST_NVGPRS(r7)                         /* GPR14-31 */
 420
 421         /* Load up PPR and DSCR here so we don't run with user values for long
 422          */
 423         mtspr   SPRN_DSCR, r5
 424         mtspr   SPRN_PPR, r6
 425
 426         /* Do final sanity check on TEXASR to make sure FS is set.  Do this
 427          * here before we load up the userspace r1 so any bugs we hit will get
 428          * a call chain */
 429         mfspr   r5, SPRN_TEXASR
 430         srdi    r5, r5, 16
 431         li      r6, (TEXASR_FS)@h
 432         and     r6, r6, r5
 433 1:      tdeqi   r6, 0
 434         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,0
 435
 436         /* Do final sanity check on MSR to make sure we are not transactional
 437          * or suspended
 438          */
 439         mfmsr   r6
 440         li      r5, (MSR_TS_MASK)@higher
 441         srdi    r6, r6, 32
 442         and     r6, r6, r5
 443 1:      tdnei   r6, 0
 444         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,0
 445
 446         /* Restore CR */
 447         ld      r6, _CCR(r7)
 448         mtcr    r6
 449
 450         REST_GPR(1, r7)                         /* GPR1 */
 451         REST_GPR(5, r7)                         /* GPR5-7 */
 452         REST_GPR(6, r7)
 453         ld      r7, GPR7(r7)
 454
 455         /* Commit register state as checkpointed state: */
 456         TRECHKPT
 457
 458         HMT_MEDIUM
 459
 460         /* Our transactional state has now changed.
 461          *
 462          * Now just get out of here.  Transactional (current) state will be
 463          * updated once restore is called on the return path in the _switch-ed
 464          * -to process.
 465          */
 466
 467         GET_PACA(r13)
 468         GET_SCRATCH0(r1)
 469
 470         /* R1 is restored, so we are recoverable again.  EE is still off */
 471         li      r4, MSR_RI
 472         mtmsrd  r4, 1
 473
 474         REST_NVGPRS(r1)
 475
 476         addi    r1, r1, TM_FRAME_SIZE
 477         lwz     r4, 8(r1)
 478         ld      r0, 16(r1)
 479         mtcr    r4
 480         mtlr    r0
 481         ld      r2, 40(r1)
 482
 483         /* Load system default DSCR */
 484         ld      r4, DSCR_DEFAULT@toc(r2)
 485         ld      r0, 0(r4)
 486         mtspr   SPRN_DSCR, r0
 487
 488         blr
 489
 490         /* ****************************************************************** */