arch/x86/include/asm/calling.h

   1 /*
   2
   3  x86 function call convention, 64-bit:
   4  -------------------------------------
   5   arguments           |  callee-saved      | extra caller-saved | return
   6  [callee-clobbered]   |                    | [callee-clobbered] |
   7  ---------------------------------------------------------------------------
   8  rdi rsi rdx rcx r8-9 | rbx rbp [*] r12-15 | r10-11             | rax, rdx [**]
   9
  10  ( rsp is obviously invariant across normal function calls. (gcc can 'merge'
  11    functions when it sees tail-call optimization possibilities) rflags is
  12    clobbered. Leftover arguments are passed over the stack frame.)
  13
  14  [*]  In the frame-pointers case rbp is fixed to the stack frame.
  15
  16  [**] for struct return values wider than 64 bits the return convention is a
  17       bit more complex: up to 128 bits width we return small structures
  18       straight in rax, rdx. For structures larger than that (3 words or
  19       larger) the caller puts a pointer to an on-stack return struct
  20       [allocated in the caller's stack frame] into the first argument - i.e.
  21       into rdi. All other arguments shift up by one in this case.
  22       Fortunately this case is rare in the kernel.
  23
  24 For 32-bit we have the following conventions - kernel is built with
  25 -mregparm=3 and -freg-struct-return:
  26
  27  x86 function calling convention, 32-bit:
  28  ----------------------------------------
  29   arguments         | callee-saved        | extra caller-saved | return
  30  [callee-clobbered] |                     | [callee-clobbered] |
  31  -------------------------------------------------------------------------
  32  eax edx ecx        | ebx edi esi ebp [*] | <none>             | eax, edx [**]
  33
  34  ( here too esp is obviously invariant across normal function calls. eflags
  35    is clobbered. Leftover arguments are passed over the stack frame. )
  36
  37  [*]  In the frame-pointers case ebp is fixed to the stack frame.
  38
  39  [**] We build with -freg-struct-return, which on 32-bit means similar
  40       semantics as on 64-bit: edx can be used for a second return value
  41       (i.e. covering integer and structure sizes up to 64 bits) - after that
  42       it gets more complex and more expensive: 3-word or larger struct returns
  43       get done in the caller's frame and the pointer to the return struct goes
  44       into regparm0, i.e. eax - the other arguments shift up and the
  45       function's register parameters degenerate to regparm=2 in essence.
  46
  47 */
  48
  49 #include <asm/dwarf2.h>
  50
  51 #ifdef CONFIG_X86_64
  52
  53 /*
  54  * 64-bit system call stack frame layout defines and helpers,
  55  * for assembly code:
  56  */
  57
  58 #define R15               0
  59 #define R14               8
  60 #define R13              16
  61 #define R12              24
  62 #define RBP              32
  63 #define RBX              40
  64
  65 /* arguments: interrupts/non tracing syscalls only save up to here: */
  66 #define R11              48
  67 #define R10              56
  68 #define R9               64
  69 #define R8               72
  70 #define RAX              80
  71 #define RCX              88
  72 #define RDX              96
  73 #define RSI             104
  74 #define RDI             112
  75 #define ORIG_RAX        120       /* + error_code */
  76 /* end of arguments */
  77
  78 /* cpu exception frame or undefined in case of fast syscall: */
  79 #define RIP             128
  80 #define CS              136
  81 #define EFLAGS          144
  82 #define RSP             152
  83 #define SS              160
  84
  85 #define ARGOFFSET       R11
  86 #define SWFRAME         ORIG_RAX
  87
  88         .macro SAVE_ARGS addskip=0, save_rcx=1, save_r891011=1, rax_enosys=0
  89         subq  $9*8+\addskip, %rsp
  90         CFI_ADJUST_CFA_OFFSET   9*8+\addskip
  91         movq_cfi rdi, 8*8
  92         movq_cfi rsi, 7*8
  93         movq_cfi rdx, 6*8
  94
  95         .if \save_rcx
  96         movq_cfi rcx, 5*8
  97         .endif
  98
  99         .if \rax_enosys
 100         movq $-ENOSYS, 4*8(%rsp)
 101         .else
 102         movq_cfi rax, 4*8
 103         .endif
 104
 105         .if \save_r891011
 106         movq_cfi r8,  3*8
 107         movq_cfi r9,  2*8
 108         movq_cfi r10, 1*8
 109         movq_cfi r11, 0*8
 110         .endif
 111
 112         .endm
 113
 114 #define ARG_SKIP        (9*8)
 115
 116         .macro RESTORE_ARGS rstor_rax=1, addskip=0, rstor_rcx=1, rstor_r11=1, \
 117                             rstor_r8910=1, rstor_rdx=1
 118         .if \rstor_r11
 119         movq_cfi_restore 0*8, r11
 120         .endif
 121
 122         .if \rstor_r8910
 123         movq_cfi_restore 1*8, r10
 124         movq_cfi_restore 2*8, r9
 125         movq_cfi_restore 3*8, r8
 126         .endif
 127
 128         .if \rstor_rax
 129         movq_cfi_restore 4*8, rax
 130         .endif
 131
 132         .if \rstor_rcx
 133         movq_cfi_restore 5*8, rcx
 134         .endif
 135
 136         .if \rstor_rdx
 137         movq_cfi_restore 6*8, rdx
 138         .endif
 139
 140         movq_cfi_restore 7*8, rsi
 141         movq_cfi_restore 8*8, rdi
 142
 143         .if ARG_SKIP+\addskip > 0
 144         addq $ARG_SKIP+\addskip, %rsp
 145         CFI_ADJUST_CFA_OFFSET   -(ARG_SKIP+\addskip)
 146         .endif
 147         .endm
 148
 149         .macro LOAD_ARGS offset, skiprax=0
 150         movq \offset(%rsp),    %r11
 151         movq \offset+8(%rsp),  %r10
 152         movq \offset+16(%rsp), %r9
 153         movq \offset+24(%rsp), %r8
 154         movq \offset+40(%rsp), %rcx
 155         movq \offset+48(%rsp), %rdx
 156         movq \offset+56(%rsp), %rsi
 157         movq \offset+64(%rsp), %rdi
 158         .if \skiprax
 159         .else
 160         movq \offset+72(%rsp), %rax
 161         .endif
 162         .endm
 163
 164 #define REST_SKIP       (6*8)
 165
 166         .macro SAVE_REST
 167         subq $REST_SKIP, %rsp
 168         CFI_ADJUST_CFA_OFFSET   REST_SKIP
 169         movq_cfi rbx, 5*8
 170         movq_cfi rbp, 4*8
 171         movq_cfi r12, 3*8
 172         movq_cfi r13, 2*8
 173         movq_cfi r14, 1*8
 174         movq_cfi r15, 0*8
 175         .endm
 176
 177         .macro RESTORE_REST
 178         movq_cfi_restore 0*8, r15
 179         movq_cfi_restore 1*8, r14
 180         movq_cfi_restore 2*8, r13
 181         movq_cfi_restore 3*8, r12
 182         movq_cfi_restore 4*8, rbp
 183         movq_cfi_restore 5*8, rbx
 184         addq $REST_SKIP, %rsp
 185         CFI_ADJUST_CFA_OFFSET   -(REST_SKIP)
 186         .endm
 187
 188         .macro SAVE_ALL
 189         SAVE_ARGS
 190         SAVE_REST
 191         .endm
 192
 193         .macro RESTORE_ALL addskip=0
 194         RESTORE_REST
 195         RESTORE_ARGS 1, \addskip
 196         .endm
 197
 198         .macro icebp
 199         .byte 0xf1
 200         .endm
 201
 202 #else /* CONFIG_X86_64 */
 203
 204 /*
 205  * For 32bit only simplified versions of SAVE_ALL/RESTORE_ALL. These
 206  * are different from the entry_32.S versions in not changing the segment
 207  * registers. So only suitable for in kernel use, not when transitioning
 208  * from or to user space. The resulting stack frame is not a standard
 209  * pt_regs frame. The main use case is calling C code from assembler
 210  * when all the registers need to be preserved.
 211  */
 212
 213         .macro SAVE_ALL
 214         pushl_cfi %eax
 215         CFI_REL_OFFSET eax, 0
 216         pushl_cfi %ebp
 217         CFI_REL_OFFSET ebp, 0
 218         pushl_cfi %edi
 219         CFI_REL_OFFSET edi, 0
 220         pushl_cfi %esi
 221         CFI_REL_OFFSET esi, 0
 222         pushl_cfi %edx
 223         CFI_REL_OFFSET edx, 0
 224         pushl_cfi %ecx
 225         CFI_REL_OFFSET ecx, 0
 226         pushl_cfi %ebx
 227         CFI_REL_OFFSET ebx, 0
 228         .endm
 229
 230         .macro RESTORE_ALL
 231         popl_cfi %ebx
 232         CFI_RESTORE ebx
 233         popl_cfi %ecx
 234         CFI_RESTORE ecx
 235         popl_cfi %edx
 236         CFI_RESTORE edx
 237         popl_cfi %esi
 238         CFI_RESTORE esi
 239         popl_cfi %edi
 240         CFI_RESTORE edi
 241         popl_cfi %ebp
 242         CFI_RESTORE ebp
 243         popl_cfi %eax
 244         CFI_RESTORE eax
 245         .endm
 246
 247 #endif /* CONFIG_X86_64 */
 248