arch/s390/kernel/entry.S

   1 /*
   2  *  arch/s390/kernel/entry.S
   3  *    S390 low-level entry points.
   4  *
   5  *    Copyright (C) IBM Corp. 1999,2006
   6  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
   7  *               Hartmut Penner (hp@de.ibm.com),
   8  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
   9  *               Heiko Carstens <heiko.carstens@de.ibm.com>
  10  */
  11
  12 #include <linux/sys.h>
  13 #include <linux/linkage.h>
  14 #include <linux/init.h>
  15 #include <asm/cache.h>
  16 #include <asm/errno.h>
  17 #include <asm/ptrace.h>
  18 #include <asm/thread_info.h>
  19 #include <asm/asm-offsets.h>
  20 #include <asm/unistd.h>
  21 #include <asm/page.h>
  22
  23 /*
  24  * Stack layout for the system_call stack entry.
  25  * The first few entries are identical to the user_regs_struct.
  26  */
  27 SP_PTREGS    =  STACK_FRAME_OVERHEAD
  28 SP_ARGS      =  STACK_FRAME_OVERHEAD + __PT_ARGS
  29 SP_PSW       =  STACK_FRAME_OVERHEAD + __PT_PSW
  30 SP_R0        =  STACK_FRAME_OVERHEAD + __PT_GPRS
  31 SP_R1        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 4
  32 SP_R2        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 8
  33 SP_R3        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 12
  34 SP_R4        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 16
  35 SP_R5        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 20
  36 SP_R6        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 24
  37 SP_R7        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 28
  38 SP_R8        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 32
  39 SP_R9        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 36
  40 SP_R10       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 40
  41 SP_R11       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 44
  42 SP_R12       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 48
  43 SP_R13       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 52
  44 SP_R14       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 56
  45 SP_R15       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 60
  46 SP_ORIG_R2   =  STACK_FRAME_OVERHEAD + __PT_ORIG_GPR2
  47 SP_ILC       =  STACK_FRAME_OVERHEAD + __PT_ILC
  48 SP_SVCNR     =  STACK_FRAME_OVERHEAD + __PT_SVCNR
  49 SP_SIZE      =  STACK_FRAME_OVERHEAD + __PT_SIZE
  50
  51 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  52                  _TIF_MCCK_PENDING | _TIF_RESTART_SVC | _TIF_SINGLE_STEP )
  53 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  54                  _TIF_MCCK_PENDING)
  55 _TIF_SYSCALL = (_TIF_SYSCALL_TRACE>>8 | _TIF_SYSCALL_AUDIT>>8 | \
  56                 _TIF_SECCOMP>>8 | _TIF_SYSCALL_TRACEPOINT>>8)
  57
  58 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
  59 STACK_SIZE  = 1 << STACK_SHIFT
  60
  61 #define BASED(name) name-system_call(%r13)
  62
  63 #ifdef CONFIG_TRACE_IRQFLAGS
  64         .macro  TRACE_IRQS_ON
  65         basr    %r2,%r0
  66         l       %r1,BASED(.Ltrace_irq_on_caller)
  67         basr    %r14,%r1
  68         .endm
  69
  70         .macro  TRACE_IRQS_OFF
  71         basr    %r2,%r0
  72         l       %r1,BASED(.Ltrace_irq_off_caller)
  73         basr    %r14,%r1
  74         .endm
  75
  76         .macro  TRACE_IRQS_CHECK
  77         basr    %r2,%r0
  78         tm      SP_PSW(%r15),0x03       # irqs enabled?
  79         jz      0f
  80         l       %r1,BASED(.Ltrace_irq_on_caller)
  81         basr    %r14,%r1
  82         j       1f
  83 0:      l       %r1,BASED(.Ltrace_irq_off_caller)
  84         basr    %r14,%r1
  85 1:
  86         .endm
  87 #else
  88 #define TRACE_IRQS_ON
  89 #define TRACE_IRQS_OFF
  90 #define TRACE_IRQS_CHECK
  91 #endif
  92
  93 #ifdef CONFIG_LOCKDEP
  94         .macro  LOCKDEP_SYS_EXIT
  95         tm      SP_PSW+1(%r15),0x01     # returning to user ?
  96         jz      0f
  97         l       %r1,BASED(.Llockdep_sys_exit)
  98         basr    %r14,%r1
  99 0:
 100         .endm
 101 #else
 102 #define LOCKDEP_SYS_EXIT
 103 #endif
 104
 105 /*
 106  * Register usage in interrupt handlers:
 107  *    R9  - pointer to current task structure
 108  *    R13 - pointer to literal pool
 109  *    R14 - return register for function calls
 110  *    R15 - kernel stack pointer
 111  */
 112
 113         .macro  UPDATE_VTIME lc_from,lc_to,lc_sum
 114         lm      %r10,%r11,\lc_from
 115         sl      %r10,\lc_to
 116         sl      %r11,\lc_to+4
 117         bc      3,BASED(0f)
 118         sl      %r10,BASED(.Lc_1)
 119 0:      al      %r10,\lc_sum
 120         al      %r11,\lc_sum+4
 121         bc      12,BASED(1f)
 122         al      %r10,BASED(.Lc_1)
 123 1:      stm     %r10,%r11,\lc_sum
 124         .endm
 125
 126         .macro  SAVE_ALL_BASE savearea
 127         stm     %r12,%r15,\savearea
 128         l       %r13,__LC_SVC_NEW_PSW+4 # load &system_call to %r13
 129         .endm
 130
 131         .macro  SAVE_ALL_SVC psworg,savearea
 132         la      %r12,\psworg
 133         l       %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 134         .endm
 135
 136         .macro  SAVE_ALL_SYNC psworg,savearea
 137         la      %r12,\psworg
 138         tm      \psworg+1,0x01          # test problem state bit
 139         bz      BASED(2f)               # skip stack setup save
 140         l       %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 141 #ifdef CONFIG_CHECK_STACK
 142         b       BASED(3f)
 143 2:      tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
 144         bz      BASED(stack_overflow)
 145 3:
 146 #endif
 147 2:
 148         .endm
 149
 150         .macro  SAVE_ALL_ASYNC psworg,savearea
 151         la      %r12,\psworg
 152         tm      \psworg+1,0x01          # test problem state bit
 153         bnz     BASED(1f)               # from user -> load async stack
 154         clc     \psworg+4(4),BASED(.Lcritical_end)
 155         bhe     BASED(0f)
 156         clc     \psworg+4(4),BASED(.Lcritical_start)
 157         bl      BASED(0f)
 158         l       %r14,BASED(.Lcleanup_critical)
 159         basr    %r14,%r14
 160         tm      1(%r12),0x01            # retest problem state after cleanup
 161         bnz     BASED(1f)
 162 0:      l       %r14,__LC_ASYNC_STACK   # are we already on the async stack ?
 163         slr     %r14,%r15
 164         sra     %r14,STACK_SHIFT
 165         be      BASED(2f)
 166 1:      l       %r15,__LC_ASYNC_STACK
 167 #ifdef CONFIG_CHECK_STACK
 168         b       BASED(3f)
 169 2:      tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
 170         bz      BASED(stack_overflow)
 171 3:
 172 #endif
 173 2:
 174         .endm
 175
 176         .macro  CREATE_STACK_FRAME psworg,savearea
 177         s       %r15,BASED(.Lc_spsize)  # make room for registers & psw
 178         mvc     SP_PSW(8,%r15),0(%r12)  # move user PSW to stack
 179         st      %r2,SP_ORIG_R2(%r15)    # store original content of gpr 2
 180         icm     %r12,3,__LC_SVC_ILC
 181         stm     %r0,%r11,SP_R0(%r15)    # store gprs %r0-%r11 to kernel stack
 182         st      %r12,SP_SVCNR(%r15)
 183         mvc     SP_R12(16,%r15),\savearea # move %r12-%r15 to stack
 184         la      %r12,0
 185         st      %r12,__SF_BACKCHAIN(%r15)       # clear back chain
 186         .endm
 187
 188         .macro  RESTORE_ALL psworg,sync
 189         mvc     \psworg(8),SP_PSW(%r15) # move user PSW to lowcore
 190         .if !\sync
 191         ni      \psworg+1,0xfd          # clear wait state bit
 192         .endif
 193         lm      %r0,%r15,SP_R0(%r15)    # load gprs 0-15 of user
 194         stpt    __LC_EXIT_TIMER
 195         lpsw    \psworg                 # back to caller
 196         .endm
 197
 198 /*
 199  * Scheduler resume function, called by switch_to
 200  *  gpr2 = (task_struct *) prev
 201  *  gpr3 = (task_struct *) next
 202  * Returns:
 203  *  gpr2 = prev
 204  */
 205         .globl  __switch_to
 206 __switch_to:
 207         basr    %r1,0
 208 __switch_to_base:
 209         tm      __THREAD_per(%r3),0xe8          # new process is using per ?
 210         bz      __switch_to_noper-__switch_to_base(%r1) # if not we're fine
 211         stctl   %c9,%c11,__SF_EMPTY(%r15)       # We are using per stuff
 212         clc     __THREAD_per(12,%r3),__SF_EMPTY(%r15)
 213         be      __switch_to_noper-__switch_to_base(%r1) # we got away w/o bashing TLB's
 214         lctl    %c9,%c11,__THREAD_per(%r3)      # Nope we didn't
 215 __switch_to_noper:
 216         l       %r4,__THREAD_info(%r2)          # get thread_info of prev
 217         tm      __TI_flags+3(%r4),_TIF_MCCK_PENDING # machine check pending?
 218         bz      __switch_to_no_mcck-__switch_to_base(%r1)
 219         ni      __TI_flags+3(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
 220         l       %r4,__THREAD_info(%r3)          # get thread_info of next
 221         oi      __TI_flags+3(%r4),_TIF_MCCK_PENDING # set it in next
 222 __switch_to_no_mcck:
 223         stm     %r6,%r15,__SF_GPRS(%r15)# store __switch_to registers of prev task
 224         st      %r15,__THREAD_ksp(%r2)  # store kernel stack to prev->tss.ksp
 225         l       %r15,__THREAD_ksp(%r3)  # load kernel stack from next->tss.ksp
 226         lm      %r6,%r15,__SF_GPRS(%r15)# load __switch_to registers of next task
 227         st      %r3,__LC_CURRENT        # __LC_CURRENT = current task struct
 228         lctl    %c4,%c4,__TASK_pid(%r3) # load pid to control reg. 4
 229         l       %r3,__THREAD_info(%r3)  # load thread_info from task struct
 230         st      %r3,__LC_THREAD_INFO
 231         ahi     %r3,STACK_SIZE
 232         st      %r3,__LC_KERNEL_STACK   # __LC_KERNEL_STACK = new kernel stack
 233         br      %r14
 234
 235 __critical_start:
 236 /*
 237  * SVC interrupt handler routine. System calls are synchronous events and
 238  * are executed with interrupts enabled.
 239  */
 240
 241         .globl  system_call
 242 system_call:
 243         stpt    __LC_SYNC_ENTER_TIMER
 244 sysc_saveall:
 245         SAVE_ALL_BASE __LC_SAVE_AREA
 246         SAVE_ALL_SVC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 247         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 248         lh      %r7,0x8a          # get svc number from lowcore
 249 sysc_vtime:
 250         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 251 sysc_stime:
 252         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 253 sysc_update:
 254         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 255 sysc_do_svc:
 256         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 257         ltr     %r7,%r7                 # test for svc 0
 258         bnz     BASED(sysc_nr_ok)       # svc number > 0
 259         # svc 0: system call number in %r1
 260         cl      %r1,BASED(.Lnr_syscalls)
 261         bnl     BASED(sysc_nr_ok)
 262         lr      %r7,%r1           # copy svc number to %r7
 263 sysc_nr_ok:
 264         mvc     SP_ARGS(4,%r15),SP_R7(%r15)
 265 sysc_do_restart:
 266         sth     %r7,SP_SVCNR(%r15)
 267         sll     %r7,2             # svc number *4
 268         l       %r8,BASED(.Lsysc_table)
 269         tm      __TI_flags+2(%r9),_TIF_SYSCALL
 270         l       %r8,0(%r7,%r8)    # get system call addr.
 271         bnz     BASED(sysc_tracesys)
 272         basr    %r14,%r8          # call sys_xxxx
 273         st      %r2,SP_R2(%r15)   # store return value (change R2 on stack)
 274
 275 sysc_return:
 276         tm      __TI_flags+3(%r9),_TIF_WORK_SVC
 277         bnz     BASED(sysc_work)  # there is work to do (signals etc.)
 278 sysc_restore:
 279 #ifdef CONFIG_TRACE_IRQFLAGS
 280         la      %r1,BASED(sysc_restore_trace_psw_addr)
 281         l       %r1,0(%r1)
 282         lpsw    0(%r1)
 283 sysc_restore_trace:
 284         TRACE_IRQS_CHECK
 285         LOCKDEP_SYS_EXIT
 286 #endif
 287 sysc_leave:
 288         RESTORE_ALL __LC_RETURN_PSW,1
 289 sysc_done:
 290
 291 #ifdef CONFIG_TRACE_IRQFLAGS
 292 sysc_restore_trace_psw_addr:
 293         .long sysc_restore_trace_psw
 294
 295         .section .data,"aw",@progbits
 296         .align  8
 297         .globl  sysc_restore_trace_psw
 298 sysc_restore_trace_psw:
 299         .long   0, sysc_restore_trace + 0x80000000
 300         .previous
 301 #endif
 302
 303 #
 304 # There is work to do, but first we need to check if we return to userspace.
 305 #
 306 sysc_work:
 307         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 308         bno     BASED(sysc_restore)
 309
 310 #
 311 # One of the work bits is on. Find out which one.
 312 #
 313 sysc_work_loop:
 314         tm      __TI_flags+3(%r9),_TIF_MCCK_PENDING
 315         bo      BASED(sysc_mcck_pending)
 316         tm      __TI_flags+3(%r9),_TIF_NEED_RESCHED
 317         bo      BASED(sysc_reschedule)
 318         tm      __TI_flags+3(%r9),_TIF_SIGPENDING
 319         bo      BASED(sysc_sigpending)
 320         tm      __TI_flags+3(%r9),_TIF_NOTIFY_RESUME
 321         bo      BASED(sysc_notify_resume)
 322         tm      __TI_flags+3(%r9),_TIF_RESTART_SVC
 323         bo      BASED(sysc_restart)
 324         tm      __TI_flags+3(%r9),_TIF_SINGLE_STEP
 325         bo      BASED(sysc_singlestep)
 326         b       BASED(sysc_return)      # beware of critical section cleanup
 327
 328 #
 329 # _TIF_NEED_RESCHED is set, call schedule
 330 #
 331 sysc_reschedule:
 332         l       %r1,BASED(.Lschedule)
 333         la      %r14,BASED(sysc_work_loop)
 334         br      %r1                     # call scheduler
 335
 336 #
 337 # _TIF_MCCK_PENDING is set, call handler
 338 #
 339 sysc_mcck_pending:
 340         l       %r1,BASED(.Ls390_handle_mcck)
 341         la      %r14,BASED(sysc_work_loop)
 342         br      %r1                     # TIF bit will be cleared by handler
 343
 344 #
 345 # _TIF_SIGPENDING is set, call do_signal
 346 #
 347 sysc_sigpending:
 348         ni      __TI_flags+3(%r9),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
 349         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 350         l       %r1,BASED(.Ldo_signal)
 351         basr    %r14,%r1                # call do_signal
 352         tm      __TI_flags+3(%r9),_TIF_RESTART_SVC
 353         bo      BASED(sysc_restart)
 354         tm      __TI_flags+3(%r9),_TIF_SINGLE_STEP
 355         bo      BASED(sysc_singlestep)
 356         b       BASED(sysc_work_loop)
 357
 358 #
 359 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
 360 #
 361 sysc_notify_resume:
 362         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 363         l       %r1,BASED(.Ldo_notify_resume)
 364         la      %r14,BASED(sysc_work_loop)
 365         br      %r1                     # call do_notify_resume
 366
 367
 368 #
 369 # _TIF_RESTART_SVC is set, set up registers and restart svc
 370 #
 371 sysc_restart:
 372         ni      __TI_flags+3(%r9),255-_TIF_RESTART_SVC # clear TIF_RESTART_SVC
 373         l       %r7,SP_R2(%r15)         # load new svc number
 374         mvc     SP_R2(4,%r15),SP_ORIG_R2(%r15) # restore first argument
 375         lm      %r2,%r6,SP_R2(%r15)     # load svc arguments
 376         b       BASED(sysc_do_restart)  # restart svc
 377
 378 #
 379 # _TIF_SINGLE_STEP is set, call do_single_step
 380 #
 381 sysc_singlestep:
 382         ni      __TI_flags+3(%r9),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
 383         mvi     SP_SVCNR(%r15),0xff     # set trap indication to pgm check
 384         mvi     SP_SVCNR+1(%r15),0xff
 385         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 386         l       %r1,BASED(.Lhandle_per) # load adr. of per handler
 387         la      %r14,BASED(sysc_work_loop)      # load adr. of system return
 388         br      %r1                     # branch to do_single_step
 389
 390 #
 391 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
 392 # and after the system call
 393 #
 394 sysc_tracesys:
 395         l       %r1,BASED(.Ltrace_entry)
 396         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 397         la      %r3,0
 398         srl     %r7,2
 399         st      %r7,SP_R2(%r15)
 400         basr    %r14,%r1
 401         cl      %r2,BASED(.Lnr_syscalls)
 402         bnl     BASED(sysc_tracenogo)
 403         l       %r8,BASED(.Lsysc_table)
 404         lr      %r7,%r2
 405         sll     %r7,2                   # svc number *4
 406         l       %r8,0(%r7,%r8)
 407 sysc_tracego:
 408         lm      %r3,%r6,SP_R3(%r15)
 409         l       %r2,SP_ORIG_R2(%r15)
 410         basr    %r14,%r8                # call sys_xxx
 411         st      %r2,SP_R2(%r15)         # store return value
 412 sysc_tracenogo:
 413         tm      __TI_flags+2(%r9),_TIF_SYSCALL
 414         bz      BASED(sysc_return)
 415         l       %r1,BASED(.Ltrace_exit)
 416         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 417         la      %r14,BASED(sysc_return)
 418         br      %r1
 419
 420 #
 421 # a new process exits the kernel with ret_from_fork
 422 #
 423         .globl  ret_from_fork
 424 ret_from_fork:
 425         l       %r13,__LC_SVC_NEW_PSW+4
 426         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 427         tm      SP_PSW+1(%r15),0x01     # forking a kernel thread ?
 428         bo      BASED(0f)
 429         st      %r15,SP_R15(%r15)       # store stack pointer for new kthread
 430 0:      l       %r1,BASED(.Lschedtail)
 431         basr    %r14,%r1
 432         TRACE_IRQS_ON
 433         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 434         b       BASED(sysc_tracenogo)
 435
 436 #
 437 # kernel_execve function needs to deal with pt_regs that is not
 438 # at the usual place
 439 #
 440         .globl  kernel_execve
 441 kernel_execve:
 442         stm     %r12,%r15,48(%r15)
 443         lr      %r14,%r15
 444         l       %r13,__LC_SVC_NEW_PSW+4
 445         s       %r15,BASED(.Lc_spsize)
 446         st      %r14,__SF_BACKCHAIN(%r15)
 447         la      %r12,SP_PTREGS(%r15)
 448         xc      0(__PT_SIZE,%r12),0(%r12)
 449         l       %r1,BASED(.Ldo_execve)
 450         lr      %r5,%r12
 451         basr    %r14,%r1
 452         ltr     %r2,%r2
 453         be      BASED(0f)
 454         a       %r15,BASED(.Lc_spsize)
 455         lm      %r12,%r15,48(%r15)
 456         br      %r14
 457         # execve succeeded.
 458 0:      stnsm   __SF_EMPTY(%r15),0xfc   # disable interrupts
 459         l       %r15,__LC_KERNEL_STACK  # load ksp
 460         s       %r15,BASED(.Lc_spsize)  # make room for registers & psw
 461         l       %r9,__LC_THREAD_INFO
 462         mvc     SP_PTREGS(__PT_SIZE,%r15),0(%r12)       # copy pt_regs
 463         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
 464         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 465         l       %r1,BASED(.Lexecve_tail)
 466         basr    %r14,%r1
 467         b       BASED(sysc_return)
 468
 469 /*
 470  * Program check handler routine
 471  */
 472
 473         .globl  pgm_check_handler
 474 pgm_check_handler:
 475 /*
 476  * First we need to check for a special case:
 477  * Single stepping an instruction that disables the PER event mask will
 478  * cause a PER event AFTER the mask has been set. Example: SVC or LPSW.
 479  * For a single stepped SVC the program check handler gets control after
 480  * the SVC new PSW has been loaded. But we want to execute the SVC first and
 481  * then handle the PER event. Therefore we update the SVC old PSW to point
 482  * to the pgm_check_handler and branch to the SVC handler after we checked
 483  * if we have to load the kernel stack register.
 484  * For every other possible cause for PER event without the PER mask set
 485  * we just ignore the PER event (FIXME: is there anything we have to do
 486  * for LPSW?).
 487  */
 488         stpt    __LC_SYNC_ENTER_TIMER
 489         SAVE_ALL_BASE __LC_SAVE_AREA
 490         tm      __LC_PGM_INT_CODE+1,0x80 # check whether we got a per exception
 491         bnz     BASED(pgm_per)          # got per exception -> special case
 492         SAVE_ALL_SYNC __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 493         CREATE_STACK_FRAME __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 494         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 495         bz      BASED(pgm_no_vtime)
 496         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 497         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 498         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 499 pgm_no_vtime:
 500         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 501         TRACE_IRQS_OFF
 502         l       %r3,__LC_PGM_ILC        # load program interruption code
 503         la      %r8,0x7f
 504         nr      %r8,%r3
 505 pgm_do_call:
 506         l       %r7,BASED(.Ljump_table)
 507         sll     %r8,2
 508         l       %r7,0(%r8,%r7)          # load address of handler routine
 509         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 510         la      %r14,BASED(sysc_return)
 511         br      %r7                     # branch to interrupt-handler
 512
 513 #
 514 # handle per exception
 515 #
 516 pgm_per:
 517         tm      __LC_PGM_OLD_PSW,0x40   # test if per event recording is on
 518         bnz     BASED(pgm_per_std)      # ok, normal per event from user space
 519 # ok its one of the special cases, now we need to find out which one
 520         clc     __LC_PGM_OLD_PSW(8),__LC_SVC_NEW_PSW
 521         be      BASED(pgm_svcper)
 522 # no interesting special case, ignore PER event
 523         lm      %r12,%r15,__LC_SAVE_AREA
 524         lpsw    0x28
 525
 526 #
 527 # Normal per exception
 528 #
 529 pgm_per_std:
 530         SAVE_ALL_SYNC __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 531         CREATE_STACK_FRAME __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 532         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 533         bz      BASED(pgm_no_vtime2)
 534         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 535         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 536         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 537 pgm_no_vtime2:
 538         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 539         TRACE_IRQS_OFF
 540         l       %r1,__TI_task(%r9)
 541         mvc     __THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
 542         mvc     __THREAD_per+__PER_address(4,%r1),__LC_PER_ADDRESS
 543         mvc     __THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
 544         oi      __TI_flags+3(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
 545         tm      SP_PSW+1(%r15),0x01     # kernel per event ?
 546         bz      BASED(kernel_per)
 547         l       %r3,__LC_PGM_ILC        # load program interruption code
 548         la      %r8,0x7f
 549         nr      %r8,%r3                 # clear per-event-bit and ilc
 550         be      BASED(sysc_return)      # only per or per+check ?
 551         b       BASED(pgm_do_call)
 552
 553 #
 554 # it was a single stepped SVC that is causing all the trouble
 555 #
 556 pgm_svcper:
 557         SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 558         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 559         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 560         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 561         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 562         lh      %r7,0x8a                # get svc number from lowcore
 563         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 564         TRACE_IRQS_OFF
 565         l       %r8,__TI_task(%r9)
 566         mvc     __THREAD_per+__PER_atmid(2,%r8),__LC_PER_ATMID
 567         mvc     __THREAD_per+__PER_address(4,%r8),__LC_PER_ADDRESS
 568         mvc     __THREAD_per+__PER_access_id(1,%r8),__LC_PER_ACCESS_ID
 569         oi      __TI_flags+3(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
 570         TRACE_IRQS_ON
 571         lm      %r2,%r6,SP_R2(%r15)     # load svc arguments
 572         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 573         b       BASED(sysc_do_svc)
 574
 575 #
 576 # per was called from kernel, must be kprobes
 577 #
 578 kernel_per:
 579         mvi     SP_SVCNR(%r15),0xff     # set trap indication to pgm check
 580         mvi     SP_SVCNR+1(%r15),0xff
 581         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 582         l       %r1,BASED(.Lhandle_per) # load adr. of per handler
 583         la      %r14,BASED(sysc_restore)# load adr. of system return
 584         br      %r1                     # branch to do_single_step
 585
 586 /*
 587  * IO interrupt handler routine
 588  */
 589
 590         .globl io_int_handler
 591 io_int_handler:
 592         stck    __LC_INT_CLOCK
 593         stpt    __LC_ASYNC_ENTER_TIMER
 594         SAVE_ALL_BASE __LC_SAVE_AREA+16
 595         SAVE_ALL_ASYNC __LC_IO_OLD_PSW,__LC_SAVE_AREA+16
 596         CREATE_STACK_FRAME __LC_IO_OLD_PSW,__LC_SAVE_AREA+16
 597         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 598         bz      BASED(io_no_vtime)
 599         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 600         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 601         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 602 io_no_vtime:
 603         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 604         TRACE_IRQS_OFF
 605         l       %r1,BASED(.Ldo_IRQ)     # load address of do_IRQ
 606         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 607         basr    %r14,%r1                # branch to standard irq handler
 608 io_return:
 609         tm      __TI_flags+3(%r9),_TIF_WORK_INT
 610         bnz     BASED(io_work)          # there is work to do (signals etc.)
 611 io_restore:
 612 #ifdef CONFIG_TRACE_IRQFLAGS
 613         la      %r1,BASED(io_restore_trace_psw_addr)
 614         l       %r1,0(%r1)
 615         lpsw    0(%r1)
 616 io_restore_trace:
 617         TRACE_IRQS_CHECK
 618         LOCKDEP_SYS_EXIT
 619 #endif
 620 io_leave:
 621         RESTORE_ALL __LC_RETURN_PSW,0
 622 io_done:
 623
 624 #ifdef CONFIG_TRACE_IRQFLAGS
 625 io_restore_trace_psw_addr:
 626         .long io_restore_trace_psw
 627
 628         .section .data,"aw",@progbits
 629         .align  8
 630         .globl  io_restore_trace_psw
 631 io_restore_trace_psw:
 632         .long   0, io_restore_trace + 0x80000000
 633         .previous
 634 #endif
 635
 636 #
 637 # There is work todo, find out in which context we have been interrupted:
 638 # 1) if we return to user space we can do all _TIF_WORK_INT work
 639 # 2) if we return to kernel code and preemptive scheduling is enabled check
 640 #    the preemption counter and if it is zero call preempt_schedule_irq
 641 # Before any work can be done, a switch to the kernel stack is required.
 642 #
 643 io_work:
 644         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 645         bo      BASED(io_work_user)     # yes -> do resched & signal
 646 #ifdef CONFIG_PREEMPT
 647         # check for preemptive scheduling
 648         icm     %r0,15,__TI_precount(%r9)
 649         bnz     BASED(io_restore)       # preemption disabled
 650         # switch to kernel stack
 651         l       %r1,SP_R15(%r15)
 652         s       %r1,BASED(.Lc_spsize)
 653         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 654         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 655         lr      %r15,%r1
 656 io_resume_loop:
 657         l       %r1,BASED(.Lpreempt_schedule_irq)
 658         la      %r14,BASED(io_resume_loop)
 659         tm      __TI_flags+3(%r9),_TIF_NEED_RESCHED
 660         bor     %r1                     # call preempt_schedule_irq
 661 #endif
 662         b       BASED(io_restore)
 663
 664 #
 665 # Need to do work before returning to userspace, switch to kernel stack
 666 #
 667 io_work_user:
 668         l       %r1,__LC_KERNEL_STACK
 669         s       %r1,BASED(.Lc_spsize)
 670         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 671         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 672         lr      %r15,%r1
 673 #
 674 # One of the work bits is on. Find out which one.
 675 # Checked are: _TIF_SIGPENDING, _TIF_NOTIFY_RESUME, _TIF_NEED_RESCHED
 676 #               and _TIF_MCCK_PENDING
 677 #
 678 io_work_loop:
 679         tm      __TI_flags+3(%r9),_TIF_MCCK_PENDING
 680         bo      BASED(io_mcck_pending)
 681         tm      __TI_flags+3(%r9),_TIF_NEED_RESCHED
 682         bo      BASED(io_reschedule)
 683         tm      __TI_flags+3(%r9),_TIF_SIGPENDING
 684         bo      BASED(io_sigpending)
 685         tm      __TI_flags+3(%r9),_TIF_NOTIFY_RESUME
 686         bo      BASED(io_notify_resume)
 687         b       BASED(io_return)        # beware of critical section cleanup
 688
 689 #
 690 # _TIF_MCCK_PENDING is set, call handler
 691 #
 692 io_mcck_pending:
 693         l       %r1,BASED(.Ls390_handle_mcck)
 694         basr    %r14,%r1                # TIF bit will be cleared by handler
 695         b       BASED(io_work_loop)
 696
 697 #
 698 # _TIF_NEED_RESCHED is set, call schedule
 699 #
 700 io_reschedule:
 701         TRACE_IRQS_ON
 702         l       %r1,BASED(.Lschedule)
 703         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 704         basr    %r14,%r1                # call scheduler
 705         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 706         TRACE_IRQS_OFF
 707         b       BASED(io_work_loop)
 708
 709 #
 710 # _TIF_SIGPENDING is set, call do_signal
 711 #
 712 io_sigpending:
 713         TRACE_IRQS_ON
 714         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 715         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 716         l       %r1,BASED(.Ldo_signal)
 717         basr    %r14,%r1                # call do_signal
 718         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 719         TRACE_IRQS_OFF
 720         b       BASED(io_work_loop)
 721
 722 #
 723 # _TIF_SIGPENDING is set, call do_signal
 724 #
 725 io_notify_resume:
 726         TRACE_IRQS_ON
 727         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 728         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 729         l       %r1,BASED(.Ldo_notify_resume)
 730         basr    %r14,%r1                # call do_signal
 731         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 732         TRACE_IRQS_OFF
 733         b       BASED(io_work_loop)
 734
 735 /*
 736  * External interrupt handler routine
 737  */
 738
 739         .globl  ext_int_handler
 740 ext_int_handler:
 741         stck    __LC_INT_CLOCK
 742         stpt    __LC_ASYNC_ENTER_TIMER
 743         SAVE_ALL_BASE __LC_SAVE_AREA+16
 744         SAVE_ALL_ASYNC __LC_EXT_OLD_PSW,__LC_SAVE_AREA+16
 745         CREATE_STACK_FRAME __LC_EXT_OLD_PSW,__LC_SAVE_AREA+16
 746         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 747         bz      BASED(ext_no_vtime)
 748         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 749         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 750         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 751 ext_no_vtime:
 752         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 753         TRACE_IRQS_OFF
 754         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 755         lh      %r3,__LC_EXT_INT_CODE   # get interruption code
 756         l       %r1,BASED(.Ldo_extint)
 757         basr    %r14,%r1
 758         b       BASED(io_return)
 759
 760 __critical_end:
 761
 762 /*
 763  * Machine check handler routines
 764  */
 765
 766         .globl mcck_int_handler
 767 mcck_int_handler:
 768         stck    __LC_INT_CLOCK
 769         spt     __LC_CPU_TIMER_SAVE_AREA        # revalidate cpu timer
 770         lm      %r0,%r15,__LC_GPREGS_SAVE_AREA  # revalidate gprs
 771         SAVE_ALL_BASE __LC_SAVE_AREA+32
 772         la      %r12,__LC_MCK_OLD_PSW
 773         tm      __LC_MCCK_CODE,0x80     # system damage?
 774         bo      BASED(mcck_int_main)    # yes -> rest of mcck code invalid
 775         mvc     __LC_SAVE_AREA+52(8),__LC_ASYNC_ENTER_TIMER
 776         mvc     __LC_ASYNC_ENTER_TIMER(8),__LC_CPU_TIMER_SAVE_AREA
 777         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
 778         bo      BASED(1f)
 779         la      %r14,__LC_SYNC_ENTER_TIMER
 780         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
 781         bl      BASED(0f)
 782         la      %r14,__LC_ASYNC_ENTER_TIMER
 783 0:      clc     0(8,%r14),__LC_EXIT_TIMER
 784         bl      BASED(0f)
 785         la      %r14,__LC_EXIT_TIMER
 786 0:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
 787         bl      BASED(0f)
 788         la      %r14,__LC_LAST_UPDATE_TIMER
 789 0:      spt     0(%r14)
 790         mvc     __LC_ASYNC_ENTER_TIMER(8),0(%r14)
 791 1:      tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
 792         bno     BASED(mcck_int_main)    # no -> skip cleanup critical
 793         tm      __LC_MCK_OLD_PSW+1,0x01 # test problem state bit
 794         bnz     BASED(mcck_int_main)    # from user -> load async stack
 795         clc     __LC_MCK_OLD_PSW+4(4),BASED(.Lcritical_end)
 796         bhe     BASED(mcck_int_main)
 797         clc     __LC_MCK_OLD_PSW+4(4),BASED(.Lcritical_start)
 798         bl      BASED(mcck_int_main)
 799         l       %r14,BASED(.Lcleanup_critical)
 800         basr    %r14,%r14
 801 mcck_int_main:
 802         l       %r14,__LC_PANIC_STACK   # are we already on the panic stack?
 803         slr     %r14,%r15
 804         sra     %r14,PAGE_SHIFT
 805         be      BASED(0f)
 806         l       %r15,__LC_PANIC_STACK   # load panic stack
 807 0:      CREATE_STACK_FRAME __LC_MCK_OLD_PSW,__LC_SAVE_AREA+32
 808         tm      __LC_MCCK_CODE+2,0x08   # mwp of old psw valid?
 809         bno     BASED(mcck_no_vtime)    # no -> skip cleanup critical
 810         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 811         bz      BASED(mcck_no_vtime)
 812         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 813         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 814         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 815 mcck_no_vtime:
 816         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 817         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 818         l       %r1,BASED(.Ls390_mcck)
 819         basr    %r14,%r1                # call machine check handler
 820         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 821         bno     BASED(mcck_return)
 822         l       %r1,__LC_KERNEL_STACK   # switch to kernel stack
 823         s       %r1,BASED(.Lc_spsize)
 824         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 825         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 826         lr      %r15,%r1
 827         stosm   __SF_EMPTY(%r15),0x04   # turn dat on
 828         tm      __TI_flags+3(%r9),_TIF_MCCK_PENDING
 829         bno     BASED(mcck_return)
 830         TRACE_IRQS_OFF
 831         l       %r1,BASED(.Ls390_handle_mcck)
 832         basr    %r14,%r1                # call machine check handler
 833         TRACE_IRQS_ON
 834 mcck_return:
 835         mvc     __LC_RETURN_MCCK_PSW(8),SP_PSW(%r15) # move return PSW
 836         ni      __LC_RETURN_MCCK_PSW+1,0xfd # clear wait state bit
 837         mvc     __LC_ASYNC_ENTER_TIMER(8),__LC_SAVE_AREA+52
 838         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
 839         bno     BASED(0f)
 840         lm      %r0,%r15,SP_R0(%r15)    # load gprs 0-15
 841         stpt    __LC_EXIT_TIMER
 842         lpsw    __LC_RETURN_MCCK_PSW    # back to caller
 843 0:      lm      %r0,%r15,SP_R0(%r15)    # load gprs 0-15
 844         lpsw    __LC_RETURN_MCCK_PSW    # back to caller
 845
 846         RESTORE_ALL __LC_RETURN_MCCK_PSW,0
 847
 848 /*
 849  * Restart interruption handler, kick starter for additional CPUs
 850  */
 851 #ifdef CONFIG_SMP
 852         __CPUINIT
 853         .globl restart_int_handler
 854 restart_int_handler:
 855         basr    %r1,0
 856 restart_base:
 857         spt     restart_vtime-restart_base(%r1)
 858         stck    __LC_LAST_UPDATE_CLOCK
 859         mvc     __LC_LAST_UPDATE_TIMER(8),restart_vtime-restart_base(%r1)
 860         mvc     __LC_EXIT_TIMER(8),restart_vtime-restart_base(%r1)
 861         l       %r15,__LC_SAVE_AREA+60  # load ksp
 862         lctl    %c0,%c15,__LC_CREGS_SAVE_AREA # get new ctl regs
 863         lam     %a0,%a15,__LC_AREGS_SAVE_AREA
 864         lm      %r6,%r15,__SF_GPRS(%r15) # load registers from clone
 865         l       %r1,__LC_THREAD_INFO
 866         mvc     __LC_USER_TIMER(8),__TI_user_timer(%r1)
 867         mvc     __LC_SYSTEM_TIMER(8),__TI_system_timer(%r1)
 868         xc      __LC_STEAL_TIMER(8),__LC_STEAL_TIMER
 869         stosm   __SF_EMPTY(%r15),0x04   # now we can turn dat on
 870         basr    %r14,0
 871         l       %r14,restart_addr-.(%r14)
 872         br      %r14                    # branch to start_secondary
 873 restart_addr:
 874         .long   start_secondary
 875         .align  8
 876 restart_vtime:
 877         .long   0x7fffffff,0xffffffff
 878         .previous
 879 #else
 880 /*
 881  * If we do not run with SMP enabled, let the new CPU crash ...
 882  */
 883         .globl restart_int_handler
 884 restart_int_handler:
 885         basr    %r1,0
 886 restart_base:
 887         lpsw    restart_crash-restart_base(%r1)
 888         .align  8
 889 restart_crash:
 890         .long   0x000a0000,0x00000000
 891 restart_go:
 892 #endif
 893
 894 #ifdef CONFIG_CHECK_STACK
 895 /*
 896  * The synchronous or the asynchronous stack overflowed. We are dead.
 897  * No need to properly save the registers, we are going to panic anyway.
 898  * Setup a pt_regs so that show_trace can provide a good call trace.
 899  */
 900 stack_overflow:
 901         l       %r15,__LC_PANIC_STACK   # change to panic stack
 902         sl      %r15,BASED(.Lc_spsize)
 903         mvc     SP_PSW(8,%r15),0(%r12)  # move user PSW to stack
 904         stm     %r0,%r11,SP_R0(%r15)    # store gprs %r0-%r11 to kernel stack
 905         la      %r1,__LC_SAVE_AREA
 906         ch      %r12,BASED(.L0x020)     # old psw addr == __LC_SVC_OLD_PSW ?
 907         be      BASED(0f)
 908         ch      %r12,BASED(.L0x028)     # old psw addr == __LC_PGM_OLD_PSW ?
 909         be      BASED(0f)
 910         la      %r1,__LC_SAVE_AREA+16
 911 0:      mvc     SP_R12(16,%r15),0(%r1)  # move %r12-%r15 to stack
 912         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15) # clear back chain
 913         l       %r1,BASED(1f)           # branch to kernel_stack_overflow
 914         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 915         br      %r1
 916 1:      .long   kernel_stack_overflow
 917 #endif
 918
 919 cleanup_table_system_call:
 920         .long   system_call + 0x80000000, sysc_do_svc + 0x80000000
 921 cleanup_table_sysc_return:
 922         .long   sysc_return + 0x80000000, sysc_leave + 0x80000000
 923 cleanup_table_sysc_leave:
 924         .long   sysc_leave + 0x80000000, sysc_done + 0x80000000
 925 cleanup_table_io_return:
 926         .long   io_return + 0x80000000, io_leave + 0x80000000
 927 cleanup_table_io_leave:
 928         .long   io_leave + 0x80000000, io_done + 0x80000000
 929
 930 cleanup_critical:
 931         clc     4(4,%r12),BASED(cleanup_table_system_call)
 932         bl      BASED(0f)
 933         clc     4(4,%r12),BASED(cleanup_table_system_call+4)
 934         bl      BASED(cleanup_system_call)
 935 0:
 936         clc     4(4,%r12),BASED(cleanup_table_sysc_return)
 937         bl      BASED(0f)
 938         clc     4(4,%r12),BASED(cleanup_table_sysc_return+4)
 939         bl      BASED(cleanup_sysc_return)
 940 0:
 941         clc     4(4,%r12),BASED(cleanup_table_sysc_leave)
 942         bl      BASED(0f)
 943         clc     4(4,%r12),BASED(cleanup_table_sysc_leave+4)
 944         bl      BASED(cleanup_sysc_leave)
 945 0:
 946         clc     4(4,%r12),BASED(cleanup_table_io_return)
 947         bl      BASED(0f)
 948         clc     4(4,%r12),BASED(cleanup_table_io_return+4)
 949         bl      BASED(cleanup_io_return)
 950 0:
 951         clc     4(4,%r12),BASED(cleanup_table_io_leave)
 952         bl      BASED(0f)
 953         clc     4(4,%r12),BASED(cleanup_table_io_leave+4)
 954         bl      BASED(cleanup_io_leave)
 955 0:
 956         br      %r14
 957
 958 cleanup_system_call:
 959         mvc     __LC_RETURN_PSW(8),0(%r12)
 960         c       %r12,BASED(.Lmck_old_psw)
 961         be      BASED(0f)
 962         la      %r12,__LC_SAVE_AREA+16
 963         b       BASED(1f)
 964 0:      la      %r12,__LC_SAVE_AREA+32
 965 1:
 966         clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+4)
 967         bh      BASED(0f)
 968         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
 969 0:      clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+8)
 970         bhe     BASED(cleanup_vtime)
 971         clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn)
 972         bh      BASED(0f)
 973         mvc     __LC_SAVE_AREA(16),0(%r12)
 974 0:      st      %r13,4(%r12)
 975         st      %r12,__LC_SAVE_AREA+48  # argh
 976         SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 977         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 978         l       %r12,__LC_SAVE_AREA+48  # argh
 979         st      %r15,12(%r12)
 980         lh      %r7,0x8a
 981 cleanup_vtime:
 982         clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+12)
 983         bhe     BASED(cleanup_stime)
 984         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 985 cleanup_stime:
 986         clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+16)
 987         bh      BASED(cleanup_update)
 988         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 989 cleanup_update:
 990         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 991         mvc     __LC_RETURN_PSW+4(4),BASED(cleanup_table_system_call+4)
 992         la      %r12,__LC_RETURN_PSW
 993         br      %r14
 994 cleanup_system_call_insn:
 995         .long   sysc_saveall + 0x80000000
 996         .long   system_call + 0x80000000
 997         .long   sysc_vtime + 0x80000000
 998         .long   sysc_stime + 0x80000000
 999         .long   sysc_update + 0x80000000
1000
1001 cleanup_sysc_return:
1002         mvc     __LC_RETURN_PSW(4),0(%r12)
1003         mvc     __LC_RETURN_PSW+4(4),BASED(cleanup_table_sysc_return)
1004         la      %r12,__LC_RETURN_PSW
1005         br      %r14
1006
1007 cleanup_sysc_leave:
1008         clc     4(4,%r12),BASED(cleanup_sysc_leave_insn)
1009         be      BASED(2f)
1010         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
1011         clc     4(4,%r12),BASED(cleanup_sysc_leave_insn+4)
1012         be      BASED(2f)
1013         mvc     __LC_RETURN_PSW(8),SP_PSW(%r15)
1014         c       %r12,BASED(.Lmck_old_psw)
1015         bne     BASED(0f)
1016         mvc     __LC_SAVE_AREA+32(16),SP_R12(%r15)
1017         b       BASED(1f)
1018 0:      mvc     __LC_SAVE_AREA+16(16),SP_R12(%r15)
1019 1:      lm      %r0,%r11,SP_R0(%r15)
1020         l       %r15,SP_R15(%r15)
1021 2:      la      %r12,__LC_RETURN_PSW
1022         br      %r14
1023 cleanup_sysc_leave_insn:
1024         .long   sysc_done - 4 + 0x80000000
1025         .long   sysc_done - 8 + 0x80000000
1026
1027 cleanup_io_return:
1028         mvc     __LC_RETURN_PSW(4),0(%r12)
1029         mvc     __LC_RETURN_PSW+4(4),BASED(cleanup_table_io_return)
1030         la      %r12,__LC_RETURN_PSW
1031         br      %r14
1032
1033 cleanup_io_leave:
1034         clc     4(4,%r12),BASED(cleanup_io_leave_insn)
1035         be      BASED(2f)
1036         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
1037         clc     4(4,%r12),BASED(cleanup_io_leave_insn+4)
1038         be      BASED(2f)
1039         mvc     __LC_RETURN_PSW(8),SP_PSW(%r15)
1040         c       %r12,BASED(.Lmck_old_psw)
1041         bne     BASED(0f)
1042         mvc     __LC_SAVE_AREA+32(16),SP_R12(%r15)
1043         b       BASED(1f)
1044 0:      mvc     __LC_SAVE_AREA+16(16),SP_R12(%r15)
1045 1:      lm      %r0,%r11,SP_R0(%r15)
1046         l       %r15,SP_R15(%r15)
1047 2:      la      %r12,__LC_RETURN_PSW
1048         br      %r14
1049 cleanup_io_leave_insn:
1050         .long   io_done - 4 + 0x80000000
1051         .long   io_done - 8 + 0x80000000
1052
1053 /*
1054  * Integer constants
1055  */
1056                 .align  4
1057 .Lc_spsize:     .long   SP_SIZE
1058 .Lc_overhead:   .long   STACK_FRAME_OVERHEAD
1059 .Lnr_syscalls:  .long   NR_syscalls
1060 .L0x018:        .short  0x018
1061 .L0x020:        .short  0x020
1062 .L0x028:        .short  0x028
1063 .L0x030:        .short  0x030
1064 .L0x038:        .short  0x038
1065 .Lc_1:          .long   1
1066
1067 /*
1068  * Symbol constants
1069  */
1070 .Ls390_mcck:    .long   s390_do_machine_check
1071 .Ls390_handle_mcck:
1072                 .long   s390_handle_mcck
1073 .Lmck_old_psw:  .long   __LC_MCK_OLD_PSW
1074 .Ldo_IRQ:       .long   do_IRQ
1075 .Ldo_extint:    .long   do_extint
1076 .Ldo_signal:    .long   do_signal
1077 .Ldo_notify_resume:
1078                 .long   do_notify_resume
1079 .Lhandle_per:   .long   do_single_step
1080 .Ldo_execve:    .long   do_execve
1081 .Lexecve_tail:  .long   execve_tail
1082 .Ljump_table:   .long   pgm_check_table
1083 .Lschedule:     .long   schedule
1084 #ifdef CONFIG_PREEMPT
1085 .Lpreempt_schedule_irq:
1086                 .long   preempt_schedule_irq
1087 #endif
1088 .Ltrace_entry:  .long   do_syscall_trace_enter
1089 .Ltrace_exit:   .long   do_syscall_trace_exit
1090 .Lschedtail:    .long   schedule_tail
1091 .Lsysc_table:   .long   sys_call_table
1092 #ifdef CONFIG_TRACE_IRQFLAGS
1093 .Ltrace_irq_on_caller:
1094                 .long   trace_hardirqs_on_caller
1095 .Ltrace_irq_off_caller:
1096                 .long   trace_hardirqs_off_caller
1097 #endif
1098 #ifdef CONFIG_LOCKDEP
1099 .Llockdep_sys_exit:
1100                 .long   lockdep_sys_exit
1101 #endif
1102 .Lcritical_start:
1103                 .long   __critical_start + 0x80000000
1104 .Lcritical_end:
1105                 .long   __critical_end + 0x80000000
1106 .Lcleanup_critical:
1107                 .long   cleanup_critical
1108
1109                 .section .rodata, "a"
1110 #define SYSCALL(esa,esame,emu)  .long esa
1111         .globl  sys_call_table
1112 sys_call_table:
1113 #include "syscalls.S"
1114 #undef SYSCALL