arch/powerpc/kvm/book3s_hv_rmhandlers.S

   1 /*
   2  * This program is free software; you can redistribute it and/or modify
   3  * it under the terms of the GNU General Public License, version 2, as
   4  * published by the Free Software Foundation.
   5  *
   6  * This program is distributed in the hope that it will be useful,
   7  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   8  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   9  * GNU General Public License for more details.
  10  *
  11  * Copyright 2011 Paul Mackerras, IBM Corp. <paulus@au1.ibm.com>
  12  *
  13  * Derived from book3s_rmhandlers.S and other files, which are:
  14  *
  15  * Copyright SUSE Linux Products GmbH 2009
  16  *
  17  * Authors: Alexander Graf <agraf@suse.de>
  18  */
  19
  20 #include <asm/ppc_asm.h>
  21 #include <asm/kvm_asm.h>
  22 #include <asm/reg.h>
  23 #include <asm/mmu.h>
  24 #include <asm/page.h>
  25 #include <asm/ptrace.h>
  26 #include <asm/hvcall.h>
  27 #include <asm/asm-offsets.h>
  28 #include <asm/exception-64s.h>
  29 #include <asm/kvm_book3s_asm.h>
  30 #include <asm/book3s/64/mmu-hash.h>
  31 #include <asm/tm.h>
  32 #include <asm/opal.h>
  33
  34 #define VCPU_GPRS_TM(reg) (((reg) * ULONG_SIZE) + VCPU_GPR_TM)
  35
  36 /* Values in HSTATE_NAPPING(r13) */
  37 #define NAPPING_CEDE    1
  38 #define NAPPING_NOVCPU  2
  39
  40 /*
  41  * Call kvmppc_hv_entry in real mode.
  42  * Must be called with interrupts hard-disabled.
  43  *
  44  * Input Registers:
  45  *
  46  * LR = return address to continue at after eventually re-enabling MMU
  47  */
  48 _GLOBAL_TOC(kvmppc_hv_entry_trampoline)
  49         mflr    r0
  50         std     r0, PPC_LR_STKOFF(r1)
  51         stdu    r1, -112(r1)
  52         mfmsr   r10
  53         LOAD_REG_ADDR(r5, kvmppc_call_hv_entry)
  54         li      r0,MSR_RI
  55         andc    r0,r10,r0
  56         li      r6,MSR_IR | MSR_DR
  57         andc    r6,r10,r6
  58         mtmsrd  r0,1            /* clear RI in MSR */
  59         mtsrr0  r5
  60         mtsrr1  r6
  61         RFI
  62
  63 kvmppc_call_hv_entry:
  64         ld      r4, HSTATE_KVM_VCPU(r13)
  65         bl      kvmppc_hv_entry
  66
  67         /* Back from guest - restore host state and return to caller */
  68
  69 BEGIN_FTR_SECTION
  70         /* Restore host DABR and DABRX */
  71         ld      r5,HSTATE_DABR(r13)
  72         li      r6,7
  73         mtspr   SPRN_DABR,r5
  74         mtspr   SPRN_DABRX,r6
  75 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_207S)
  76
  77         /* Restore SPRG3 */
  78         ld      r3,PACA_SPRG_VDSO(r13)
  79         mtspr   SPRN_SPRG_VDSO_WRITE,r3
  80
  81         /* Reload the host's PMU registers */
  82         ld      r3, PACALPPACAPTR(r13)  /* is the host using the PMU? */
  83         lbz     r4, LPPACA_PMCINUSE(r3)
  84         cmpwi   r4, 0
  85         beq     23f                     /* skip if not */
  86 BEGIN_FTR_SECTION
  87         ld      r3, HSTATE_MMCR0(r13)
  88         andi.   r4, r3, MMCR0_PMAO_SYNC | MMCR0_PMAO
  89         cmpwi   r4, MMCR0_PMAO
  90         beql    kvmppc_fix_pmao
  91 END_FTR_SECTION_IFSET(CPU_FTR_PMAO_BUG)
  92         lwz     r3, HSTATE_PMC1(r13)
  93         lwz     r4, HSTATE_PMC2(r13)
  94         lwz     r5, HSTATE_PMC3(r13)
  95         lwz     r6, HSTATE_PMC4(r13)
  96         lwz     r8, HSTATE_PMC5(r13)
  97         lwz     r9, HSTATE_PMC6(r13)
  98         mtspr   SPRN_PMC1, r3
  99         mtspr   SPRN_PMC2, r4
 100         mtspr   SPRN_PMC3, r5
 101         mtspr   SPRN_PMC4, r6
 102         mtspr   SPRN_PMC5, r8
 103         mtspr   SPRN_PMC6, r9
 104         ld      r3, HSTATE_MMCR0(r13)
 105         ld      r4, HSTATE_MMCR1(r13)
 106         ld      r5, HSTATE_MMCRA(r13)
 107         ld      r6, HSTATE_SIAR(r13)
 108         ld      r7, HSTATE_SDAR(r13)
 109         mtspr   SPRN_MMCR1, r4
 110         mtspr   SPRN_MMCRA, r5
 111         mtspr   SPRN_SIAR, r6
 112         mtspr   SPRN_SDAR, r7
 113 BEGIN_FTR_SECTION
 114         ld      r8, HSTATE_MMCR2(r13)
 115         ld      r9, HSTATE_SIER(r13)
 116         mtspr   SPRN_MMCR2, r8
 117         mtspr   SPRN_SIER, r9
 118 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 119         mtspr   SPRN_MMCR0, r3
 120         isync
 121 23:
 122
 123         /*
 124          * Reload DEC.  HDEC interrupts were disabled when
 125          * we reloaded the host's LPCR value.
 126          */
 127         ld      r3, HSTATE_DECEXP(r13)
 128         mftb    r4
 129         subf    r4, r4, r3
 130         mtspr   SPRN_DEC, r4
 131
 132         /* hwthread_req may have got set by cede or no vcpu, so clear it */
 133         li      r0, 0
 134         stb     r0, HSTATE_HWTHREAD_REQ(r13)
 135
 136         /*
 137          * For external and machine check interrupts, we need
 138          * to call the Linux handler to process the interrupt.
 139          * We do that by jumping to absolute address 0x500 for
 140          * external interrupts, or the machine_check_fwnmi label
 141          * for machine checks (since firmware might have patched
 142          * the vector area at 0x200).  The [h]rfid at the end of the
 143          * handler will return to the book3s_hv_interrupts.S code.
 144          * For other interrupts we do the rfid to get back
 145          * to the book3s_hv_interrupts.S code here.
 146          */
 147         ld      r8, 112+PPC_LR_STKOFF(r1)
 148         addi    r1, r1, 112
 149         ld      r7, HSTATE_HOST_MSR(r13)
 150
 151         cmpwi   cr1, r12, BOOK3S_INTERRUPT_MACHINE_CHECK
 152         cmpwi   r12, BOOK3S_INTERRUPT_EXTERNAL
 153         beq     11f
 154         cmpwi   r12, BOOK3S_INTERRUPT_H_DOORBELL
 155         beq     15f     /* Invoke the H_DOORBELL handler */
 156         cmpwi   cr2, r12, BOOK3S_INTERRUPT_HMI
 157         beq     cr2, 14f                        /* HMI check */
 158
 159         /* RFI into the highmem handler, or branch to interrupt handler */
 160         mfmsr   r6
 161         li      r0, MSR_RI
 162         andc    r6, r6, r0
 163         mtmsrd  r6, 1                   /* Clear RI in MSR */
 164         mtsrr0  r8
 165         mtsrr1  r7
 166         beq     cr1, 13f                /* machine check */
 167         RFI
 168
 169         /* On POWER7, we have external interrupts set to use HSRR0/1 */
 170 11:     mtspr   SPRN_HSRR0, r8
 171         mtspr   SPRN_HSRR1, r7
 172         ba      0x500
 173
 174 13:     b       machine_check_fwnmi
 175
 176 14:     mtspr   SPRN_HSRR0, r8
 177         mtspr   SPRN_HSRR1, r7
 178         b       hmi_exception_after_realmode
 179
 180 15:     mtspr SPRN_HSRR0, r8
 181         mtspr SPRN_HSRR1, r7
 182         ba    0xe80
 183
 184 kvmppc_primary_no_guest:
 185         /* We handle this much like a ceded vcpu */
 186         /* put the HDEC into the DEC, since HDEC interrupts don't wake us */
 187         mfspr   r3, SPRN_HDEC
 188         mtspr   SPRN_DEC, r3
 189         /*
 190          * Make sure the primary has finished the MMU switch.
 191          * We should never get here on a secondary thread, but
 192          * check it for robustness' sake.
 193          */
 194         ld      r5, HSTATE_KVM_VCORE(r13)
 195 65:     lbz     r0, VCORE_IN_GUEST(r5)
 196         cmpwi   r0, 0
 197         beq     65b
 198         /* Set LPCR. */
 199         ld      r8,VCORE_LPCR(r5)
 200         mtspr   SPRN_LPCR,r8
 201         isync
 202         /* set our bit in napping_threads */
 203         ld      r5, HSTATE_KVM_VCORE(r13)
 204         lbz     r7, HSTATE_PTID(r13)
 205         li      r0, 1
 206         sld     r0, r0, r7
 207         addi    r6, r5, VCORE_NAPPING_THREADS
 208 1:      lwarx   r3, 0, r6
 209         or      r3, r3, r0
 210         stwcx.  r3, 0, r6
 211         bne     1b
 212         /* order napping_threads update vs testing entry_exit_map */
 213         isync
 214         li      r12, 0
 215         lwz     r7, VCORE_ENTRY_EXIT(r5)
 216         cmpwi   r7, 0x100
 217         bge     kvm_novcpu_exit /* another thread already exiting */
 218         li      r3, NAPPING_NOVCPU
 219         stb     r3, HSTATE_NAPPING(r13)
 220
 221         li      r3, 0           /* Don't wake on privileged (OS) doorbell */
 222         b       kvm_do_nap
 223
 224 /*
 225  * kvm_novcpu_wakeup
 226  *      Entered from kvm_start_guest if kvm_hstate.napping is set
 227  *      to NAPPING_NOVCPU
 228  *              r2 = kernel TOC
 229  *              r13 = paca
 230  */
 231 kvm_novcpu_wakeup:
 232         ld      r1, HSTATE_HOST_R1(r13)
 233         ld      r5, HSTATE_KVM_VCORE(r13)
 234         li      r0, 0
 235         stb     r0, HSTATE_NAPPING(r13)
 236
 237         /* check the wake reason */
 238         bl      kvmppc_check_wake_reason
 239
 240         /*
 241          * Restore volatile registers since we could have called
 242          * a C routine in kvmppc_check_wake_reason.
 243          *      r5 = VCORE
 244          */
 245         ld      r5, HSTATE_KVM_VCORE(r13)
 246
 247         /* see if any other thread is already exiting */
 248         lwz     r0, VCORE_ENTRY_EXIT(r5)
 249         cmpwi   r0, 0x100
 250         bge     kvm_novcpu_exit
 251
 252         /* clear our bit in napping_threads */
 253         lbz     r7, HSTATE_PTID(r13)
 254         li      r0, 1
 255         sld     r0, r0, r7
 256         addi    r6, r5, VCORE_NAPPING_THREADS
 257 4:      lwarx   r7, 0, r6
 258         andc    r7, r7, r0
 259         stwcx.  r7, 0, r6
 260         bne     4b
 261
 262         /* See if the wake reason means we need to exit */
 263         cmpdi   r3, 0
 264         bge     kvm_novcpu_exit
 265
 266         /* See if our timeslice has expired (HDEC is negative) */
 267         mfspr   r0, SPRN_HDEC
 268         li      r12, BOOK3S_INTERRUPT_HV_DECREMENTER
 269         cmpwi   r0, 0
 270         blt     kvm_novcpu_exit
 271
 272         /* Got an IPI but other vcpus aren't yet exiting, must be a latecomer */
 273         ld      r4, HSTATE_KVM_VCPU(r13)
 274         cmpdi   r4, 0
 275         beq     kvmppc_primary_no_guest
 276
 277 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
 278         addi    r3, r4, VCPU_TB_RMENTRY
 279         bl      kvmhv_start_timing
 280 #endif
 281         b       kvmppc_got_guest
 282
 283 kvm_novcpu_exit:
 284 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
 285         ld      r4, HSTATE_KVM_VCPU(r13)
 286         cmpdi   r4, 0
 287         beq     13f
 288         addi    r3, r4, VCPU_TB_RMEXIT
 289         bl      kvmhv_accumulate_time
 290 #endif
 291 13:     mr      r3, r12
 292         stw     r12, 112-4(r1)
 293         bl      kvmhv_commence_exit
 294         nop
 295         lwz     r12, 112-4(r1)
 296         b       kvmhv_switch_to_host
 297
 298 /*
 299  * We come in here when wakened from nap mode.
 300  * Relocation is off and most register values are lost.
 301  * r13 points to the PACA.
 302  */
 303         .globl  kvm_start_guest
 304 kvm_start_guest:
 305
 306         /* Set runlatch bit the minute you wake up from nap */
 307         mfspr   r0, SPRN_CTRLF
 308         ori     r0, r0, 1
 309         mtspr   SPRN_CTRLT, r0
 310
 311         ld      r2,PACATOC(r13)
 312
 313         li      r0,KVM_HWTHREAD_IN_KVM
 314         stb     r0,HSTATE_HWTHREAD_STATE(r13)
 315
 316         /* NV GPR values from power7_idle() will no longer be valid */
 317         li      r0,1
 318         stb     r0,PACA_NAPSTATELOST(r13)
 319
 320         /* were we napping due to cede? */
 321         lbz     r0,HSTATE_NAPPING(r13)
 322         cmpwi   r0,NAPPING_CEDE
 323         beq     kvm_end_cede
 324         cmpwi   r0,NAPPING_NOVCPU
 325         beq     kvm_novcpu_wakeup
 326
 327         ld      r1,PACAEMERGSP(r13)
 328         subi    r1,r1,STACK_FRAME_OVERHEAD
 329
 330         /*
 331          * We weren't napping due to cede, so this must be a secondary
 332          * thread being woken up to run a guest, or being woken up due
 333          * to a stray IPI.  (Or due to some machine check or hypervisor
 334          * maintenance interrupt while the core is in KVM.)
 335          */
 336
 337         /* Check the wake reason in SRR1 to see why we got here */
 338         bl      kvmppc_check_wake_reason
 339         /*
 340          * kvmppc_check_wake_reason could invoke a C routine, but we
 341          * have no volatile registers to restore when we return.
 342          */
 343
 344         cmpdi   r3, 0
 345         bge     kvm_no_guest
 346
 347         /* get vcore pointer, NULL if we have nothing to run */
 348         ld      r5,HSTATE_KVM_VCORE(r13)
 349         cmpdi   r5,0
 350         /* if we have no vcore to run, go back to sleep */
 351         beq     kvm_no_guest
 352
 353 kvm_secondary_got_guest:
 354
 355         /* Set HSTATE_DSCR(r13) to something sensible */
 356         ld      r6, PACA_DSCR_DEFAULT(r13)
 357         std     r6, HSTATE_DSCR(r13)
 358
 359         /* On thread 0 of a subcore, set HDEC to max */
 360         lbz     r4, HSTATE_PTID(r13)
 361         cmpwi   r4, 0
 362         bne     63f
 363         lis     r6, 0x7fff
 364         ori     r6, r6, 0xffff
 365         mtspr   SPRN_HDEC, r6
 366         /* and set per-LPAR registers, if doing dynamic micro-threading */
 367         ld      r6, HSTATE_SPLIT_MODE(r13)
 368         cmpdi   r6, 0
 369         beq     63f
 370         ld      r0, KVM_SPLIT_RPR(r6)
 371         mtspr   SPRN_RPR, r0
 372         ld      r0, KVM_SPLIT_PMMAR(r6)
 373         mtspr   SPRN_PMMAR, r0
 374         ld      r0, KVM_SPLIT_LDBAR(r6)
 375         mtspr   SPRN_LDBAR, r0
 376         isync
 377 63:
 378         /* Order load of vcpu after load of vcore */
 379         lwsync
 380         ld      r4, HSTATE_KVM_VCPU(r13)
 381         bl      kvmppc_hv_entry
 382
 383         /* Back from the guest, go back to nap */
 384         /* Clear our vcpu and vcore pointers so we don't come back in early */
 385         li      r0, 0
 386         std     r0, HSTATE_KVM_VCPU(r13)
 387         /*
 388          * Once we clear HSTATE_KVM_VCORE(r13), the code in
 389          * kvmppc_run_core() is going to assume that all our vcpu
 390          * state is visible in memory.  This lwsync makes sure
 391          * that that is true.
 392          */
 393         lwsync
 394         std     r0, HSTATE_KVM_VCORE(r13)
 395
 396         /*
 397          * All secondaries exiting guest will fall through this path.
 398          * Before proceeding, just check for HMI interrupt and
 399          * invoke opal hmi handler. By now we are sure that the
 400          * primary thread on this core/subcore has already made partition
 401          * switch/TB resync and we are good to call opal hmi handler.
 402          */
 403         cmpwi   r12, BOOK3S_INTERRUPT_HMI
 404         bne     kvm_no_guest
 405
 406         li      r3,0                    /* NULL argument */
 407         bl      hmi_exception_realmode
 408 /*
 409  * At this point we have finished executing in the guest.
 410  * We need to wait for hwthread_req to become zero, since
 411  * we may not turn on the MMU while hwthread_req is non-zero.
 412  * While waiting we also need to check if we get given a vcpu to run.
 413  */
 414 kvm_no_guest:
 415         lbz     r3, HSTATE_HWTHREAD_REQ(r13)
 416         cmpwi   r3, 0
 417         bne     53f
 418         HMT_MEDIUM
 419         li      r0, KVM_HWTHREAD_IN_KERNEL
 420         stb     r0, HSTATE_HWTHREAD_STATE(r13)
 421         /* need to recheck hwthread_req after a barrier, to avoid race */
 422         sync
 423         lbz     r3, HSTATE_HWTHREAD_REQ(r13)
 424         cmpwi   r3, 0
 425         bne     54f
 426 /*
 427  * We jump to pnv_wakeup_loss, which will return to the caller
 428  * of power7_nap in the powernv cpu offline loop.  The value we
 429  * put in r3 becomes the return value for power7_nap.
 430  */
 431         li      r3, LPCR_PECE0
 432         mfspr   r4, SPRN_LPCR
 433         rlwimi  r4, r3, 0, LPCR_PECE0 | LPCR_PECE1
 434         mtspr   SPRN_LPCR, r4
 435         li      r3, 0
 436         b       pnv_wakeup_loss
 437
 438 53:     HMT_LOW
 439         ld      r5, HSTATE_KVM_VCORE(r13)
 440         cmpdi   r5, 0
 441         bne     60f
 442         ld      r3, HSTATE_SPLIT_MODE(r13)
 443         cmpdi   r3, 0
 444         beq     kvm_no_guest
 445         lbz     r0, KVM_SPLIT_DO_NAP(r3)
 446         cmpwi   r0, 0
 447         beq     kvm_no_guest
 448         HMT_MEDIUM
 449         b       kvm_unsplit_nap
 450 60:     HMT_MEDIUM
 451         b       kvm_secondary_got_guest
 452
 453 54:     li      r0, KVM_HWTHREAD_IN_KVM
 454         stb     r0, HSTATE_HWTHREAD_STATE(r13)
 455         b       kvm_no_guest
 456
 457 /*
 458  * Here the primary thread is trying to return the core to
 459  * whole-core mode, so we need to nap.
 460  */
 461 kvm_unsplit_nap:
 462         /*
 463          * When secondaries are napping in kvm_unsplit_nap() with
 464          * hwthread_req = 1, HMI goes ignored even though subcores are
 465          * already exited the guest. Hence HMI keeps waking up secondaries
 466          * from nap in a loop and secondaries always go back to nap since
 467          * no vcore is assigned to them. This makes impossible for primary
 468          * thread to get hold of secondary threads resulting into a soft
 469          * lockup in KVM path.
 470          *
 471          * Let us check if HMI is pending and handle it before we go to nap.
 472          */
 473         cmpwi   r12, BOOK3S_INTERRUPT_HMI
 474         bne     55f
 475         li      r3, 0                   /* NULL argument */
 476         bl      hmi_exception_realmode
 477 55:
 478         /*
 479          * Ensure that secondary doesn't nap when it has
 480          * its vcore pointer set.
 481          */
 482         sync            /* matches smp_mb() before setting split_info.do_nap */
 483         ld      r0, HSTATE_KVM_VCORE(r13)
 484         cmpdi   r0, 0
 485         bne     kvm_no_guest
 486         /* clear any pending message */
 487 BEGIN_FTR_SECTION
 488         lis     r6, (PPC_DBELL_SERVER << (63-36))@h
 489         PPC_MSGCLR(6)
 490 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 491         /* Set kvm_split_mode.napped[tid] = 1 */
 492         ld      r3, HSTATE_SPLIT_MODE(r13)
 493         li      r0, 1
 494         lhz     r4, PACAPACAINDEX(r13)
 495         clrldi  r4, r4, 61      /* micro-threading => P8 => 8 threads/core */
 496         addi    r4, r4, KVM_SPLIT_NAPPED
 497         stbx    r0, r3, r4
 498         /* Check the do_nap flag again after setting napped[] */
 499         sync
 500         lbz     r0, KVM_SPLIT_DO_NAP(r3)
 501         cmpwi   r0, 0
 502         beq     57f
 503         li      r3, (LPCR_PECEDH | LPCR_PECE0) >> 4
 504         mfspr   r5, SPRN_LPCR
 505         rlwimi  r5, r3, 4, (LPCR_PECEDP | LPCR_PECEDH | LPCR_PECE0 | LPCR_PECE1)
 506         b       kvm_nap_sequence
 507
 508 57:     li      r0, 0
 509         stbx    r0, r3, r4
 510         b       kvm_no_guest
 511
 512 /******************************************************************************
 513  *                                                                            *
 514  *                               Entry code                                   *
 515  *                                                                            *
 516  *****************************************************************************/
 517
 518 /* Stack frame offsets */
 519 #define STACK_SLOT_TID          (112-16)
 520 #define STACK_SLOT_PSSCR        (112-24)
 521
 522 .global kvmppc_hv_entry
 523 kvmppc_hv_entry:
 524
 525         /* Required state:
 526          *
 527          * R4 = vcpu pointer (or NULL)
 528          * MSR = ~IR|DR
 529          * R13 = PACA
 530          * R1 = host R1
 531          * R2 = TOC
 532          * all other volatile GPRS = free
 533          */
 534         mflr    r0
 535         std     r0, PPC_LR_STKOFF(r1)
 536         stdu    r1, -112(r1)
 537
 538         /* Save R1 in the PACA */
 539         std     r1, HSTATE_HOST_R1(r13)
 540
 541         li      r6, KVM_GUEST_MODE_HOST_HV
 542         stb     r6, HSTATE_IN_GUEST(r13)
 543
 544 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
 545         /* Store initial timestamp */
 546         cmpdi   r4, 0
 547         beq     1f
 548         addi    r3, r4, VCPU_TB_RMENTRY
 549         bl      kvmhv_start_timing
 550 1:
 551 #endif
 552         /* Clear out SLB */
 553         li      r6,0
 554         slbmte  r6,r6
 555         slbia
 556         ptesync
 557
 558         /*
 559          * POWER7/POWER8 host -> guest partition switch code.
 560          * We don't have to lock against concurrent tlbies,
 561          * but we do have to coordinate across hardware threads.
 562          */
 563         /* Set bit in entry map iff exit map is zero. */
 564         ld      r5, HSTATE_KVM_VCORE(r13)
 565         li      r7, 1
 566         lbz     r6, HSTATE_PTID(r13)
 567         sld     r7, r7, r6
 568         addi    r9, r5, VCORE_ENTRY_EXIT
 569 21:     lwarx   r3, 0, r9
 570         cmpwi   r3, 0x100               /* any threads starting to exit? */
 571         bge     secondary_too_late      /* if so we're too late to the party */
 572         or      r3, r3, r7
 573         stwcx.  r3, 0, r9
 574         bne     21b
 575
 576         /* Primary thread switches to guest partition. */
 577         ld      r9,VCORE_KVM(r5)        /* pointer to struct kvm */
 578         cmpwi   r6,0
 579         bne     10f
 580         lwz     r7,KVM_LPID(r9)
 581 BEGIN_FTR_SECTION
 582         ld      r6,KVM_SDR1(r9)
 583         li      r0,LPID_RSVD            /* switch to reserved LPID */
 584         mtspr   SPRN_LPID,r0
 585         ptesync
 586         mtspr   SPRN_SDR1,r6            /* switch to partition page table */
 587 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_300)
 588         mtspr   SPRN_LPID,r7
 589         isync
 590
 591         /* See if we need to flush the TLB */
 592         lhz     r6,PACAPACAINDEX(r13)   /* test_bit(cpu, need_tlb_flush) */
 593         clrldi  r7,r6,64-6              /* extract bit number (6 bits) */
 594         srdi    r6,r6,6                 /* doubleword number */
 595         sldi    r6,r6,3                 /* address offset */
 596         add     r6,r6,r9
 597         addi    r6,r6,KVM_NEED_FLUSH    /* dword in kvm->arch.need_tlb_flush */
 598         li      r0,1
 599         sld     r0,r0,r7
 600         ld      r7,0(r6)
 601         and.    r7,r7,r0
 602         beq     22f
 603 23:     ldarx   r7,0,r6                 /* if set, clear the bit */
 604         andc    r7,r7,r0
 605         stdcx.  r7,0,r6
 606         bne     23b
 607         /* Flush the TLB of any entries for this LPID */
 608         lwz     r6,KVM_TLB_SETS(r9)
 609         li      r0,0                    /* RS for P9 version of tlbiel */
 610         mtctr   r6
 611         li      r7,0x800                /* IS field = 0b10 */
 612         ptesync
 613 28:     tlbiel  r7
 614         addi    r7,r7,0x1000
 615         bdnz    28b
 616         ptesync
 617
 618         /* Add timebase offset onto timebase */
 619 22:     ld      r8,VCORE_TB_OFFSET(r5)
 620         cmpdi   r8,0
 621         beq     37f
 622         mftb    r6              /* current host timebase */
 623         add     r8,r8,r6
 624         mtspr   SPRN_TBU40,r8   /* update upper 40 bits */
 625         mftb    r7              /* check if lower 24 bits overflowed */
 626         clrldi  r6,r6,40
 627         clrldi  r7,r7,40
 628         cmpld   r7,r6
 629         bge     37f
 630         addis   r8,r8,0x100     /* if so, increment upper 40 bits */
 631         mtspr   SPRN_TBU40,r8
 632
 633         /* Load guest PCR value to select appropriate compat mode */
 634 37:     ld      r7, VCORE_PCR(r5)
 635         cmpdi   r7, 0
 636         beq     38f
 637         mtspr   SPRN_PCR, r7
 638 38:
 639
 640 BEGIN_FTR_SECTION
 641         /* DPDES and VTB are shared between threads */
 642         ld      r8, VCORE_DPDES(r5)
 643         ld      r7, VCORE_VTB(r5)
 644         mtspr   SPRN_DPDES, r8
 645         mtspr   SPRN_VTB, r7
 646 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 647
 648         /* Mark the subcore state as inside guest */
 649         bl      kvmppc_subcore_enter_guest
 650         nop
 651         ld      r5, HSTATE_KVM_VCORE(r13)
 652         ld      r4, HSTATE_KVM_VCPU(r13)
 653         li      r0,1
 654         stb     r0,VCORE_IN_GUEST(r5)   /* signal secondaries to continue */
 655
 656         /* Do we have a guest vcpu to run? */
 657 10:     cmpdi   r4, 0
 658         beq     kvmppc_primary_no_guest
 659 kvmppc_got_guest:
 660
 661         /* Load up guest SLB entries */
 662         lwz     r5,VCPU_SLB_MAX(r4)
 663         cmpwi   r5,0
 664         beq     9f
 665         mtctr   r5
 666         addi    r6,r4,VCPU_SLB
 667 1:      ld      r8,VCPU_SLB_E(r6)
 668         ld      r9,VCPU_SLB_V(r6)
 669         slbmte  r9,r8
 670         addi    r6,r6,VCPU_SLB_SIZE
 671         bdnz    1b
 672 9:
 673         /* Increment yield count if they have a VPA */
 674         ld      r3, VCPU_VPA(r4)
 675         cmpdi   r3, 0
 676         beq     25f
 677         li      r6, LPPACA_YIELDCOUNT
 678         LWZX_BE r5, r3, r6
 679         addi    r5, r5, 1
 680         STWX_BE r5, r3, r6
 681         li      r6, 1
 682         stb     r6, VCPU_VPA_DIRTY(r4)
 683 25:
 684
 685         /* Save purr/spurr */
 686         mfspr   r5,SPRN_PURR
 687         mfspr   r6,SPRN_SPURR
 688         std     r5,HSTATE_PURR(r13)
 689         std     r6,HSTATE_SPURR(r13)
 690         ld      r7,VCPU_PURR(r4)
 691         ld      r8,VCPU_SPURR(r4)
 692         mtspr   SPRN_PURR,r7
 693         mtspr   SPRN_SPURR,r8
 694
 695         /* Save host values of some registers */
 696 BEGIN_FTR_SECTION
 697         mfspr   r5, SPRN_TIDR
 698         mfspr   r6, SPRN_PSSCR
 699         std     r5, STACK_SLOT_TID(r1)
 700         std     r6, STACK_SLOT_PSSCR(r1)
 701 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
 702
 703 BEGIN_FTR_SECTION
 704         /* Set partition DABR */
 705         /* Do this before re-enabling PMU to avoid P7 DABR corruption bug */
 706         lwz     r5,VCPU_DABRX(r4)
 707         ld      r6,VCPU_DABR(r4)
 708         mtspr   SPRN_DABRX,r5
 709         mtspr   SPRN_DABR,r6
 710         isync
 711 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_207S)
 712
 713 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
 714 BEGIN_FTR_SECTION
 715         bl      kvmppc_restore_tm
 716 END_FTR_SECTION_IFSET(CPU_FTR_TM)
 717 #endif
 718
 719         /* Load guest PMU registers */
 720         /* R4 is live here (vcpu pointer) */
 721         li      r3, 1
 722         sldi    r3, r3, 31              /* MMCR0_FC (freeze counters) bit */
 723         mtspr   SPRN_MMCR0, r3          /* freeze all counters, disable ints */
 724         isync
 725 BEGIN_FTR_SECTION
 726         ld      r3, VCPU_MMCR(r4)
 727         andi.   r5, r3, MMCR0_PMAO_SYNC | MMCR0_PMAO
 728         cmpwi   r5, MMCR0_PMAO
 729         beql    kvmppc_fix_pmao
 730 END_FTR_SECTION_IFSET(CPU_FTR_PMAO_BUG)
 731         lwz     r3, VCPU_PMC(r4)        /* always load up guest PMU registers */
 732         lwz     r5, VCPU_PMC + 4(r4)    /* to prevent information leak */
 733         lwz     r6, VCPU_PMC + 8(r4)
 734         lwz     r7, VCPU_PMC + 12(r4)
 735         lwz     r8, VCPU_PMC + 16(r4)
 736         lwz     r9, VCPU_PMC + 20(r4)
 737         mtspr   SPRN_PMC1, r3
 738         mtspr   SPRN_PMC2, r5
 739         mtspr   SPRN_PMC3, r6
 740         mtspr   SPRN_PMC4, r7
 741         mtspr   SPRN_PMC5, r8
 742         mtspr   SPRN_PMC6, r9
 743         ld      r3, VCPU_MMCR(r4)
 744         ld      r5, VCPU_MMCR + 8(r4)
 745         ld      r6, VCPU_MMCR + 16(r4)
 746         ld      r7, VCPU_SIAR(r4)
 747         ld      r8, VCPU_SDAR(r4)
 748         mtspr   SPRN_MMCR1, r5
 749         mtspr   SPRN_MMCRA, r6
 750         mtspr   SPRN_SIAR, r7
 751         mtspr   SPRN_SDAR, r8
 752 BEGIN_FTR_SECTION
 753         ld      r5, VCPU_MMCR + 24(r4)
 754         ld      r6, VCPU_SIER(r4)
 755         mtspr   SPRN_MMCR2, r5
 756         mtspr   SPRN_SIER, r6
 757 BEGIN_FTR_SECTION_NESTED(96)
 758         lwz     r7, VCPU_PMC + 24(r4)
 759         lwz     r8, VCPU_PMC + 28(r4)
 760         ld      r9, VCPU_MMCR + 32(r4)
 761         mtspr   SPRN_SPMC1, r7
 762         mtspr   SPRN_SPMC2, r8
 763         mtspr   SPRN_MMCRS, r9
 764 END_FTR_SECTION_NESTED(CPU_FTR_ARCH_300, 0, 96)
 765 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 766         mtspr   SPRN_MMCR0, r3
 767         isync
 768
 769         /* Load up FP, VMX and VSX registers */
 770         bl      kvmppc_load_fp
 771
 772         ld      r14, VCPU_GPR(R14)(r4)
 773         ld      r15, VCPU_GPR(R15)(r4)
 774         ld      r16, VCPU_GPR(R16)(r4)
 775         ld      r17, VCPU_GPR(R17)(r4)
 776         ld      r18, VCPU_GPR(R18)(r4)
 777         ld      r19, VCPU_GPR(R19)(r4)
 778         ld      r20, VCPU_GPR(R20)(r4)
 779         ld      r21, VCPU_GPR(R21)(r4)
 780         ld      r22, VCPU_GPR(R22)(r4)
 781         ld      r23, VCPU_GPR(R23)(r4)
 782         ld      r24, VCPU_GPR(R24)(r4)
 783         ld      r25, VCPU_GPR(R25)(r4)
 784         ld      r26, VCPU_GPR(R26)(r4)
 785         ld      r27, VCPU_GPR(R27)(r4)
 786         ld      r28, VCPU_GPR(R28)(r4)
 787         ld      r29, VCPU_GPR(R29)(r4)
 788         ld      r30, VCPU_GPR(R30)(r4)
 789         ld      r31, VCPU_GPR(R31)(r4)
 790
 791         /* Switch DSCR to guest value */
 792         ld      r5, VCPU_DSCR(r4)
 793         mtspr   SPRN_DSCR, r5
 794
 795 BEGIN_FTR_SECTION
 796         /* Skip next section on POWER7 */
 797         b       8f
 798 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_207S)
 799         /* Load up POWER8-specific registers */
 800         ld      r5, VCPU_IAMR(r4)
 801         lwz     r6, VCPU_PSPB(r4)
 802         ld      r7, VCPU_FSCR(r4)
 803         mtspr   SPRN_IAMR, r5
 804         mtspr   SPRN_PSPB, r6
 805         mtspr   SPRN_FSCR, r7
 806         ld      r5, VCPU_DAWR(r4)
 807         ld      r6, VCPU_DAWRX(r4)
 808         ld      r7, VCPU_CIABR(r4)
 809         ld      r8, VCPU_TAR(r4)
 810         mtspr   SPRN_DAWR, r5
 811         mtspr   SPRN_DAWRX, r6
 812         mtspr   SPRN_CIABR, r7
 813         mtspr   SPRN_TAR, r8
 814         ld      r5, VCPU_IC(r4)
 815         ld      r8, VCPU_EBBHR(r4)
 816         mtspr   SPRN_IC, r5
 817         mtspr   SPRN_EBBHR, r8
 818         ld      r5, VCPU_EBBRR(r4)
 819         ld      r6, VCPU_BESCR(r4)
 820         lwz     r7, VCPU_GUEST_PID(r4)
 821         ld      r8, VCPU_WORT(r4)
 822         mtspr   SPRN_EBBRR, r5
 823         mtspr   SPRN_BESCR, r6
 824         mtspr   SPRN_PID, r7
 825         mtspr   SPRN_WORT, r8
 826 BEGIN_FTR_SECTION
 827         /* POWER8-only registers */
 828         ld      r5, VCPU_TCSCR(r4)
 829         ld      r6, VCPU_ACOP(r4)
 830         ld      r7, VCPU_CSIGR(r4)
 831         ld      r8, VCPU_TACR(r4)
 832         mtspr   SPRN_TCSCR, r5
 833         mtspr   SPRN_ACOP, r6
 834         mtspr   SPRN_CSIGR, r7
 835         mtspr   SPRN_TACR, r8
 836 FTR_SECTION_ELSE
 837         /* POWER9-only registers */
 838         ld      r5, VCPU_TID(r4)
 839         ld      r6, VCPU_PSSCR(r4)
 840         oris    r6, r6, PSSCR_EC@h      /* This makes stop trap to HV */
 841         mtspr   SPRN_TIDR, r5
 842         mtspr   SPRN_PSSCR, r6
 843 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_ARCH_300)
 844 8:
 845
 846         /*
 847          * Set the decrementer to the guest decrementer.
 848          */
 849         ld      r8,VCPU_DEC_EXPIRES(r4)
 850         /* r8 is a host timebase value here, convert to guest TB */
 851         ld      r5,HSTATE_KVM_VCORE(r13)
 852         ld      r6,VCORE_TB_OFFSET(r5)
 853         add     r8,r8,r6
 854         mftb    r7
 855         subf    r3,r7,r8
 856         mtspr   SPRN_DEC,r3
 857         stw     r3,VCPU_DEC(r4)
 858
 859         ld      r5, VCPU_SPRG0(r4)
 860         ld      r6, VCPU_SPRG1(r4)
 861         ld      r7, VCPU_SPRG2(r4)
 862         ld      r8, VCPU_SPRG3(r4)
 863         mtspr   SPRN_SPRG0, r5
 864         mtspr   SPRN_SPRG1, r6
 865         mtspr   SPRN_SPRG2, r7
 866         mtspr   SPRN_SPRG3, r8
 867
 868         /* Load up DAR and DSISR */
 869         ld      r5, VCPU_DAR(r4)
 870         lwz     r6, VCPU_DSISR(r4)
 871         mtspr   SPRN_DAR, r5
 872         mtspr   SPRN_DSISR, r6
 873
 874         /* Restore AMR and UAMOR, set AMOR to all 1s */
 875         ld      r5,VCPU_AMR(r4)
 876         ld      r6,VCPU_UAMOR(r4)
 877         li      r7,-1
 878         mtspr   SPRN_AMR,r5
 879         mtspr   SPRN_UAMOR,r6
 880         mtspr   SPRN_AMOR,r7
 881
 882         /* Restore state of CTRL run bit; assume 1 on entry */
 883         lwz     r5,VCPU_CTRL(r4)
 884         andi.   r5,r5,1
 885         bne     4f
 886         mfspr   r6,SPRN_CTRLF
 887         clrrdi  r6,r6,1
 888         mtspr   SPRN_CTRLT,r6
 889 4:
 890         /* Secondary threads wait for primary to have done partition switch */
 891         ld      r5, HSTATE_KVM_VCORE(r13)
 892         lbz     r6, HSTATE_PTID(r13)
 893         cmpwi   r6, 0
 894         beq     21f
 895         lbz     r0, VCORE_IN_GUEST(r5)
 896         cmpwi   r0, 0
 897         bne     21f
 898         HMT_LOW
 899 20:     lwz     r3, VCORE_ENTRY_EXIT(r5)
 900         cmpwi   r3, 0x100
 901         bge     no_switch_exit
 902         lbz     r0, VCORE_IN_GUEST(r5)
 903         cmpwi   r0, 0
 904         beq     20b
 905         HMT_MEDIUM
 906 21:
 907         /* Set LPCR. */
 908         ld      r8,VCORE_LPCR(r5)
 909         mtspr   SPRN_LPCR,r8
 910         isync
 911
 912         /* Check if HDEC expires soon */
 913         mfspr   r3, SPRN_HDEC
 914         cmpwi   r3, 512         /* 1 microsecond */
 915         blt     hdec_soon
 916
 917 deliver_guest_interrupt:
 918         ld      r6, VCPU_CTR(r4)
 919         ld      r7, VCPU_XER(r4)
 920
 921         mtctr   r6
 922         mtxer   r7
 923
 924 kvmppc_cede_reentry:            /* r4 = vcpu, r13 = paca */
 925         ld      r10, VCPU_PC(r4)
 926         ld      r11, VCPU_MSR(r4)
 927         ld      r6, VCPU_SRR0(r4)
 928         ld      r7, VCPU_SRR1(r4)
 929         mtspr   SPRN_SRR0, r6
 930         mtspr   SPRN_SRR1, r7
 931
 932         /* r11 = vcpu->arch.msr & ~MSR_HV */
 933         rldicl  r11, r11, 63 - MSR_HV_LG, 1
 934         rotldi  r11, r11, 1 + MSR_HV_LG
 935         ori     r11, r11, MSR_ME
 936
 937         /* Check if we can deliver an external or decrementer interrupt now */
 938         ld      r0, VCPU_PENDING_EXC(r4)
 939         rldicl  r0, r0, 64 - BOOK3S_IRQPRIO_EXTERNAL_LEVEL, 63
 940         cmpdi   cr1, r0, 0
 941         andi.   r8, r11, MSR_EE
 942         mfspr   r8, SPRN_LPCR
 943         /* Insert EXTERNAL_LEVEL bit into LPCR at the MER bit position */
 944         rldimi  r8, r0, LPCR_MER_SH, 63 - LPCR_MER_SH
 945         mtspr   SPRN_LPCR, r8
 946         isync
 947         beq     5f
 948         li      r0, BOOK3S_INTERRUPT_EXTERNAL
 949         bne     cr1, 12f
 950         mfspr   r0, SPRN_DEC
 951         cmpwi   r0, 0
 952         li      r0, BOOK3S_INTERRUPT_DECREMENTER
 953         bge     5f
 954
 955 12:     mtspr   SPRN_SRR0, r10
 956         mr      r10,r0
 957         mtspr   SPRN_SRR1, r11
 958         mr      r9, r4
 959         bl      kvmppc_msr_interrupt
 960 5:
 961
 962 /*
 963  * Required state:
 964  * R4 = vcpu
 965  * R10: value for HSRR0
 966  * R11: value for HSRR1
 967  * R13 = PACA
 968  */
 969 fast_guest_return:
 970         li      r0,0
 971         stb     r0,VCPU_CEDED(r4)       /* cancel cede */
 972         mtspr   SPRN_HSRR0,r10
 973         mtspr   SPRN_HSRR1,r11
 974
 975         /* Activate guest mode, so faults get handled by KVM */
 976         li      r9, KVM_GUEST_MODE_GUEST_HV
 977         stb     r9, HSTATE_IN_GUEST(r13)
 978
 979 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
 980         /* Accumulate timing */
 981         addi    r3, r4, VCPU_TB_GUEST
 982         bl      kvmhv_accumulate_time
 983 #endif
 984
 985         /* Enter guest */
 986
 987 BEGIN_FTR_SECTION
 988         ld      r5, VCPU_CFAR(r4)
 989         mtspr   SPRN_CFAR, r5
 990 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
 991 BEGIN_FTR_SECTION
 992         ld      r0, VCPU_PPR(r4)
 993 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
 994
 995         ld      r5, VCPU_LR(r4)
 996         lwz     r6, VCPU_CR(r4)
 997         mtlr    r5
 998         mtcr    r6
 999
1000         ld      r1, VCPU_GPR(R1)(r4)
1001         ld      r2, VCPU_GPR(R2)(r4)
1002         ld      r3, VCPU_GPR(R3)(r4)
1003         ld      r5, VCPU_GPR(R5)(r4)
1004         ld      r6, VCPU_GPR(R6)(r4)
1005         ld      r7, VCPU_GPR(R7)(r4)
1006         ld      r8, VCPU_GPR(R8)(r4)
1007         ld      r9, VCPU_GPR(R9)(r4)
1008         ld      r10, VCPU_GPR(R10)(r4)
1009         ld      r11, VCPU_GPR(R11)(r4)
1010         ld      r12, VCPU_GPR(R12)(r4)
1011         ld      r13, VCPU_GPR(R13)(r4)
1012
1013 BEGIN_FTR_SECTION
1014         mtspr   SPRN_PPR, r0
1015 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
1016         ld      r0, VCPU_GPR(R0)(r4)
1017         ld      r4, VCPU_GPR(R4)(r4)
1018
1019         hrfid
1020         b       .
1021
1022 secondary_too_late:
1023         li      r12, 0
1024         cmpdi   r4, 0
1025         beq     11f
1026         stw     r12, VCPU_TRAP(r4)
1027 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
1028         addi    r3, r4, VCPU_TB_RMEXIT
1029         bl      kvmhv_accumulate_time
1030 #endif
1031 11:     b       kvmhv_switch_to_host
1032
1033 no_switch_exit:
1034         HMT_MEDIUM
1035         li      r12, 0
1036         b       12f
1037 hdec_soon:
1038         li      r12, BOOK3S_INTERRUPT_HV_DECREMENTER
1039 12:     stw     r12, VCPU_TRAP(r4)
1040         mr      r9, r4
1041 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
1042         addi    r3, r4, VCPU_TB_RMEXIT
1043         bl      kvmhv_accumulate_time
1044 #endif
1045         b       guest_exit_cont
1046
1047 /******************************************************************************
1048  *                                                                            *
1049  *                               Exit code                                    *
1050  *                                                                            *
1051  *****************************************************************************/
1052
1053 /*
1054  * We come here from the first-level interrupt handlers.
1055  */
1056         .globl  kvmppc_interrupt_hv
1057 kvmppc_interrupt_hv:
1058         /*
1059          * Register contents:
1060          * R12          = (guest CR << 32) | interrupt vector
1061          * R13          = PACA
1062          * guest R12 saved in shadow VCPU SCRATCH0
1063          * guest CTR saved in shadow VCPU SCRATCH1 if RELOCATABLE
1064          * guest R13 saved in SPRN_SCRATCH0
1065          */
1066         std     r9, HSTATE_SCRATCH2(r13)
1067         lbz     r9, HSTATE_IN_GUEST(r13)
1068         cmpwi   r9, KVM_GUEST_MODE_HOST_HV
1069         beq     kvmppc_bad_host_intr
1070 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
1071         cmpwi   r9, KVM_GUEST_MODE_GUEST
1072         ld      r9, HSTATE_SCRATCH2(r13)
1073         beq     kvmppc_interrupt_pr
1074 #endif
1075         /* We're now back in the host but in guest MMU context */
1076         li      r9, KVM_GUEST_MODE_HOST_HV
1077         stb     r9, HSTATE_IN_GUEST(r13)
1078
1079         ld      r9, HSTATE_KVM_VCPU(r13)
1080
1081         /* Save registers */
1082
1083         std     r0, VCPU_GPR(R0)(r9)
1084         std     r1, VCPU_GPR(R1)(r9)
1085         std     r2, VCPU_GPR(R2)(r9)
1086         std     r3, VCPU_GPR(R3)(r9)
1087         std     r4, VCPU_GPR(R4)(r9)
1088         std     r5, VCPU_GPR(R5)(r9)
1089         std     r6, VCPU_GPR(R6)(r9)
1090         std     r7, VCPU_GPR(R7)(r9)
1091         std     r8, VCPU_GPR(R8)(r9)
1092         ld      r0, HSTATE_SCRATCH2(r13)
1093         std     r0, VCPU_GPR(R9)(r9)
1094         std     r10, VCPU_GPR(R10)(r9)
1095         std     r11, VCPU_GPR(R11)(r9)
1096         ld      r3, HSTATE_SCRATCH0(r13)
1097         std     r3, VCPU_GPR(R12)(r9)
1098         /* CR is in the high half of r12 */
1099         srdi    r4, r12, 32
1100         stw     r4, VCPU_CR(r9)
1101 BEGIN_FTR_SECTION
1102         ld      r3, HSTATE_CFAR(r13)
1103         std     r3, VCPU_CFAR(r9)
1104 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
1105 BEGIN_FTR_SECTION
1106         ld      r4, HSTATE_PPR(r13)
1107         std     r4, VCPU_PPR(r9)
1108 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
1109
1110         /* Restore R1/R2 so we can handle faults */
1111         ld      r1, HSTATE_HOST_R1(r13)
1112         ld      r2, PACATOC(r13)
1113
1114         mfspr   r10, SPRN_SRR0
1115         mfspr   r11, SPRN_SRR1
1116         std     r10, VCPU_SRR0(r9)
1117         std     r11, VCPU_SRR1(r9)
1118         /* trap is in the low half of r12, clear CR from the high half */
1119         clrldi  r12, r12, 32
1120         andi.   r0, r12, 2              /* need to read HSRR0/1? */
1121         beq     1f
1122         mfspr   r10, SPRN_HSRR0
1123         mfspr   r11, SPRN_HSRR1
1124         clrrdi  r12, r12, 2
1125 1:      std     r10, VCPU_PC(r9)
1126         std     r11, VCPU_MSR(r9)
1127
1128         GET_SCRATCH0(r3)
1129         mflr    r4
1130         std     r3, VCPU_GPR(R13)(r9)
1131         std     r4, VCPU_LR(r9)
1132
1133         stw     r12,VCPU_TRAP(r9)
1134
1135 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
1136         addi    r3, r9, VCPU_TB_RMINTR
1137         mr      r4, r9
1138         bl      kvmhv_accumulate_time
1139         ld      r5, VCPU_GPR(R5)(r9)
1140         ld      r6, VCPU_GPR(R6)(r9)
1141         ld      r7, VCPU_GPR(R7)(r9)
1142         ld      r8, VCPU_GPR(R8)(r9)
1143 #endif
1144
1145         /* Save HEIR (HV emulation assist reg) in emul_inst
1146            if this is an HEI (HV emulation interrupt, e40) */
1147         li      r3,KVM_INST_FETCH_FAILED
1148         stw     r3,VCPU_LAST_INST(r9)
1149         cmpwi   r12,BOOK3S_INTERRUPT_H_EMUL_ASSIST
1150         bne     11f
1151         mfspr   r3,SPRN_HEIR
1152 11:     stw     r3,VCPU_HEIR(r9)
1153
1154         /* these are volatile across C function calls */
1155 #ifdef CONFIG_RELOCATABLE
1156         ld      r3, HSTATE_SCRATCH1(r13)
1157         mtctr   r3
1158 #else
1159         mfctr   r3
1160 #endif
1161         mfxer   r4
1162         std     r3, VCPU_CTR(r9)
1163         std     r4, VCPU_XER(r9)
1164
1165         /* If this is a page table miss then see if it's theirs or ours */
1166         cmpwi   r12, BOOK3S_INTERRUPT_H_DATA_STORAGE
1167         beq     kvmppc_hdsi
1168         cmpwi   r12, BOOK3S_INTERRUPT_H_INST_STORAGE
1169         beq     kvmppc_hisi
1170
1171         /* See if this is a leftover HDEC interrupt */
1172         cmpwi   r12,BOOK3S_INTERRUPT_HV_DECREMENTER
1173         bne     2f
1174         mfspr   r3,SPRN_HDEC
1175         cmpwi   r3,0
1176         mr      r4,r9
1177         bge     fast_guest_return
1178 2:
1179         /* See if this is an hcall we can handle in real mode */
1180         cmpwi   r12,BOOK3S_INTERRUPT_SYSCALL
1181         beq     hcall_try_real_mode
1182
1183         /* Hypervisor doorbell - exit only if host IPI flag set */
1184         cmpwi   r12, BOOK3S_INTERRUPT_H_DOORBELL
1185         bne     3f
1186         lbz     r0, HSTATE_HOST_IPI(r13)
1187         cmpwi   r0, 0
1188         beq     4f
1189         b       guest_exit_cont
1190 3:
1191         /* External interrupt ? */
1192         cmpwi   r12, BOOK3S_INTERRUPT_EXTERNAL
1193         bne+    guest_exit_cont
1194
1195         /* External interrupt, first check for host_ipi. If this is
1196          * set, we know the host wants us out so let's do it now
1197          */
1198         bl      kvmppc_read_intr
1199
1200         /*
1201          * Restore the active volatile registers after returning from
1202          * a C function.
1203          */
1204         ld      r9, HSTATE_KVM_VCPU(r13)
1205         li      r12, BOOK3S_INTERRUPT_EXTERNAL
1206
1207         /*
1208          * kvmppc_read_intr return codes:
1209          *
1210          * Exit to host (r3 > 0)
1211          *   1 An interrupt is pending that needs to be handled by the host
1212          *     Exit guest and return to host by branching to guest_exit_cont
1213          *
1214          *   2 Passthrough that needs completion in the host
1215          *     Exit guest and return to host by branching to guest_exit_cont
1216          *     However, we also set r12 to BOOK3S_INTERRUPT_HV_RM_HARD
1217          *     to indicate to the host to complete handling the interrupt
1218          *
1219          * Before returning to guest, we check if any CPU is heading out
1220          * to the host and if so, we head out also. If no CPUs are heading
1221          * check return values <= 0.
1222          *
1223          * Return to guest (r3 <= 0)
1224          *  0 No external interrupt is pending
1225          * -1 A guest wakeup IPI (which has now been cleared)
1226          *    In either case, we return to guest to deliver any pending
1227          *    guest interrupts.
1228          *
1229          * -2 A PCI passthrough external interrupt was handled
1230          *    (interrupt was delivered directly to guest)
1231          *    Return to guest to deliver any pending guest interrupts.
1232          */
1233
1234         cmpdi   r3, 1
1235         ble     1f
1236
1237         /* Return code = 2 */
1238         li      r12, BOOK3S_INTERRUPT_HV_RM_HARD
1239         stw     r12, VCPU_TRAP(r9)
1240         b       guest_exit_cont
1241
1242 1:      /* Return code <= 1 */
1243         cmpdi   r3, 0
1244         bgt     guest_exit_cont
1245
1246         /* Return code <= 0 */
1247 4:      ld      r5, HSTATE_KVM_VCORE(r13)
1248         lwz     r0, VCORE_ENTRY_EXIT(r5)
1249         cmpwi   r0, 0x100
1250         mr      r4, r9
1251         blt     deliver_guest_interrupt
1252
1253 guest_exit_cont:                /* r9 = vcpu, r12 = trap, r13 = paca */
1254         /* Save more register state  */
1255         mfdar   r6
1256         mfdsisr r7
1257         std     r6, VCPU_DAR(r9)
1258         stw     r7, VCPU_DSISR(r9)
1259         /* don't overwrite fault_dar/fault_dsisr if HDSI */
1260         cmpwi   r12,BOOK3S_INTERRUPT_H_DATA_STORAGE
1261         beq     mc_cont
1262         std     r6, VCPU_FAULT_DAR(r9)
1263         stw     r7, VCPU_FAULT_DSISR(r9)
1264
1265         /* See if it is a machine check */
1266         cmpwi   r12, BOOK3S_INTERRUPT_MACHINE_CHECK
1267         beq     machine_check_realmode
1268 mc_cont:
1269 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
1270         addi    r3, r9, VCPU_TB_RMEXIT
1271         mr      r4, r9
1272         bl      kvmhv_accumulate_time
1273 #endif
1274
1275         mr      r3, r12
1276         /* Increment exit count, poke other threads to exit */
1277         bl      kvmhv_commence_exit
1278         nop
1279         ld      r9, HSTATE_KVM_VCPU(r13)
1280         lwz     r12, VCPU_TRAP(r9)
1281
1282         /* Stop others sending VCPU interrupts to this physical CPU */
1283         li      r0, -1
1284         stw     r0, VCPU_CPU(r9)
1285         stw     r0, VCPU_THREAD_CPU(r9)
1286
1287         /* Save guest CTRL register, set runlatch to 1 */
1288         mfspr   r6,SPRN_CTRLF
1289         stw     r6,VCPU_CTRL(r9)
1290         andi.   r0,r6,1
1291         bne     4f
1292         ori     r6,r6,1
1293         mtspr   SPRN_CTRLT,r6
1294 4:
1295         /* Read the guest SLB and save it away */
1296         lwz     r0,VCPU_SLB_NR(r9)      /* number of entries in SLB */
1297         mtctr   r0
1298         li      r6,0
1299         addi    r7,r9,VCPU_SLB
1300         li      r5,0
1301 1:      slbmfee r8,r6
1302         andis.  r0,r8,SLB_ESID_V@h
1303         beq     2f
1304         add     r8,r8,r6                /* put index in */
1305         slbmfev r3,r6
1306         std     r8,VCPU_SLB_E(r7)
1307         std     r3,VCPU_SLB_V(r7)
1308         addi    r7,r7,VCPU_SLB_SIZE
1309         addi    r5,r5,1
1310 2:      addi    r6,r6,1
1311         bdnz    1b
1312         stw     r5,VCPU_SLB_MAX(r9)
1313
1314         /*
1315          * Save the guest PURR/SPURR
1316          */
1317         mfspr   r5,SPRN_PURR
1318         mfspr   r6,SPRN_SPURR
1319         ld      r7,VCPU_PURR(r9)
1320         ld      r8,VCPU_SPURR(r9)
1321         std     r5,VCPU_PURR(r9)
1322         std     r6,VCPU_SPURR(r9)
1323         subf    r5,r7,r5
1324         subf    r6,r8,r6
1325
1326         /*
1327          * Restore host PURR/SPURR and add guest times
1328          * so that the time in the guest gets accounted.
1329          */
1330         ld      r3,HSTATE_PURR(r13)
1331         ld      r4,HSTATE_SPURR(r13)
1332         add     r3,r3,r5
1333         add     r4,r4,r6
1334         mtspr   SPRN_PURR,r3
1335         mtspr   SPRN_SPURR,r4
1336
1337         /* Save DEC */
1338         mfspr   r5,SPRN_DEC
1339         mftb    r6
1340         extsw   r5,r5
1341         add     r5,r5,r6
1342         /* r5 is a guest timebase value here, convert to host TB */
1343         ld      r3,HSTATE_KVM_VCORE(r13)
1344         ld      r4,VCORE_TB_OFFSET(r3)
1345         subf    r5,r4,r5
1346         std     r5,VCPU_DEC_EXPIRES(r9)
1347
1348 BEGIN_FTR_SECTION
1349         b       8f
1350 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_207S)
1351         /* Save POWER8-specific registers */
1352         mfspr   r5, SPRN_IAMR
1353         mfspr   r6, SPRN_PSPB
1354         mfspr   r7, SPRN_FSCR
1355         std     r5, VCPU_IAMR(r9)
1356         stw     r6, VCPU_PSPB(r9)
1357         std     r7, VCPU_FSCR(r9)
1358         mfspr   r5, SPRN_IC
1359         mfspr   r7, SPRN_TAR
1360         std     r5, VCPU_IC(r9)
1361         std     r7, VCPU_TAR(r9)
1362         mfspr   r8, SPRN_EBBHR
1363         std     r8, VCPU_EBBHR(r9)
1364         mfspr   r5, SPRN_EBBRR
1365         mfspr   r6, SPRN_BESCR
1366         mfspr   r7, SPRN_PID
1367         mfspr   r8, SPRN_WORT
1368         std     r5, VCPU_EBBRR(r9)
1369         std     r6, VCPU_BESCR(r9)
1370         stw     r7, VCPU_GUEST_PID(r9)
1371         std     r8, VCPU_WORT(r9)
1372 BEGIN_FTR_SECTION
1373         mfspr   r5, SPRN_TCSCR
1374         mfspr   r6, SPRN_ACOP
1375         mfspr   r7, SPRN_CSIGR
1376         mfspr   r8, SPRN_TACR
1377         std     r5, VCPU_TCSCR(r9)
1378         std     r6, VCPU_ACOP(r9)
1379         std     r7, VCPU_CSIGR(r9)
1380         std     r8, VCPU_TACR(r9)
1381 FTR_SECTION_ELSE
1382         mfspr   r5, SPRN_TIDR
1383         mfspr   r6, SPRN_PSSCR
1384         std     r5, VCPU_TID(r9)
1385         rldicl  r6, r6, 4, 50           /* r6 &= PSSCR_GUEST_VIS */
1386         rotldi  r6, r6, 60
1387         std     r6, VCPU_PSSCR(r9)
1388 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_ARCH_300)
1389         /*
1390          * Restore various registers to 0, where non-zero values
1391          * set by the guest could disrupt the host.
1392          */
1393         li      r0, 0
1394         mtspr   SPRN_IAMR, r0
1395         mtspr   SPRN_CIABR, r0
1396         mtspr   SPRN_DAWRX, r0
1397         mtspr   SPRN_WORT, r0
1398 BEGIN_FTR_SECTION
1399         mtspr   SPRN_TCSCR, r0
1400         /* Set MMCRS to 1<<31 to freeze and disable the SPMC counters */
1401         li      r0, 1
1402         sldi    r0, r0, 31
1403         mtspr   SPRN_MMCRS, r0
1404 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_300)
1405 8:
1406
1407         /* Save and reset AMR and UAMOR before turning on the MMU */
1408         mfspr   r5,SPRN_AMR
1409         mfspr   r6,SPRN_UAMOR
1410         std     r5,VCPU_AMR(r9)
1411         std     r6,VCPU_UAMOR(r9)
1412         li      r6,0
1413         mtspr   SPRN_AMR,r6
1414
1415         /* Switch DSCR back to host value */
1416         mfspr   r8, SPRN_DSCR
1417         ld      r7, HSTATE_DSCR(r13)
1418         std     r8, VCPU_DSCR(r9)
1419         mtspr   SPRN_DSCR, r7
1420
1421         /* Save non-volatile GPRs */
1422         std     r14, VCPU_GPR(R14)(r9)
1423         std     r15, VCPU_GPR(R15)(r9)
1424         std     r16, VCPU_GPR(R16)(r9)
1425         std     r17, VCPU_GPR(R17)(r9)
1426         std     r18, VCPU_GPR(R18)(r9)
1427         std     r19, VCPU_GPR(R19)(r9)
1428         std     r20, VCPU_GPR(R20)(r9)
1429         std     r21, VCPU_GPR(R21)(r9)
1430         std     r22, VCPU_GPR(R22)(r9)
1431         std     r23, VCPU_GPR(R23)(r9)
1432         std     r24, VCPU_GPR(R24)(r9)
1433         std     r25, VCPU_GPR(R25)(r9)
1434         std     r26, VCPU_GPR(R26)(r9)
1435         std     r27, VCPU_GPR(R27)(r9)
1436         std     r28, VCPU_GPR(R28)(r9)
1437         std     r29, VCPU_GPR(R29)(r9)
1438         std     r30, VCPU_GPR(R30)(r9)
1439         std     r31, VCPU_GPR(R31)(r9)
1440
1441         /* Save SPRGs */
1442         mfspr   r3, SPRN_SPRG0
1443         mfspr   r4, SPRN_SPRG1
1444         mfspr   r5, SPRN_SPRG2
1445         mfspr   r6, SPRN_SPRG3
1446         std     r3, VCPU_SPRG0(r9)
1447         std     r4, VCPU_SPRG1(r9)
1448         std     r5, VCPU_SPRG2(r9)
1449         std     r6, VCPU_SPRG3(r9)
1450
1451         /* save FP state */
1452         mr      r3, r9
1453         bl      kvmppc_save_fp
1454
1455 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
1456 BEGIN_FTR_SECTION
1457         bl      kvmppc_save_tm
1458 END_FTR_SECTION_IFSET(CPU_FTR_TM)
1459 #endif
1460
1461         /* Increment yield count if they have a VPA */
1462         ld      r8, VCPU_VPA(r9)        /* do they have a VPA? */
1463         cmpdi   r8, 0
1464         beq     25f
1465         li      r4, LPPACA_YIELDCOUNT
1466         LWZX_BE r3, r8, r4
1467         addi    r3, r3, 1
1468         STWX_BE r3, r8, r4
1469         li      r3, 1
1470         stb     r3, VCPU_VPA_DIRTY(r9)
1471 25:
1472         /* Save PMU registers if requested */
1473         /* r8 and cr0.eq are live here */
1474 BEGIN_FTR_SECTION
1475         /*
1476          * POWER8 seems to have a hardware bug where setting
1477          * MMCR0[PMAE] along with MMCR0[PMC1CE] and/or MMCR0[PMCjCE]
1478          * when some counters are already negative doesn't seem
1479          * to cause a performance monitor alert (and hence interrupt).
1480          * The effect of this is that when saving the PMU state,
1481          * if there is no PMU alert pending when we read MMCR0
1482          * before freezing the counters, but one becomes pending
1483          * before we read the counters, we lose it.
1484          * To work around this, we need a way to freeze the counters
1485          * before reading MMCR0.  Normally, freezing the counters
1486          * is done by writing MMCR0 (to set MMCR0[FC]) which
1487          * unavoidably writes MMCR0[PMA0] as well.  On POWER8,
1488          * we can also freeze the counters using MMCR2, by writing
1489          * 1s to all the counter freeze condition bits (there are
1490          * 9 bits each for 6 counters).
1491          */
1492         li      r3, -1                  /* set all freeze bits */
1493         clrrdi  r3, r3, 10
1494         mfspr   r10, SPRN_MMCR2
1495         mtspr   SPRN_MMCR2, r3
1496         isync
1497 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
1498         li      r3, 1
1499         sldi    r3, r3, 31              /* MMCR0_FC (freeze counters) bit */
1500         mfspr   r4, SPRN_MMCR0          /* save MMCR0 */
1501         mtspr   SPRN_MMCR0, r3          /* freeze all counters, disable ints */
1502         mfspr   r6, SPRN_MMCRA
1503         /* Clear MMCRA in order to disable SDAR updates */
1504         li      r7, 0
1505         mtspr   SPRN_MMCRA, r7
1506         isync
1507         beq     21f                     /* if no VPA, save PMU stuff anyway */
1508         lbz     r7, LPPACA_PMCINUSE(r8)
1509         cmpwi   r7, 0                   /* did they ask for PMU stuff to be saved? */
1510         bne     21f
1511         std     r3, VCPU_MMCR(r9)       /* if not, set saved MMCR0 to FC */
1512         b       22f
1513 21:     mfspr   r5, SPRN_MMCR1
1514         mfspr   r7, SPRN_SIAR
1515         mfspr   r8, SPRN_SDAR
1516         std     r4, VCPU_MMCR(r9)
1517         std     r5, VCPU_MMCR + 8(r9)
1518         std     r6, VCPU_MMCR + 16(r9)
1519 BEGIN_FTR_SECTION
1520         std     r10, VCPU_MMCR + 24(r9)
1521 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
1522         std     r7, VCPU_SIAR(r9)
1523         std     r8, VCPU_SDAR(r9)
1524         mfspr   r3, SPRN_PMC1
1525         mfspr   r4, SPRN_PMC2
1526         mfspr   r5, SPRN_PMC3
1527         mfspr   r6, SPRN_PMC4
1528         mfspr   r7, SPRN_PMC5
1529         mfspr   r8, SPRN_PMC6
1530         stw     r3, VCPU_PMC(r9)
1531         stw     r4, VCPU_PMC + 4(r9)
1532         stw     r5, VCPU_PMC + 8(r9)
1533         stw     r6, VCPU_PMC + 12(r9)
1534         stw     r7, VCPU_PMC + 16(r9)
1535         stw     r8, VCPU_PMC + 20(r9)
1536 BEGIN_FTR_SECTION
1537         mfspr   r5, SPRN_SIER
1538         std     r5, VCPU_SIER(r9)
1539 BEGIN_FTR_SECTION_NESTED(96)
1540         mfspr   r6, SPRN_SPMC1
1541         mfspr   r7, SPRN_SPMC2
1542         mfspr   r8, SPRN_MMCRS
1543         stw     r6, VCPU_PMC + 24(r9)
1544         stw     r7, VCPU_PMC + 28(r9)
1545         std     r8, VCPU_MMCR + 32(r9)
1546         lis     r4, 0x8000
1547         mtspr   SPRN_MMCRS, r4
1548 END_FTR_SECTION_NESTED(CPU_FTR_ARCH_300, 0, 96)
1549 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
1550 22:
1551         /* Clear out SLB */
1552         li      r5,0
1553         slbmte  r5,r5
1554         slbia
1555         ptesync
1556
1557         /* Restore host values of some registers */
1558 BEGIN_FTR_SECTION
1559         ld      r5, STACK_SLOT_TID(r1)
1560         ld      r6, STACK_SLOT_PSSCR(r1)
1561         mtspr   SPRN_TIDR, r5
1562         mtspr   SPRN_PSSCR, r6
1563 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
1564
1565         /*
1566          * POWER7/POWER8 guest -> host partition switch code.
1567          * We don't have to lock against tlbies but we do
1568          * have to coordinate the hardware threads.
1569          */
1570 kvmhv_switch_to_host:
1571         /* Secondary threads wait for primary to do partition switch */
1572         ld      r5,HSTATE_KVM_VCORE(r13)
1573         ld      r4,VCORE_KVM(r5)        /* pointer to struct kvm */
1574         lbz     r3,HSTATE_PTID(r13)
1575         cmpwi   r3,0
1576         beq     15f
1577         HMT_LOW
1578 13:     lbz     r3,VCORE_IN_GUEST(r5)
1579         cmpwi   r3,0
1580         bne     13b
1581         HMT_MEDIUM
1582         b       16f
1583
1584         /* Primary thread waits for all the secondaries to exit guest */
1585 15:     lwz     r3,VCORE_ENTRY_EXIT(r5)
1586         rlwinm  r0,r3,32-8,0xff
1587         clrldi  r3,r3,56
1588         cmpw    r3,r0
1589         bne     15b
1590         isync
1591
1592         /* Did we actually switch to the guest at all? */
1593         lbz     r6, VCORE_IN_GUEST(r5)
1594         cmpwi   r6, 0
1595         beq     19f
1596
1597         /* Primary thread switches back to host partition */
1598         lwz     r7,KVM_HOST_LPID(r4)
1599 BEGIN_FTR_SECTION
1600         ld      r6,KVM_HOST_SDR1(r4)
1601         li      r8,LPID_RSVD            /* switch to reserved LPID */
1602         mtspr   SPRN_LPID,r8
1603         ptesync
1604         mtspr   SPRN_SDR1,r6            /* switch to host page table */
1605 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_300)
1606         mtspr   SPRN_LPID,r7
1607         isync
1608
1609 BEGIN_FTR_SECTION
1610         /* DPDES and VTB are shared between threads */
1611         mfspr   r7, SPRN_DPDES
1612         mfspr   r8, SPRN_VTB
1613         std     r7, VCORE_DPDES(r5)
1614         std     r8, VCORE_VTB(r5)
1615         /* clear DPDES so we don't get guest doorbells in the host */
1616         li      r8, 0
1617         mtspr   SPRN_DPDES, r8
1618 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
1619
1620         /* If HMI, call kvmppc_realmode_hmi_handler() */
1621         cmpwi   r12, BOOK3S_INTERRUPT_HMI
1622         bne     27f
1623         bl      kvmppc_realmode_hmi_handler
1624         nop
1625         li      r12, BOOK3S_INTERRUPT_HMI
1626         /*
1627          * At this point kvmppc_realmode_hmi_handler would have resync-ed
1628          * the TB. Hence it is not required to subtract guest timebase
1629          * offset from timebase. So, skip it.
1630          *
1631          * Also, do not call kvmppc_subcore_exit_guest() because it has
1632          * been invoked as part of kvmppc_realmode_hmi_handler().
1633          */
1634         b       30f
1635
1636 27:
1637         /* Subtract timebase offset from timebase */
1638         ld      r8,VCORE_TB_OFFSET(r5)
1639         cmpdi   r8,0
1640         beq     17f
1641         mftb    r6                      /* current guest timebase */
1642         subf    r8,r8,r6
1643         mtspr   SPRN_TBU40,r8           /* update upper 40 bits */
1644         mftb    r7                      /* check if lower 24 bits overflowed */
1645         clrldi  r6,r6,40
1646         clrldi  r7,r7,40
1647         cmpld   r7,r6
1648         bge     17f
1649         addis   r8,r8,0x100             /* if so, increment upper 40 bits */
1650         mtspr   SPRN_TBU40,r8
1651
1652 17:     bl      kvmppc_subcore_exit_guest
1653         nop
1654 30:     ld      r5,HSTATE_KVM_VCORE(r13)
1655         ld      r4,VCORE_KVM(r5)        /* pointer to struct kvm */
1656
1657         /* Reset PCR */
1658         ld      r0, VCORE_PCR(r5)
1659         cmpdi   r0, 0
1660         beq     18f
1661         li      r0, 0
1662         mtspr   SPRN_PCR, r0
1663 18:
1664         /* Signal secondary CPUs to continue */
1665         stb     r0,VCORE_IN_GUEST(r5)
1666 19:     lis     r8,0x7fff               /* MAX_INT@h */
1667         mtspr   SPRN_HDEC,r8
1668
1669 16:     ld      r8,KVM_HOST_LPCR(r4)
1670         mtspr   SPRN_LPCR,r8
1671         isync
1672
1673         /* load host SLB entries */
1674         ld      r8,PACA_SLBSHADOWPTR(r13)
1675
1676         .rept   SLB_NUM_BOLTED
1677         li      r3, SLBSHADOW_SAVEAREA
1678         LDX_BE  r5, r8, r3
1679         addi    r3, r3, 8
1680         LDX_BE  r6, r8, r3
1681         andis.  r7,r5,SLB_ESID_V@h
1682         beq     1f
1683         slbmte  r6,r5
1684 1:      addi    r8,r8,16
1685         .endr
1686
1687 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
1688         /* Finish timing, if we have a vcpu */
1689         ld      r4, HSTATE_KVM_VCPU(r13)
1690         cmpdi   r4, 0
1691         li      r3, 0
1692         beq     2f
1693         bl      kvmhv_accumulate_time
1694 2:
1695 #endif
1696         /* Unset guest mode */
1697         li      r0, KVM_GUEST_MODE_NONE
1698         stb     r0, HSTATE_IN_GUEST(r13)
1699
1700         ld      r0, 112+PPC_LR_STKOFF(r1)
1701         addi    r1, r1, 112
1702         mtlr    r0
1703         blr
1704
1705 /*
1706  * Check whether an HDSI is an HPTE not found fault or something else.
1707  * If it is an HPTE not found fault that is due to the guest accessing
1708  * a page that they have mapped but which we have paged out, then
1709  * we continue on with the guest exit path.  In all other cases,
1710  * reflect the HDSI to the guest as a DSI.
1711  */
1712 kvmppc_hdsi:
1713         mfspr   r4, SPRN_HDAR
1714         mfspr   r6, SPRN_HDSISR
1715         /* HPTE not found fault or protection fault? */
1716         andis.  r0, r6, (DSISR_NOHPTE | DSISR_PROTFAULT)@h
1717         beq     1f                      /* if not, send it to the guest */
1718         andi.   r0, r11, MSR_DR         /* data relocation enabled? */
1719         beq     3f
1720         clrrdi  r0, r4, 28
1721         PPC_SLBFEE_DOT(R5, R0)          /* if so, look up SLB */
1722         li      r0, BOOK3S_INTERRUPT_DATA_SEGMENT
1723         bne     7f                      /* if no SLB entry found */
1724 4:      std     r4, VCPU_FAULT_DAR(r9)
1725         stw     r6, VCPU_FAULT_DSISR(r9)
1726
1727         /* Search the hash table. */
1728         mr      r3, r9                  /* vcpu pointer */
1729         li      r7, 1                   /* data fault */
1730         bl      kvmppc_hpte_hv_fault
1731         ld      r9, HSTATE_KVM_VCPU(r13)
1732         ld      r10, VCPU_PC(r9)
1733         ld      r11, VCPU_MSR(r9)
1734         li      r12, BOOK3S_INTERRUPT_H_DATA_STORAGE
1735         cmpdi   r3, 0                   /* retry the instruction */
1736         beq     6f
1737         cmpdi   r3, -1                  /* handle in kernel mode */
1738         beq     guest_exit_cont
1739         cmpdi   r3, -2                  /* MMIO emulation; need instr word */
1740         beq     2f
1741
1742         /* Synthesize a DSI (or DSegI) for the guest */
1743         ld      r4, VCPU_FAULT_DAR(r9)
1744         mr      r6, r3
1745 1:      li      r0, BOOK3S_INTERRUPT_DATA_STORAGE
1746         mtspr   SPRN_DSISR, r6
1747 7:      mtspr   SPRN_DAR, r4
1748         mtspr   SPRN_SRR0, r10
1749         mtspr   SPRN_SRR1, r11
1750         mr      r10, r0
1751         bl      kvmppc_msr_interrupt
1752 fast_interrupt_c_return:
1753 6:      ld      r7, VCPU_CTR(r9)
1754         ld      r8, VCPU_XER(r9)
1755         mtctr   r7
1756         mtxer   r8
1757         mr      r4, r9
1758         b       fast_guest_return
1759
1760 3:      ld      r5, VCPU_KVM(r9)        /* not relocated, use VRMA */
1761         ld      r5, KVM_VRMA_SLB_V(r5)
1762         b       4b
1763
1764         /* If this is for emulated MMIO, load the instruction word */
1765 2:      li      r8, KVM_INST_FETCH_FAILED       /* In case lwz faults */
1766
1767         /* Set guest mode to 'jump over instruction' so if lwz faults
1768          * we'll just continue at the next IP. */
1769         li      r0, KVM_GUEST_MODE_SKIP
1770         stb     r0, HSTATE_IN_GUEST(r13)
1771
1772         /* Do the access with MSR:DR enabled */
1773         mfmsr   r3
1774         ori     r4, r3, MSR_DR          /* Enable paging for data */
1775         mtmsrd  r4
1776         lwz     r8, 0(r10)
1777         mtmsrd  r3
1778
1779         /* Store the result */
1780         stw     r8, VCPU_LAST_INST(r9)
1781
1782         /* Unset guest mode. */
1783         li      r0, KVM_GUEST_MODE_HOST_HV
1784         stb     r0, HSTATE_IN_GUEST(r13)
1785         b       guest_exit_cont
1786
1787 /*
1788  * Similarly for an HISI, reflect it to the guest as an ISI unless
1789  * it is an HPTE not found fault for a page that we have paged out.
1790  */
1791 kvmppc_hisi:
1792         andis.  r0, r11, SRR1_ISI_NOPT@h
1793         beq     1f
1794         andi.   r0, r11, MSR_IR         /* instruction relocation enabled? */
1795         beq     3f
1796         clrrdi  r0, r10, 28
1797         PPC_SLBFEE_DOT(R5, R0)          /* if so, look up SLB */
1798         li      r0, BOOK3S_INTERRUPT_INST_SEGMENT
1799         bne     7f                      /* if no SLB entry found */
1800 4:
1801         /* Search the hash table. */
1802         mr      r3, r9                  /* vcpu pointer */
1803         mr      r4, r10
1804         mr      r6, r11
1805         li      r7, 0                   /* instruction fault */
1806         bl      kvmppc_hpte_hv_fault
1807         ld      r9, HSTATE_KVM_VCPU(r13)
1808         ld      r10, VCPU_PC(r9)
1809         ld      r11, VCPU_MSR(r9)
1810         li      r12, BOOK3S_INTERRUPT_H_INST_STORAGE
1811         cmpdi   r3, 0                   /* retry the instruction */
1812         beq     fast_interrupt_c_return
1813         cmpdi   r3, -1                  /* handle in kernel mode */
1814         beq     guest_exit_cont
1815
1816         /* Synthesize an ISI (or ISegI) for the guest */
1817         mr      r11, r3
1818 1:      li      r0, BOOK3S_INTERRUPT_INST_STORAGE
1819 7:      mtspr   SPRN_SRR0, r10
1820         mtspr   SPRN_SRR1, r11
1821         mr      r10, r0
1822         bl      kvmppc_msr_interrupt
1823         b       fast_interrupt_c_return
1824
1825 3:      ld      r6, VCPU_KVM(r9)        /* not relocated, use VRMA */
1826         ld      r5, KVM_VRMA_SLB_V(r6)
1827         b       4b
1828
1829 /*
1830  * Try to handle an hcall in real mode.
1831  * Returns to the guest if we handle it, or continues on up to
1832  * the kernel if we can't (i.e. if we don't have a handler for
1833  * it, or if the handler returns H_TOO_HARD).
1834  *
1835  * r5 - r8 contain hcall args,
1836  * r9 = vcpu, r10 = pc, r11 = msr, r12 = trap, r13 = paca
1837  */
1838 hcall_try_real_mode:
1839         ld      r3,VCPU_GPR(R3)(r9)
1840         andi.   r0,r11,MSR_PR
1841         /* sc 1 from userspace - reflect to guest syscall */
1842         bne     sc_1_fast_return
1843         clrrdi  r3,r3,2
1844         cmpldi  r3,hcall_real_table_end - hcall_real_table
1845         bge     guest_exit_cont
1846         /* See if this hcall is enabled for in-kernel handling */
1847         ld      r4, VCPU_KVM(r9)
1848         srdi    r0, r3, 8       /* r0 = (r3 / 4) >> 6 */
1849         sldi    r0, r0, 3       /* index into kvm->arch.enabled_hcalls[] */
1850         add     r4, r4, r0
1851         ld      r0, KVM_ENABLED_HCALLS(r4)
1852         rlwinm  r4, r3, 32-2, 0x3f      /* r4 = (r3 / 4) & 0x3f */
1853         srd     r0, r0, r4
1854         andi.   r0, r0, 1
1855         beq     guest_exit_cont
1856         /* Get pointer to handler, if any, and call it */
1857         LOAD_REG_ADDR(r4, hcall_real_table)
1858         lwax    r3,r3,r4
1859         cmpwi   r3,0
1860         beq     guest_exit_cont
1861         add     r12,r3,r4
1862         mtctr   r12
1863         mr      r3,r9           /* get vcpu pointer */
1864         ld      r4,VCPU_GPR(R4)(r9)
1865         bctrl
1866         cmpdi   r3,H_TOO_HARD
1867         beq     hcall_real_fallback
1868         ld      r4,HSTATE_KVM_VCPU(r13)
1869         std     r3,VCPU_GPR(R3)(r4)
1870         ld      r10,VCPU_PC(r4)
1871         ld      r11,VCPU_MSR(r4)
1872         b       fast_guest_return
1873
1874 sc_1_fast_return:
1875         mtspr   SPRN_SRR0,r10
1876         mtspr   SPRN_SRR1,r11
1877         li      r10, BOOK3S_INTERRUPT_SYSCALL
1878         bl      kvmppc_msr_interrupt
1879         mr      r4,r9
1880         b       fast_guest_return
1881
1882         /* We've attempted a real mode hcall, but it's punted it back
1883          * to userspace.  We need to restore some clobbered volatiles
1884          * before resuming the pass-it-to-qemu path */
1885 hcall_real_fallback:
1886         li      r12,BOOK3S_INTERRUPT_SYSCALL
1887         ld      r9, HSTATE_KVM_VCPU(r13)
1888
1889         b       guest_exit_cont
1890
1891         .globl  hcall_real_table
1892 hcall_real_table:
1893         .long   0               /* 0 - unused */
1894         .long   DOTSYM(kvmppc_h_remove) - hcall_real_table
1895         .long   DOTSYM(kvmppc_h_enter) - hcall_real_table
1896         .long   DOTSYM(kvmppc_h_read) - hcall_real_table
1897         .long   DOTSYM(kvmppc_h_clear_mod) - hcall_real_table
1898         .long   DOTSYM(kvmppc_h_clear_ref) - hcall_real_table
1899         .long   DOTSYM(kvmppc_h_protect) - hcall_real_table
1900         .long   DOTSYM(kvmppc_h_get_tce) - hcall_real_table
1901         .long   DOTSYM(kvmppc_rm_h_put_tce) - hcall_real_table
1902         .long   0               /* 0x24 - H_SET_SPRG0 */
1903         .long   DOTSYM(kvmppc_h_set_dabr) - hcall_real_table
1904         .long   0               /* 0x2c */
1905         .long   0               /* 0x30 */
1906         .long   0               /* 0x34 */
1907         .long   0               /* 0x38 */
1908         .long   0               /* 0x3c */
1909         .long   0               /* 0x40 */
1910         .long   0               /* 0x44 */
1911         .long   0               /* 0x48 */
1912         .long   0               /* 0x4c */
1913         .long   0               /* 0x50 */
1914         .long   0               /* 0x54 */
1915         .long   0               /* 0x58 */
1916         .long   0               /* 0x5c */
1917         .long   0               /* 0x60 */
1918 #ifdef CONFIG_KVM_XICS
1919         .long   DOTSYM(kvmppc_rm_h_eoi) - hcall_real_table
1920         .long   DOTSYM(kvmppc_rm_h_cppr) - hcall_real_table
1921         .long   DOTSYM(kvmppc_rm_h_ipi) - hcall_real_table
1922         .long   0               /* 0x70 - H_IPOLL */
1923         .long   DOTSYM(kvmppc_rm_h_xirr) - hcall_real_table
1924 #else
1925         .long   0               /* 0x64 - H_EOI */
1926         .long   0               /* 0x68 - H_CPPR */
1927         .long   0               /* 0x6c - H_IPI */
1928         .long   0               /* 0x70 - H_IPOLL */
1929         .long   0               /* 0x74 - H_XIRR */
1930 #endif
1931         .long   0               /* 0x78 */
1932         .long   0               /* 0x7c */
1933         .long   0               /* 0x80 */
1934         .long   0               /* 0x84 */
1935         .long   0               /* 0x88 */
1936         .long   0               /* 0x8c */
1937         .long   0               /* 0x90 */
1938         .long   0               /* 0x94 */
1939         .long   0               /* 0x98 */
1940         .long   0               /* 0x9c */
1941         .long   0               /* 0xa0 */
1942         .long   0               /* 0xa4 */
1943         .long   0               /* 0xa8 */
1944         .long   0               /* 0xac */
1945         .long   0               /* 0xb0 */
1946         .long   0               /* 0xb4 */
1947         .long   0               /* 0xb8 */
1948         .long   0               /* 0xbc */
1949         .long   0               /* 0xc0 */
1950         .long   0               /* 0xc4 */
1951         .long   0               /* 0xc8 */
1952         .long   0               /* 0xcc */
1953         .long   0               /* 0xd0 */
1954         .long   0               /* 0xd4 */
1955         .long   0               /* 0xd8 */
1956         .long   0               /* 0xdc */
1957         .long   DOTSYM(kvmppc_h_cede) - hcall_real_table
1958         .long   DOTSYM(kvmppc_rm_h_confer) - hcall_real_table
1959         .long   0               /* 0xe8 */
1960         .long   0               /* 0xec */
1961         .long   0               /* 0xf0 */
1962         .long   0               /* 0xf4 */
1963         .long   0               /* 0xf8 */
1964         .long   0               /* 0xfc */
1965         .long   0               /* 0x100 */
1966         .long   0               /* 0x104 */
1967         .long   0               /* 0x108 */
1968         .long   0               /* 0x10c */
1969         .long   0               /* 0x110 */
1970         .long   0               /* 0x114 */
1971         .long   0               /* 0x118 */
1972         .long   0               /* 0x11c */
1973         .long   0               /* 0x120 */
1974         .long   DOTSYM(kvmppc_h_bulk_remove) - hcall_real_table
1975         .long   0               /* 0x128 */
1976         .long   0               /* 0x12c */
1977         .long   0               /* 0x130 */
1978         .long   DOTSYM(kvmppc_h_set_xdabr) - hcall_real_table
1979         .long   DOTSYM(kvmppc_rm_h_stuff_tce) - hcall_real_table
1980         .long   DOTSYM(kvmppc_rm_h_put_tce_indirect) - hcall_real_table
1981         .long   0               /* 0x140 */
1982         .long   0               /* 0x144 */
1983         .long   0               /* 0x148 */
1984         .long   0               /* 0x14c */
1985         .long   0               /* 0x150 */
1986         .long   0               /* 0x154 */
1987         .long   0               /* 0x158 */
1988         .long   0               /* 0x15c */
1989         .long   0               /* 0x160 */
1990         .long   0               /* 0x164 */
1991         .long   0               /* 0x168 */
1992         .long   0               /* 0x16c */
1993         .long   0               /* 0x170 */
1994         .long   0               /* 0x174 */
1995         .long   0               /* 0x178 */
1996         .long   0               /* 0x17c */
1997         .long   0               /* 0x180 */
1998         .long   0               /* 0x184 */
1999         .long   0               /* 0x188 */
2000         .long   0               /* 0x18c */
2001         .long   0               /* 0x190 */
2002         .long   0               /* 0x194 */
2003         .long   0               /* 0x198 */
2004         .long   0               /* 0x19c */
2005         .long   0               /* 0x1a0 */
2006         .long   0               /* 0x1a4 */
2007         .long   0               /* 0x1a8 */
2008         .long   0               /* 0x1ac */
2009         .long   0               /* 0x1b0 */
2010         .long   0               /* 0x1b4 */
2011         .long   0               /* 0x1b8 */
2012         .long   0               /* 0x1bc */
2013         .long   0               /* 0x1c0 */
2014         .long   0               /* 0x1c4 */
2015         .long   0               /* 0x1c8 */
2016         .long   0               /* 0x1cc */
2017         .long   0               /* 0x1d0 */
2018         .long   0               /* 0x1d4 */
2019         .long   0               /* 0x1d8 */
2020         .long   0               /* 0x1dc */
2021         .long   0               /* 0x1e0 */
2022         .long   0               /* 0x1e4 */
2023         .long   0               /* 0x1e8 */
2024         .long   0               /* 0x1ec */
2025         .long   0               /* 0x1f0 */
2026         .long   0               /* 0x1f4 */
2027         .long   0               /* 0x1f8 */
2028         .long   0               /* 0x1fc */
2029         .long   0               /* 0x200 */
2030         .long   0               /* 0x204 */
2031         .long   0               /* 0x208 */
2032         .long   0               /* 0x20c */
2033         .long   0               /* 0x210 */
2034         .long   0               /* 0x214 */
2035         .long   0               /* 0x218 */
2036         .long   0               /* 0x21c */
2037         .long   0               /* 0x220 */
2038         .long   0               /* 0x224 */
2039         .long   0               /* 0x228 */
2040         .long   0               /* 0x22c */
2041         .long   0               /* 0x230 */
2042         .long   0               /* 0x234 */
2043         .long   0               /* 0x238 */
2044         .long   0               /* 0x23c */
2045         .long   0               /* 0x240 */
2046         .long   0               /* 0x244 */
2047         .long   0               /* 0x248 */
2048         .long   0               /* 0x24c */
2049         .long   0               /* 0x250 */
2050         .long   0               /* 0x254 */
2051         .long   0               /* 0x258 */
2052         .long   0               /* 0x25c */
2053         .long   0               /* 0x260 */
2054         .long   0               /* 0x264 */
2055         .long   0               /* 0x268 */
2056         .long   0               /* 0x26c */
2057         .long   0               /* 0x270 */
2058         .long   0               /* 0x274 */
2059         .long   0               /* 0x278 */
2060         .long   0               /* 0x27c */
2061         .long   0               /* 0x280 */
2062         .long   0               /* 0x284 */
2063         .long   0               /* 0x288 */
2064         .long   0               /* 0x28c */
2065         .long   0               /* 0x290 */
2066         .long   0               /* 0x294 */
2067         .long   0               /* 0x298 */
2068         .long   0               /* 0x29c */
2069         .long   0               /* 0x2a0 */
2070         .long   0               /* 0x2a4 */
2071         .long   0               /* 0x2a8 */
2072         .long   0               /* 0x2ac */
2073         .long   0               /* 0x2b0 */
2074         .long   0               /* 0x2b4 */
2075         .long   0               /* 0x2b8 */
2076         .long   0               /* 0x2bc */
2077         .long   0               /* 0x2c0 */
2078         .long   0               /* 0x2c4 */
2079         .long   0               /* 0x2c8 */
2080         .long   0               /* 0x2cc */
2081         .long   0               /* 0x2d0 */
2082         .long   0               /* 0x2d4 */
2083         .long   0               /* 0x2d8 */
2084         .long   0               /* 0x2dc */
2085         .long   0               /* 0x2e0 */
2086         .long   0               /* 0x2e4 */
2087         .long   0               /* 0x2e8 */
2088         .long   0               /* 0x2ec */
2089         .long   0               /* 0x2f0 */
2090         .long   0               /* 0x2f4 */
2091         .long   0               /* 0x2f8 */
2092         .long   0               /* 0x2fc */
2093         .long   DOTSYM(kvmppc_h_random) - hcall_real_table
2094         .globl  hcall_real_table_end
2095 hcall_real_table_end:
2096
2097 _GLOBAL(kvmppc_h_set_xdabr)
2098         andi.   r0, r5, DABRX_USER | DABRX_KERNEL
2099         beq     6f
2100         li      r0, DABRX_USER | DABRX_KERNEL | DABRX_BTI
2101         andc.   r0, r5, r0
2102         beq     3f
2103 6:      li      r3, H_PARAMETER
2104         blr
2105
2106 _GLOBAL(kvmppc_h_set_dabr)
2107         li      r5, DABRX_USER | DABRX_KERNEL
2108 3:
2109 BEGIN_FTR_SECTION
2110         b       2f
2111 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
2112         std     r4,VCPU_DABR(r3)
2113         stw     r5, VCPU_DABRX(r3)
2114         mtspr   SPRN_DABRX, r5
2115         /* Work around P7 bug where DABR can get corrupted on mtspr */
2116 1:      mtspr   SPRN_DABR,r4
2117         mfspr   r5, SPRN_DABR
2118         cmpd    r4, r5
2119         bne     1b
2120         isync
2121         li      r3,0
2122         blr
2123
2124         /* Emulate H_SET_DABR/X on P8 for the sake of compat mode guests */
2125 2:      rlwimi  r5, r4, 5, DAWRX_DR | DAWRX_DW
2126         rlwimi  r5, r4, 2, DAWRX_WT
2127         clrrdi  r4, r4, 3
2128         std     r4, VCPU_DAWR(r3)
2129         std     r5, VCPU_DAWRX(r3)
2130         mtspr   SPRN_DAWR, r4
2131         mtspr   SPRN_DAWRX, r5
2132         li      r3, 0
2133         blr
2134
2135 _GLOBAL(kvmppc_h_cede)          /* r3 = vcpu pointer, r11 = msr, r13 = paca */
2136         ori     r11,r11,MSR_EE
2137         std     r11,VCPU_MSR(r3)
2138         li      r0,1
2139         stb     r0,VCPU_CEDED(r3)
2140         sync                    /* order setting ceded vs. testing prodded */
2141         lbz     r5,VCPU_PRODDED(r3)
2142         cmpwi   r5,0
2143         bne     kvm_cede_prodded
2144         li      r12,0           /* set trap to 0 to say hcall is handled */
2145         stw     r12,VCPU_TRAP(r3)
2146         li      r0,H_SUCCESS
2147         std     r0,VCPU_GPR(R3)(r3)
2148
2149         /*
2150          * Set our bit in the bitmask of napping threads unless all the
2151          * other threads are already napping, in which case we send this
2152          * up to the host.
2153          */
2154         ld      r5,HSTATE_KVM_VCORE(r13)
2155         lbz     r6,HSTATE_PTID(r13)
2156         lwz     r8,VCORE_ENTRY_EXIT(r5)
2157         clrldi  r8,r8,56
2158         li      r0,1
2159         sld     r0,r0,r6
2160         addi    r6,r5,VCORE_NAPPING_THREADS
2161 31:     lwarx   r4,0,r6
2162         or      r4,r4,r0
2163         cmpw    r4,r8
2164         beq     kvm_cede_exit
2165         stwcx.  r4,0,r6
2166         bne     31b
2167         /* order napping_threads update vs testing entry_exit_map */
2168         isync
2169         li      r0,NAPPING_CEDE
2170         stb     r0,HSTATE_NAPPING(r13)
2171         lwz     r7,VCORE_ENTRY_EXIT(r5)
2172         cmpwi   r7,0x100
2173         bge     33f             /* another thread already exiting */
2174
2175 /*
2176  * Although not specifically required by the architecture, POWER7
2177  * preserves the following registers in nap mode, even if an SMT mode
2178  * switch occurs: SLB entries, PURR, SPURR, AMOR, UAMOR, AMR, SPRG0-3,
2179  * DAR, DSISR, DABR, DABRX, DSCR, PMCx, MMCRx, SIAR, SDAR.
2180  */
2181         /* Save non-volatile GPRs */
2182         std     r14, VCPU_GPR(R14)(r3)
2183         std     r15, VCPU_GPR(R15)(r3)
2184         std     r16, VCPU_GPR(R16)(r3)
2185         std     r17, VCPU_GPR(R17)(r3)
2186         std     r18, VCPU_GPR(R18)(r3)
2187         std     r19, VCPU_GPR(R19)(r3)
2188         std     r20, VCPU_GPR(R20)(r3)
2189         std     r21, VCPU_GPR(R21)(r3)
2190         std     r22, VCPU_GPR(R22)(r3)
2191         std     r23, VCPU_GPR(R23)(r3)
2192         std     r24, VCPU_GPR(R24)(r3)
2193         std     r25, VCPU_GPR(R25)(r3)
2194         std     r26, VCPU_GPR(R26)(r3)
2195         std     r27, VCPU_GPR(R27)(r3)
2196         std     r28, VCPU_GPR(R28)(r3)
2197         std     r29, VCPU_GPR(R29)(r3)
2198         std     r30, VCPU_GPR(R30)(r3)
2199         std     r31, VCPU_GPR(R31)(r3)
2200
2201         /* save FP state */
2202         bl      kvmppc_save_fp
2203
2204 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
2205 BEGIN_FTR_SECTION
2206         ld      r9, HSTATE_KVM_VCPU(r13)
2207         bl      kvmppc_save_tm
2208 END_FTR_SECTION_IFSET(CPU_FTR_TM)
2209 #endif
2210
2211         /*
2212          * Set DEC to the smaller of DEC and HDEC, so that we wake
2213          * no later than the end of our timeslice (HDEC interrupts
2214          * don't wake us from nap).
2215          */
2216         mfspr   r3, SPRN_DEC
2217         mfspr   r4, SPRN_HDEC
2218         mftb    r5
2219         cmpw    r3, r4
2220         ble     67f
2221         mtspr   SPRN_DEC, r4
2222 67:
2223         /* save expiry time of guest decrementer */
2224         extsw   r3, r3
2225         add     r3, r3, r5
2226         ld      r4, HSTATE_KVM_VCPU(r13)
2227         ld      r5, HSTATE_KVM_VCORE(r13)
2228         ld      r6, VCORE_TB_OFFSET(r5)
2229         subf    r3, r6, r3      /* convert to host TB value */
2230         std     r3, VCPU_DEC_EXPIRES(r4)
2231
2232 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
2233         ld      r4, HSTATE_KVM_VCPU(r13)
2234         addi    r3, r4, VCPU_TB_CEDE
2235         bl      kvmhv_accumulate_time
2236 #endif
2237
2238         lis     r3, LPCR_PECEDP@h       /* Do wake on privileged doorbell */
2239
2240         /*
2241          * Take a nap until a decrementer or external or doobell interrupt
2242          * occurs, with PECE1 and PECE0 set in LPCR.
2243          * On POWER8, set PECEDH, and if we are ceding, also set PECEDP.
2244          * Also clear the runlatch bit before napping.
2245          */
2246 kvm_do_nap:
2247         mfspr   r0, SPRN_CTRLF
2248         clrrdi  r0, r0, 1
2249         mtspr   SPRN_CTRLT, r0
2250
2251         li      r0,1
2252         stb     r0,HSTATE_HWTHREAD_REQ(r13)
2253         mfspr   r5,SPRN_LPCR
2254         ori     r5,r5,LPCR_PECE0 | LPCR_PECE1
2255 BEGIN_FTR_SECTION
2256         ori     r5, r5, LPCR_PECEDH
2257         rlwimi  r5, r3, 0, LPCR_PECEDP
2258 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
2259
2260 kvm_nap_sequence:               /* desired LPCR value in r5 */
2261 BEGIN_FTR_SECTION
2262         /*
2263          * PSSCR bits:  exit criterion = 1 (wakeup based on LPCR at sreset)
2264          *              enable state loss = 1 (allow SMT mode switch)
2265          *              requested level = 0 (just stop dispatching)
2266          */
2267         lis     r3, (PSSCR_EC | PSSCR_ESL)@h
2268         mtspr   SPRN_PSSCR, r3
2269         /* Set LPCR_PECE_HVEE bit to enable wakeup by HV interrupts */
2270         li      r4, LPCR_PECE_HVEE@higher
2271         sldi    r4, r4, 32
2272         or      r5, r5, r4
2273 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
2274         mtspr   SPRN_LPCR,r5
2275         isync
2276         li      r0, 0
2277         std     r0, HSTATE_SCRATCH0(r13)
2278         ptesync
2279         ld      r0, HSTATE_SCRATCH0(r13)
2280 1:      cmpd    r0, r0
2281         bne     1b
2282 BEGIN_FTR_SECTION
2283         nap
2284 FTR_SECTION_ELSE
2285         PPC_STOP
2286 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_ARCH_300)
2287         b       .
2288
2289 33:     mr      r4, r3
2290         li      r3, 0
2291         li      r12, 0
2292         b       34f
2293
2294 kvm_end_cede:
2295         /* get vcpu pointer */
2296         ld      r4, HSTATE_KVM_VCPU(r13)
2297
2298         /* Woken by external or decrementer interrupt */
2299         ld      r1, HSTATE_HOST_R1(r13)
2300
2301 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
2302         addi    r3, r4, VCPU_TB_RMINTR
2303         bl      kvmhv_accumulate_time
2304 #endif
2305
2306 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
2307 BEGIN_FTR_SECTION
2308         bl      kvmppc_restore_tm
2309 END_FTR_SECTION_IFSET(CPU_FTR_TM)
2310 #endif
2311
2312         /* load up FP state */
2313         bl      kvmppc_load_fp
2314
2315         /* Restore guest decrementer */
2316         ld      r3, VCPU_DEC_EXPIRES(r4)
2317         ld      r5, HSTATE_KVM_VCORE(r13)
2318         ld      r6, VCORE_TB_OFFSET(r5)
2319         add     r3, r3, r6      /* convert host TB to guest TB value */
2320         mftb    r7
2321         subf    r3, r7, r3
2322         mtspr   SPRN_DEC, r3
2323
2324         /* Load NV GPRS */
2325         ld      r14, VCPU_GPR(R14)(r4)
2326         ld      r15, VCPU_GPR(R15)(r4)
2327         ld      r16, VCPU_GPR(R16)(r4)
2328         ld      r17, VCPU_GPR(R17)(r4)
2329         ld      r18, VCPU_GPR(R18)(r4)
2330         ld      r19, VCPU_GPR(R19)(r4)
2331         ld      r20, VCPU_GPR(R20)(r4)
2332         ld      r21, VCPU_GPR(R21)(r4)
2333         ld      r22, VCPU_GPR(R22)(r4)
2334         ld      r23, VCPU_GPR(R23)(r4)
2335         ld      r24, VCPU_GPR(R24)(r4)
2336         ld      r25, VCPU_GPR(R25)(r4)
2337         ld      r26, VCPU_GPR(R26)(r4)
2338         ld      r27, VCPU_GPR(R27)(r4)
2339         ld      r28, VCPU_GPR(R28)(r4)
2340         ld      r29, VCPU_GPR(R29)(r4)
2341         ld      r30, VCPU_GPR(R30)(r4)
2342         ld      r31, VCPU_GPR(R31)(r4)
2343
2344         /* Check the wake reason in SRR1 to see why we got here */
2345         bl      kvmppc_check_wake_reason
2346
2347         /*
2348          * Restore volatile registers since we could have called a
2349          * C routine in kvmppc_check_wake_reason
2350          *      r4 = VCPU
2351          * r3 tells us whether we need to return to host or not
2352          * WARNING: it gets checked further down:
2353          * should not modify r3 until this check is done.
2354          */
2355         ld      r4, HSTATE_KVM_VCPU(r13)
2356
2357         /* clear our bit in vcore->napping_threads */
2358 34:     ld      r5,HSTATE_KVM_VCORE(r13)
2359         lbz     r7,HSTATE_PTID(r13)
2360         li      r0,1
2361         sld     r0,r0,r7
2362         addi    r6,r5,VCORE_NAPPING_THREADS
2363 32:     lwarx   r7,0,r6
2364         andc    r7,r7,r0
2365         stwcx.  r7,0,r6
2366         bne     32b
2367         li      r0,0
2368         stb     r0,HSTATE_NAPPING(r13)
2369
2370         /* See if the wake reason saved in r3 means we need to exit */
2371         stw     r12, VCPU_TRAP(r4)
2372         mr      r9, r4
2373         cmpdi   r3, 0
2374         bgt     guest_exit_cont
2375
2376         /* see if any other thread is already exiting */
2377         lwz     r0,VCORE_ENTRY_EXIT(r5)
2378         cmpwi   r0,0x100
2379         bge     guest_exit_cont
2380
2381         b       kvmppc_cede_reentry     /* if not go back to guest */
2382
2383         /* cede when already previously prodded case */
2384 kvm_cede_prodded:
2385         li      r0,0
2386         stb     r0,VCPU_PRODDED(r3)
2387         sync                    /* order testing prodded vs. clearing ceded */
2388         stb     r0,VCPU_CEDED(r3)
2389         li      r3,H_SUCCESS
2390         blr
2391
2392         /* we've ceded but we want to give control to the host */
2393 kvm_cede_exit:
2394         ld      r9, HSTATE_KVM_VCPU(r13)
2395         b       guest_exit_cont
2396
2397         /* Try to handle a machine check in real mode */
2398 machine_check_realmode:
2399         mr      r3, r9          /* get vcpu pointer */
2400         bl      kvmppc_realmode_machine_check
2401         nop
2402         ld      r9, HSTATE_KVM_VCPU(r13)
2403         li      r12, BOOK3S_INTERRUPT_MACHINE_CHECK
2404         /*
2405          * Deliver unhandled/fatal (e.g. UE) MCE errors to guest through
2406          * machine check interrupt (set HSRR0 to 0x200). And for handled
2407          * errors (no-fatal), just go back to guest execution with current
2408          * HSRR0 instead of exiting guest. This new approach will inject
2409          * machine check to guest for fatal error causing guest to crash.
2410          *
2411          * The old code used to return to host for unhandled errors which
2412          * was causing guest to hang with soft lockups inside guest and
2413          * makes it difficult to recover guest instance.
2414          *
2415          * if we receive machine check with MSR(RI=0) then deliver it to
2416          * guest as machine check causing guest to crash.
2417          */
2418         ld      r11, VCPU_MSR(r9)
2419         rldicl. r0, r11, 64-MSR_HV_LG, 63 /* check if it happened in HV mode */
2420         bne     mc_cont                 /* if so, exit to host */
2421         andi.   r10, r11, MSR_RI        /* check for unrecoverable exception */
2422         beq     1f                      /* Deliver a machine check to guest */
2423         ld      r10, VCPU_PC(r9)
2424         cmpdi   r3, 0           /* Did we handle MCE ? */
2425         bne     2f      /* Continue guest execution. */
2426         /* If not, deliver a machine check.  SRR0/1 are already set */
2427 1:      li      r10, BOOK3S_INTERRUPT_MACHINE_CHECK
2428         bl      kvmppc_msr_interrupt
2429 2:      b       fast_interrupt_c_return
2430
2431 /*
2432  * Check the reason we woke from nap, and take appropriate action.
2433  * Returns (in r3):
2434  *      0 if nothing needs to be done
2435  *      1 if something happened that needs to be handled by the host
2436  *      -1 if there was a guest wakeup (IPI or msgsnd)
2437  *      -2 if we handled a PCI passthrough interrupt (returned by
2438  *              kvmppc_read_intr only)
2439  *
2440  * Also sets r12 to the interrupt vector for any interrupt that needs
2441  * to be handled now by the host (0x500 for external interrupt), or zero.
2442  * Modifies all volatile registers (since it may call a C function).
2443  * This routine calls kvmppc_read_intr, a C function, if an external
2444  * interrupt is pending.
2445  */
2446 kvmppc_check_wake_reason:
2447         mfspr   r6, SPRN_SRR1
2448 BEGIN_FTR_SECTION
2449         rlwinm  r6, r6, 45-31, 0xf      /* extract wake reason field (P8) */
2450 FTR_SECTION_ELSE
2451         rlwinm  r6, r6, 45-31, 0xe      /* P7 wake reason field is 3 bits */
2452 ALT_FTR_SECTION_END_IFSET(CPU_FTR_ARCH_207S)
2453         cmpwi   r6, 8                   /* was it an external interrupt? */
2454         beq     7f                      /* if so, see what it was */
2455         li      r3, 0
2456         li      r12, 0
2457         cmpwi   r6, 6                   /* was it the decrementer? */
2458         beq     0f
2459 BEGIN_FTR_SECTION
2460         cmpwi   r6, 5                   /* privileged doorbell? */
2461         beq     0f
2462         cmpwi   r6, 3                   /* hypervisor doorbell? */
2463         beq     3f
2464 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
2465         cmpwi   r6, 0xa                 /* Hypervisor maintenance ? */
2466         beq     4f
2467         li      r3, 1                   /* anything else, return 1 */
2468 0:      blr
2469
2470         /* hypervisor doorbell */
2471 3:      li      r12, BOOK3S_INTERRUPT_H_DOORBELL
2472
2473         /*
2474          * Clear the doorbell as we will invoke the handler
2475          * explicitly in the guest exit path.
2476          */
2477         lis     r6, (PPC_DBELL_SERVER << (63-36))@h
2478         PPC_MSGCLR(6)
2479         /* see if it's a host IPI */
2480         li      r3, 1
2481         lbz     r0, HSTATE_HOST_IPI(r13)
2482         cmpwi   r0, 0
2483         bnelr
2484         /* if not, return -1 */
2485         li      r3, -1
2486         blr
2487
2488         /* Woken up due to Hypervisor maintenance interrupt */
2489 4:      li      r12, BOOK3S_INTERRUPT_HMI
2490         li      r3, 1
2491         blr
2492
2493         /* external interrupt - create a stack frame so we can call C */
2494 7:      mflr    r0
2495         std     r0, PPC_LR_STKOFF(r1)
2496         stdu    r1, -PPC_MIN_STKFRM(r1)
2497         bl      kvmppc_read_intr
2498         nop
2499         li      r12, BOOK3S_INTERRUPT_EXTERNAL
2500         cmpdi   r3, 1
2501         ble     1f
2502
2503         /*
2504          * Return code of 2 means PCI passthrough interrupt, but
2505          * we need to return back to host to complete handling the
2506          * interrupt. Trap reason is expected in r12 by guest
2507          * exit code.
2508          */
2509         li      r12, BOOK3S_INTERRUPT_HV_RM_HARD
2510 1:
2511         ld      r0, PPC_MIN_STKFRM+PPC_LR_STKOFF(r1)
2512         addi    r1, r1, PPC_MIN_STKFRM
2513         mtlr    r0
2514         blr
2515
2516 /*
2517  * Save away FP, VMX and VSX registers.
2518  * r3 = vcpu pointer
2519  * N.B. r30 and r31 are volatile across this function,
2520  * thus it is not callable from C.
2521  */
2522 kvmppc_save_fp:
2523         mflr    r30
2524         mr      r31,r3
2525         mfmsr   r5
2526         ori     r8,r5,MSR_FP
2527 #ifdef CONFIG_ALTIVEC
2528 BEGIN_FTR_SECTION
2529         oris    r8,r8,MSR_VEC@h
2530 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
2531 #endif
2532 #ifdef CONFIG_VSX
2533 BEGIN_FTR_SECTION
2534         oris    r8,r8,MSR_VSX@h
2535 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
2536 #endif
2537         mtmsrd  r8
2538         addi    r3,r3,VCPU_FPRS
2539         bl      store_fp_state
2540 #ifdef CONFIG_ALTIVEC
2541 BEGIN_FTR_SECTION
2542         addi    r3,r31,VCPU_VRS
2543         bl      store_vr_state
2544 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
2545 #endif
2546         mfspr   r6,SPRN_VRSAVE
2547         stw     r6,VCPU_VRSAVE(r31)
2548         mtlr    r30
2549         blr
2550
2551 /*
2552  * Load up FP, VMX and VSX registers
2553  * r4 = vcpu pointer
2554  * N.B. r30 and r31 are volatile across this function,
2555  * thus it is not callable from C.
2556  */
2557 kvmppc_load_fp:
2558         mflr    r30
2559         mr      r31,r4
2560         mfmsr   r9
2561         ori     r8,r9,MSR_FP
2562 #ifdef CONFIG_ALTIVEC
2563 BEGIN_FTR_SECTION
2564         oris    r8,r8,MSR_VEC@h
2565 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
2566 #endif
2567 #ifdef CONFIG_VSX
2568 BEGIN_FTR_SECTION
2569         oris    r8,r8,MSR_VSX@h
2570 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
2571 #endif
2572         mtmsrd  r8
2573         addi    r3,r4,VCPU_FPRS
2574         bl      load_fp_state
2575 #ifdef CONFIG_ALTIVEC
2576 BEGIN_FTR_SECTION
2577         addi    r3,r31,VCPU_VRS
2578         bl      load_vr_state
2579 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
2580 #endif
2581         lwz     r7,VCPU_VRSAVE(r31)
2582         mtspr   SPRN_VRSAVE,r7
2583         mtlr    r30
2584         mr      r4,r31
2585         blr
2586
2587 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
2588 /*
2589  * Save transactional state and TM-related registers.
2590  * Called with r9 pointing to the vcpu struct.
2591  * This can modify all checkpointed registers, but
2592  * restores r1, r2 and r9 (vcpu pointer) before exit.
2593  */
2594 kvmppc_save_tm:
2595         mflr    r0
2596         std     r0, PPC_LR_STKOFF(r1)
2597
2598         /* Turn on TM. */
2599         mfmsr   r8
2600         li      r0, 1
2601         rldimi  r8, r0, MSR_TM_LG, 63-MSR_TM_LG
2602         mtmsrd  r8
2603
2604         ld      r5, VCPU_MSR(r9)
2605         rldicl. r5, r5, 64 - MSR_TS_S_LG, 62
2606         beq     1f      /* TM not active in guest. */
2607
2608         std     r1, HSTATE_HOST_R1(r13)
2609         li      r3, TM_CAUSE_KVM_RESCHED
2610
2611         /* Clear the MSR RI since r1, r13 are all going to be foobar. */
2612         li      r5, 0
2613         mtmsrd  r5, 1
2614
2615         /* All GPRs are volatile at this point. */
2616         TRECLAIM(R3)
2617
2618         /* Temporarily store r13 and r9 so we have some regs to play with */
2619         SET_SCRATCH0(r13)
2620         GET_PACA(r13)
2621         std     r9, PACATMSCRATCH(r13)
2622         ld      r9, HSTATE_KVM_VCPU(r13)
2623
2624         /* Get a few more GPRs free. */
2625         std     r29, VCPU_GPRS_TM(29)(r9)
2626         std     r30, VCPU_GPRS_TM(30)(r9)
2627         std     r31, VCPU_GPRS_TM(31)(r9)
2628
2629         /* Save away PPR and DSCR soon so don't run with user values. */
2630         mfspr   r31, SPRN_PPR
2631         HMT_MEDIUM
2632         mfspr   r30, SPRN_DSCR
2633         ld      r29, HSTATE_DSCR(r13)
2634         mtspr   SPRN_DSCR, r29
2635
2636         /* Save all but r9, r13 & r29-r31 */
2637         reg = 0
2638         .rept   29
2639         .if (reg != 9) && (reg != 13)
2640         std     reg, VCPU_GPRS_TM(reg)(r9)
2641         .endif
2642         reg = reg + 1
2643         .endr
2644         /* ... now save r13 */
2645         GET_SCRATCH0(r4)
2646         std     r4, VCPU_GPRS_TM(13)(r9)
2647         /* ... and save r9 */
2648         ld      r4, PACATMSCRATCH(r13)
2649         std     r4, VCPU_GPRS_TM(9)(r9)
2650
2651         /* Reload stack pointer and TOC. */
2652         ld      r1, HSTATE_HOST_R1(r13)
2653         ld      r2, PACATOC(r13)
2654
2655         /* Set MSR RI now we have r1 and r13 back. */
2656         li      r5, MSR_RI
2657         mtmsrd  r5, 1
2658
2659         /* Save away checkpinted SPRs. */
2660         std     r31, VCPU_PPR_TM(r9)
2661         std     r30, VCPU_DSCR_TM(r9)
2662         mflr    r5
2663         mfcr    r6
2664         mfctr   r7
2665         mfspr   r8, SPRN_AMR
2666         mfspr   r10, SPRN_TAR
2667         mfxer   r11
2668         std     r5, VCPU_LR_TM(r9)
2669         stw     r6, VCPU_CR_TM(r9)
2670         std     r7, VCPU_CTR_TM(r9)
2671         std     r8, VCPU_AMR_TM(r9)
2672         std     r10, VCPU_TAR_TM(r9)
2673         std     r11, VCPU_XER_TM(r9)
2674
2675         /* Restore r12 as trap number. */
2676         lwz     r12, VCPU_TRAP(r9)
2677
2678         /* Save FP/VSX. */
2679         addi    r3, r9, VCPU_FPRS_TM
2680         bl      store_fp_state
2681         addi    r3, r9, VCPU_VRS_TM
2682         bl      store_vr_state
2683         mfspr   r6, SPRN_VRSAVE
2684         stw     r6, VCPU_VRSAVE_TM(r9)
2685 1:
2686         /*
2687          * We need to save these SPRs after the treclaim so that the software
2688          * error code is recorded correctly in the TEXASR.  Also the user may
2689          * change these outside of a transaction, so they must always be
2690          * context switched.
2691          */
2692         mfspr   r5, SPRN_TFHAR
2693         mfspr   r6, SPRN_TFIAR
2694         mfspr   r7, SPRN_TEXASR
2695         std     r5, VCPU_TFHAR(r9)
2696         std     r6, VCPU_TFIAR(r9)
2697         std     r7, VCPU_TEXASR(r9)
2698
2699         ld      r0, PPC_LR_STKOFF(r1)
2700         mtlr    r0
2701         blr
2702
2703 /*
2704  * Restore transactional state and TM-related registers.
2705  * Called with r4 pointing to the vcpu struct.
2706  * This potentially modifies all checkpointed registers.
2707  * It restores r1, r2, r4 from the PACA.
2708  */
2709 kvmppc_restore_tm:
2710         mflr    r0
2711         std     r0, PPC_LR_STKOFF(r1)
2712
2713         /* Turn on TM/FP/VSX/VMX so we can restore them. */
2714         mfmsr   r5
2715         li      r6, MSR_TM >> 32
2716         sldi    r6, r6, 32
2717         or      r5, r5, r6
2718         ori     r5, r5, MSR_FP
2719         oris    r5, r5, (MSR_VEC | MSR_VSX)@h
2720         mtmsrd  r5
2721
2722         /*
2723          * The user may change these outside of a transaction, so they must
2724          * always be context switched.
2725          */
2726         ld      r5, VCPU_TFHAR(r4)
2727         ld      r6, VCPU_TFIAR(r4)
2728         ld      r7, VCPU_TEXASR(r4)
2729         mtspr   SPRN_TFHAR, r5
2730         mtspr   SPRN_TFIAR, r6
2731         mtspr   SPRN_TEXASR, r7
2732
2733         ld      r5, VCPU_MSR(r4)
2734         rldicl. r5, r5, 64 - MSR_TS_S_LG, 62
2735         beqlr           /* TM not active in guest */
2736         std     r1, HSTATE_HOST_R1(r13)
2737
2738         /* Make sure the failure summary is set, otherwise we'll program check
2739          * when we trechkpt.  It's possible that this might have been not set
2740          * on a kvmppc_set_one_reg() call but we shouldn't let this crash the
2741          * host.
2742          */
2743         oris    r7, r7, (TEXASR_FS)@h
2744         mtspr   SPRN_TEXASR, r7
2745
2746         /*
2747          * We need to load up the checkpointed state for the guest.
2748          * We need to do this early as it will blow away any GPRs, VSRs and
2749          * some SPRs.
2750          */
2751
2752         mr      r31, r4
2753         addi    r3, r31, VCPU_FPRS_TM
2754         bl      load_fp_state
2755         addi    r3, r31, VCPU_VRS_TM
2756         bl      load_vr_state
2757         mr      r4, r31
2758         lwz     r7, VCPU_VRSAVE_TM(r4)
2759         mtspr   SPRN_VRSAVE, r7
2760
2761         ld      r5, VCPU_LR_TM(r4)
2762         lwz     r6, VCPU_CR_TM(r4)
2763         ld      r7, VCPU_CTR_TM(r4)
2764         ld      r8, VCPU_AMR_TM(r4)
2765         ld      r9, VCPU_TAR_TM(r4)
2766         ld      r10, VCPU_XER_TM(r4)
2767         mtlr    r5
2768         mtcr    r6
2769         mtctr   r7
2770         mtspr   SPRN_AMR, r8
2771         mtspr   SPRN_TAR, r9
2772         mtxer   r10
2773
2774         /*
2775          * Load up PPR and DSCR values but don't put them in the actual SPRs
2776          * till the last moment to avoid running with userspace PPR and DSCR for
2777          * too long.
2778          */
2779         ld      r29, VCPU_DSCR_TM(r4)
2780         ld      r30, VCPU_PPR_TM(r4)
2781
2782         std     r2, PACATMSCRATCH(r13) /* Save TOC */
2783
2784         /* Clear the MSR RI since r1, r13 are all going to be foobar. */
2785         li      r5, 0
2786         mtmsrd  r5, 1
2787
2788         /* Load GPRs r0-r28 */
2789         reg = 0
2790         .rept   29
2791         ld      reg, VCPU_GPRS_TM(reg)(r31)
2792         reg = reg + 1
2793         .endr
2794
2795         mtspr   SPRN_DSCR, r29
2796         mtspr   SPRN_PPR, r30
2797
2798         /* Load final GPRs */
2799         ld      29, VCPU_GPRS_TM(29)(r31)
2800         ld      30, VCPU_GPRS_TM(30)(r31)
2801         ld      31, VCPU_GPRS_TM(31)(r31)
2802
2803         /* TM checkpointed state is now setup.  All GPRs are now volatile. */
2804         TRECHKPT
2805
2806         /* Now let's get back the state we need. */
2807         HMT_MEDIUM
2808         GET_PACA(r13)
2809         ld      r29, HSTATE_DSCR(r13)
2810         mtspr   SPRN_DSCR, r29
2811         ld      r4, HSTATE_KVM_VCPU(r13)
2812         ld      r1, HSTATE_HOST_R1(r13)
2813         ld      r2, PACATMSCRATCH(r13)
2814
2815         /* Set the MSR RI since we have our registers back. */
2816         li      r5, MSR_RI
2817         mtmsrd  r5, 1
2818
2819         ld      r0, PPC_LR_STKOFF(r1)
2820         mtlr    r0
2821         blr
2822 #endif
2823
2824 /*
2825  * We come here if we get any exception or interrupt while we are
2826  * executing host real mode code while in guest MMU context.
2827  * For now just spin, but we should do something better.
2828  */
2829 kvmppc_bad_host_intr:
2830         b       .
2831
2832 /*
2833  * This mimics the MSR transition on IRQ delivery.  The new guest MSR is taken
2834  * from VCPU_INTR_MSR and is modified based on the required TM state changes.
2835  *   r11 has the guest MSR value (in/out)
2836  *   r9 has a vcpu pointer (in)
2837  *   r0 is used as a scratch register
2838  */
2839 kvmppc_msr_interrupt:
2840         rldicl  r0, r11, 64 - MSR_TS_S_LG, 62
2841         cmpwi   r0, 2 /* Check if we are in transactional state..  */
2842         ld      r11, VCPU_INTR_MSR(r9)
2843         bne     1f
2844         /* ... if transactional, change to suspended */
2845         li      r0, 1
2846 1:      rldimi  r11, r0, MSR_TS_S_LG, 63 - MSR_TS_T_LG
2847         blr
2848
2849 /*
2850  * This works around a hardware bug on POWER8E processors, where
2851  * writing a 1 to the MMCR0[PMAO] bit doesn't generate a
2852  * performance monitor interrupt.  Instead, when we need to have
2853  * an interrupt pending, we have to arrange for a counter to overflow.
2854  */
2855 kvmppc_fix_pmao:
2856         li      r3, 0
2857         mtspr   SPRN_MMCR2, r3
2858         lis     r3, (MMCR0_PMXE | MMCR0_FCECE)@h
2859         ori     r3, r3, MMCR0_PMCjCE | MMCR0_C56RUN
2860         mtspr   SPRN_MMCR0, r3
2861         lis     r3, 0x7fff
2862         ori     r3, r3, 0xffff
2863         mtspr   SPRN_PMC6, r3
2864         isync
2865         blr
2866
2867 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
2868 /*
2869  * Start timing an activity
2870  * r3 = pointer to time accumulation struct, r4 = vcpu
2871  */
2872 kvmhv_start_timing:
2873         ld      r5, HSTATE_KVM_VCORE(r13)
2874         lbz     r6, VCORE_IN_GUEST(r5)
2875         cmpwi   r6, 0
2876         beq     5f                              /* if in guest, need to */
2877         ld      r6, VCORE_TB_OFFSET(r5)         /* subtract timebase offset */
2878 5:      mftb    r5
2879         subf    r5, r6, r5
2880         std     r3, VCPU_CUR_ACTIVITY(r4)
2881         std     r5, VCPU_ACTIVITY_START(r4)
2882         blr
2883
2884 /*
2885  * Accumulate time to one activity and start another.
2886  * r3 = pointer to new time accumulation struct, r4 = vcpu
2887  */
2888 kvmhv_accumulate_time:
2889         ld      r5, HSTATE_KVM_VCORE(r13)
2890         lbz     r8, VCORE_IN_GUEST(r5)
2891         cmpwi   r8, 0
2892         beq     4f                              /* if in guest, need to */
2893         ld      r8, VCORE_TB_OFFSET(r5)         /* subtract timebase offset */
2894 4:      ld      r5, VCPU_CUR_ACTIVITY(r4)
2895         ld      r6, VCPU_ACTIVITY_START(r4)
2896         std     r3, VCPU_CUR_ACTIVITY(r4)
2897         mftb    r7
2898         subf    r7, r8, r7
2899         std     r7, VCPU_ACTIVITY_START(r4)
2900         cmpdi   r5, 0
2901         beqlr
2902         subf    r3, r6, r7
2903         ld      r8, TAS_SEQCOUNT(r5)
2904         cmpdi   r8, 0
2905         addi    r8, r8, 1
2906         std     r8, TAS_SEQCOUNT(r5)
2907         lwsync
2908         ld      r7, TAS_TOTAL(r5)
2909         add     r7, r7, r3
2910         std     r7, TAS_TOTAL(r5)
2911         ld      r6, TAS_MIN(r5)
2912         ld      r7, TAS_MAX(r5)
2913         beq     3f
2914         cmpd    r3, r6
2915         bge     1f
2916 3:      std     r3, TAS_MIN(r5)
2917 1:      cmpd    r3, r7
2918         ble     2f
2919         std     r3, TAS_MAX(r5)
2920 2:      lwsync
2921         addi    r8, r8, 1
2922         std     r8, TAS_SEQCOUNT(r5)
2923         blr
2924 #endif