arch/powerpc/kvm/book3s_interrupts.S

   1 /*
   2  * This program is free software; you can redistribute it and/or modify
   3  * it under the terms of the GNU General Public License, version 2, as
   4  * published by the Free Software Foundation.
   5  *
   6  * This program is distributed in the hope that it will be useful,
   7  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   8  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   9  * GNU General Public License for more details.
  10  *
  11  * You should have received a copy of the GNU General Public License
  12  * along with this program; if not, write to the Free Software
  13  * Foundation, 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
  14  *
  15  * Copyright SUSE Linux Products GmbH 2009
  16  *
  17  * Authors: Alexander Graf <agraf@suse.de>
  18  */
  19
  20 #include <asm/ppc_asm.h>
  21 #include <asm/kvm_asm.h>
  22 #include <asm/reg.h>
  23 #include <asm/page.h>
  24 #include <asm/asm-offsets.h>
  25 #include <asm/exception-64s.h>
  26
  27 #if defined(CONFIG_PPC_BOOK3S_64)
  28
  29 #define ULONG_SIZE              8
  30 #define FUNC(name)              GLUE(.,name)
  31
  32 #define GET_SHADOW_VCPU_R13
  33
  34 #define DISABLE_INTERRUPTS      \
  35         mfmsr   r0;             \
  36         rldicl  r0,r0,48,1;     \
  37         rotldi  r0,r0,16;       \
  38         mtmsrd  r0,1;           \
  39
  40 #elif defined(CONFIG_PPC_BOOK3S_32)
  41
  42 #define ULONG_SIZE              4
  43 #define FUNC(name)              name
  44
  45 #define GET_SHADOW_VCPU_R13     \
  46         lwz     r13, (THREAD + THREAD_KVM_SVCPU)(r2)
  47
  48 #define DISABLE_INTERRUPTS      \
  49         mfmsr   r0;             \
  50         rlwinm  r0,r0,0,17,15;  \
  51         mtmsr   r0;             \
  52
  53 #endif /* CONFIG_PPC_BOOK3S_XX */
  54
  55
  56 #define VCPU_GPR(n)             (VCPU_GPRS + (n * ULONG_SIZE))
  57 #define VCPU_LOAD_NVGPRS(vcpu) \
  58         PPC_LL  r14, VCPU_GPR(r14)(vcpu); \
  59         PPC_LL  r15, VCPU_GPR(r15)(vcpu); \
  60         PPC_LL  r16, VCPU_GPR(r16)(vcpu); \
  61         PPC_LL  r17, VCPU_GPR(r17)(vcpu); \
  62         PPC_LL  r18, VCPU_GPR(r18)(vcpu); \
  63         PPC_LL  r19, VCPU_GPR(r19)(vcpu); \
  64         PPC_LL  r20, VCPU_GPR(r20)(vcpu); \
  65         PPC_LL  r21, VCPU_GPR(r21)(vcpu); \
  66         PPC_LL  r22, VCPU_GPR(r22)(vcpu); \
  67         PPC_LL  r23, VCPU_GPR(r23)(vcpu); \
  68         PPC_LL  r24, VCPU_GPR(r24)(vcpu); \
  69         PPC_LL  r25, VCPU_GPR(r25)(vcpu); \
  70         PPC_LL  r26, VCPU_GPR(r26)(vcpu); \
  71         PPC_LL  r27, VCPU_GPR(r27)(vcpu); \
  72         PPC_LL  r28, VCPU_GPR(r28)(vcpu); \
  73         PPC_LL  r29, VCPU_GPR(r29)(vcpu); \
  74         PPC_LL  r30, VCPU_GPR(r30)(vcpu); \
  75         PPC_LL  r31, VCPU_GPR(r31)(vcpu); \
  76
  77 /*****************************************************************************
  78  *                                                                           *
  79  *     Guest entry / exit code that is in kernel module memory (highmem)     *
  80  *                                                                           *
  81  ****************************************************************************/
  82
  83 /* Registers:
  84  *  r3: kvm_run pointer
  85  *  r4: vcpu pointer
  86  */
  87 _GLOBAL(__kvmppc_vcpu_run)
  88
  89 kvm_start_entry:
  90         /* Write correct stack frame */
  91         mflr    r0
  92         PPC_STL r0,PPC_LR_STKOFF(r1)
  93
  94         /* Save host state to the stack */
  95         PPC_STLU r1, -SWITCH_FRAME_SIZE(r1)
  96
  97         /* Save r3 (kvm_run) and r4 (vcpu) */
  98         SAVE_2GPRS(3, r1)
  99
 100         /* Save non-volatile registers (r14 - r31) */
 101         SAVE_NVGPRS(r1)
 102
 103         /* Save LR */
 104         PPC_STL r0, _LINK(r1)
 105
 106         /* Load non-volatile guest state from the vcpu */
 107         VCPU_LOAD_NVGPRS(r4)
 108
 109 kvm_start_lightweight:
 110
 111         GET_SHADOW_VCPU_R13
 112         PPC_LL  r3, VCPU_HIGHMEM_HANDLER(r4)
 113         PPC_STL r3, HSTATE_VMHANDLER(r13)
 114
 115         PPC_LL  r10, VCPU_SHADOW_MSR(r4)        /* r10 = vcpu->arch.shadow_msr */
 116
 117         DISABLE_INTERRUPTS
 118
 119 #ifdef CONFIG_PPC_BOOK3S_64
 120         /* Some guests may need to have dcbz set to 32 byte length.
 121          *
 122          * Usually we ensure that by patching the guest's instructions
 123          * to trap on dcbz and emulate it in the hypervisor.
 124          *
 125          * If we can, we should tell the CPU to use 32 byte dcbz though,
 126          * because that's a lot faster.
 127          */
 128
 129         PPC_LL  r3, VCPU_HFLAGS(r4)
 130         rldicl. r3, r3, 0, 63           /* CR = ((r3 & 1) == 0) */
 131         beq     no_dcbz32_on
 132
 133         mfspr   r3,SPRN_HID5
 134         ori     r3, r3, 0x80            /* XXX HID5_dcbz32 = 0x80 */
 135         mtspr   SPRN_HID5,r3
 136
 137 no_dcbz32_on:
 138
 139 #endif /* CONFIG_PPC_BOOK3S_64 */
 140
 141         PPC_LL  r6, VCPU_RMCALL(r4)
 142         mtctr   r6
 143
 144         PPC_LL  r3, VCPU_TRAMPOLINE_ENTER(r4)
 145         LOAD_REG_IMMEDIATE(r4, MSR_KERNEL & ~(MSR_IR | MSR_DR))
 146
 147         /* Jump to segment patching handler and into our guest */
 148         bctr
 149
 150 /*
 151  * This is the handler in module memory. It gets jumped at from the
 152  * lowmem trampoline code, so it's basically the guest exit code.
 153  *
 154  */
 155
 156 .global kvmppc_handler_highmem
 157 kvmppc_handler_highmem:
 158
 159         /*
 160          * Register usage at this point:
 161          *
 162          * R1       = host R1
 163          * R2       = host R2
 164          * R12      = exit handler id
 165          * R13      = PACA
 166          * SVCPU.*  = guest *
 167          *
 168          */
 169
 170         /* R7 = vcpu */
 171         PPC_LL  r7, GPR4(r1)
 172
 173 #ifdef CONFIG_PPC_BOOK3S_64
 174
 175         PPC_LL  r5, VCPU_HFLAGS(r7)
 176         rldicl. r5, r5, 0, 63           /* CR = ((r5 & 1) == 0) */
 177         beq     no_dcbz32_off
 178
 179         li      r4, 0
 180         mfspr   r5,SPRN_HID5
 181         rldimi  r5,r4,6,56
 182         mtspr   SPRN_HID5,r5
 183
 184 no_dcbz32_off:
 185
 186 #endif /* CONFIG_PPC_BOOK3S_64 */
 187
 188         PPC_STL r14, VCPU_GPR(r14)(r7)
 189         PPC_STL r15, VCPU_GPR(r15)(r7)
 190         PPC_STL r16, VCPU_GPR(r16)(r7)
 191         PPC_STL r17, VCPU_GPR(r17)(r7)
 192         PPC_STL r18, VCPU_GPR(r18)(r7)
 193         PPC_STL r19, VCPU_GPR(r19)(r7)
 194         PPC_STL r20, VCPU_GPR(r20)(r7)
 195         PPC_STL r21, VCPU_GPR(r21)(r7)
 196         PPC_STL r22, VCPU_GPR(r22)(r7)
 197         PPC_STL r23, VCPU_GPR(r23)(r7)
 198         PPC_STL r24, VCPU_GPR(r24)(r7)
 199         PPC_STL r25, VCPU_GPR(r25)(r7)
 200         PPC_STL r26, VCPU_GPR(r26)(r7)
 201         PPC_STL r27, VCPU_GPR(r27)(r7)
 202         PPC_STL r28, VCPU_GPR(r28)(r7)
 203         PPC_STL r29, VCPU_GPR(r29)(r7)
 204         PPC_STL r30, VCPU_GPR(r30)(r7)
 205         PPC_STL r31, VCPU_GPR(r31)(r7)
 206
 207         /* Restore host msr -> SRR1 */
 208         PPC_LL  r6, VCPU_HOST_MSR(r7)
 209
 210         /*
 211          * For some interrupts, we need to call the real Linux
 212          * handler, so it can do work for us. This has to happen
 213          * as if the interrupt arrived from the kernel though,
 214          * so let's fake it here where most state is restored.
 215          *
 216          * Call Linux for hardware interrupts/decrementer
 217          * r3 = address of interrupt handler (exit reason)
 218          */
 219
 220         cmpwi   r12, BOOK3S_INTERRUPT_EXTERNAL
 221         beq     call_linux_handler
 222         cmpwi   r12, BOOK3S_INTERRUPT_DECREMENTER
 223         beq     call_linux_handler
 224         cmpwi   r12, BOOK3S_INTERRUPT_PERFMON
 225         beq     call_linux_handler
 226
 227         /* Back to EE=1 */
 228         mtmsr   r6
 229         sync
 230         b       kvm_return_point
 231
 232 call_linux_handler:
 233
 234         /*
 235          * If we land here we need to jump back to the handler we
 236          * came from.
 237          *
 238          * We have a page that we can access from real mode, so let's
 239          * jump back to that and use it as a trampoline to get back into the
 240          * interrupt handler!
 241          *
 242          * R3 still contains the exit code,
 243          * R5 VCPU_HOST_RETIP and
 244          * R6 VCPU_HOST_MSR
 245          */
 246
 247         /* Restore host IP -> SRR0 */
 248         PPC_LL  r5, VCPU_HOST_RETIP(r7)
 249
 250         /* XXX Better move to a safe function?
 251          *     What if we get an HTAB flush in between mtsrr0 and mtsrr1? */
 252
 253         mtlr    r12
 254
 255         PPC_LL  r4, VCPU_TRAMPOLINE_LOWMEM(r7)
 256         mtsrr0  r4
 257         LOAD_REG_IMMEDIATE(r3, MSR_KERNEL & ~(MSR_IR | MSR_DR))
 258         mtsrr1  r3
 259
 260         RFI
 261
 262 .global kvm_return_point
 263 kvm_return_point:
 264
 265         /* Jump back to lightweight entry if we're supposed to */
 266         /* go back into the guest */
 267
 268         /* Pass the exit number as 3rd argument to kvmppc_handle_exit */
 269         mr      r5, r12
 270
 271         /* Restore r3 (kvm_run) and r4 (vcpu) */
 272         REST_2GPRS(3, r1)
 273         bl      FUNC(kvmppc_handle_exit)
 274
 275         /* If RESUME_GUEST, get back in the loop */
 276         cmpwi   r3, RESUME_GUEST
 277         beq     kvm_loop_lightweight
 278
 279         cmpwi   r3, RESUME_GUEST_NV
 280         beq     kvm_loop_heavyweight
 281
 282 kvm_exit_loop:
 283
 284         PPC_LL  r4, _LINK(r1)
 285         mtlr    r4
 286
 287         /* Restore non-volatile host registers (r14 - r31) */
 288         REST_NVGPRS(r1)
 289
 290         addi    r1, r1, SWITCH_FRAME_SIZE
 291         blr
 292
 293 kvm_loop_heavyweight:
 294
 295         PPC_LL  r4, _LINK(r1)
 296         PPC_STL r4, (PPC_LR_STKOFF + SWITCH_FRAME_SIZE)(r1)
 297
 298         /* Load vcpu and cpu_run */
 299         REST_2GPRS(3, r1)
 300
 301         /* Load non-volatile guest state from the vcpu */
 302         VCPU_LOAD_NVGPRS(r4)
 303
 304         /* Jump back into the beginning of this function */
 305         b       kvm_start_lightweight
 306
 307 kvm_loop_lightweight:
 308
 309         /* We'll need the vcpu pointer */
 310         REST_GPR(4, r1)
 311
 312         /* Jump back into the beginning of this function */
 313         b       kvm_start_lightweight