arch/powerpc/kvm/book3s_hv_rmhandlers.S

   1 /*
   2  * This program is free software; you can redistribute it and/or modify
   3  * it under the terms of the GNU General Public License, version 2, as
   4  * published by the Free Software Foundation.
   5  *
   6  * This program is distributed in the hope that it will be useful,
   7  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   8  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   9  * GNU General Public License for more details.
  10  *
  11  * Copyright 2011 Paul Mackerras, IBM Corp. <paulus@au1.ibm.com>
  12  *
  13  * Derived from book3s_rmhandlers.S and other files, which are:
  14  *
  15  * Copyright SUSE Linux Products GmbH 2009
  16  *
  17  * Authors: Alexander Graf <agraf@suse.de>
  18  */
  19
  20 #include <asm/ppc_asm.h>
  21 #include <asm/kvm_asm.h>
  22 #include <asm/reg.h>
  23 #include <asm/mmu.h>
  24 #include <asm/page.h>
  25 #include <asm/ptrace.h>
  26 #include <asm/hvcall.h>
  27 #include <asm/asm-offsets.h>
  28 #include <asm/exception-64s.h>
  29 #include <asm/kvm_book3s_asm.h>
  30 #include <asm/book3s/64/mmu-hash.h>
  31 #include <asm/tm.h>
  32 #include <asm/opal.h>
  33
  34 #define VCPU_GPRS_TM(reg) (((reg) * ULONG_SIZE) + VCPU_GPR_TM)
  35
  36 /* Values in HSTATE_NAPPING(r13) */
  37 #define NAPPING_CEDE    1
  38 #define NAPPING_NOVCPU  2
  39
  40 /*
  41  * Call kvmppc_hv_entry in real mode.
  42  * Must be called with interrupts hard-disabled.
  43  *
  44  * Input Registers:
  45  *
  46  * LR = return address to continue at after eventually re-enabling MMU
  47  */
  48 _GLOBAL_TOC(kvmppc_hv_entry_trampoline)
  49         mflr    r0
  50         std     r0, PPC_LR_STKOFF(r1)
  51         stdu    r1, -112(r1)
  52         mfmsr   r10
  53         LOAD_REG_ADDR(r5, kvmppc_call_hv_entry)
  54         li      r0,MSR_RI
  55         andc    r0,r10,r0
  56         li      r6,MSR_IR | MSR_DR
  57         andc    r6,r10,r6
  58         mtmsrd  r0,1            /* clear RI in MSR */
  59         mtsrr0  r5
  60         mtsrr1  r6
  61         RFI
  62
  63 kvmppc_call_hv_entry:
  64         ld      r4, HSTATE_KVM_VCPU(r13)
  65         bl      kvmppc_hv_entry
  66
  67         /* Back from guest - restore host state and return to caller */
  68
  69 BEGIN_FTR_SECTION
  70         /* Restore host DABR and DABRX */
  71         ld      r5,HSTATE_DABR(r13)
  72         li      r6,7
  73         mtspr   SPRN_DABR,r5
  74         mtspr   SPRN_DABRX,r6
  75 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_207S)
  76
  77         /* Restore SPRG3 */
  78         ld      r3,PACA_SPRG_VDSO(r13)
  79         mtspr   SPRN_SPRG_VDSO_WRITE,r3
  80
  81         /* Reload the host's PMU registers */
  82         ld      r3, PACALPPACAPTR(r13)  /* is the host using the PMU? */
  83         lbz     r4, LPPACA_PMCINUSE(r3)
  84         cmpwi   r4, 0
  85         beq     23f                     /* skip if not */
  86 BEGIN_FTR_SECTION
  87         ld      r3, HSTATE_MMCR0(r13)
  88         andi.   r4, r3, MMCR0_PMAO_SYNC | MMCR0_PMAO
  89         cmpwi   r4, MMCR0_PMAO
  90         beql    kvmppc_fix_pmao
  91 END_FTR_SECTION_IFSET(CPU_FTR_PMAO_BUG)
  92         lwz     r3, HSTATE_PMC1(r13)
  93         lwz     r4, HSTATE_PMC2(r13)
  94         lwz     r5, HSTATE_PMC3(r13)
  95         lwz     r6, HSTATE_PMC4(r13)
  96         lwz     r8, HSTATE_PMC5(r13)
  97         lwz     r9, HSTATE_PMC6(r13)
  98         mtspr   SPRN_PMC1, r3
  99         mtspr   SPRN_PMC2, r4
 100         mtspr   SPRN_PMC3, r5
 101         mtspr   SPRN_PMC4, r6
 102         mtspr   SPRN_PMC5, r8
 103         mtspr   SPRN_PMC6, r9
 104         ld      r3, HSTATE_MMCR0(r13)
 105         ld      r4, HSTATE_MMCR1(r13)
 106         ld      r5, HSTATE_MMCRA(r13)
 107         ld      r6, HSTATE_SIAR(r13)
 108         ld      r7, HSTATE_SDAR(r13)
 109         mtspr   SPRN_MMCR1, r4
 110         mtspr   SPRN_MMCRA, r5
 111         mtspr   SPRN_SIAR, r6
 112         mtspr   SPRN_SDAR, r7
 113 BEGIN_FTR_SECTION
 114         ld      r8, HSTATE_MMCR2(r13)
 115         ld      r9, HSTATE_SIER(r13)
 116         mtspr   SPRN_MMCR2, r8
 117         mtspr   SPRN_SIER, r9
 118 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 119         mtspr   SPRN_MMCR0, r3
 120         isync
 121 23:
 122
 123         /*
 124          * Reload DEC.  HDEC interrupts were disabled when
 125          * we reloaded the host's LPCR value.
 126          */
 127         ld      r3, HSTATE_DECEXP(r13)
 128         mftb    r4
 129         subf    r4, r4, r3
 130         mtspr   SPRN_DEC, r4
 131
 132         /* hwthread_req may have got set by cede or no vcpu, so clear it */
 133         li      r0, 0
 134         stb     r0, HSTATE_HWTHREAD_REQ(r13)
 135
 136         /*
 137          * For external and machine check interrupts, we need
 138          * to call the Linux handler to process the interrupt.
 139          * We do that by jumping to absolute address 0x500 for
 140          * external interrupts, or the machine_check_fwnmi label
 141          * for machine checks (since firmware might have patched
 142          * the vector area at 0x200).  The [h]rfid at the end of the
 143          * handler will return to the book3s_hv_interrupts.S code.
 144          * For other interrupts we do the rfid to get back
 145          * to the book3s_hv_interrupts.S code here.
 146          */
 147         ld      r8, 112+PPC_LR_STKOFF(r1)
 148         addi    r1, r1, 112
 149         ld      r7, HSTATE_HOST_MSR(r13)
 150
 151         cmpwi   cr1, r12, BOOK3S_INTERRUPT_MACHINE_CHECK
 152         cmpwi   r12, BOOK3S_INTERRUPT_EXTERNAL
 153         beq     11f
 154         cmpwi   r12, BOOK3S_INTERRUPT_H_DOORBELL
 155         beq     15f     /* Invoke the H_DOORBELL handler */
 156         cmpwi   cr2, r12, BOOK3S_INTERRUPT_HMI
 157         beq     cr2, 14f                        /* HMI check */
 158
 159         /* RFI into the highmem handler, or branch to interrupt handler */
 160         mfmsr   r6
 161         li      r0, MSR_RI
 162         andc    r6, r6, r0
 163         mtmsrd  r6, 1                   /* Clear RI in MSR */
 164         mtsrr0  r8
 165         mtsrr1  r7
 166         beq     cr1, 13f                /* machine check */
 167         RFI
 168
 169         /* On POWER7, we have external interrupts set to use HSRR0/1 */
 170 11:     mtspr   SPRN_HSRR0, r8
 171         mtspr   SPRN_HSRR1, r7
 172         ba      0x500
 173
 174 13:     b       machine_check_fwnmi
 175
 176 14:     mtspr   SPRN_HSRR0, r8
 177         mtspr   SPRN_HSRR1, r7
 178         b       hmi_exception_after_realmode
 179
 180 15:     mtspr SPRN_HSRR0, r8
 181         mtspr SPRN_HSRR1, r7
 182         ba    0xe80
 183
 184 kvmppc_primary_no_guest:
 185         /* We handle this much like a ceded vcpu */
 186         /* put the HDEC into the DEC, since HDEC interrupts don't wake us */
 187         mfspr   r3, SPRN_HDEC
 188         mtspr   SPRN_DEC, r3
 189         /*
 190          * Make sure the primary has finished the MMU switch.
 191          * We should never get here on a secondary thread, but
 192          * check it for robustness' sake.
 193          */
 194         ld      r5, HSTATE_KVM_VCORE(r13)
 195 65:     lbz     r0, VCORE_IN_GUEST(r5)
 196         cmpwi   r0, 0
 197         beq     65b
 198         /* Set LPCR. */
 199         ld      r8,VCORE_LPCR(r5)
 200         mtspr   SPRN_LPCR,r8
 201         isync
 202         /* set our bit in napping_threads */
 203         ld      r5, HSTATE_KVM_VCORE(r13)
 204         lbz     r7, HSTATE_PTID(r13)
 205         li      r0, 1
 206         sld     r0, r0, r7
 207         addi    r6, r5, VCORE_NAPPING_THREADS
 208 1:      lwarx   r3, 0, r6
 209         or      r3, r3, r0
 210         stwcx.  r3, 0, r6
 211         bne     1b
 212         /* order napping_threads update vs testing entry_exit_map */
 213         isync
 214         li      r12, 0
 215         lwz     r7, VCORE_ENTRY_EXIT(r5)
 216         cmpwi   r7, 0x100
 217         bge     kvm_novcpu_exit /* another thread already exiting */
 218         li      r3, NAPPING_NOVCPU
 219         stb     r3, HSTATE_NAPPING(r13)
 220
 221         li      r3, 0           /* Don't wake on privileged (OS) doorbell */
 222         b       kvm_do_nap
 223
 224 /*
 225  * kvm_novcpu_wakeup
 226  *      Entered from kvm_start_guest if kvm_hstate.napping is set
 227  *      to NAPPING_NOVCPU
 228  *              r2 = kernel TOC
 229  *              r13 = paca
 230  */
 231 kvm_novcpu_wakeup:
 232         ld      r1, HSTATE_HOST_R1(r13)
 233         ld      r5, HSTATE_KVM_VCORE(r13)
 234         li      r0, 0
 235         stb     r0, HSTATE_NAPPING(r13)
 236
 237         /* check the wake reason */
 238         bl      kvmppc_check_wake_reason
 239
 240         /*
 241          * Restore volatile registers since we could have called
 242          * a C routine in kvmppc_check_wake_reason.
 243          *      r5 = VCORE
 244          */
 245         ld      r5, HSTATE_KVM_VCORE(r13)
 246
 247         /* see if any other thread is already exiting */
 248         lwz     r0, VCORE_ENTRY_EXIT(r5)
 249         cmpwi   r0, 0x100
 250         bge     kvm_novcpu_exit
 251
 252         /* clear our bit in napping_threads */
 253         lbz     r7, HSTATE_PTID(r13)
 254         li      r0, 1
 255         sld     r0, r0, r7
 256         addi    r6, r5, VCORE_NAPPING_THREADS
 257 4:      lwarx   r7, 0, r6
 258         andc    r7, r7, r0
 259         stwcx.  r7, 0, r6
 260         bne     4b
 261
 262         /* See if the wake reason means we need to exit */
 263         cmpdi   r3, 0
 264         bge     kvm_novcpu_exit
 265
 266         /* See if our timeslice has expired (HDEC is negative) */
 267         mfspr   r0, SPRN_HDEC
 268         li      r12, BOOK3S_INTERRUPT_HV_DECREMENTER
 269         cmpwi   r0, 0
 270         blt     kvm_novcpu_exit
 271
 272         /* Got an IPI but other vcpus aren't yet exiting, must be a latecomer */
 273         ld      r4, HSTATE_KVM_VCPU(r13)
 274         cmpdi   r4, 0
 275         beq     kvmppc_primary_no_guest
 276
 277 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
 278         addi    r3, r4, VCPU_TB_RMENTRY
 279         bl      kvmhv_start_timing
 280 #endif
 281         b       kvmppc_got_guest
 282
 283 kvm_novcpu_exit:
 284 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
 285         ld      r4, HSTATE_KVM_VCPU(r13)
 286         cmpdi   r4, 0
 287         beq     13f
 288         addi    r3, r4, VCPU_TB_RMEXIT
 289         bl      kvmhv_accumulate_time
 290 #endif
 291 13:     mr      r3, r12
 292         stw     r12, 112-4(r1)
 293         bl      kvmhv_commence_exit
 294         nop
 295         lwz     r12, 112-4(r1)
 296         b       kvmhv_switch_to_host
 297
 298 /*
 299  * We come in here when wakened from nap mode.
 300  * Relocation is off and most register values are lost.
 301  * r13 points to the PACA.
 302  */
 303         .globl  kvm_start_guest
 304 kvm_start_guest:
 305
 306         /* Set runlatch bit the minute you wake up from nap */
 307         mfspr   r0, SPRN_CTRLF
 308         ori     r0, r0, 1
 309         mtspr   SPRN_CTRLT, r0
 310
 311         ld      r2,PACATOC(r13)
 312
 313         li      r0,KVM_HWTHREAD_IN_KVM
 314         stb     r0,HSTATE_HWTHREAD_STATE(r13)
 315
 316         /* NV GPR values from power7_idle() will no longer be valid */
 317         li      r0,1
 318         stb     r0,PACA_NAPSTATELOST(r13)
 319
 320         /* were we napping due to cede? */
 321         lbz     r0,HSTATE_NAPPING(r13)
 322         cmpwi   r0,NAPPING_CEDE
 323         beq     kvm_end_cede
 324         cmpwi   r0,NAPPING_NOVCPU
 325         beq     kvm_novcpu_wakeup
 326
 327         ld      r1,PACAEMERGSP(r13)
 328         subi    r1,r1,STACK_FRAME_OVERHEAD
 329
 330         /*
 331          * We weren't napping due to cede, so this must be a secondary
 332          * thread being woken up to run a guest, or being woken up due
 333          * to a stray IPI.  (Or due to some machine check or hypervisor
 334          * maintenance interrupt while the core is in KVM.)
 335          */
 336
 337         /* Check the wake reason in SRR1 to see why we got here */
 338         bl      kvmppc_check_wake_reason
 339         /*
 340          * kvmppc_check_wake_reason could invoke a C routine, but we
 341          * have no volatile registers to restore when we return.
 342          */
 343
 344         cmpdi   r3, 0
 345         bge     kvm_no_guest
 346
 347         /* get vcore pointer, NULL if we have nothing to run */
 348         ld      r5,HSTATE_KVM_VCORE(r13)
 349         cmpdi   r5,0
 350         /* if we have no vcore to run, go back to sleep */
 351         beq     kvm_no_guest
 352
 353 kvm_secondary_got_guest:
 354
 355         /* Set HSTATE_DSCR(r13) to something sensible */
 356         ld      r6, PACA_DSCR_DEFAULT(r13)
 357         std     r6, HSTATE_DSCR(r13)
 358
 359         /* On thread 0 of a subcore, set HDEC to max */
 360         lbz     r4, HSTATE_PTID(r13)
 361         cmpwi   r4, 0
 362         bne     63f
 363         lis     r6, 0x7fff
 364         ori     r6, r6, 0xffff
 365         mtspr   SPRN_HDEC, r6
 366         /* and set per-LPAR registers, if doing dynamic micro-threading */
 367         ld      r6, HSTATE_SPLIT_MODE(r13)
 368         cmpdi   r6, 0
 369         beq     63f
 370         ld      r0, KVM_SPLIT_RPR(r6)
 371         mtspr   SPRN_RPR, r0
 372         ld      r0, KVM_SPLIT_PMMAR(r6)
 373         mtspr   SPRN_PMMAR, r0
 374         ld      r0, KVM_SPLIT_LDBAR(r6)
 375         mtspr   SPRN_LDBAR, r0
 376         isync
 377 63:
 378         /* Order load of vcpu after load of vcore */
 379         lwsync
 380         ld      r4, HSTATE_KVM_VCPU(r13)
 381         bl      kvmppc_hv_entry
 382
 383         /* Back from the guest, go back to nap */
 384         /* Clear our vcpu and vcore pointers so we don't come back in early */
 385         li      r0, 0
 386         std     r0, HSTATE_KVM_VCPU(r13)
 387         /*
 388          * Once we clear HSTATE_KVM_VCORE(r13), the code in
 389          * kvmppc_run_core() is going to assume that all our vcpu
 390          * state is visible in memory.  This lwsync makes sure
 391          * that that is true.
 392          */
 393         lwsync
 394         std     r0, HSTATE_KVM_VCORE(r13)
 395
 396         /*
 397          * All secondaries exiting guest will fall through this path.
 398          * Before proceeding, just check for HMI interrupt and
 399          * invoke opal hmi handler. By now we are sure that the
 400          * primary thread on this core/subcore has already made partition
 401          * switch/TB resync and we are good to call opal hmi handler.
 402          */
 403         cmpwi   r12, BOOK3S_INTERRUPT_HMI
 404         bne     kvm_no_guest
 405
 406         li      r3,0                    /* NULL argument */
 407         bl      hmi_exception_realmode
 408 /*
 409  * At this point we have finished executing in the guest.
 410  * We need to wait for hwthread_req to become zero, since
 411  * we may not turn on the MMU while hwthread_req is non-zero.
 412  * While waiting we also need to check if we get given a vcpu to run.
 413  */
 414 kvm_no_guest:
 415         lbz     r3, HSTATE_HWTHREAD_REQ(r13)
 416         cmpwi   r3, 0
 417         bne     53f
 418         HMT_MEDIUM
 419         li      r0, KVM_HWTHREAD_IN_KERNEL
 420         stb     r0, HSTATE_HWTHREAD_STATE(r13)
 421         /* need to recheck hwthread_req after a barrier, to avoid race */
 422         sync
 423         lbz     r3, HSTATE_HWTHREAD_REQ(r13)
 424         cmpwi   r3, 0
 425         bne     54f
 426 /*
 427  * We jump to pnv_wakeup_loss, which will return to the caller
 428  * of power7_nap in the powernv cpu offline loop.  The value we
 429  * put in r3 becomes the return value for power7_nap.
 430  */
 431         li      r3, LPCR_PECE0
 432         mfspr   r4, SPRN_LPCR
 433         rlwimi  r4, r3, 0, LPCR_PECE0 | LPCR_PECE1
 434         mtspr   SPRN_LPCR, r4
 435         li      r3, 0
 436         b       pnv_wakeup_loss
 437
 438 53:     HMT_LOW
 439         ld      r5, HSTATE_KVM_VCORE(r13)
 440         cmpdi   r5, 0
 441         bne     60f
 442         ld      r3, HSTATE_SPLIT_MODE(r13)
 443         cmpdi   r3, 0
 444         beq     kvm_no_guest
 445         lbz     r0, KVM_SPLIT_DO_NAP(r3)
 446         cmpwi   r0, 0
 447         beq     kvm_no_guest
 448         HMT_MEDIUM
 449         b       kvm_unsplit_nap
 450 60:     HMT_MEDIUM
 451         b       kvm_secondary_got_guest
 452
 453 54:     li      r0, KVM_HWTHREAD_IN_KVM
 454         stb     r0, HSTATE_HWTHREAD_STATE(r13)
 455         b       kvm_no_guest
 456
 457 /*
 458  * Here the primary thread is trying to return the core to
 459  * whole-core mode, so we need to nap.
 460  */
 461 kvm_unsplit_nap:
 462         /*
 463          * When secondaries are napping in kvm_unsplit_nap() with
 464          * hwthread_req = 1, HMI goes ignored even though subcores are
 465          * already exited the guest. Hence HMI keeps waking up secondaries
 466          * from nap in a loop and secondaries always go back to nap since
 467          * no vcore is assigned to them. This makes impossible for primary
 468          * thread to get hold of secondary threads resulting into a soft
 469          * lockup in KVM path.
 470          *
 471          * Let us check if HMI is pending and handle it before we go to nap.
 472          */
 473         cmpwi   r12, BOOK3S_INTERRUPT_HMI
 474         bne     55f
 475         li      r3, 0                   /* NULL argument */
 476         bl      hmi_exception_realmode
 477 55:
 478         /*
 479          * Ensure that secondary doesn't nap when it has
 480          * its vcore pointer set.
 481          */
 482         sync            /* matches smp_mb() before setting split_info.do_nap */
 483         ld      r0, HSTATE_KVM_VCORE(r13)
 484         cmpdi   r0, 0
 485         bne     kvm_no_guest
 486         /* clear any pending message */
 487 BEGIN_FTR_SECTION
 488         lis     r6, (PPC_DBELL_SERVER << (63-36))@h
 489         PPC_MSGCLR(6)
 490 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 491         /* Set kvm_split_mode.napped[tid] = 1 */
 492         ld      r3, HSTATE_SPLIT_MODE(r13)
 493         li      r0, 1
 494         lhz     r4, PACAPACAINDEX(r13)
 495         clrldi  r4, r4, 61      /* micro-threading => P8 => 8 threads/core */
 496         addi    r4, r4, KVM_SPLIT_NAPPED
 497         stbx    r0, r3, r4
 498         /* Check the do_nap flag again after setting napped[] */
 499         sync
 500         lbz     r0, KVM_SPLIT_DO_NAP(r3)
 501         cmpwi   r0, 0
 502         beq     57f
 503         li      r3, (LPCR_PECEDH | LPCR_PECE0) >> 4
 504         mfspr   r5, SPRN_LPCR
 505         rlwimi  r5, r3, 4, (LPCR_PECEDP | LPCR_PECEDH | LPCR_PECE0 | LPCR_PECE1)
 506         b       kvm_nap_sequence
 507
 508 57:     li      r0, 0
 509         stbx    r0, r3, r4
 510         b       kvm_no_guest
 511
 512 /******************************************************************************
 513  *                                                                            *
 514  *                               Entry code                                   *
 515  *                                                                            *
 516  *****************************************************************************/
 517
 518 /* Stack frame offsets */
 519 #define STACK_SLOT_TID          (112-16)
 520 #define STACK_SLOT_PSSCR        (112-24)
 521
 522 .global kvmppc_hv_entry
 523 kvmppc_hv_entry:
 524
 525         /* Required state:
 526          *
 527          * R4 = vcpu pointer (or NULL)
 528          * MSR = ~IR|DR
 529          * R13 = PACA
 530          * R1 = host R1
 531          * R2 = TOC
 532          * all other volatile GPRS = free
 533          */
 534         mflr    r0
 535         std     r0, PPC_LR_STKOFF(r1)
 536         stdu    r1, -112(r1)
 537
 538         /* Save R1 in the PACA */
 539         std     r1, HSTATE_HOST_R1(r13)
 540
 541         li      r6, KVM_GUEST_MODE_HOST_HV
 542         stb     r6, HSTATE_IN_GUEST(r13)
 543
 544 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
 545         /* Store initial timestamp */
 546         cmpdi   r4, 0
 547         beq     1f
 548         addi    r3, r4, VCPU_TB_RMENTRY
 549         bl      kvmhv_start_timing
 550 1:
 551 #endif
 552         /* Clear out SLB */
 553         li      r6,0
 554         slbmte  r6,r6
 555         slbia
 556         ptesync
 557
 558         /*
 559          * POWER7/POWER8 host -> guest partition switch code.
 560          * We don't have to lock against concurrent tlbies,
 561          * but we do have to coordinate across hardware threads.
 562          */
 563         /* Set bit in entry map iff exit map is zero. */
 564         ld      r5, HSTATE_KVM_VCORE(r13)
 565         li      r7, 1
 566         lbz     r6, HSTATE_PTID(r13)
 567         sld     r7, r7, r6
 568         addi    r9, r5, VCORE_ENTRY_EXIT
 569 21:     lwarx   r3, 0, r9
 570         cmpwi   r3, 0x100               /* any threads starting to exit? */
 571         bge     secondary_too_late      /* if so we're too late to the party */
 572         or      r3, r3, r7
 573         stwcx.  r3, 0, r9
 574         bne     21b
 575
 576         /* Primary thread switches to guest partition. */
 577         ld      r9,VCORE_KVM(r5)        /* pointer to struct kvm */
 578         cmpwi   r6,0
 579         bne     10f
 580         lwz     r7,KVM_LPID(r9)
 581 BEGIN_FTR_SECTION
 582         ld      r6,KVM_SDR1(r9)
 583         li      r0,LPID_RSVD            /* switch to reserved LPID */
 584         mtspr   SPRN_LPID,r0
 585         ptesync
 586         mtspr   SPRN_SDR1,r6            /* switch to partition page table */
 587 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_300)
 588         mtspr   SPRN_LPID,r7
 589         isync
 590
 591         /* See if we need to flush the TLB */
 592         lhz     r6,PACAPACAINDEX(r13)   /* test_bit(cpu, need_tlb_flush) */
 593         clrldi  r7,r6,64-6              /* extract bit number (6 bits) */
 594         srdi    r6,r6,6                 /* doubleword number */
 595         sldi    r6,r6,3                 /* address offset */
 596         add     r6,r6,r9
 597         addi    r6,r6,KVM_NEED_FLUSH    /* dword in kvm->arch.need_tlb_flush */
 598         li      r0,1
 599         sld     r0,r0,r7
 600         ld      r7,0(r6)
 601         and.    r7,r7,r0
 602         beq     22f
 603 23:     ldarx   r7,0,r6                 /* if set, clear the bit */
 604         andc    r7,r7,r0
 605         stdcx.  r7,0,r6
 606         bne     23b
 607         /* Flush the TLB of any entries for this LPID */
 608         lwz     r6,KVM_TLB_SETS(r9)
 609         li      r0,0                    /* RS for P9 version of tlbiel */
 610         mtctr   r6
 611         li      r7,0x800                /* IS field = 0b10 */
 612         ptesync
 613 28:     tlbiel  r7
 614         addi    r7,r7,0x1000
 615         bdnz    28b
 616         ptesync
 617
 618         /* Add timebase offset onto timebase */
 619 22:     ld      r8,VCORE_TB_OFFSET(r5)
 620         cmpdi   r8,0
 621         beq     37f
 622         mftb    r6              /* current host timebase */
 623         add     r8,r8,r6
 624         mtspr   SPRN_TBU40,r8   /* update upper 40 bits */
 625         mftb    r7              /* check if lower 24 bits overflowed */
 626         clrldi  r6,r6,40
 627         clrldi  r7,r7,40
 628         cmpld   r7,r6
 629         bge     37f
 630         addis   r8,r8,0x100     /* if so, increment upper 40 bits */
 631         mtspr   SPRN_TBU40,r8
 632
 633         /* Load guest PCR value to select appropriate compat mode */
 634 37:     ld      r7, VCORE_PCR(r5)
 635         cmpdi   r7, 0
 636         beq     38f
 637         mtspr   SPRN_PCR, r7
 638 38:
 639
 640 BEGIN_FTR_SECTION
 641         /* DPDES and VTB are shared between threads */
 642         ld      r8, VCORE_DPDES(r5)
 643         ld      r7, VCORE_VTB(r5)
 644         mtspr   SPRN_DPDES, r8
 645         mtspr   SPRN_VTB, r7
 646 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 647
 648         /* Mark the subcore state as inside guest */
 649         bl      kvmppc_subcore_enter_guest
 650         nop
 651         ld      r5, HSTATE_KVM_VCORE(r13)
 652         ld      r4, HSTATE_KVM_VCPU(r13)
 653         li      r0,1
 654         stb     r0,VCORE_IN_GUEST(r5)   /* signal secondaries to continue */
 655
 656         /* Do we have a guest vcpu to run? */
 657 10:     cmpdi   r4, 0
 658         beq     kvmppc_primary_no_guest
 659 kvmppc_got_guest:
 660
 661         /* Load up guest SLB entries */
 662         lwz     r5,VCPU_SLB_MAX(r4)
 663         cmpwi   r5,0
 664         beq     9f
 665         mtctr   r5
 666         addi    r6,r4,VCPU_SLB
 667 1:      ld      r8,VCPU_SLB_E(r6)
 668         ld      r9,VCPU_SLB_V(r6)
 669         slbmte  r9,r8
 670         addi    r6,r6,VCPU_SLB_SIZE
 671         bdnz    1b
 672 9:
 673         /* Increment yield count if they have a VPA */
 674         ld      r3, VCPU_VPA(r4)
 675         cmpdi   r3, 0
 676         beq     25f
 677         li      r6, LPPACA_YIELDCOUNT
 678         LWZX_BE r5, r3, r6
 679         addi    r5, r5, 1
 680         STWX_BE r5, r3, r6
 681         li      r6, 1
 682         stb     r6, VCPU_VPA_DIRTY(r4)
 683 25:
 684
 685         /* Save purr/spurr */
 686         mfspr   r5,SPRN_PURR
 687         mfspr   r6,SPRN_SPURR
 688         std     r5,HSTATE_PURR(r13)
 689         std     r6,HSTATE_SPURR(r13)
 690         ld      r7,VCPU_PURR(r4)
 691         ld      r8,VCPU_SPURR(r4)
 692         mtspr   SPRN_PURR,r7
 693         mtspr   SPRN_SPURR,r8
 694
 695         /* Save host values of some registers */
 696 BEGIN_FTR_SECTION
 697         mfspr   r5, SPRN_TIDR
 698         mfspr   r6, SPRN_PSSCR
 699         std     r5, STACK_SLOT_TID(r1)
 700         std     r6, STACK_SLOT_PSSCR(r1)
 701 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
 702
 703 BEGIN_FTR_SECTION
 704         /* Set partition DABR */
 705         /* Do this before re-enabling PMU to avoid P7 DABR corruption bug */
 706         lwz     r5,VCPU_DABRX(r4)
 707         ld      r6,VCPU_DABR(r4)
 708         mtspr   SPRN_DABRX,r5
 709         mtspr   SPRN_DABR,r6
 710         isync
 711 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_207S)
 712
 713 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
 714 BEGIN_FTR_SECTION
 715         bl      kvmppc_restore_tm
 716 END_FTR_SECTION_IFSET(CPU_FTR_TM)
 717 #endif
 718
 719         /* Load guest PMU registers */
 720         /* R4 is live here (vcpu pointer) */
 721         li      r3, 1
 722         sldi    r3, r3, 31              /* MMCR0_FC (freeze counters) bit */
 723         mtspr   SPRN_MMCR0, r3          /* freeze all counters, disable ints */
 724         isync
 725 BEGIN_FTR_SECTION
 726         ld      r3, VCPU_MMCR(r4)
 727         andi.   r5, r3, MMCR0_PMAO_SYNC | MMCR0_PMAO
 728         cmpwi   r5, MMCR0_PMAO
 729         beql    kvmppc_fix_pmao
 730 END_FTR_SECTION_IFSET(CPU_FTR_PMAO_BUG)
 731         lwz     r3, VCPU_PMC(r4)        /* always load up guest PMU registers */
 732         lwz     r5, VCPU_PMC + 4(r4)    /* to prevent information leak */
 733         lwz     r6, VCPU_PMC + 8(r4)
 734         lwz     r7, VCPU_PMC + 12(r4)
 735         lwz     r8, VCPU_PMC + 16(r4)
 736         lwz     r9, VCPU_PMC + 20(r4)
 737         mtspr   SPRN_PMC1, r3
 738         mtspr   SPRN_PMC2, r5
 739         mtspr   SPRN_PMC3, r6
 740         mtspr   SPRN_PMC4, r7
 741         mtspr   SPRN_PMC5, r8
 742         mtspr   SPRN_PMC6, r9
 743         ld      r3, VCPU_MMCR(r4)
 744         ld      r5, VCPU_MMCR + 8(r4)
 745         ld      r6, VCPU_MMCR + 16(r4)
 746         ld      r7, VCPU_SIAR(r4)
 747         ld      r8, VCPU_SDAR(r4)
 748         mtspr   SPRN_MMCR1, r5
 749         mtspr   SPRN_MMCRA, r6
 750         mtspr   SPRN_SIAR, r7
 751         mtspr   SPRN_SDAR, r8
 752 BEGIN_FTR_SECTION
 753         ld      r5, VCPU_MMCR + 24(r4)
 754         ld      r6, VCPU_SIER(r4)
 755         mtspr   SPRN_MMCR2, r5
 756         mtspr   SPRN_SIER, r6
 757 BEGIN_FTR_SECTION_NESTED(96)
 758         lwz     r7, VCPU_PMC + 24(r4)
 759         lwz     r8, VCPU_PMC + 28(r4)
 760         ld      r9, VCPU_MMCR + 32(r4)
 761         mtspr   SPRN_SPMC1, r7
 762         mtspr   SPRN_SPMC2, r8
 763         mtspr   SPRN_MMCRS, r9
 764 END_FTR_SECTION_NESTED(CPU_FTR_ARCH_300, 0, 96)
 765 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 766         mtspr   SPRN_MMCR0, r3
 767         isync
 768
 769         /* Load up FP, VMX and VSX registers */
 770         bl      kvmppc_load_fp
 771
 772         ld      r14, VCPU_GPR(R14)(r4)
 773         ld      r15, VCPU_GPR(R15)(r4)
 774         ld      r16, VCPU_GPR(R16)(r4)
 775         ld      r17, VCPU_GPR(R17)(r4)
 776         ld      r18, VCPU_GPR(R18)(r4)
 777         ld      r19, VCPU_GPR(R19)(r4)
 778         ld      r20, VCPU_GPR(R20)(r4)
 779         ld      r21, VCPU_GPR(R21)(r4)
 780         ld      r22, VCPU_GPR(R22)(r4)
 781         ld      r23, VCPU_GPR(R23)(r4)
 782         ld      r24, VCPU_GPR(R24)(r4)
 783         ld      r25, VCPU_GPR(R25)(r4)
 784         ld      r26, VCPU_GPR(R26)(r4)
 785         ld      r27, VCPU_GPR(R27)(r4)
 786         ld      r28, VCPU_GPR(R28)(r4)
 787         ld      r29, VCPU_GPR(R29)(r4)
 788         ld      r30, VCPU_GPR(R30)(r4)
 789         ld      r31, VCPU_GPR(R31)(r4)
 790
 791         /* Switch DSCR to guest value */
 792         ld      r5, VCPU_DSCR(r4)
 793         mtspr   SPRN_DSCR, r5
 794
 795 BEGIN_FTR_SECTION
 796         /* Skip next section on POWER7 */
 797         b       8f
 798 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_207S)
 799         /* Load up POWER8-specific registers */
 800         ld      r5, VCPU_IAMR(r4)
 801         lwz     r6, VCPU_PSPB(r4)
 802         ld      r7, VCPU_FSCR(r4)
 803         mtspr   SPRN_IAMR, r5
 804         mtspr   SPRN_PSPB, r6
 805         mtspr   SPRN_FSCR, r7
 806         ld      r5, VCPU_DAWR(r4)
 807         ld      r6, VCPU_DAWRX(r4)
 808         ld      r7, VCPU_CIABR(r4)
 809         ld      r8, VCPU_TAR(r4)
 810         mtspr   SPRN_DAWR, r5
 811         mtspr   SPRN_DAWRX, r6
 812         mtspr   SPRN_CIABR, r7
 813         mtspr   SPRN_TAR, r8
 814         ld      r5, VCPU_IC(r4)
 815         ld      r8, VCPU_EBBHR(r4)
 816         mtspr   SPRN_IC, r5
 817         mtspr   SPRN_EBBHR, r8
 818         ld      r5, VCPU_EBBRR(r4)
 819         ld      r6, VCPU_BESCR(r4)
 820         lwz     r7, VCPU_GUEST_PID(r4)
 821         ld      r8, VCPU_WORT(r4)
 822         mtspr   SPRN_EBBRR, r5
 823         mtspr   SPRN_BESCR, r6
 824         mtspr   SPRN_PID, r7
 825         mtspr   SPRN_WORT, r8
 826 BEGIN_FTR_SECTION
 827         /* POWER8-only registers */
 828         ld      r5, VCPU_TCSCR(r4)
 829         ld      r6, VCPU_ACOP(r4)
 830         ld      r7, VCPU_CSIGR(r4)
 831         ld      r8, VCPU_TACR(r4)
 832         mtspr   SPRN_TCSCR, r5
 833         mtspr   SPRN_ACOP, r6
 834         mtspr   SPRN_CSIGR, r7
 835         mtspr   SPRN_TACR, r8
 836 FTR_SECTION_ELSE
 837         /* POWER9-only registers */
 838         ld      r5, VCPU_TID(r4)
 839         ld      r6, VCPU_PSSCR(r4)
 840         oris    r6, r6, PSSCR_EC@h      /* This makes stop trap to HV */
 841         mtspr   SPRN_TIDR, r5
 842         mtspr   SPRN_PSSCR, r6
 843 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_ARCH_300)
 844 8:
 845
 846         /*
 847          * Set the decrementer to the guest decrementer.
 848          */
 849         ld      r8,VCPU_DEC_EXPIRES(r4)
 850         /* r8 is a host timebase value here, convert to guest TB */
 851         ld      r5,HSTATE_KVM_VCORE(r13)
 852         ld      r6,VCORE_TB_OFFSET(r5)
 853         add     r8,r8,r6
 854         mftb    r7
 855         subf    r3,r7,r8
 856         mtspr   SPRN_DEC,r3
 857         stw     r3,VCPU_DEC(r4)
 858
 859         ld      r5, VCPU_SPRG0(r4)
 860         ld      r6, VCPU_SPRG1(r4)
 861         ld      r7, VCPU_SPRG2(r4)
 862         ld      r8, VCPU_SPRG3(r4)
 863         mtspr   SPRN_SPRG0, r5
 864         mtspr   SPRN_SPRG1, r6
 865         mtspr   SPRN_SPRG2, r7
 866         mtspr   SPRN_SPRG3, r8
 867
 868         /* Load up DAR and DSISR */
 869         ld      r5, VCPU_DAR(r4)
 870         lwz     r6, VCPU_DSISR(r4)
 871         mtspr   SPRN_DAR, r5
 872         mtspr   SPRN_DSISR, r6
 873
 874         /* Restore AMR and UAMOR, set AMOR to all 1s */
 875         ld      r5,VCPU_AMR(r4)
 876         ld      r6,VCPU_UAMOR(r4)
 877         li      r7,-1
 878         mtspr   SPRN_AMR,r5
 879         mtspr   SPRN_UAMOR,r6
 880         mtspr   SPRN_AMOR,r7
 881
 882         /* Restore state of CTRL run bit; assume 1 on entry */
 883         lwz     r5,VCPU_CTRL(r4)
 884         andi.   r5,r5,1
 885         bne     4f
 886         mfspr   r6,SPRN_CTRLF
 887         clrrdi  r6,r6,1
 888         mtspr   SPRN_CTRLT,r6
 889 4:
 890         /* Secondary threads wait for primary to have done partition switch */
 891         ld      r5, HSTATE_KVM_VCORE(r13)
 892         lbz     r6, HSTATE_PTID(r13)
 893         cmpwi   r6, 0
 894         beq     21f
 895         lbz     r0, VCORE_IN_GUEST(r5)
 896         cmpwi   r0, 0
 897         bne     21f
 898         HMT_LOW
 899 20:     lwz     r3, VCORE_ENTRY_EXIT(r5)
 900         cmpwi   r3, 0x100
 901         bge     no_switch_exit
 902         lbz     r0, VCORE_IN_GUEST(r5)
 903         cmpwi   r0, 0
 904         beq     20b
 905         HMT_MEDIUM
 906 21:
 907         /* Set LPCR. */
 908         ld      r8,VCORE_LPCR(r5)
 909         mtspr   SPRN_LPCR,r8
 910         isync
 911
 912         /* Check if HDEC expires soon */
 913         mfspr   r3, SPRN_HDEC
 914         cmpwi   r3, 512         /* 1 microsecond */
 915         blt     hdec_soon
 916
 917 deliver_guest_interrupt:
 918         ld      r6, VCPU_CTR(r4)
 919         ld      r7, VCPU_XER(r4)
 920
 921         mtctr   r6
 922         mtxer   r7
 923
 924 kvmppc_cede_reentry:            /* r4 = vcpu, r13 = paca */
 925         ld      r10, VCPU_PC(r4)
 926         ld      r11, VCPU_MSR(r4)
 927         ld      r6, VCPU_SRR0(r4)
 928         ld      r7, VCPU_SRR1(r4)
 929         mtspr   SPRN_SRR0, r6
 930         mtspr   SPRN_SRR1, r7
 931
 932         /* r11 = vcpu->arch.msr & ~MSR_HV */
 933         rldicl  r11, r11, 63 - MSR_HV_LG, 1
 934         rotldi  r11, r11, 1 + MSR_HV_LG
 935         ori     r11, r11, MSR_ME
 936
 937         /* Check if we can deliver an external or decrementer interrupt now */
 938         ld      r0, VCPU_PENDING_EXC(r4)
 939         rldicl  r0, r0, 64 - BOOK3S_IRQPRIO_EXTERNAL_LEVEL, 63
 940         cmpdi   cr1, r0, 0
 941         andi.   r8, r11, MSR_EE
 942         mfspr   r8, SPRN_LPCR
 943         /* Insert EXTERNAL_LEVEL bit into LPCR at the MER bit position */
 944         rldimi  r8, r0, LPCR_MER_SH, 63 - LPCR_MER_SH
 945         mtspr   SPRN_LPCR, r8
 946         isync
 947         beq     5f
 948         li      r0, BOOK3S_INTERRUPT_EXTERNAL
 949         bne     cr1, 12f
 950         mfspr   r0, SPRN_DEC
 951         cmpwi   r0, 0
 952         li      r0, BOOK3S_INTERRUPT_DECREMENTER
 953         bge     5f
 954
 955 12:     mtspr   SPRN_SRR0, r10
 956         mr      r10,r0
 957         mtspr   SPRN_SRR1, r11
 958         mr      r9, r4
 959         bl      kvmppc_msr_interrupt
 960 5:
 961
 962 /*
 963  * Required state:
 964  * R4 = vcpu
 965  * R10: value for HSRR0
 966  * R11: value for HSRR1
 967  * R13 = PACA
 968  */
 969 fast_guest_return:
 970         li      r0,0
 971         stb     r0,VCPU_CEDED(r4)       /* cancel cede */
 972         mtspr   SPRN_HSRR0,r10
 973         mtspr   SPRN_HSRR1,r11
 974
 975         /* Activate guest mode, so faults get handled by KVM */
 976         li      r9, KVM_GUEST_MODE_GUEST_HV
 977         stb     r9, HSTATE_IN_GUEST(r13)
 978
 979 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
 980         /* Accumulate timing */
 981         addi    r3, r4, VCPU_TB_GUEST
 982         bl      kvmhv_accumulate_time
 983 #endif
 984
 985         /* Enter guest */
 986
 987 BEGIN_FTR_SECTION
 988         ld      r5, VCPU_CFAR(r4)
 989         mtspr   SPRN_CFAR, r5
 990 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
 991 BEGIN_FTR_SECTION
 992         ld      r0, VCPU_PPR(r4)
 993 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
 994
 995         ld      r5, VCPU_LR(r4)
 996         lwz     r6, VCPU_CR(r4)
 997         mtlr    r5
 998         mtcr    r6
 999
1000         ld      r1, VCPU_GPR(R1)(r4)
1001         ld      r2, VCPU_GPR(R2)(r4)
1002         ld      r3, VCPU_GPR(R3)(r4)
1003         ld      r5, VCPU_GPR(R5)(r4)
1004         ld      r6, VCPU_GPR(R6)(r4)
1005         ld      r7, VCPU_GPR(R7)(r4)
1006         ld      r8, VCPU_GPR(R8)(r4)
1007         ld      r9, VCPU_GPR(R9)(r4)
1008         ld      r10, VCPU_GPR(R10)(r4)
1009         ld      r11, VCPU_GPR(R11)(r4)
1010         ld      r12, VCPU_GPR(R12)(r4)
1011         ld      r13, VCPU_GPR(R13)(r4)
1012
1013 BEGIN_FTR_SECTION
1014         mtspr   SPRN_PPR, r0
1015 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
1016         ld      r0, VCPU_GPR(R0)(r4)
1017         ld      r4, VCPU_GPR(R4)(r4)
1018
1019         hrfid
1020         b       .
1021
1022 secondary_too_late:
1023         li      r12, 0
1024         cmpdi   r4, 0
1025         beq     11f
1026         stw     r12, VCPU_TRAP(r4)
1027 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
1028         addi    r3, r4, VCPU_TB_RMEXIT
1029         bl      kvmhv_accumulate_time
1030 #endif
1031 11:     b       kvmhv_switch_to_host
1032
1033 no_switch_exit:
1034         HMT_MEDIUM
1035         li      r12, 0
1036         b       12f
1037 hdec_soon:
1038         li      r12, BOOK3S_INTERRUPT_HV_DECREMENTER
1039 12:     stw     r12, VCPU_TRAP(r4)
1040         mr      r9, r4
1041 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
1042         addi    r3, r4, VCPU_TB_RMEXIT
1043         bl      kvmhv_accumulate_time
1044 #endif
1045         b       guest_exit_cont
1046
1047 /******************************************************************************
1048  *                                                                            *
1049  *                               Exit code                                    *
1050  *                                                                            *
1051  *****************************************************************************/
1052
1053 /*
1054  * We come here from the first-level interrupt handlers.
1055  */
1056         .globl  kvmppc_interrupt_hv
1057 kvmppc_interrupt_hv:
1058         /*
1059          * Register contents:
1060          * R12          = (guest CR << 32) | interrupt vector
1061          * R13          = PACA
1062          * guest R12 saved in shadow VCPU SCRATCH0
1063          * guest R13 saved in SPRN_SCRATCH0
1064          */
1065         std     r9, HSTATE_SCRATCH1(r13)
1066         lbz     r9, HSTATE_IN_GUEST(r13)
1067         cmpwi   r9, KVM_GUEST_MODE_HOST_HV
1068         beq     kvmppc_bad_host_intr
1069 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
1070         cmpwi   r9, KVM_GUEST_MODE_GUEST
1071         ld      r9, HSTATE_SCRATCH1(r13)
1072         beq     kvmppc_interrupt_pr
1073 #endif
1074         /* We're now back in the host but in guest MMU context */
1075         li      r9, KVM_GUEST_MODE_HOST_HV
1076         stb     r9, HSTATE_IN_GUEST(r13)
1077
1078         ld      r9, HSTATE_KVM_VCPU(r13)
1079
1080         /* Save registers */
1081
1082         std     r0, VCPU_GPR(R0)(r9)
1083         std     r1, VCPU_GPR(R1)(r9)
1084         std     r2, VCPU_GPR(R2)(r9)
1085         std     r3, VCPU_GPR(R3)(r9)
1086         std     r4, VCPU_GPR(R4)(r9)
1087         std     r5, VCPU_GPR(R5)(r9)
1088         std     r6, VCPU_GPR(R6)(r9)
1089         std     r7, VCPU_GPR(R7)(r9)
1090         std     r8, VCPU_GPR(R8)(r9)
1091         ld      r0, HSTATE_SCRATCH1(r13)
1092         std     r0, VCPU_GPR(R9)(r9)
1093         std     r10, VCPU_GPR(R10)(r9)
1094         std     r11, VCPU_GPR(R11)(r9)
1095         ld      r3, HSTATE_SCRATCH0(r13)
1096         std     r3, VCPU_GPR(R12)(r9)
1097         /* CR is in the high half of r12 */
1098         srdi    r4, r12, 32
1099         stw     r4, VCPU_CR(r9)
1100 BEGIN_FTR_SECTION
1101         ld      r3, HSTATE_CFAR(r13)
1102         std     r3, VCPU_CFAR(r9)
1103 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
1104 BEGIN_FTR_SECTION
1105         ld      r4, HSTATE_PPR(r13)
1106         std     r4, VCPU_PPR(r9)
1107 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
1108
1109         /* Restore R1/R2 so we can handle faults */
1110         ld      r1, HSTATE_HOST_R1(r13)
1111         ld      r2, PACATOC(r13)
1112
1113         mfspr   r10, SPRN_SRR0
1114         mfspr   r11, SPRN_SRR1
1115         std     r10, VCPU_SRR0(r9)
1116         std     r11, VCPU_SRR1(r9)
1117         /* trap is in the low half of r12, clear CR from the high half */
1118         clrldi  r12, r12, 32
1119         andi.   r0, r12, 2              /* need to read HSRR0/1? */
1120         beq     1f
1121         mfspr   r10, SPRN_HSRR0
1122         mfspr   r11, SPRN_HSRR1
1123         clrrdi  r12, r12, 2
1124 1:      std     r10, VCPU_PC(r9)
1125         std     r11, VCPU_MSR(r9)
1126
1127         GET_SCRATCH0(r3)
1128         mflr    r4
1129         std     r3, VCPU_GPR(R13)(r9)
1130         std     r4, VCPU_LR(r9)
1131
1132         stw     r12,VCPU_TRAP(r9)
1133
1134 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
1135         addi    r3, r9, VCPU_TB_RMINTR
1136         mr      r4, r9
1137         bl      kvmhv_accumulate_time
1138         ld      r5, VCPU_GPR(R5)(r9)
1139         ld      r6, VCPU_GPR(R6)(r9)
1140         ld      r7, VCPU_GPR(R7)(r9)
1141         ld      r8, VCPU_GPR(R8)(r9)
1142 #endif
1143
1144         /* Save HEIR (HV emulation assist reg) in emul_inst
1145            if this is an HEI (HV emulation interrupt, e40) */
1146         li      r3,KVM_INST_FETCH_FAILED
1147         stw     r3,VCPU_LAST_INST(r9)
1148         cmpwi   r12,BOOK3S_INTERRUPT_H_EMUL_ASSIST
1149         bne     11f
1150         mfspr   r3,SPRN_HEIR
1151 11:     stw     r3,VCPU_HEIR(r9)
1152
1153         /* these are volatile across C function calls */
1154         mfctr   r3
1155         mfxer   r4
1156         std     r3, VCPU_CTR(r9)
1157         std     r4, VCPU_XER(r9)
1158
1159         /* If this is a page table miss then see if it's theirs or ours */
1160         cmpwi   r12, BOOK3S_INTERRUPT_H_DATA_STORAGE
1161         beq     kvmppc_hdsi
1162         cmpwi   r12, BOOK3S_INTERRUPT_H_INST_STORAGE
1163         beq     kvmppc_hisi
1164
1165         /* See if this is a leftover HDEC interrupt */
1166         cmpwi   r12,BOOK3S_INTERRUPT_HV_DECREMENTER
1167         bne     2f
1168         mfspr   r3,SPRN_HDEC
1169         cmpwi   r3,0
1170         mr      r4,r9
1171         bge     fast_guest_return
1172 2:
1173         /* See if this is an hcall we can handle in real mode */
1174         cmpwi   r12,BOOK3S_INTERRUPT_SYSCALL
1175         beq     hcall_try_real_mode
1176
1177         /* Hypervisor doorbell - exit only if host IPI flag set */
1178         cmpwi   r12, BOOK3S_INTERRUPT_H_DOORBELL
1179         bne     3f
1180         lbz     r0, HSTATE_HOST_IPI(r13)
1181         cmpwi   r0, 0
1182         beq     4f
1183         b       guest_exit_cont
1184 3:
1185         /* External interrupt ? */
1186         cmpwi   r12, BOOK3S_INTERRUPT_EXTERNAL
1187         bne+    guest_exit_cont
1188
1189         /* External interrupt, first check for host_ipi. If this is
1190          * set, we know the host wants us out so let's do it now
1191          */
1192         bl      kvmppc_read_intr
1193
1194         /*
1195          * Restore the active volatile registers after returning from
1196          * a C function.
1197          */
1198         ld      r9, HSTATE_KVM_VCPU(r13)
1199         li      r12, BOOK3S_INTERRUPT_EXTERNAL
1200
1201         /*
1202          * kvmppc_read_intr return codes:
1203          *
1204          * Exit to host (r3 > 0)
1205          *   1 An interrupt is pending that needs to be handled by the host
1206          *     Exit guest and return to host by branching to guest_exit_cont
1207          *
1208          *   2 Passthrough that needs completion in the host
1209          *     Exit guest and return to host by branching to guest_exit_cont
1210          *     However, we also set r12 to BOOK3S_INTERRUPT_HV_RM_HARD
1211          *     to indicate to the host to complete handling the interrupt
1212          *
1213          * Before returning to guest, we check if any CPU is heading out
1214          * to the host and if so, we head out also. If no CPUs are heading
1215          * check return values <= 0.
1216          *
1217          * Return to guest (r3 <= 0)
1218          *  0 No external interrupt is pending
1219          * -1 A guest wakeup IPI (which has now been cleared)
1220          *    In either case, we return to guest to deliver any pending
1221          *    guest interrupts.
1222          *
1223          * -2 A PCI passthrough external interrupt was handled
1224          *    (interrupt was delivered directly to guest)
1225          *    Return to guest to deliver any pending guest interrupts.
1226          */
1227
1228         cmpdi   r3, 1
1229         ble     1f
1230
1231         /* Return code = 2 */
1232         li      r12, BOOK3S_INTERRUPT_HV_RM_HARD
1233         stw     r12, VCPU_TRAP(r9)
1234         b       guest_exit_cont
1235
1236 1:      /* Return code <= 1 */
1237         cmpdi   r3, 0
1238         bgt     guest_exit_cont
1239
1240         /* Return code <= 0 */
1241 4:      ld      r5, HSTATE_KVM_VCORE(r13)
1242         lwz     r0, VCORE_ENTRY_EXIT(r5)
1243         cmpwi   r0, 0x100
1244         mr      r4, r9
1245         blt     deliver_guest_interrupt
1246
1247 guest_exit_cont:                /* r9 = vcpu, r12 = trap, r13 = paca */
1248         /* Save more register state  */
1249         mfdar   r6
1250         mfdsisr r7
1251         std     r6, VCPU_DAR(r9)
1252         stw     r7, VCPU_DSISR(r9)
1253         /* don't overwrite fault_dar/fault_dsisr if HDSI */
1254         cmpwi   r12,BOOK3S_INTERRUPT_H_DATA_STORAGE
1255         beq     mc_cont
1256         std     r6, VCPU_FAULT_DAR(r9)
1257         stw     r7, VCPU_FAULT_DSISR(r9)
1258
1259         /* See if it is a machine check */
1260         cmpwi   r12, BOOK3S_INTERRUPT_MACHINE_CHECK
1261         beq     machine_check_realmode
1262 mc_cont:
1263 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
1264         addi    r3, r9, VCPU_TB_RMEXIT
1265         mr      r4, r9
1266         bl      kvmhv_accumulate_time
1267 #endif
1268
1269         mr      r3, r12
1270         /* Increment exit count, poke other threads to exit */
1271         bl      kvmhv_commence_exit
1272         nop
1273         ld      r9, HSTATE_KVM_VCPU(r13)
1274         lwz     r12, VCPU_TRAP(r9)
1275
1276         /* Stop others sending VCPU interrupts to this physical CPU */
1277         li      r0, -1
1278         stw     r0, VCPU_CPU(r9)
1279         stw     r0, VCPU_THREAD_CPU(r9)
1280
1281         /* Save guest CTRL register, set runlatch to 1 */
1282         mfspr   r6,SPRN_CTRLF
1283         stw     r6,VCPU_CTRL(r9)
1284         andi.   r0,r6,1
1285         bne     4f
1286         ori     r6,r6,1
1287         mtspr   SPRN_CTRLT,r6
1288 4:
1289         /* Read the guest SLB and save it away */
1290         lwz     r0,VCPU_SLB_NR(r9)      /* number of entries in SLB */
1291         mtctr   r0
1292         li      r6,0
1293         addi    r7,r9,VCPU_SLB
1294         li      r5,0
1295 1:      slbmfee r8,r6
1296         andis.  r0,r8,SLB_ESID_V@h
1297         beq     2f
1298         add     r8,r8,r6                /* put index in */
1299         slbmfev r3,r6
1300         std     r8,VCPU_SLB_E(r7)
1301         std     r3,VCPU_SLB_V(r7)
1302         addi    r7,r7,VCPU_SLB_SIZE
1303         addi    r5,r5,1
1304 2:      addi    r6,r6,1
1305         bdnz    1b
1306         stw     r5,VCPU_SLB_MAX(r9)
1307
1308         /*
1309          * Save the guest PURR/SPURR
1310          */
1311         mfspr   r5,SPRN_PURR
1312         mfspr   r6,SPRN_SPURR
1313         ld      r7,VCPU_PURR(r9)
1314         ld      r8,VCPU_SPURR(r9)
1315         std     r5,VCPU_PURR(r9)
1316         std     r6,VCPU_SPURR(r9)
1317         subf    r5,r7,r5
1318         subf    r6,r8,r6
1319
1320         /*
1321          * Restore host PURR/SPURR and add guest times
1322          * so that the time in the guest gets accounted.
1323          */
1324         ld      r3,HSTATE_PURR(r13)
1325         ld      r4,HSTATE_SPURR(r13)
1326         add     r3,r3,r5
1327         add     r4,r4,r6
1328         mtspr   SPRN_PURR,r3
1329         mtspr   SPRN_SPURR,r4
1330
1331         /* Save DEC */
1332         mfspr   r5,SPRN_DEC
1333         mftb    r6
1334         extsw   r5,r5
1335         add     r5,r5,r6
1336         /* r5 is a guest timebase value here, convert to host TB */
1337         ld      r3,HSTATE_KVM_VCORE(r13)
1338         ld      r4,VCORE_TB_OFFSET(r3)
1339         subf    r5,r4,r5
1340         std     r5,VCPU_DEC_EXPIRES(r9)
1341
1342 BEGIN_FTR_SECTION
1343         b       8f
1344 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_207S)
1345         /* Save POWER8-specific registers */
1346         mfspr   r5, SPRN_IAMR
1347         mfspr   r6, SPRN_PSPB
1348         mfspr   r7, SPRN_FSCR
1349         std     r5, VCPU_IAMR(r9)
1350         stw     r6, VCPU_PSPB(r9)
1351         std     r7, VCPU_FSCR(r9)
1352         mfspr   r5, SPRN_IC
1353         mfspr   r7, SPRN_TAR
1354         std     r5, VCPU_IC(r9)
1355         std     r7, VCPU_TAR(r9)
1356         mfspr   r8, SPRN_EBBHR
1357         std     r8, VCPU_EBBHR(r9)
1358         mfspr   r5, SPRN_EBBRR
1359         mfspr   r6, SPRN_BESCR
1360         mfspr   r7, SPRN_PID
1361         mfspr   r8, SPRN_WORT
1362         std     r5, VCPU_EBBRR(r9)
1363         std     r6, VCPU_BESCR(r9)
1364         stw     r7, VCPU_GUEST_PID(r9)
1365         std     r8, VCPU_WORT(r9)
1366 BEGIN_FTR_SECTION
1367         mfspr   r5, SPRN_TCSCR
1368         mfspr   r6, SPRN_ACOP
1369         mfspr   r7, SPRN_CSIGR
1370         mfspr   r8, SPRN_TACR
1371         std     r5, VCPU_TCSCR(r9)
1372         std     r6, VCPU_ACOP(r9)
1373         std     r7, VCPU_CSIGR(r9)
1374         std     r8, VCPU_TACR(r9)
1375 FTR_SECTION_ELSE
1376         mfspr   r5, SPRN_TIDR
1377         mfspr   r6, SPRN_PSSCR
1378         std     r5, VCPU_TID(r9)
1379         rldicl  r6, r6, 4, 50           /* r6 &= PSSCR_GUEST_VIS */
1380         rotldi  r6, r6, 60
1381         std     r6, VCPU_PSSCR(r9)
1382 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_ARCH_300)
1383         /*
1384          * Restore various registers to 0, where non-zero values
1385          * set by the guest could disrupt the host.
1386          */
1387         li      r0, 0
1388         mtspr   SPRN_IAMR, r0
1389         mtspr   SPRN_CIABR, r0
1390         mtspr   SPRN_DAWRX, r0
1391         mtspr   SPRN_WORT, r0
1392 BEGIN_FTR_SECTION
1393         mtspr   SPRN_TCSCR, r0
1394         /* Set MMCRS to 1<<31 to freeze and disable the SPMC counters */
1395         li      r0, 1
1396         sldi    r0, r0, 31
1397         mtspr   SPRN_MMCRS, r0
1398 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_300)
1399 8:
1400
1401         /* Save and reset AMR and UAMOR before turning on the MMU */
1402         mfspr   r5,SPRN_AMR
1403         mfspr   r6,SPRN_UAMOR
1404         std     r5,VCPU_AMR(r9)
1405         std     r6,VCPU_UAMOR(r9)
1406         li      r6,0
1407         mtspr   SPRN_AMR,r6
1408
1409         /* Switch DSCR back to host value */
1410         mfspr   r8, SPRN_DSCR
1411         ld      r7, HSTATE_DSCR(r13)
1412         std     r8, VCPU_DSCR(r9)
1413         mtspr   SPRN_DSCR, r7
1414
1415         /* Save non-volatile GPRs */
1416         std     r14, VCPU_GPR(R14)(r9)
1417         std     r15, VCPU_GPR(R15)(r9)
1418         std     r16, VCPU_GPR(R16)(r9)
1419         std     r17, VCPU_GPR(R17)(r9)
1420         std     r18, VCPU_GPR(R18)(r9)
1421         std     r19, VCPU_GPR(R19)(r9)
1422         std     r20, VCPU_GPR(R20)(r9)
1423         std     r21, VCPU_GPR(R21)(r9)
1424         std     r22, VCPU_GPR(R22)(r9)
1425         std     r23, VCPU_GPR(R23)(r9)
1426         std     r24, VCPU_GPR(R24)(r9)
1427         std     r25, VCPU_GPR(R25)(r9)
1428         std     r26, VCPU_GPR(R26)(r9)
1429         std     r27, VCPU_GPR(R27)(r9)
1430         std     r28, VCPU_GPR(R28)(r9)
1431         std     r29, VCPU_GPR(R29)(r9)
1432         std     r30, VCPU_GPR(R30)(r9)
1433         std     r31, VCPU_GPR(R31)(r9)
1434
1435         /* Save SPRGs */
1436         mfspr   r3, SPRN_SPRG0
1437         mfspr   r4, SPRN_SPRG1
1438         mfspr   r5, SPRN_SPRG2
1439         mfspr   r6, SPRN_SPRG3
1440         std     r3, VCPU_SPRG0(r9)
1441         std     r4, VCPU_SPRG1(r9)
1442         std     r5, VCPU_SPRG2(r9)
1443         std     r6, VCPU_SPRG3(r9)
1444
1445         /* save FP state */
1446         mr      r3, r9
1447         bl      kvmppc_save_fp
1448
1449 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
1450 BEGIN_FTR_SECTION
1451         bl      kvmppc_save_tm
1452 END_FTR_SECTION_IFSET(CPU_FTR_TM)
1453 #endif
1454
1455         /* Increment yield count if they have a VPA */
1456         ld      r8, VCPU_VPA(r9)        /* do they have a VPA? */
1457         cmpdi   r8, 0
1458         beq     25f
1459         li      r4, LPPACA_YIELDCOUNT
1460         LWZX_BE r3, r8, r4
1461         addi    r3, r3, 1
1462         STWX_BE r3, r8, r4
1463         li      r3, 1
1464         stb     r3, VCPU_VPA_DIRTY(r9)
1465 25:
1466         /* Save PMU registers if requested */
1467         /* r8 and cr0.eq are live here */
1468 BEGIN_FTR_SECTION
1469         /*
1470          * POWER8 seems to have a hardware bug where setting
1471          * MMCR0[PMAE] along with MMCR0[PMC1CE] and/or MMCR0[PMCjCE]
1472          * when some counters are already negative doesn't seem
1473          * to cause a performance monitor alert (and hence interrupt).
1474          * The effect of this is that when saving the PMU state,
1475          * if there is no PMU alert pending when we read MMCR0
1476          * before freezing the counters, but one becomes pending
1477          * before we read the counters, we lose it.
1478          * To work around this, we need a way to freeze the counters
1479          * before reading MMCR0.  Normally, freezing the counters
1480          * is done by writing MMCR0 (to set MMCR0[FC]) which
1481          * unavoidably writes MMCR0[PMA0] as well.  On POWER8,
1482          * we can also freeze the counters using MMCR2, by writing
1483          * 1s to all the counter freeze condition bits (there are
1484          * 9 bits each for 6 counters).
1485          */
1486         li      r3, -1                  /* set all freeze bits */
1487         clrrdi  r3, r3, 10
1488         mfspr   r10, SPRN_MMCR2
1489         mtspr   SPRN_MMCR2, r3
1490         isync
1491 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
1492         li      r3, 1
1493         sldi    r3, r3, 31              /* MMCR0_FC (freeze counters) bit */
1494         mfspr   r4, SPRN_MMCR0          /* save MMCR0 */
1495         mtspr   SPRN_MMCR0, r3          /* freeze all counters, disable ints */
1496         mfspr   r6, SPRN_MMCRA
1497         /* Clear MMCRA in order to disable SDAR updates */
1498         li      r7, 0
1499         mtspr   SPRN_MMCRA, r7
1500         isync
1501         beq     21f                     /* if no VPA, save PMU stuff anyway */
1502         lbz     r7, LPPACA_PMCINUSE(r8)
1503         cmpwi   r7, 0                   /* did they ask for PMU stuff to be saved? */
1504         bne     21f
1505         std     r3, VCPU_MMCR(r9)       /* if not, set saved MMCR0 to FC */
1506         b       22f
1507 21:     mfspr   r5, SPRN_MMCR1
1508         mfspr   r7, SPRN_SIAR
1509         mfspr   r8, SPRN_SDAR
1510         std     r4, VCPU_MMCR(r9)
1511         std     r5, VCPU_MMCR + 8(r9)
1512         std     r6, VCPU_MMCR + 16(r9)
1513 BEGIN_FTR_SECTION
1514         std     r10, VCPU_MMCR + 24(r9)
1515 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
1516         std     r7, VCPU_SIAR(r9)
1517         std     r8, VCPU_SDAR(r9)
1518         mfspr   r3, SPRN_PMC1
1519         mfspr   r4, SPRN_PMC2
1520         mfspr   r5, SPRN_PMC3
1521         mfspr   r6, SPRN_PMC4
1522         mfspr   r7, SPRN_PMC5
1523         mfspr   r8, SPRN_PMC6
1524         stw     r3, VCPU_PMC(r9)
1525         stw     r4, VCPU_PMC + 4(r9)
1526         stw     r5, VCPU_PMC + 8(r9)
1527         stw     r6, VCPU_PMC + 12(r9)
1528         stw     r7, VCPU_PMC + 16(r9)
1529         stw     r8, VCPU_PMC + 20(r9)
1530 BEGIN_FTR_SECTION
1531         mfspr   r5, SPRN_SIER
1532         std     r5, VCPU_SIER(r9)
1533 BEGIN_FTR_SECTION_NESTED(96)
1534         mfspr   r6, SPRN_SPMC1
1535         mfspr   r7, SPRN_SPMC2
1536         mfspr   r8, SPRN_MMCRS
1537         stw     r6, VCPU_PMC + 24(r9)
1538         stw     r7, VCPU_PMC + 28(r9)
1539         std     r8, VCPU_MMCR + 32(r9)
1540         lis     r4, 0x8000
1541         mtspr   SPRN_MMCRS, r4
1542 END_FTR_SECTION_NESTED(CPU_FTR_ARCH_300, 0, 96)
1543 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
1544 22:
1545         /* Clear out SLB */
1546         li      r5,0
1547         slbmte  r5,r5
1548         slbia
1549         ptesync
1550
1551         /* Restore host values of some registers */
1552 BEGIN_FTR_SECTION
1553         ld      r5, STACK_SLOT_TID(r1)
1554         ld      r6, STACK_SLOT_PSSCR(r1)
1555         mtspr   SPRN_TIDR, r5
1556         mtspr   SPRN_PSSCR, r6
1557 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
1558
1559         /*
1560          * POWER7/POWER8 guest -> host partition switch code.
1561          * We don't have to lock against tlbies but we do
1562          * have to coordinate the hardware threads.
1563          */
1564 kvmhv_switch_to_host:
1565         /* Secondary threads wait for primary to do partition switch */
1566         ld      r5,HSTATE_KVM_VCORE(r13)
1567         ld      r4,VCORE_KVM(r5)        /* pointer to struct kvm */
1568         lbz     r3,HSTATE_PTID(r13)
1569         cmpwi   r3,0
1570         beq     15f
1571         HMT_LOW
1572 13:     lbz     r3,VCORE_IN_GUEST(r5)
1573         cmpwi   r3,0
1574         bne     13b
1575         HMT_MEDIUM
1576         b       16f
1577
1578         /* Primary thread waits for all the secondaries to exit guest */
1579 15:     lwz     r3,VCORE_ENTRY_EXIT(r5)
1580         rlwinm  r0,r3,32-8,0xff
1581         clrldi  r3,r3,56
1582         cmpw    r3,r0
1583         bne     15b
1584         isync
1585
1586         /* Did we actually switch to the guest at all? */
1587         lbz     r6, VCORE_IN_GUEST(r5)
1588         cmpwi   r6, 0
1589         beq     19f
1590
1591         /* Primary thread switches back to host partition */
1592         lwz     r7,KVM_HOST_LPID(r4)
1593 BEGIN_FTR_SECTION
1594         ld      r6,KVM_HOST_SDR1(r4)
1595         li      r8,LPID_RSVD            /* switch to reserved LPID */
1596         mtspr   SPRN_LPID,r8
1597         ptesync
1598         mtspr   SPRN_SDR1,r6            /* switch to host page table */
1599 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_300)
1600         mtspr   SPRN_LPID,r7
1601         isync
1602
1603 BEGIN_FTR_SECTION
1604         /* DPDES and VTB are shared between threads */
1605         mfspr   r7, SPRN_DPDES
1606         mfspr   r8, SPRN_VTB
1607         std     r7, VCORE_DPDES(r5)
1608         std     r8, VCORE_VTB(r5)
1609         /* clear DPDES so we don't get guest doorbells in the host */
1610         li      r8, 0
1611         mtspr   SPRN_DPDES, r8
1612 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
1613
1614         /* If HMI, call kvmppc_realmode_hmi_handler() */
1615         cmpwi   r12, BOOK3S_INTERRUPT_HMI
1616         bne     27f
1617         bl      kvmppc_realmode_hmi_handler
1618         nop
1619         li      r12, BOOK3S_INTERRUPT_HMI
1620         /*
1621          * At this point kvmppc_realmode_hmi_handler would have resync-ed
1622          * the TB. Hence it is not required to subtract guest timebase
1623          * offset from timebase. So, skip it.
1624          *
1625          * Also, do not call kvmppc_subcore_exit_guest() because it has
1626          * been invoked as part of kvmppc_realmode_hmi_handler().
1627          */
1628         b       30f
1629
1630 27:
1631         /* Subtract timebase offset from timebase */
1632         ld      r8,VCORE_TB_OFFSET(r5)
1633         cmpdi   r8,0
1634         beq     17f
1635         mftb    r6                      /* current guest timebase */
1636         subf    r8,r8,r6
1637         mtspr   SPRN_TBU40,r8           /* update upper 40 bits */
1638         mftb    r7                      /* check if lower 24 bits overflowed */
1639         clrldi  r6,r6,40
1640         clrldi  r7,r7,40
1641         cmpld   r7,r6
1642         bge     17f
1643         addis   r8,r8,0x100             /* if so, increment upper 40 bits */
1644         mtspr   SPRN_TBU40,r8
1645
1646 17:     bl      kvmppc_subcore_exit_guest
1647         nop
1648 30:     ld      r5,HSTATE_KVM_VCORE(r13)
1649         ld      r4,VCORE_KVM(r5)        /* pointer to struct kvm */
1650
1651         /* Reset PCR */
1652         ld      r0, VCORE_PCR(r5)
1653         cmpdi   r0, 0
1654         beq     18f
1655         li      r0, 0
1656         mtspr   SPRN_PCR, r0
1657 18:
1658         /* Signal secondary CPUs to continue */
1659         stb     r0,VCORE_IN_GUEST(r5)
1660 19:     lis     r8,0x7fff               /* MAX_INT@h */
1661         mtspr   SPRN_HDEC,r8
1662
1663 16:     ld      r8,KVM_HOST_LPCR(r4)
1664         mtspr   SPRN_LPCR,r8
1665         isync
1666
1667         /* load host SLB entries */
1668         ld      r8,PACA_SLBSHADOWPTR(r13)
1669
1670         .rept   SLB_NUM_BOLTED
1671         li      r3, SLBSHADOW_SAVEAREA
1672         LDX_BE  r5, r8, r3
1673         addi    r3, r3, 8
1674         LDX_BE  r6, r8, r3
1675         andis.  r7,r5,SLB_ESID_V@h
1676         beq     1f
1677         slbmte  r6,r5
1678 1:      addi    r8,r8,16
1679         .endr
1680
1681 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
1682         /* Finish timing, if we have a vcpu */
1683         ld      r4, HSTATE_KVM_VCPU(r13)
1684         cmpdi   r4, 0
1685         li      r3, 0
1686         beq     2f
1687         bl      kvmhv_accumulate_time
1688 2:
1689 #endif
1690         /* Unset guest mode */
1691         li      r0, KVM_GUEST_MODE_NONE
1692         stb     r0, HSTATE_IN_GUEST(r13)
1693
1694         ld      r0, 112+PPC_LR_STKOFF(r1)
1695         addi    r1, r1, 112
1696         mtlr    r0
1697         blr
1698
1699 /*
1700  * Check whether an HDSI is an HPTE not found fault or something else.
1701  * If it is an HPTE not found fault that is due to the guest accessing
1702  * a page that they have mapped but which we have paged out, then
1703  * we continue on with the guest exit path.  In all other cases,
1704  * reflect the HDSI to the guest as a DSI.
1705  */
1706 kvmppc_hdsi:
1707         mfspr   r4, SPRN_HDAR
1708         mfspr   r6, SPRN_HDSISR
1709         /* HPTE not found fault or protection fault? */
1710         andis.  r0, r6, (DSISR_NOHPTE | DSISR_PROTFAULT)@h
1711         beq     1f                      /* if not, send it to the guest */
1712         andi.   r0, r11, MSR_DR         /* data relocation enabled? */
1713         beq     3f
1714         clrrdi  r0, r4, 28
1715         PPC_SLBFEE_DOT(R5, R0)          /* if so, look up SLB */
1716         li      r0, BOOK3S_INTERRUPT_DATA_SEGMENT
1717         bne     7f                      /* if no SLB entry found */
1718 4:      std     r4, VCPU_FAULT_DAR(r9)
1719         stw     r6, VCPU_FAULT_DSISR(r9)
1720
1721         /* Search the hash table. */
1722         mr      r3, r9                  /* vcpu pointer */
1723         li      r7, 1                   /* data fault */
1724         bl      kvmppc_hpte_hv_fault
1725         ld      r9, HSTATE_KVM_VCPU(r13)
1726         ld      r10, VCPU_PC(r9)
1727         ld      r11, VCPU_MSR(r9)
1728         li      r12, BOOK3S_INTERRUPT_H_DATA_STORAGE
1729         cmpdi   r3, 0                   /* retry the instruction */
1730         beq     6f
1731         cmpdi   r3, -1                  /* handle in kernel mode */
1732         beq     guest_exit_cont
1733         cmpdi   r3, -2                  /* MMIO emulation; need instr word */
1734         beq     2f
1735
1736         /* Synthesize a DSI (or DSegI) for the guest */
1737         ld      r4, VCPU_FAULT_DAR(r9)
1738         mr      r6, r3
1739 1:      li      r0, BOOK3S_INTERRUPT_DATA_STORAGE
1740         mtspr   SPRN_DSISR, r6
1741 7:      mtspr   SPRN_DAR, r4
1742         mtspr   SPRN_SRR0, r10
1743         mtspr   SPRN_SRR1, r11
1744         mr      r10, r0
1745         bl      kvmppc_msr_interrupt
1746 fast_interrupt_c_return:
1747 6:      ld      r7, VCPU_CTR(r9)
1748         ld      r8, VCPU_XER(r9)
1749         mtctr   r7
1750         mtxer   r8
1751         mr      r4, r9
1752         b       fast_guest_return
1753
1754 3:      ld      r5, VCPU_KVM(r9)        /* not relocated, use VRMA */
1755         ld      r5, KVM_VRMA_SLB_V(r5)
1756         b       4b
1757
1758         /* If this is for emulated MMIO, load the instruction word */
1759 2:      li      r8, KVM_INST_FETCH_FAILED       /* In case lwz faults */
1760
1761         /* Set guest mode to 'jump over instruction' so if lwz faults
1762          * we'll just continue at the next IP. */
1763         li      r0, KVM_GUEST_MODE_SKIP
1764         stb     r0, HSTATE_IN_GUEST(r13)
1765
1766         /* Do the access with MSR:DR enabled */
1767         mfmsr   r3
1768         ori     r4, r3, MSR_DR          /* Enable paging for data */
1769         mtmsrd  r4
1770         lwz     r8, 0(r10)
1771         mtmsrd  r3
1772
1773         /* Store the result */
1774         stw     r8, VCPU_LAST_INST(r9)
1775
1776         /* Unset guest mode. */
1777         li      r0, KVM_GUEST_MODE_HOST_HV
1778         stb     r0, HSTATE_IN_GUEST(r13)
1779         b       guest_exit_cont
1780
1781 /*
1782  * Similarly for an HISI, reflect it to the guest as an ISI unless
1783  * it is an HPTE not found fault for a page that we have paged out.
1784  */
1785 kvmppc_hisi:
1786         andis.  r0, r11, SRR1_ISI_NOPT@h
1787         beq     1f
1788         andi.   r0, r11, MSR_IR         /* instruction relocation enabled? */
1789         beq     3f
1790         clrrdi  r0, r10, 28
1791         PPC_SLBFEE_DOT(R5, R0)          /* if so, look up SLB */
1792         li      r0, BOOK3S_INTERRUPT_INST_SEGMENT
1793         bne     7f                      /* if no SLB entry found */
1794 4:
1795         /* Search the hash table. */
1796         mr      r3, r9                  /* vcpu pointer */
1797         mr      r4, r10
1798         mr      r6, r11
1799         li      r7, 0                   /* instruction fault */
1800         bl      kvmppc_hpte_hv_fault
1801         ld      r9, HSTATE_KVM_VCPU(r13)
1802         ld      r10, VCPU_PC(r9)
1803         ld      r11, VCPU_MSR(r9)
1804         li      r12, BOOK3S_INTERRUPT_H_INST_STORAGE
1805         cmpdi   r3, 0                   /* retry the instruction */
1806         beq     fast_interrupt_c_return
1807         cmpdi   r3, -1                  /* handle in kernel mode */
1808         beq     guest_exit_cont
1809
1810         /* Synthesize an ISI (or ISegI) for the guest */
1811         mr      r11, r3
1812 1:      li      r0, BOOK3S_INTERRUPT_INST_STORAGE
1813 7:      mtspr   SPRN_SRR0, r10
1814         mtspr   SPRN_SRR1, r11
1815         mr      r10, r0
1816         bl      kvmppc_msr_interrupt
1817         b       fast_interrupt_c_return
1818
1819 3:      ld      r6, VCPU_KVM(r9)        /* not relocated, use VRMA */
1820         ld      r5, KVM_VRMA_SLB_V(r6)
1821         b       4b
1822
1823 /*
1824  * Try to handle an hcall in real mode.
1825  * Returns to the guest if we handle it, or continues on up to
1826  * the kernel if we can't (i.e. if we don't have a handler for
1827  * it, or if the handler returns H_TOO_HARD).
1828  *
1829  * r5 - r8 contain hcall args,
1830  * r9 = vcpu, r10 = pc, r11 = msr, r12 = trap, r13 = paca
1831  */
1832 hcall_try_real_mode:
1833         ld      r3,VCPU_GPR(R3)(r9)
1834         andi.   r0,r11,MSR_PR
1835         /* sc 1 from userspace - reflect to guest syscall */
1836         bne     sc_1_fast_return
1837         clrrdi  r3,r3,2
1838         cmpldi  r3,hcall_real_table_end - hcall_real_table
1839         bge     guest_exit_cont
1840         /* See if this hcall is enabled for in-kernel handling */
1841         ld      r4, VCPU_KVM(r9)
1842         srdi    r0, r3, 8       /* r0 = (r3 / 4) >> 6 */
1843         sldi    r0, r0, 3       /* index into kvm->arch.enabled_hcalls[] */
1844         add     r4, r4, r0
1845         ld      r0, KVM_ENABLED_HCALLS(r4)
1846         rlwinm  r4, r3, 32-2, 0x3f      /* r4 = (r3 / 4) & 0x3f */
1847         srd     r0, r0, r4
1848         andi.   r0, r0, 1
1849         beq     guest_exit_cont
1850         /* Get pointer to handler, if any, and call it */
1851         LOAD_REG_ADDR(r4, hcall_real_table)
1852         lwax    r3,r3,r4
1853         cmpwi   r3,0
1854         beq     guest_exit_cont
1855         add     r12,r3,r4
1856         mtctr   r12
1857         mr      r3,r9           /* get vcpu pointer */
1858         ld      r4,VCPU_GPR(R4)(r9)
1859         bctrl
1860         cmpdi   r3,H_TOO_HARD
1861         beq     hcall_real_fallback
1862         ld      r4,HSTATE_KVM_VCPU(r13)
1863         std     r3,VCPU_GPR(R3)(r4)
1864         ld      r10,VCPU_PC(r4)
1865         ld      r11,VCPU_MSR(r4)
1866         b       fast_guest_return
1867
1868 sc_1_fast_return:
1869         mtspr   SPRN_SRR0,r10
1870         mtspr   SPRN_SRR1,r11
1871         li      r10, BOOK3S_INTERRUPT_SYSCALL
1872         bl      kvmppc_msr_interrupt
1873         mr      r4,r9
1874         b       fast_guest_return
1875
1876         /* We've attempted a real mode hcall, but it's punted it back
1877          * to userspace.  We need to restore some clobbered volatiles
1878          * before resuming the pass-it-to-qemu path */
1879 hcall_real_fallback:
1880         li      r12,BOOK3S_INTERRUPT_SYSCALL
1881         ld      r9, HSTATE_KVM_VCPU(r13)
1882
1883         b       guest_exit_cont
1884
1885         .globl  hcall_real_table
1886 hcall_real_table:
1887         .long   0               /* 0 - unused */
1888         .long   DOTSYM(kvmppc_h_remove) - hcall_real_table
1889         .long   DOTSYM(kvmppc_h_enter) - hcall_real_table
1890         .long   DOTSYM(kvmppc_h_read) - hcall_real_table
1891         .long   DOTSYM(kvmppc_h_clear_mod) - hcall_real_table
1892         .long   DOTSYM(kvmppc_h_clear_ref) - hcall_real_table
1893         .long   DOTSYM(kvmppc_h_protect) - hcall_real_table
1894         .long   DOTSYM(kvmppc_h_get_tce) - hcall_real_table
1895         .long   DOTSYM(kvmppc_rm_h_put_tce) - hcall_real_table
1896         .long   0               /* 0x24 - H_SET_SPRG0 */
1897         .long   DOTSYM(kvmppc_h_set_dabr) - hcall_real_table
1898         .long   0               /* 0x2c */
1899         .long   0               /* 0x30 */
1900         .long   0               /* 0x34 */
1901         .long   0               /* 0x38 */
1902         .long   0               /* 0x3c */
1903         .long   0               /* 0x40 */
1904         .long   0               /* 0x44 */
1905         .long   0               /* 0x48 */
1906         .long   0               /* 0x4c */
1907         .long   0               /* 0x50 */
1908         .long   0               /* 0x54 */
1909         .long   0               /* 0x58 */
1910         .long   0               /* 0x5c */
1911         .long   0               /* 0x60 */
1912 #ifdef CONFIG_KVM_XICS
1913         .long   DOTSYM(kvmppc_rm_h_eoi) - hcall_real_table
1914         .long   DOTSYM(kvmppc_rm_h_cppr) - hcall_real_table
1915         .long   DOTSYM(kvmppc_rm_h_ipi) - hcall_real_table
1916         .long   0               /* 0x70 - H_IPOLL */
1917         .long   DOTSYM(kvmppc_rm_h_xirr) - hcall_real_table
1918 #else
1919         .long   0               /* 0x64 - H_EOI */
1920         .long   0               /* 0x68 - H_CPPR */
1921         .long   0               /* 0x6c - H_IPI */
1922         .long   0               /* 0x70 - H_IPOLL */
1923         .long   0               /* 0x74 - H_XIRR */
1924 #endif
1925         .long   0               /* 0x78 */
1926         .long   0               /* 0x7c */
1927         .long   0               /* 0x80 */
1928         .long   0               /* 0x84 */
1929         .long   0               /* 0x88 */
1930         .long   0               /* 0x8c */
1931         .long   0               /* 0x90 */
1932         .long   0               /* 0x94 */
1933         .long   0               /* 0x98 */
1934         .long   0               /* 0x9c */
1935         .long   0               /* 0xa0 */
1936         .long   0               /* 0xa4 */
1937         .long   0               /* 0xa8 */
1938         .long   0               /* 0xac */
1939         .long   0               /* 0xb0 */
1940         .long   0               /* 0xb4 */
1941         .long   0               /* 0xb8 */
1942         .long   0               /* 0xbc */
1943         .long   0               /* 0xc0 */
1944         .long   0               /* 0xc4 */
1945         .long   0               /* 0xc8 */
1946         .long   0               /* 0xcc */
1947         .long   0               /* 0xd0 */
1948         .long   0               /* 0xd4 */
1949         .long   0               /* 0xd8 */
1950         .long   0               /* 0xdc */
1951         .long   DOTSYM(kvmppc_h_cede) - hcall_real_table
1952         .long   DOTSYM(kvmppc_rm_h_confer) - hcall_real_table
1953         .long   0               /* 0xe8 */
1954         .long   0               /* 0xec */
1955         .long   0               /* 0xf0 */
1956         .long   0               /* 0xf4 */
1957         .long   0               /* 0xf8 */
1958         .long   0               /* 0xfc */
1959         .long   0               /* 0x100 */
1960         .long   0               /* 0x104 */
1961         .long   0               /* 0x108 */
1962         .long   0               /* 0x10c */
1963         .long   0               /* 0x110 */
1964         .long   0               /* 0x114 */
1965         .long   0               /* 0x118 */
1966         .long   0               /* 0x11c */
1967         .long   0               /* 0x120 */
1968         .long   DOTSYM(kvmppc_h_bulk_remove) - hcall_real_table
1969         .long   0               /* 0x128 */
1970         .long   0               /* 0x12c */
1971         .long   0               /* 0x130 */
1972         .long   DOTSYM(kvmppc_h_set_xdabr) - hcall_real_table
1973         .long   DOTSYM(kvmppc_rm_h_stuff_tce) - hcall_real_table
1974         .long   DOTSYM(kvmppc_rm_h_put_tce_indirect) - hcall_real_table
1975         .long   0               /* 0x140 */
1976         .long   0               /* 0x144 */
1977         .long   0               /* 0x148 */
1978         .long   0               /* 0x14c */
1979         .long   0               /* 0x150 */
1980         .long   0               /* 0x154 */
1981         .long   0               /* 0x158 */
1982         .long   0               /* 0x15c */
1983         .long   0               /* 0x160 */
1984         .long   0               /* 0x164 */
1985         .long   0               /* 0x168 */
1986         .long   0               /* 0x16c */
1987         .long   0               /* 0x170 */
1988         .long   0               /* 0x174 */
1989         .long   0               /* 0x178 */
1990         .long   0               /* 0x17c */
1991         .long   0               /* 0x180 */
1992         .long   0               /* 0x184 */
1993         .long   0               /* 0x188 */
1994         .long   0               /* 0x18c */
1995         .long   0               /* 0x190 */
1996         .long   0               /* 0x194 */
1997         .long   0               /* 0x198 */
1998         .long   0               /* 0x19c */
1999         .long   0               /* 0x1a0 */
2000         .long   0               /* 0x1a4 */
2001         .long   0               /* 0x1a8 */
2002         .long   0               /* 0x1ac */
2003         .long   0               /* 0x1b0 */
2004         .long   0               /* 0x1b4 */
2005         .long   0               /* 0x1b8 */
2006         .long   0               /* 0x1bc */
2007         .long   0               /* 0x1c0 */
2008         .long   0               /* 0x1c4 */
2009         .long   0               /* 0x1c8 */
2010         .long   0               /* 0x1cc */
2011         .long   0               /* 0x1d0 */
2012         .long   0               /* 0x1d4 */
2013         .long   0               /* 0x1d8 */
2014         .long   0               /* 0x1dc */
2015         .long   0               /* 0x1e0 */
2016         .long   0               /* 0x1e4 */
2017         .long   0               /* 0x1e8 */
2018         .long   0               /* 0x1ec */
2019         .long   0               /* 0x1f0 */
2020         .long   0               /* 0x1f4 */
2021         .long   0               /* 0x1f8 */
2022         .long   0               /* 0x1fc */
2023         .long   0               /* 0x200 */
2024         .long   0               /* 0x204 */
2025         .long   0               /* 0x208 */
2026         .long   0               /* 0x20c */
2027         .long   0               /* 0x210 */
2028         .long   0               /* 0x214 */
2029         .long   0               /* 0x218 */
2030         .long   0               /* 0x21c */
2031         .long   0               /* 0x220 */
2032         .long   0               /* 0x224 */
2033         .long   0               /* 0x228 */
2034         .long   0               /* 0x22c */
2035         .long   0               /* 0x230 */
2036         .long   0               /* 0x234 */
2037         .long   0               /* 0x238 */
2038         .long   0               /* 0x23c */
2039         .long   0               /* 0x240 */
2040         .long   0               /* 0x244 */
2041         .long   0               /* 0x248 */
2042         .long   0               /* 0x24c */
2043         .long   0               /* 0x250 */
2044         .long   0               /* 0x254 */
2045         .long   0               /* 0x258 */
2046         .long   0               /* 0x25c */
2047         .long   0               /* 0x260 */
2048         .long   0               /* 0x264 */
2049         .long   0               /* 0x268 */
2050         .long   0               /* 0x26c */
2051         .long   0               /* 0x270 */
2052         .long   0               /* 0x274 */
2053         .long   0               /* 0x278 */
2054         .long   0               /* 0x27c */
2055         .long   0               /* 0x280 */
2056         .long   0               /* 0x284 */
2057         .long   0               /* 0x288 */
2058         .long   0               /* 0x28c */
2059         .long   0               /* 0x290 */
2060         .long   0               /* 0x294 */
2061         .long   0               /* 0x298 */
2062         .long   0               /* 0x29c */
2063         .long   0               /* 0x2a0 */
2064         .long   0               /* 0x2a4 */
2065         .long   0               /* 0x2a8 */
2066         .long   0               /* 0x2ac */
2067         .long   0               /* 0x2b0 */
2068         .long   0               /* 0x2b4 */
2069         .long   0               /* 0x2b8 */
2070         .long   0               /* 0x2bc */
2071         .long   0               /* 0x2c0 */
2072         .long   0               /* 0x2c4 */
2073         .long   0               /* 0x2c8 */
2074         .long   0               /* 0x2cc */
2075         .long   0               /* 0x2d0 */
2076         .long   0               /* 0x2d4 */
2077         .long   0               /* 0x2d8 */
2078         .long   0               /* 0x2dc */
2079         .long   0               /* 0x2e0 */
2080         .long   0               /* 0x2e4 */
2081         .long   0               /* 0x2e8 */
2082         .long   0               /* 0x2ec */
2083         .long   0               /* 0x2f0 */
2084         .long   0               /* 0x2f4 */
2085         .long   0               /* 0x2f8 */
2086         .long   0               /* 0x2fc */
2087         .long   DOTSYM(kvmppc_h_random) - hcall_real_table
2088         .globl  hcall_real_table_end
2089 hcall_real_table_end:
2090
2091 _GLOBAL(kvmppc_h_set_xdabr)
2092         andi.   r0, r5, DABRX_USER | DABRX_KERNEL
2093         beq     6f
2094         li      r0, DABRX_USER | DABRX_KERNEL | DABRX_BTI
2095         andc.   r0, r5, r0
2096         beq     3f
2097 6:      li      r3, H_PARAMETER
2098         blr
2099
2100 _GLOBAL(kvmppc_h_set_dabr)
2101         li      r5, DABRX_USER | DABRX_KERNEL
2102 3:
2103 BEGIN_FTR_SECTION
2104         b       2f
2105 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
2106         std     r4,VCPU_DABR(r3)
2107         stw     r5, VCPU_DABRX(r3)
2108         mtspr   SPRN_DABRX, r5
2109         /* Work around P7 bug where DABR can get corrupted on mtspr */
2110 1:      mtspr   SPRN_DABR,r4
2111         mfspr   r5, SPRN_DABR
2112         cmpd    r4, r5
2113         bne     1b
2114         isync
2115         li      r3,0
2116         blr
2117
2118         /* Emulate H_SET_DABR/X on P8 for the sake of compat mode guests */
2119 2:      rlwimi  r5, r4, 5, DAWRX_DR | DAWRX_DW
2120         rlwimi  r5, r4, 2, DAWRX_WT
2121         clrrdi  r4, r4, 3
2122         std     r4, VCPU_DAWR(r3)
2123         std     r5, VCPU_DAWRX(r3)
2124         mtspr   SPRN_DAWR, r4
2125         mtspr   SPRN_DAWRX, r5
2126         li      r3, 0
2127         blr
2128
2129 _GLOBAL(kvmppc_h_cede)          /* r3 = vcpu pointer, r11 = msr, r13 = paca */
2130         ori     r11,r11,MSR_EE
2131         std     r11,VCPU_MSR(r3)
2132         li      r0,1
2133         stb     r0,VCPU_CEDED(r3)
2134         sync                    /* order setting ceded vs. testing prodded */
2135         lbz     r5,VCPU_PRODDED(r3)
2136         cmpwi   r5,0
2137         bne     kvm_cede_prodded
2138         li      r12,0           /* set trap to 0 to say hcall is handled */
2139         stw     r12,VCPU_TRAP(r3)
2140         li      r0,H_SUCCESS
2141         std     r0,VCPU_GPR(R3)(r3)
2142
2143         /*
2144          * Set our bit in the bitmask of napping threads unless all the
2145          * other threads are already napping, in which case we send this
2146          * up to the host.
2147          */
2148         ld      r5,HSTATE_KVM_VCORE(r13)
2149         lbz     r6,HSTATE_PTID(r13)
2150         lwz     r8,VCORE_ENTRY_EXIT(r5)
2151         clrldi  r8,r8,56
2152         li      r0,1
2153         sld     r0,r0,r6
2154         addi    r6,r5,VCORE_NAPPING_THREADS
2155 31:     lwarx   r4,0,r6
2156         or      r4,r4,r0
2157         cmpw    r4,r8
2158         beq     kvm_cede_exit
2159         stwcx.  r4,0,r6
2160         bne     31b
2161         /* order napping_threads update vs testing entry_exit_map */
2162         isync
2163         li      r0,NAPPING_CEDE
2164         stb     r0,HSTATE_NAPPING(r13)
2165         lwz     r7,VCORE_ENTRY_EXIT(r5)
2166         cmpwi   r7,0x100
2167         bge     33f             /* another thread already exiting */
2168
2169 /*
2170  * Although not specifically required by the architecture, POWER7
2171  * preserves the following registers in nap mode, even if an SMT mode
2172  * switch occurs: SLB entries, PURR, SPURR, AMOR, UAMOR, AMR, SPRG0-3,
2173  * DAR, DSISR, DABR, DABRX, DSCR, PMCx, MMCRx, SIAR, SDAR.
2174  */
2175         /* Save non-volatile GPRs */
2176         std     r14, VCPU_GPR(R14)(r3)
2177         std     r15, VCPU_GPR(R15)(r3)
2178         std     r16, VCPU_GPR(R16)(r3)
2179         std     r17, VCPU_GPR(R17)(r3)
2180         std     r18, VCPU_GPR(R18)(r3)
2181         std     r19, VCPU_GPR(R19)(r3)
2182         std     r20, VCPU_GPR(R20)(r3)
2183         std     r21, VCPU_GPR(R21)(r3)
2184         std     r22, VCPU_GPR(R22)(r3)
2185         std     r23, VCPU_GPR(R23)(r3)
2186         std     r24, VCPU_GPR(R24)(r3)
2187         std     r25, VCPU_GPR(R25)(r3)
2188         std     r26, VCPU_GPR(R26)(r3)
2189         std     r27, VCPU_GPR(R27)(r3)
2190         std     r28, VCPU_GPR(R28)(r3)
2191         std     r29, VCPU_GPR(R29)(r3)
2192         std     r30, VCPU_GPR(R30)(r3)
2193         std     r31, VCPU_GPR(R31)(r3)
2194
2195         /* save FP state */
2196         bl      kvmppc_save_fp
2197
2198 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
2199 BEGIN_FTR_SECTION
2200         ld      r9, HSTATE_KVM_VCPU(r13)
2201         bl      kvmppc_save_tm
2202 END_FTR_SECTION_IFSET(CPU_FTR_TM)
2203 #endif
2204
2205         /*
2206          * Set DEC to the smaller of DEC and HDEC, so that we wake
2207          * no later than the end of our timeslice (HDEC interrupts
2208          * don't wake us from nap).
2209          */
2210         mfspr   r3, SPRN_DEC
2211         mfspr   r4, SPRN_HDEC
2212         mftb    r5
2213         cmpw    r3, r4
2214         ble     67f
2215         mtspr   SPRN_DEC, r4
2216 67:
2217         /* save expiry time of guest decrementer */
2218         extsw   r3, r3
2219         add     r3, r3, r5
2220         ld      r4, HSTATE_KVM_VCPU(r13)
2221         ld      r5, HSTATE_KVM_VCORE(r13)
2222         ld      r6, VCORE_TB_OFFSET(r5)
2223         subf    r3, r6, r3      /* convert to host TB value */
2224         std     r3, VCPU_DEC_EXPIRES(r4)
2225
2226 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
2227         ld      r4, HSTATE_KVM_VCPU(r13)
2228         addi    r3, r4, VCPU_TB_CEDE
2229         bl      kvmhv_accumulate_time
2230 #endif
2231
2232         lis     r3, LPCR_PECEDP@h       /* Do wake on privileged doorbell */
2233
2234         /*
2235          * Take a nap until a decrementer or external or doobell interrupt
2236          * occurs, with PECE1 and PECE0 set in LPCR.
2237          * On POWER8, set PECEDH, and if we are ceding, also set PECEDP.
2238          * Also clear the runlatch bit before napping.
2239          */
2240 kvm_do_nap:
2241         mfspr   r0, SPRN_CTRLF
2242         clrrdi  r0, r0, 1
2243         mtspr   SPRN_CTRLT, r0
2244
2245         li      r0,1
2246         stb     r0,HSTATE_HWTHREAD_REQ(r13)
2247         mfspr   r5,SPRN_LPCR
2248         ori     r5,r5,LPCR_PECE0 | LPCR_PECE1
2249 BEGIN_FTR_SECTION
2250         ori     r5, r5, LPCR_PECEDH
2251         rlwimi  r5, r3, 0, LPCR_PECEDP
2252 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
2253
2254 kvm_nap_sequence:               /* desired LPCR value in r5 */
2255 BEGIN_FTR_SECTION
2256         /*
2257          * PSSCR bits:  exit criterion = 1 (wakeup based on LPCR at sreset)
2258          *              enable state loss = 1 (allow SMT mode switch)
2259          *              requested level = 0 (just stop dispatching)
2260          */
2261         lis     r3, (PSSCR_EC | PSSCR_ESL)@h
2262         mtspr   SPRN_PSSCR, r3
2263         /* Set LPCR_PECE_HVEE bit to enable wakeup by HV interrupts */
2264         li      r4, LPCR_PECE_HVEE@higher
2265         sldi    r4, r4, 32
2266         or      r5, r5, r4
2267 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
2268         mtspr   SPRN_LPCR,r5
2269         isync
2270         li      r0, 0
2271         std     r0, HSTATE_SCRATCH0(r13)
2272         ptesync
2273         ld      r0, HSTATE_SCRATCH0(r13)
2274 1:      cmpd    r0, r0
2275         bne     1b
2276 BEGIN_FTR_SECTION
2277         nap
2278 FTR_SECTION_ELSE
2279         PPC_STOP
2280 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_ARCH_300)
2281         b       .
2282
2283 33:     mr      r4, r3
2284         li      r3, 0
2285         li      r12, 0
2286         b       34f
2287
2288 kvm_end_cede:
2289         /* get vcpu pointer */
2290         ld      r4, HSTATE_KVM_VCPU(r13)
2291
2292         /* Woken by external or decrementer interrupt */
2293         ld      r1, HSTATE_HOST_R1(r13)
2294
2295 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
2296         addi    r3, r4, VCPU_TB_RMINTR
2297         bl      kvmhv_accumulate_time
2298 #endif
2299
2300 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
2301 BEGIN_FTR_SECTION
2302         bl      kvmppc_restore_tm
2303 END_FTR_SECTION_IFSET(CPU_FTR_TM)
2304 #endif
2305
2306         /* load up FP state */
2307         bl      kvmppc_load_fp
2308
2309         /* Restore guest decrementer */
2310         ld      r3, VCPU_DEC_EXPIRES(r4)
2311         ld      r5, HSTATE_KVM_VCORE(r13)
2312         ld      r6, VCORE_TB_OFFSET(r5)
2313         add     r3, r3, r6      /* convert host TB to guest TB value */
2314         mftb    r7
2315         subf    r3, r7, r3
2316         mtspr   SPRN_DEC, r3
2317
2318         /* Load NV GPRS */
2319         ld      r14, VCPU_GPR(R14)(r4)
2320         ld      r15, VCPU_GPR(R15)(r4)
2321         ld      r16, VCPU_GPR(R16)(r4)
2322         ld      r17, VCPU_GPR(R17)(r4)
2323         ld      r18, VCPU_GPR(R18)(r4)
2324         ld      r19, VCPU_GPR(R19)(r4)
2325         ld      r20, VCPU_GPR(R20)(r4)
2326         ld      r21, VCPU_GPR(R21)(r4)
2327         ld      r22, VCPU_GPR(R22)(r4)
2328         ld      r23, VCPU_GPR(R23)(r4)
2329         ld      r24, VCPU_GPR(R24)(r4)
2330         ld      r25, VCPU_GPR(R25)(r4)
2331         ld      r26, VCPU_GPR(R26)(r4)
2332         ld      r27, VCPU_GPR(R27)(r4)
2333         ld      r28, VCPU_GPR(R28)(r4)
2334         ld      r29, VCPU_GPR(R29)(r4)
2335         ld      r30, VCPU_GPR(R30)(r4)
2336         ld      r31, VCPU_GPR(R31)(r4)
2337
2338         /* Check the wake reason in SRR1 to see why we got here */
2339         bl      kvmppc_check_wake_reason
2340
2341         /*
2342          * Restore volatile registers since we could have called a
2343          * C routine in kvmppc_check_wake_reason
2344          *      r4 = VCPU
2345          * r3 tells us whether we need to return to host or not
2346          * WARNING: it gets checked further down:
2347          * should not modify r3 until this check is done.
2348          */
2349         ld      r4, HSTATE_KVM_VCPU(r13)
2350
2351         /* clear our bit in vcore->napping_threads */
2352 34:     ld      r5,HSTATE_KVM_VCORE(r13)
2353         lbz     r7,HSTATE_PTID(r13)
2354         li      r0,1
2355         sld     r0,r0,r7
2356         addi    r6,r5,VCORE_NAPPING_THREADS
2357 32:     lwarx   r7,0,r6
2358         andc    r7,r7,r0
2359         stwcx.  r7,0,r6
2360         bne     32b
2361         li      r0,0
2362         stb     r0,HSTATE_NAPPING(r13)
2363
2364         /* See if the wake reason saved in r3 means we need to exit */
2365         stw     r12, VCPU_TRAP(r4)
2366         mr      r9, r4
2367         cmpdi   r3, 0
2368         bgt     guest_exit_cont
2369
2370         /* see if any other thread is already exiting */
2371         lwz     r0,VCORE_ENTRY_EXIT(r5)
2372         cmpwi   r0,0x100
2373         bge     guest_exit_cont
2374
2375         b       kvmppc_cede_reentry     /* if not go back to guest */
2376
2377         /* cede when already previously prodded case */
2378 kvm_cede_prodded:
2379         li      r0,0
2380         stb     r0,VCPU_PRODDED(r3)
2381         sync                    /* order testing prodded vs. clearing ceded */
2382         stb     r0,VCPU_CEDED(r3)
2383         li      r3,H_SUCCESS
2384         blr
2385
2386         /* we've ceded but we want to give control to the host */
2387 kvm_cede_exit:
2388         ld      r9, HSTATE_KVM_VCPU(r13)
2389         b       guest_exit_cont
2390
2391         /* Try to handle a machine check in real mode */
2392 machine_check_realmode:
2393         mr      r3, r9          /* get vcpu pointer */
2394         bl      kvmppc_realmode_machine_check
2395         nop
2396         ld      r9, HSTATE_KVM_VCPU(r13)
2397         li      r12, BOOK3S_INTERRUPT_MACHINE_CHECK
2398         /*
2399          * Deliver unhandled/fatal (e.g. UE) MCE errors to guest through
2400          * machine check interrupt (set HSRR0 to 0x200). And for handled
2401          * errors (no-fatal), just go back to guest execution with current
2402          * HSRR0 instead of exiting guest. This new approach will inject
2403          * machine check to guest for fatal error causing guest to crash.
2404          *
2405          * The old code used to return to host for unhandled errors which
2406          * was causing guest to hang with soft lockups inside guest and
2407          * makes it difficult to recover guest instance.
2408          *
2409          * if we receive machine check with MSR(RI=0) then deliver it to
2410          * guest as machine check causing guest to crash.
2411          */
2412         ld      r11, VCPU_MSR(r9)
2413         rldicl. r0, r11, 64-MSR_HV_LG, 63 /* check if it happened in HV mode */
2414         bne     mc_cont                 /* if so, exit to host */
2415         andi.   r10, r11, MSR_RI        /* check for unrecoverable exception */
2416         beq     1f                      /* Deliver a machine check to guest */
2417         ld      r10, VCPU_PC(r9)
2418         cmpdi   r3, 0           /* Did we handle MCE ? */
2419         bne     2f      /* Continue guest execution. */
2420         /* If not, deliver a machine check.  SRR0/1 are already set */
2421 1:      li      r10, BOOK3S_INTERRUPT_MACHINE_CHECK
2422         bl      kvmppc_msr_interrupt
2423 2:      b       fast_interrupt_c_return
2424
2425 /*
2426  * Check the reason we woke from nap, and take appropriate action.
2427  * Returns (in r3):
2428  *      0 if nothing needs to be done
2429  *      1 if something happened that needs to be handled by the host
2430  *      -1 if there was a guest wakeup (IPI or msgsnd)
2431  *      -2 if we handled a PCI passthrough interrupt (returned by
2432  *              kvmppc_read_intr only)
2433  *
2434  * Also sets r12 to the interrupt vector for any interrupt that needs
2435  * to be handled now by the host (0x500 for external interrupt), or zero.
2436  * Modifies all volatile registers (since it may call a C function).
2437  * This routine calls kvmppc_read_intr, a C function, if an external
2438  * interrupt is pending.
2439  */
2440 kvmppc_check_wake_reason:
2441         mfspr   r6, SPRN_SRR1
2442 BEGIN_FTR_SECTION
2443         rlwinm  r6, r6, 45-31, 0xf      /* extract wake reason field (P8) */
2444 FTR_SECTION_ELSE
2445         rlwinm  r6, r6, 45-31, 0xe      /* P7 wake reason field is 3 bits */
2446 ALT_FTR_SECTION_END_IFSET(CPU_FTR_ARCH_207S)
2447         cmpwi   r6, 8                   /* was it an external interrupt? */
2448         beq     7f                      /* if so, see what it was */
2449         li      r3, 0
2450         li      r12, 0
2451         cmpwi   r6, 6                   /* was it the decrementer? */
2452         beq     0f
2453 BEGIN_FTR_SECTION
2454         cmpwi   r6, 5                   /* privileged doorbell? */
2455         beq     0f
2456         cmpwi   r6, 3                   /* hypervisor doorbell? */
2457         beq     3f
2458 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
2459         cmpwi   r6, 0xa                 /* Hypervisor maintenance ? */
2460         beq     4f
2461         li      r3, 1                   /* anything else, return 1 */
2462 0:      blr
2463
2464         /* hypervisor doorbell */
2465 3:      li      r12, BOOK3S_INTERRUPT_H_DOORBELL
2466
2467         /*
2468          * Clear the doorbell as we will invoke the handler
2469          * explicitly in the guest exit path.
2470          */
2471         lis     r6, (PPC_DBELL_SERVER << (63-36))@h
2472         PPC_MSGCLR(6)
2473         /* see if it's a host IPI */
2474         li      r3, 1
2475         lbz     r0, HSTATE_HOST_IPI(r13)
2476         cmpwi   r0, 0
2477         bnelr
2478         /* if not, return -1 */
2479         li      r3, -1
2480         blr
2481
2482         /* Woken up due to Hypervisor maintenance interrupt */
2483 4:      li      r12, BOOK3S_INTERRUPT_HMI
2484         li      r3, 1
2485         blr
2486
2487         /* external interrupt - create a stack frame so we can call C */
2488 7:      mflr    r0
2489         std     r0, PPC_LR_STKOFF(r1)
2490         stdu    r1, -PPC_MIN_STKFRM(r1)
2491         bl      kvmppc_read_intr
2492         nop
2493         li      r12, BOOK3S_INTERRUPT_EXTERNAL
2494         cmpdi   r3, 1
2495         ble     1f
2496
2497         /*
2498          * Return code of 2 means PCI passthrough interrupt, but
2499          * we need to return back to host to complete handling the
2500          * interrupt. Trap reason is expected in r12 by guest
2501          * exit code.
2502          */
2503         li      r12, BOOK3S_INTERRUPT_HV_RM_HARD
2504 1:
2505         ld      r0, PPC_MIN_STKFRM+PPC_LR_STKOFF(r1)
2506         addi    r1, r1, PPC_MIN_STKFRM
2507         mtlr    r0
2508         blr
2509
2510 /*
2511  * Save away FP, VMX and VSX registers.
2512  * r3 = vcpu pointer
2513  * N.B. r30 and r31 are volatile across this function,
2514  * thus it is not callable from C.
2515  */
2516 kvmppc_save_fp:
2517         mflr    r30
2518         mr      r31,r3
2519         mfmsr   r5
2520         ori     r8,r5,MSR_FP
2521 #ifdef CONFIG_ALTIVEC
2522 BEGIN_FTR_SECTION
2523         oris    r8,r8,MSR_VEC@h
2524 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
2525 #endif
2526 #ifdef CONFIG_VSX
2527 BEGIN_FTR_SECTION
2528         oris    r8,r8,MSR_VSX@h
2529 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
2530 #endif
2531         mtmsrd  r8
2532         addi    r3,r3,VCPU_FPRS
2533         bl      store_fp_state
2534 #ifdef CONFIG_ALTIVEC
2535 BEGIN_FTR_SECTION
2536         addi    r3,r31,VCPU_VRS
2537         bl      store_vr_state
2538 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
2539 #endif
2540         mfspr   r6,SPRN_VRSAVE
2541         stw     r6,VCPU_VRSAVE(r31)
2542         mtlr    r30
2543         blr
2544
2545 /*
2546  * Load up FP, VMX and VSX registers
2547  * r4 = vcpu pointer
2548  * N.B. r30 and r31 are volatile across this function,
2549  * thus it is not callable from C.
2550  */
2551 kvmppc_load_fp:
2552         mflr    r30
2553         mr      r31,r4
2554         mfmsr   r9
2555         ori     r8,r9,MSR_FP
2556 #ifdef CONFIG_ALTIVEC
2557 BEGIN_FTR_SECTION
2558         oris    r8,r8,MSR_VEC@h
2559 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
2560 #endif
2561 #ifdef CONFIG_VSX
2562 BEGIN_FTR_SECTION
2563         oris    r8,r8,MSR_VSX@h
2564 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
2565 #endif
2566         mtmsrd  r8
2567         addi    r3,r4,VCPU_FPRS
2568         bl      load_fp_state
2569 #ifdef CONFIG_ALTIVEC
2570 BEGIN_FTR_SECTION
2571         addi    r3,r31,VCPU_VRS
2572         bl      load_vr_state
2573 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
2574 #endif
2575         lwz     r7,VCPU_VRSAVE(r31)
2576         mtspr   SPRN_VRSAVE,r7
2577         mtlr    r30
2578         mr      r4,r31
2579         blr
2580
2581 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
2582 /*
2583  * Save transactional state and TM-related registers.
2584  * Called with r9 pointing to the vcpu struct.
2585  * This can modify all checkpointed registers, but
2586  * restores r1, r2 and r9 (vcpu pointer) before exit.
2587  */
2588 kvmppc_save_tm:
2589         mflr    r0
2590         std     r0, PPC_LR_STKOFF(r1)
2591
2592         /* Turn on TM. */
2593         mfmsr   r8
2594         li      r0, 1
2595         rldimi  r8, r0, MSR_TM_LG, 63-MSR_TM_LG
2596         mtmsrd  r8
2597
2598         ld      r5, VCPU_MSR(r9)
2599         rldicl. r5, r5, 64 - MSR_TS_S_LG, 62
2600         beq     1f      /* TM not active in guest. */
2601
2602         std     r1, HSTATE_HOST_R1(r13)
2603         li      r3, TM_CAUSE_KVM_RESCHED
2604
2605         /* Clear the MSR RI since r1, r13 are all going to be foobar. */
2606         li      r5, 0
2607         mtmsrd  r5, 1
2608
2609         /* All GPRs are volatile at this point. */
2610         TRECLAIM(R3)
2611
2612         /* Temporarily store r13 and r9 so we have some regs to play with */
2613         SET_SCRATCH0(r13)
2614         GET_PACA(r13)
2615         std     r9, PACATMSCRATCH(r13)
2616         ld      r9, HSTATE_KVM_VCPU(r13)
2617
2618         /* Get a few more GPRs free. */
2619         std     r29, VCPU_GPRS_TM(29)(r9)
2620         std     r30, VCPU_GPRS_TM(30)(r9)
2621         std     r31, VCPU_GPRS_TM(31)(r9)
2622
2623         /* Save away PPR and DSCR soon so don't run with user values. */
2624         mfspr   r31, SPRN_PPR
2625         HMT_MEDIUM
2626         mfspr   r30, SPRN_DSCR
2627         ld      r29, HSTATE_DSCR(r13)
2628         mtspr   SPRN_DSCR, r29
2629
2630         /* Save all but r9, r13 & r29-r31 */
2631         reg = 0
2632         .rept   29
2633         .if (reg != 9) && (reg != 13)
2634         std     reg, VCPU_GPRS_TM(reg)(r9)
2635         .endif
2636         reg = reg + 1
2637         .endr
2638         /* ... now save r13 */
2639         GET_SCRATCH0(r4)
2640         std     r4, VCPU_GPRS_TM(13)(r9)
2641         /* ... and save r9 */
2642         ld      r4, PACATMSCRATCH(r13)
2643         std     r4, VCPU_GPRS_TM(9)(r9)
2644
2645         /* Reload stack pointer and TOC. */
2646         ld      r1, HSTATE_HOST_R1(r13)
2647         ld      r2, PACATOC(r13)
2648
2649         /* Set MSR RI now we have r1 and r13 back. */
2650         li      r5, MSR_RI
2651         mtmsrd  r5, 1
2652
2653         /* Save away checkpinted SPRs. */
2654         std     r31, VCPU_PPR_TM(r9)
2655         std     r30, VCPU_DSCR_TM(r9)
2656         mflr    r5
2657         mfcr    r6
2658         mfctr   r7
2659         mfspr   r8, SPRN_AMR
2660         mfspr   r10, SPRN_TAR
2661         mfxer   r11
2662         std     r5, VCPU_LR_TM(r9)
2663         stw     r6, VCPU_CR_TM(r9)
2664         std     r7, VCPU_CTR_TM(r9)
2665         std     r8, VCPU_AMR_TM(r9)
2666         std     r10, VCPU_TAR_TM(r9)
2667         std     r11, VCPU_XER_TM(r9)
2668
2669         /* Restore r12 as trap number. */
2670         lwz     r12, VCPU_TRAP(r9)
2671
2672         /* Save FP/VSX. */
2673         addi    r3, r9, VCPU_FPRS_TM
2674         bl      store_fp_state
2675         addi    r3, r9, VCPU_VRS_TM
2676         bl      store_vr_state
2677         mfspr   r6, SPRN_VRSAVE
2678         stw     r6, VCPU_VRSAVE_TM(r9)
2679 1:
2680         /*
2681          * We need to save these SPRs after the treclaim so that the software
2682          * error code is recorded correctly in the TEXASR.  Also the user may
2683          * change these outside of a transaction, so they must always be
2684          * context switched.
2685          */
2686         mfspr   r5, SPRN_TFHAR
2687         mfspr   r6, SPRN_TFIAR
2688         mfspr   r7, SPRN_TEXASR
2689         std     r5, VCPU_TFHAR(r9)
2690         std     r6, VCPU_TFIAR(r9)
2691         std     r7, VCPU_TEXASR(r9)
2692
2693         ld      r0, PPC_LR_STKOFF(r1)
2694         mtlr    r0
2695         blr
2696
2697 /*
2698  * Restore transactional state and TM-related registers.
2699  * Called with r4 pointing to the vcpu struct.
2700  * This potentially modifies all checkpointed registers.
2701  * It restores r1, r2, r4 from the PACA.
2702  */
2703 kvmppc_restore_tm:
2704         mflr    r0
2705         std     r0, PPC_LR_STKOFF(r1)
2706
2707         /* Turn on TM/FP/VSX/VMX so we can restore them. */
2708         mfmsr   r5
2709         li      r6, MSR_TM >> 32
2710         sldi    r6, r6, 32
2711         or      r5, r5, r6
2712         ori     r5, r5, MSR_FP
2713         oris    r5, r5, (MSR_VEC | MSR_VSX)@h
2714         mtmsrd  r5
2715
2716         /*
2717          * The user may change these outside of a transaction, so they must
2718          * always be context switched.
2719          */
2720         ld      r5, VCPU_TFHAR(r4)
2721         ld      r6, VCPU_TFIAR(r4)
2722         ld      r7, VCPU_TEXASR(r4)
2723         mtspr   SPRN_TFHAR, r5
2724         mtspr   SPRN_TFIAR, r6
2725         mtspr   SPRN_TEXASR, r7
2726
2727         ld      r5, VCPU_MSR(r4)
2728         rldicl. r5, r5, 64 - MSR_TS_S_LG, 62
2729         beqlr           /* TM not active in guest */
2730         std     r1, HSTATE_HOST_R1(r13)
2731
2732         /* Make sure the failure summary is set, otherwise we'll program check
2733          * when we trechkpt.  It's possible that this might have been not set
2734          * on a kvmppc_set_one_reg() call but we shouldn't let this crash the
2735          * host.
2736          */
2737         oris    r7, r7, (TEXASR_FS)@h
2738         mtspr   SPRN_TEXASR, r7
2739
2740         /*
2741          * We need to load up the checkpointed state for the guest.
2742          * We need to do this early as it will blow away any GPRs, VSRs and
2743          * some SPRs.
2744          */
2745
2746         mr      r31, r4
2747         addi    r3, r31, VCPU_FPRS_TM
2748         bl      load_fp_state
2749         addi    r3, r31, VCPU_VRS_TM
2750         bl      load_vr_state
2751         mr      r4, r31
2752         lwz     r7, VCPU_VRSAVE_TM(r4)
2753         mtspr   SPRN_VRSAVE, r7
2754
2755         ld      r5, VCPU_LR_TM(r4)
2756         lwz     r6, VCPU_CR_TM(r4)
2757         ld      r7, VCPU_CTR_TM(r4)
2758         ld      r8, VCPU_AMR_TM(r4)
2759         ld      r9, VCPU_TAR_TM(r4)
2760         ld      r10, VCPU_XER_TM(r4)
2761         mtlr    r5
2762         mtcr    r6
2763         mtctr   r7
2764         mtspr   SPRN_AMR, r8
2765         mtspr   SPRN_TAR, r9
2766         mtxer   r10
2767
2768         /*
2769          * Load up PPR and DSCR values but don't put them in the actual SPRs
2770          * till the last moment to avoid running with userspace PPR and DSCR for
2771          * too long.
2772          */
2773         ld      r29, VCPU_DSCR_TM(r4)
2774         ld      r30, VCPU_PPR_TM(r4)
2775
2776         std     r2, PACATMSCRATCH(r13) /* Save TOC */
2777
2778         /* Clear the MSR RI since r1, r13 are all going to be foobar. */
2779         li      r5, 0
2780         mtmsrd  r5, 1
2781
2782         /* Load GPRs r0-r28 */
2783         reg = 0
2784         .rept   29
2785         ld      reg, VCPU_GPRS_TM(reg)(r31)
2786         reg = reg + 1
2787         .endr
2788
2789         mtspr   SPRN_DSCR, r29
2790         mtspr   SPRN_PPR, r30
2791
2792         /* Load final GPRs */
2793         ld      29, VCPU_GPRS_TM(29)(r31)
2794         ld      30, VCPU_GPRS_TM(30)(r31)
2795         ld      31, VCPU_GPRS_TM(31)(r31)
2796
2797         /* TM checkpointed state is now setup.  All GPRs are now volatile. */
2798         TRECHKPT
2799
2800         /* Now let's get back the state we need. */
2801         HMT_MEDIUM
2802         GET_PACA(r13)
2803         ld      r29, HSTATE_DSCR(r13)
2804         mtspr   SPRN_DSCR, r29
2805         ld      r4, HSTATE_KVM_VCPU(r13)
2806         ld      r1, HSTATE_HOST_R1(r13)
2807         ld      r2, PACATMSCRATCH(r13)
2808
2809         /* Set the MSR RI since we have our registers back. */
2810         li      r5, MSR_RI
2811         mtmsrd  r5, 1
2812
2813         ld      r0, PPC_LR_STKOFF(r1)
2814         mtlr    r0
2815         blr
2816 #endif
2817
2818 /*
2819  * We come here if we get any exception or interrupt while we are
2820  * executing host real mode code while in guest MMU context.
2821  * For now just spin, but we should do something better.
2822  */
2823 kvmppc_bad_host_intr:
2824         b       .
2825
2826 /*
2827  * This mimics the MSR transition on IRQ delivery.  The new guest MSR is taken
2828  * from VCPU_INTR_MSR and is modified based on the required TM state changes.
2829  *   r11 has the guest MSR value (in/out)
2830  *   r9 has a vcpu pointer (in)
2831  *   r0 is used as a scratch register
2832  */
2833 kvmppc_msr_interrupt:
2834         rldicl  r0, r11, 64 - MSR_TS_S_LG, 62
2835         cmpwi   r0, 2 /* Check if we are in transactional state..  */
2836         ld      r11, VCPU_INTR_MSR(r9)
2837         bne     1f
2838         /* ... if transactional, change to suspended */
2839         li      r0, 1
2840 1:      rldimi  r11, r0, MSR_TS_S_LG, 63 - MSR_TS_T_LG
2841         blr
2842
2843 /*
2844  * This works around a hardware bug on POWER8E processors, where
2845  * writing a 1 to the MMCR0[PMAO] bit doesn't generate a
2846  * performance monitor interrupt.  Instead, when we need to have
2847  * an interrupt pending, we have to arrange for a counter to overflow.
2848  */
2849 kvmppc_fix_pmao:
2850         li      r3, 0
2851         mtspr   SPRN_MMCR2, r3
2852         lis     r3, (MMCR0_PMXE | MMCR0_FCECE)@h
2853         ori     r3, r3, MMCR0_PMCjCE | MMCR0_C56RUN
2854         mtspr   SPRN_MMCR0, r3
2855         lis     r3, 0x7fff
2856         ori     r3, r3, 0xffff
2857         mtspr   SPRN_PMC6, r3
2858         isync
2859         blr
2860
2861 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
2862 /*
2863  * Start timing an activity
2864  * r3 = pointer to time accumulation struct, r4 = vcpu
2865  */
2866 kvmhv_start_timing:
2867         ld      r5, HSTATE_KVM_VCORE(r13)
2868         lbz     r6, VCORE_IN_GUEST(r5)
2869         cmpwi   r6, 0
2870         beq     5f                              /* if in guest, need to */
2871         ld      r6, VCORE_TB_OFFSET(r5)         /* subtract timebase offset */
2872 5:      mftb    r5
2873         subf    r5, r6, r5
2874         std     r3, VCPU_CUR_ACTIVITY(r4)
2875         std     r5, VCPU_ACTIVITY_START(r4)
2876         blr
2877
2878 /*
2879  * Accumulate time to one activity and start another.
2880  * r3 = pointer to new time accumulation struct, r4 = vcpu
2881  */
2882 kvmhv_accumulate_time:
2883         ld      r5, HSTATE_KVM_VCORE(r13)
2884         lbz     r8, VCORE_IN_GUEST(r5)
2885         cmpwi   r8, 0
2886         beq     4f                              /* if in guest, need to */
2887         ld      r8, VCORE_TB_OFFSET(r5)         /* subtract timebase offset */
2888 4:      ld      r5, VCPU_CUR_ACTIVITY(r4)
2889         ld      r6, VCPU_ACTIVITY_START(r4)
2890         std     r3, VCPU_CUR_ACTIVITY(r4)
2891         mftb    r7
2892         subf    r7, r8, r7
2893         std     r7, VCPU_ACTIVITY_START(r4)
2894         cmpdi   r5, 0
2895         beqlr
2896         subf    r3, r6, r7
2897         ld      r8, TAS_SEQCOUNT(r5)
2898         cmpdi   r8, 0
2899         addi    r8, r8, 1
2900         std     r8, TAS_SEQCOUNT(r5)
2901         lwsync
2902         ld      r7, TAS_TOTAL(r5)
2903         add     r7, r7, r3
2904         std     r7, TAS_TOTAL(r5)
2905         ld      r6, TAS_MIN(r5)
2906         ld      r7, TAS_MAX(r5)
2907         beq     3f
2908         cmpd    r3, r6
2909         bge     1f
2910 3:      std     r3, TAS_MIN(r5)
2911 1:      cmpd    r3, r7
2912         ble     2f
2913         std     r3, TAS_MAX(r5)
2914 2:      lwsync
2915         addi    r8, r8, 1
2916         std     r8, TAS_SEQCOUNT(r5)
2917         blr
2918 #endif