arch/x86/boot/compressed/head_32.S

   1 /*
   2  *  linux/boot/head.S
   3  *
   4  *  Copyright (C) 1991, 1992, 1993  Linus Torvalds
   5  */
   6
   7 /*
   8  *  head.S contains the 32-bit startup code.
   9  *
  10  * NOTE!!! Startup happens at absolute address 0x00001000, which is also where
  11  * the page directory will exist. The startup code will be overwritten by
  12  * the page directory. [According to comments etc elsewhere on a compressed
  13  * kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
  14  *
  15  * Page 0 is deliberately kept safe, since System Management Mode code in
  16  * laptops may need to access the BIOS data stored there.  This is also
  17  * useful for future device drivers that either access the BIOS via VM86
  18  * mode.
  19  */
  20
  21 /*
  22  * High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
  23  */
  24         .text
  25
  26 #include <linux/linkage.h>
  27 #include <asm/segment.h>
  28 #include <asm/page_types.h>
  29 #include <asm/boot.h>
  30 #include <asm/asm-offsets.h>
  31
  32         .section ".text.head","ax",@progbits
  33 ENTRY(startup_32)
  34         cld
  35         /*
  36          * Test KEEP_SEGMENTS flag to see if the bootloader is asking
  37          * us to not reload segments
  38          */
  39         testb   $(1<<6), BP_loadflags(%esi)
  40         jnz     1f
  41
  42         cli
  43         movl    $__BOOT_DS, %eax
  44         movl    %eax, %ds
  45         movl    %eax, %es
  46         movl    %eax, %fs
  47         movl    %eax, %gs
  48         movl    %eax, %ss
  49 1:
  50
  51 /*
  52  * Calculate the delta between where we were compiled to run
  53  * at and where we were actually loaded at.  This can only be done
  54  * with a short local call on x86.  Nothing  else will tell us what
  55  * address we are running at.  The reserved chunk of the real-mode
  56  * data at 0x1e4 (defined as a scratch field) are used as the stack
  57  * for this calculation. Only 4 bytes are needed.
  58  */
  59         leal    (BP_scratch+4)(%esi), %esp
  60         call    1f
  61 1:      popl    %ebp
  62         subl    $1b, %ebp
  63
  64 /*
  65  * %ebp contains the address we are loaded at by the boot loader and %ebx
  66  * contains the address where we should move the kernel image temporarily
  67  * for safe in-place decompression.
  68  */
  69
  70 #ifdef CONFIG_RELOCATABLE
  71         movl    %ebp, %ebx
  72         movl    BP_kernel_alignment(%esi), %eax
  73         decl    %eax
  74         addl    %eax, %ebx
  75         notl    %eax
  76         andl    %eax, %ebx
  77 #else
  78         movl    $LOAD_PHYSICAL_ADDR, %ebx
  79 #endif
  80
  81         /* Target address to relocate to for decompression */
  82         addl    $z_extract_offset, %ebx
  83
  84         /* Set up the stack */
  85         leal    boot_stack_end(%ebx), %esp
  86
  87         /* Zero EFLAGS */
  88         pushl   $0
  89         popfl
  90
  91 /*
  92  * Copy the compressed kernel to the end of our buffer
  93  * where decompression in place becomes safe.
  94  */
  95         pushl   %esi
  96         leal    (_bss-4)(%ebp), %esi
  97         leal    (_bss-4)(%ebx), %edi
  98         movl    $(_bss - startup_32), %ecx
  99         shrl    $2, %ecx
 100         std
 101         rep     movsl
 102         cld
 103         popl    %esi
 104
 105 /*
 106  * Jump to the relocated address.
 107  */
 108         leal    relocated(%ebx), %eax
 109         jmp     *%eax
 110 ENDPROC(startup_32)
 111
 112         .text
 113 relocated:
 114
 115 /*
 116  * Clear BSS (stack is currently empty)
 117  */
 118         xorl    %eax, %eax
 119         leal    _bss(%ebx), %edi
 120         leal    _ebss(%ebx), %ecx
 121         subl    %edi, %ecx
 122         shrl    $2, %ecx
 123         rep     stosl
 124
 125 /*
 126  * Do the decompression, and jump to the new kernel..
 127  */
 128         leal    z_extract_offset_negative(%ebx), %ebp
 129                                 /* push arguments for decompress_kernel: */
 130         pushl   %ebp            /* output address */
 131         pushl   $z_input_len    /* input_len */
 132         leal    input_data(%ebx), %eax
 133         pushl   %eax            /* input_data */
 134         leal    boot_heap(%ebx), %eax
 135         pushl   %eax            /* heap area */
 136         pushl   %esi            /* real mode pointer */
 137         call    decompress_kernel
 138         addl    $20, %esp
 139
 140 #if CONFIG_RELOCATABLE
 141 /*
 142  * Find the address of the relocations.
 143  */
 144         leal    z_output_len(%ebp), %edi
 145
 146 /*
 147  * Calculate the delta between where vmlinux was compiled to run
 148  * and where it was actually loaded.
 149  */
 150         movl    %ebp, %ebx
 151         subl    $LOAD_PHYSICAL_ADDR, %ebx
 152         jz      2f      /* Nothing to be done if loaded at compiled addr. */
 153 /*
 154  * Process relocations.
 155  */
 156
 157 1:      subl    $4, %edi
 158         movl    (%edi), %ecx
 159         testl   %ecx, %ecx
 160         jz      2f
 161         addl    %ebx, -__PAGE_OFFSET(%ebx, %ecx)
 162         jmp     1b
 163 2:
 164 #endif
 165
 166 /*
 167  * Jump to the decompressed kernel.
 168  */
 169         xorl    %ebx, %ebx
 170         jmp     *%ebp
 171
 172 /*
 173  * Stack and heap for uncompression
 174  */
 175         .bss
 176         .balign 4
 177 boot_heap:
 178         .fill BOOT_HEAP_SIZE, 1, 0
 179 boot_stack:
 180         .fill BOOT_STACK_SIZE, 1, 0
 181 boot_stack_end: