arch/x86/kernel/entry_32.S

   1 /*
   2  *
   3  *  Copyright (C) 1991, 1992  Linus Torvalds
   4  */
   5
   6 /*
   7  * entry.S contains the system-call and fault low-level handling routines.
   8  * This also contains the timer-interrupt handler, as well as all interrupts
   9  * and faults that can result in a task-switch.
  10  *
  11  * NOTE: This code handles signal-recognition, which happens every time
  12  * after a timer-interrupt and after each system call.
  13  *
  14  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  15  * on a 486.
  16  *
  17  * Stack layout in 'syscall_exit':
  18  *      ptrace needs to have all regs on the stack.
  19  *      if the order here is changed, it needs to be
  20  *      updated in fork.c:copy_process, signal.c:do_signal,
  21  *      ptrace.c and ptrace.h
  22  *
  23  *       0(%esp) - %ebx
  24  *       4(%esp) - %ecx
  25  *       8(%esp) - %edx
  26  *       C(%esp) - %esi
  27  *      10(%esp) - %edi
  28  *      14(%esp) - %ebp
  29  *      18(%esp) - %eax
  30  *      1C(%esp) - %ds
  31  *      20(%esp) - %es
  32  *      24(%esp) - %fs
  33  *      28(%esp) - %gs          saved iff !CONFIG_X86_32_LAZY_GS
  34  *      2C(%esp) - orig_eax
  35  *      30(%esp) - %eip
  36  *      34(%esp) - %cs
  37  *      38(%esp) - %eflags
  38  *      3C(%esp) - %oldesp
  39  *      40(%esp) - %oldss
  40  *
  41  * "current" is in register %ebx during any slow entries.
  42  */
  43
  44 #include <linux/linkage.h>
  45 #include <linux/err.h>
  46 #include <asm/thread_info.h>
  47 #include <asm/irqflags.h>
  48 #include <asm/errno.h>
  49 #include <asm/segment.h>
  50 #include <asm/smp.h>
  51 #include <asm/page_types.h>
  52 #include <asm/percpu.h>
  53 #include <asm/dwarf2.h>
  54 #include <asm/processor-flags.h>
  55 #include <asm/ftrace.h>
  56 #include <asm/irq_vectors.h>
  57 #include <asm/cpufeature.h>
  58 #include <asm/alternative-asm.h>
  59 #include <asm/asm.h>
  60
  61 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  62 #include <linux/elf-em.h>
  63 #define AUDIT_ARCH_I386         (EM_386|__AUDIT_ARCH_LE)
  64 #define __AUDIT_ARCH_LE    0x40000000
  65
  66 #ifndef CONFIG_AUDITSYSCALL
  67 #define sysenter_audit  syscall_trace_entry
  68 #define sysexit_audit   syscall_exit_work
  69 #endif
  70
  71         .section .entry.text, "ax"
  72
  73 /*
  74  * We use macros for low-level operations which need to be overridden
  75  * for paravirtualization.  The following will never clobber any registers:
  76  *   INTERRUPT_RETURN (aka. "iret")
  77  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
  78  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
  79  *
  80  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
  81  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
  82  * Allowing a register to be clobbered can shrink the paravirt replacement
  83  * enough to patch inline, increasing performance.
  84  */
  85
  86 #ifdef CONFIG_PREEMPT
  87 #define preempt_stop(clobbers)  DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
  88 #else
  89 #define preempt_stop(clobbers)
  90 #define resume_kernel           restore_all
  91 #endif
  92
  93 .macro TRACE_IRQS_IRET
  94 #ifdef CONFIG_TRACE_IRQFLAGS
  95         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)     # interrupts off?
  96         jz 1f
  97         TRACE_IRQS_ON
  98 1:
  99 #endif
 100 .endm
 101
 102 /*
 103  * User gs save/restore
 104  *
 105  * %gs is used for userland TLS and kernel only uses it for stack
 106  * canary which is required to be at %gs:20 by gcc.  Read the comment
 107  * at the top of stackprotector.h for more info.
 108  *
 109  * Local labels 98 and 99 are used.
 110  */
 111 #ifdef CONFIG_X86_32_LAZY_GS
 112
 113  /* unfortunately push/pop can't be no-op */
 114 .macro PUSH_GS
 115         pushl_cfi $0
 116 .endm
 117 .macro POP_GS pop=0
 118         addl $(4 + \pop), %esp
 119         CFI_ADJUST_CFA_OFFSET -(4 + \pop)
 120 .endm
 121 .macro POP_GS_EX
 122 .endm
 123
 124  /* all the rest are no-op */
 125 .macro PTGS_TO_GS
 126 .endm
 127 .macro PTGS_TO_GS_EX
 128 .endm
 129 .macro GS_TO_REG reg
 130 .endm
 131 .macro REG_TO_PTGS reg
 132 .endm
 133 .macro SET_KERNEL_GS reg
 134 .endm
 135
 136 #else   /* CONFIG_X86_32_LAZY_GS */
 137
 138 .macro PUSH_GS
 139         pushl_cfi %gs
 140         /*CFI_REL_OFFSET gs, 0*/
 141 .endm
 142
 143 .macro POP_GS pop=0
 144 98:     popl_cfi %gs
 145         /*CFI_RESTORE gs*/
 146   .if \pop <> 0
 147         add $\pop, %esp
 148         CFI_ADJUST_CFA_OFFSET -\pop
 149   .endif
 150 .endm
 151 .macro POP_GS_EX
 152 .pushsection .fixup, "ax"
 153 99:     movl $0, (%esp)
 154         jmp 98b
 155 .popsection
 156         _ASM_EXTABLE(98b,99b)
 157 .endm
 158
 159 .macro PTGS_TO_GS
 160 98:     mov PT_GS(%esp), %gs
 161 .endm
 162 .macro PTGS_TO_GS_EX
 163 .pushsection .fixup, "ax"
 164 99:     movl $0, PT_GS(%esp)
 165         jmp 98b
 166 .popsection
 167         _ASM_EXTABLE(98b,99b)
 168 .endm
 169
 170 .macro GS_TO_REG reg
 171         movl %gs, \reg
 172         /*CFI_REGISTER gs, \reg*/
 173 .endm
 174 .macro REG_TO_PTGS reg
 175         movl \reg, PT_GS(%esp)
 176         /*CFI_REL_OFFSET gs, PT_GS*/
 177 .endm
 178 .macro SET_KERNEL_GS reg
 179         movl $(__KERNEL_STACK_CANARY), \reg
 180         movl \reg, %gs
 181 .endm
 182
 183 #endif  /* CONFIG_X86_32_LAZY_GS */
 184
 185 .macro SAVE_ALL
 186         cld
 187         PUSH_GS
 188         pushl_cfi %fs
 189         /*CFI_REL_OFFSET fs, 0;*/
 190         pushl_cfi %es
 191         /*CFI_REL_OFFSET es, 0;*/
 192         pushl_cfi %ds
 193         /*CFI_REL_OFFSET ds, 0;*/
 194         pushl_cfi %eax
 195         CFI_REL_OFFSET eax, 0
 196         pushl_cfi %ebp
 197         CFI_REL_OFFSET ebp, 0
 198         pushl_cfi %edi
 199         CFI_REL_OFFSET edi, 0
 200         pushl_cfi %esi
 201         CFI_REL_OFFSET esi, 0
 202         pushl_cfi %edx
 203         CFI_REL_OFFSET edx, 0
 204         pushl_cfi %ecx
 205         CFI_REL_OFFSET ecx, 0
 206         pushl_cfi %ebx
 207         CFI_REL_OFFSET ebx, 0
 208         movl $(__USER_DS), %edx
 209         movl %edx, %ds
 210         movl %edx, %es
 211         movl $(__KERNEL_PERCPU), %edx
 212         movl %edx, %fs
 213         SET_KERNEL_GS %edx
 214 .endm
 215
 216 .macro RESTORE_INT_REGS
 217         popl_cfi %ebx
 218         CFI_RESTORE ebx
 219         popl_cfi %ecx
 220         CFI_RESTORE ecx
 221         popl_cfi %edx
 222         CFI_RESTORE edx
 223         popl_cfi %esi
 224         CFI_RESTORE esi
 225         popl_cfi %edi
 226         CFI_RESTORE edi
 227         popl_cfi %ebp
 228         CFI_RESTORE ebp
 229         popl_cfi %eax
 230         CFI_RESTORE eax
 231 .endm
 232
 233 .macro RESTORE_REGS pop=0
 234         RESTORE_INT_REGS
 235 1:      popl_cfi %ds
 236         /*CFI_RESTORE ds;*/
 237 2:      popl_cfi %es
 238         /*CFI_RESTORE es;*/
 239 3:      popl_cfi %fs
 240         /*CFI_RESTORE fs;*/
 241         POP_GS \pop
 242 .pushsection .fixup, "ax"
 243 4:      movl $0, (%esp)
 244         jmp 1b
 245 5:      movl $0, (%esp)
 246         jmp 2b
 247 6:      movl $0, (%esp)
 248         jmp 3b
 249 .popsection
 250         _ASM_EXTABLE(1b,4b)
 251         _ASM_EXTABLE(2b,5b)
 252         _ASM_EXTABLE(3b,6b)
 253         POP_GS_EX
 254 .endm
 255
 256 .macro RING0_INT_FRAME
 257         CFI_STARTPROC simple
 258         CFI_SIGNAL_FRAME
 259         CFI_DEF_CFA esp, 3*4
 260         /*CFI_OFFSET cs, -2*4;*/
 261         CFI_OFFSET eip, -3*4
 262 .endm
 263
 264 .macro RING0_EC_FRAME
 265         CFI_STARTPROC simple
 266         CFI_SIGNAL_FRAME
 267         CFI_DEF_CFA esp, 4*4
 268         /*CFI_OFFSET cs, -2*4;*/
 269         CFI_OFFSET eip, -3*4
 270 .endm
 271
 272 .macro RING0_PTREGS_FRAME
 273         CFI_STARTPROC simple
 274         CFI_SIGNAL_FRAME
 275         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX
 276         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/
 277         CFI_OFFSET eip, PT_EIP-PT_OLDESP
 278         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/
 279         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/
 280         CFI_OFFSET eax, PT_EAX-PT_OLDESP
 281         CFI_OFFSET ebp, PT_EBP-PT_OLDESP
 282         CFI_OFFSET edi, PT_EDI-PT_OLDESP
 283         CFI_OFFSET esi, PT_ESI-PT_OLDESP
 284         CFI_OFFSET edx, PT_EDX-PT_OLDESP
 285         CFI_OFFSET ecx, PT_ECX-PT_OLDESP
 286         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
 287 .endm
 288
 289 ENTRY(ret_from_fork)
 290         CFI_STARTPROC
 291         pushl_cfi %eax
 292         call schedule_tail
 293         GET_THREAD_INFO(%ebp)
 294         popl_cfi %eax
 295         pushl_cfi $0x0202               # Reset kernel eflags
 296         popfl_cfi
 297         jmp syscall_exit
 298         CFI_ENDPROC
 299 END(ret_from_fork)
 300
 301 ENTRY(ret_from_kernel_execve)
 302         movl $0,PT_EAX(%eax)
 303         movl $PTREGS_SIZE, %ecx
 304         call memmove
 305         movl %eax, %esp
 306         GET_THREAD_INFO(%ebp)
 307         jmp syscall_exit
 308 END(ret_from_kernel_execve)
 309
 310 /*
 311  * Interrupt exit functions should be protected against kprobes
 312  */
 313         .pushsection .kprobes.text, "ax"
 314 /*
 315  * Return to user mode is not as complex as all this looks,
 316  * but we want the default path for a system call return to
 317  * go as quickly as possible which is why some of this is
 318  * less clear than it otherwise should be.
 319  */
 320
 321         # userspace resumption stub bypassing syscall exit tracing
 322         ALIGN
 323         RING0_PTREGS_FRAME
 324 ret_from_exception:
 325         preempt_stop(CLBR_ANY)
 326 ret_from_intr:
 327         GET_THREAD_INFO(%ebp)
 328 #ifdef CONFIG_VM86
 329         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
 330         movb PT_CS(%esp), %al
 331         andl $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
 332 #else
 333         /*
 334          * We can be coming here from child spawned by kernel_thread().
 335          */
 336         movl PT_CS(%esp), %eax
 337         andl $SEGMENT_RPL_MASK, %eax
 338 #endif
 339         cmpl $USER_RPL, %eax
 340         jb resume_kernel                # not returning to v8086 or userspace
 341
 342 ENTRY(resume_userspace)
 343         LOCKDEP_SYS_EXIT
 344         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 345                                         # setting need_resched or sigpending
 346                                         # between sampling and the iret
 347         TRACE_IRQS_OFF
 348         movl TI_flags(%ebp), %ecx
 349         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 350                                         # int/exception return?
 351         jne work_pending
 352         jmp restore_all
 353 END(ret_from_exception)
 354
 355 #ifdef CONFIG_PREEMPT
 356 ENTRY(resume_kernel)
 357         DISABLE_INTERRUPTS(CLBR_ANY)
 358         cmpl $0,TI_preempt_count(%ebp)  # non-zero preempt_count ?
 359         jnz restore_all
 360 need_resched:
 361         movl TI_flags(%ebp), %ecx       # need_resched set ?
 362         testb $_TIF_NEED_RESCHED, %cl
 363         jz restore_all
 364         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)    # interrupts off (exception path) ?
 365         jz restore_all
 366         call preempt_schedule_irq
 367         jmp need_resched
 368 END(resume_kernel)
 369 #endif
 370         CFI_ENDPROC
 371 /*
 372  * End of kprobes section
 373  */
 374         .popsection
 375
 376 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 377    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 378
 379         # sysenter call handler stub
 380 ENTRY(ia32_sysenter_target)
 381         CFI_STARTPROC simple
 382         CFI_SIGNAL_FRAME
 383         CFI_DEF_CFA esp, 0
 384         CFI_REGISTER esp, ebp
 385         movl TSS_sysenter_sp0(%esp),%esp
 386 sysenter_past_esp:
 387         /*
 388          * Interrupts are disabled here, but we can't trace it until
 389          * enough kernel state to call TRACE_IRQS_OFF can be called - but
 390          * we immediately enable interrupts at that point anyway.
 391          */
 392         pushl_cfi $__USER_DS
 393         /*CFI_REL_OFFSET ss, 0*/
 394         pushl_cfi %ebp
 395         CFI_REL_OFFSET esp, 0
 396         pushfl_cfi
 397         orl $X86_EFLAGS_IF, (%esp)
 398         pushl_cfi $__USER_CS
 399         /*CFI_REL_OFFSET cs, 0*/
 400         /*
 401          * Push current_thread_info()->sysenter_return to the stack.
 402          * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
 403          * pushed above; +8 corresponds to copy_thread's esp0 setting.
 404          */
 405         pushl_cfi ((TI_sysenter_return)-THREAD_SIZE+8+4*4)(%esp)
 406         CFI_REL_OFFSET eip, 0
 407
 408         pushl_cfi %eax
 409         SAVE_ALL
 410         ENABLE_INTERRUPTS(CLBR_NONE)
 411
 412 /*
 413  * Load the potential sixth argument from user stack.
 414  * Careful about security.
 415  */
 416         cmpl $__PAGE_OFFSET-3,%ebp
 417         jae syscall_fault
 418 1:      movl (%ebp),%ebp
 419         movl %ebp,PT_EBP(%esp)
 420         _ASM_EXTABLE(1b,syscall_fault)
 421
 422         GET_THREAD_INFO(%ebp)
 423
 424         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 425         jnz sysenter_audit
 426 sysenter_do_call:
 427         cmpl $(NR_syscalls), %eax
 428         jae syscall_badsys
 429         call *sys_call_table(,%eax,4)
 430         movl %eax,PT_EAX(%esp)
 431         LOCKDEP_SYS_EXIT
 432         DISABLE_INTERRUPTS(CLBR_ANY)
 433         TRACE_IRQS_OFF
 434         movl TI_flags(%ebp), %ecx
 435         testl $_TIF_ALLWORK_MASK, %ecx
 436         jne sysexit_audit
 437 sysenter_exit:
 438 /* if something modifies registers it must also disable sysexit */
 439         movl PT_EIP(%esp), %edx
 440         movl PT_OLDESP(%esp), %ecx
 441         xorl %ebp,%ebp
 442         TRACE_IRQS_ON
 443 1:      mov  PT_FS(%esp), %fs
 444         PTGS_TO_GS
 445         ENABLE_INTERRUPTS_SYSEXIT
 446
 447 #ifdef CONFIG_AUDITSYSCALL
 448 sysenter_audit:
 449         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 450         jnz syscall_trace_entry
 451         addl $4,%esp
 452         CFI_ADJUST_CFA_OFFSET -4
 453         /* %esi already in 8(%esp)         6th arg: 4th syscall arg */
 454         /* %edx already in 4(%esp)         5th arg: 3rd syscall arg */
 455         /* %ecx already in 0(%esp)         4th arg: 2nd syscall arg */
 456         movl %ebx,%ecx                  /* 3rd arg: 1st syscall arg */
 457         movl %eax,%edx                  /* 2nd arg: syscall number */
 458         movl $AUDIT_ARCH_I386,%eax      /* 1st arg: audit arch */
 459         call __audit_syscall_entry
 460         pushl_cfi %ebx
 461         movl PT_EAX(%esp),%eax          /* reload syscall number */
 462         jmp sysenter_do_call
 463
 464 sysexit_audit:
 465         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 466         jne syscall_exit_work
 467         TRACE_IRQS_ON
 468         ENABLE_INTERRUPTS(CLBR_ANY)
 469         movl %eax,%edx          /* second arg, syscall return value */
 470         cmpl $-MAX_ERRNO,%eax   /* is it an error ? */
 471         setbe %al               /* 1 if so, 0 if not */
 472         movzbl %al,%eax         /* zero-extend that */
 473         call __audit_syscall_exit
 474         DISABLE_INTERRUPTS(CLBR_ANY)
 475         TRACE_IRQS_OFF
 476         movl TI_flags(%ebp), %ecx
 477         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 478         jne syscall_exit_work
 479         movl PT_EAX(%esp),%eax  /* reload syscall return value */
 480         jmp sysenter_exit
 481 #endif
 482
 483         CFI_ENDPROC
 484 .pushsection .fixup,"ax"
 485 2:      movl $0,PT_FS(%esp)
 486         jmp 1b
 487 .popsection
 488         _ASM_EXTABLE(1b,2b)
 489         PTGS_TO_GS_EX
 490 ENDPROC(ia32_sysenter_target)
 491
 492 /*
 493  * syscall stub including irq exit should be protected against kprobes
 494  */
 495         .pushsection .kprobes.text, "ax"
 496         # system call handler stub
 497 ENTRY(system_call)
 498         RING0_INT_FRAME                 # can't unwind into user space anyway
 499         pushl_cfi %eax                  # save orig_eax
 500         SAVE_ALL
 501         GET_THREAD_INFO(%ebp)
 502                                         # system call tracing in operation / emulation
 503         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 504         jnz syscall_trace_entry
 505         cmpl $(NR_syscalls), %eax
 506         jae syscall_badsys
 507 syscall_call:
 508         call *sys_call_table(,%eax,4)
 509         movl %eax,PT_EAX(%esp)          # store the return value
 510 syscall_exit:
 511         LOCKDEP_SYS_EXIT
 512         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 513                                         # setting need_resched or sigpending
 514                                         # between sampling and the iret
 515         TRACE_IRQS_OFF
 516         movl TI_flags(%ebp), %ecx
 517         testl $_TIF_ALLWORK_MASK, %ecx  # current->work
 518         jne syscall_exit_work
 519
 520 restore_all:
 521         TRACE_IRQS_IRET
 522 restore_all_notrace:
 523         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
 524         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 525         # are returning to the kernel.
 526         # See comments in process.c:copy_thread() for details.
 527         movb PT_OLDSS(%esp), %ah
 528         movb PT_CS(%esp), %al
 529         andl $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 530         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
 531         CFI_REMEMBER_STATE
 532         je ldt_ss                       # returning to user-space with LDT SS
 533 restore_nocheck:
 534         RESTORE_REGS 4                  # skip orig_eax/error_code
 535 irq_return:
 536         INTERRUPT_RETURN
 537 .section .fixup,"ax"
 538 ENTRY(iret_exc)
 539         pushl $0                        # no error code
 540         pushl $do_iret_error
 541         jmp error_code
 542 .previous
 543         _ASM_EXTABLE(irq_return,iret_exc)
 544
 545         CFI_RESTORE_STATE
 546 ldt_ss:
 547         larl PT_OLDSS(%esp), %eax
 548         jnz restore_nocheck
 549         testl $0x00400000, %eax         # returning to 32bit stack?
 550         jnz restore_nocheck             # allright, normal return
 551
 552 #ifdef CONFIG_PARAVIRT
 553         /*
 554          * The kernel can't run on a non-flat stack if paravirt mode
 555          * is active.  Rather than try to fixup the high bits of
 556          * ESP, bypass this code entirely.  This may break DOSemu
 557          * and/or Wine support in a paravirt VM, although the option
 558          * is still available to implement the setting of the high
 559          * 16-bits in the INTERRUPT_RETURN paravirt-op.
 560          */
 561         cmpl $0, pv_info+PARAVIRT_enabled
 562         jne restore_nocheck
 563 #endif
 564
 565 /*
 566  * Setup and switch to ESPFIX stack
 567  *
 568  * We're returning to userspace with a 16 bit stack. The CPU will not
 569  * restore the high word of ESP for us on executing iret... This is an
 570  * "official" bug of all the x86-compatible CPUs, which we can work
 571  * around to make dosemu and wine happy. We do this by preloading the
 572  * high word of ESP with the high word of the userspace ESP while
 573  * compensating for the offset by changing to the ESPFIX segment with
 574  * a base address that matches for the difference.
 575  */
 576 #define GDT_ESPFIX_SS PER_CPU_VAR(gdt_page) + (GDT_ENTRY_ESPFIX_SS * 8)
 577         mov %esp, %edx                  /* load kernel esp */
 578         mov PT_OLDESP(%esp), %eax       /* load userspace esp */
 579         mov %dx, %ax                    /* eax: new kernel esp */
 580         sub %eax, %edx                  /* offset (low word is 0) */
 581         shr $16, %edx
 582         mov %dl, GDT_ESPFIX_SS + 4 /* bits 16..23 */
 583         mov %dh, GDT_ESPFIX_SS + 7 /* bits 24..31 */
 584         pushl_cfi $__ESPFIX_SS
 585         pushl_cfi %eax                  /* new kernel esp */
 586         /* Disable interrupts, but do not irqtrace this section: we
 587          * will soon execute iret and the tracer was already set to
 588          * the irqstate after the iret */
 589         DISABLE_INTERRUPTS(CLBR_EAX)
 590         lss (%esp), %esp                /* switch to espfix segment */
 591         CFI_ADJUST_CFA_OFFSET -8
 592         jmp restore_nocheck
 593         CFI_ENDPROC
 594 ENDPROC(system_call)
 595
 596         # perform work that needs to be done immediately before resumption
 597         ALIGN
 598         RING0_PTREGS_FRAME              # can't unwind into user space anyway
 599 work_pending:
 600         testb $_TIF_NEED_RESCHED, %cl
 601         jz work_notifysig
 602 work_resched:
 603         call schedule
 604         LOCKDEP_SYS_EXIT
 605         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 606                                         # setting need_resched or sigpending
 607                                         # between sampling and the iret
 608         TRACE_IRQS_OFF
 609         movl TI_flags(%ebp), %ecx
 610         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 611                                         # than syscall tracing?
 612         jz restore_all
 613         testb $_TIF_NEED_RESCHED, %cl
 614         jnz work_resched
 615
 616 work_notifysig:                         # deal with pending signals and
 617                                         # notify-resume requests
 618 #ifdef CONFIG_VM86
 619         testl $X86_EFLAGS_VM, PT_EFLAGS(%esp)
 620         movl %esp, %eax
 621         jne work_notifysig_v86          # returning to kernel-space or
 622                                         # vm86-space
 623 1:
 624 #else
 625         movl %esp, %eax
 626 #endif
 627         TRACE_IRQS_ON
 628         ENABLE_INTERRUPTS(CLBR_NONE)
 629         movb PT_CS(%esp), %bl
 630         andb $SEGMENT_RPL_MASK, %bl
 631         cmpb $USER_RPL, %bl
 632         jb resume_kernel
 633         xorl %edx, %edx
 634         call do_notify_resume
 635         jmp resume_userspace
 636
 637 #ifdef CONFIG_VM86
 638         ALIGN
 639 work_notifysig_v86:
 640         pushl_cfi %ecx                  # save ti_flags for do_notify_resume
 641         call save_v86_state             # %eax contains pt_regs pointer
 642         popl_cfi %ecx
 643         movl %eax, %esp
 644         jmp 1b
 645 #endif
 646 END(work_pending)
 647
 648         # perform syscall exit tracing
 649         ALIGN
 650 syscall_trace_entry:
 651         movl $-ENOSYS,PT_EAX(%esp)
 652         movl %esp, %eax
 653         call syscall_trace_enter
 654         /* What it returned is what we'll actually use.  */
 655         cmpl $(NR_syscalls), %eax
 656         jnae syscall_call
 657         jmp syscall_exit
 658 END(syscall_trace_entry)
 659
 660         # perform syscall exit tracing
 661         ALIGN
 662 syscall_exit_work:
 663         testl $_TIF_WORK_SYSCALL_EXIT, %ecx
 664         jz work_pending
 665         TRACE_IRQS_ON
 666         ENABLE_INTERRUPTS(CLBR_ANY)     # could let syscall_trace_leave() call
 667                                         # schedule() instead
 668         movl %esp, %eax
 669         call syscall_trace_leave
 670         jmp resume_userspace
 671 END(syscall_exit_work)
 672         CFI_ENDPROC
 673
 674         RING0_INT_FRAME                 # can't unwind into user space anyway
 675 syscall_fault:
 676         GET_THREAD_INFO(%ebp)
 677         movl $-EFAULT,PT_EAX(%esp)
 678         jmp resume_userspace
 679 END(syscall_fault)
 680
 681 syscall_badsys:
 682         movl $-ENOSYS,PT_EAX(%esp)
 683         jmp resume_userspace
 684 END(syscall_badsys)
 685         CFI_ENDPROC
 686 /*
 687  * End of kprobes section
 688  */
 689         .popsection
 690
 691 /*
 692  * System calls that need a pt_regs pointer.
 693  */
 694 #define PTREGSCALL0(name) \
 695 ENTRY(ptregs_##name) ;  \
 696         leal 4(%esp),%eax; \
 697         jmp sys_##name; \
 698 ENDPROC(ptregs_##name)
 699
 700 #define PTREGSCALL1(name) \
 701 ENTRY(ptregs_##name) ; \
 702         leal 4(%esp),%edx; \
 703         movl (PT_EBX+4)(%esp),%eax; \
 704         jmp sys_##name; \
 705 ENDPROC(ptregs_##name)
 706
 707 #define PTREGSCALL2(name) \
 708 ENTRY(ptregs_##name) ; \
 709         leal 4(%esp),%ecx; \
 710         movl (PT_ECX+4)(%esp),%edx; \
 711         movl (PT_EBX+4)(%esp),%eax; \
 712         jmp sys_##name; \
 713 ENDPROC(ptregs_##name)
 714
 715 #define PTREGSCALL3(name) \
 716 ENTRY(ptregs_##name) ; \
 717         CFI_STARTPROC; \
 718         leal 4(%esp),%eax; \
 719         pushl_cfi %eax; \
 720         movl PT_EDX(%eax),%ecx; \
 721         movl PT_ECX(%eax),%edx; \
 722         movl PT_EBX(%eax),%eax; \
 723         call sys_##name; \
 724         addl $4,%esp; \
 725         CFI_ADJUST_CFA_OFFSET -4; \
 726         ret; \
 727         CFI_ENDPROC; \
 728 ENDPROC(ptregs_##name)
 729
 730 PTREGSCALL1(iopl)
 731 PTREGSCALL0(fork)
 732 PTREGSCALL0(vfork)
 733 PTREGSCALL2(sigaltstack)
 734 PTREGSCALL0(sigreturn)
 735 PTREGSCALL0(rt_sigreturn)
 736 PTREGSCALL2(vm86)
 737 PTREGSCALL1(vm86old)
 738
 739 /* Clone is an oddball.  The 4th arg is in %edi */
 740 ENTRY(ptregs_clone)
 741         CFI_STARTPROC
 742         leal 4(%esp),%eax
 743         pushl_cfi %eax
 744         pushl_cfi PT_EDI(%eax)
 745         movl PT_EDX(%eax),%ecx
 746         movl PT_ECX(%eax),%edx
 747         movl PT_EBX(%eax),%eax
 748         call sys_clone
 749         addl $8,%esp
 750         CFI_ADJUST_CFA_OFFSET -8
 751         ret
 752         CFI_ENDPROC
 753 ENDPROC(ptregs_clone)
 754
 755 .macro FIXUP_ESPFIX_STACK
 756 /*
 757  * Switch back for ESPFIX stack to the normal zerobased stack
 758  *
 759  * We can't call C functions using the ESPFIX stack. This code reads
 760  * the high word of the segment base from the GDT and swiches to the
 761  * normal stack and adjusts ESP with the matching offset.
 762  */
 763         /* fixup the stack */
 764         mov GDT_ESPFIX_SS + 4, %al /* bits 16..23 */
 765         mov GDT_ESPFIX_SS + 7, %ah /* bits 24..31 */
 766         shl $16, %eax
 767         addl %esp, %eax                 /* the adjusted stack pointer */
 768         pushl_cfi $__KERNEL_DS
 769         pushl_cfi %eax
 770         lss (%esp), %esp                /* switch to the normal stack segment */
 771         CFI_ADJUST_CFA_OFFSET -8
 772 .endm
 773 .macro UNWIND_ESPFIX_STACK
 774         movl %ss, %eax
 775         /* see if on espfix stack */
 776         cmpw $__ESPFIX_SS, %ax
 777         jne 27f
 778         movl $__KERNEL_DS, %eax
 779         movl %eax, %ds
 780         movl %eax, %es
 781         /* switch to normal stack */
 782         FIXUP_ESPFIX_STACK
 783 27:
 784 .endm
 785
 786 /*
 787  * Build the entry stubs and pointer table with some assembler magic.
 788  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 789  * single cache line on all modern x86 implementations.
 790  */
 791 .section .init.rodata,"a"
 792 ENTRY(interrupt)
 793 .section .entry.text, "ax"
 794         .p2align 5
 795         .p2align CONFIG_X86_L1_CACHE_SHIFT
 796 ENTRY(irq_entries_start)
 797         RING0_INT_FRAME
 798 vector=FIRST_EXTERNAL_VECTOR
 799 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 800         .balign 32
 801   .rept 7
 802     .if vector < NR_VECTORS
 803       .if vector <> FIRST_EXTERNAL_VECTOR
 804         CFI_ADJUST_CFA_OFFSET -4
 805       .endif
 806 1:      pushl_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 807       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 808         jmp 2f
 809       .endif
 810       .previous
 811         .long 1b
 812       .section .entry.text, "ax"
 813 vector=vector+1
 814     .endif
 815   .endr
 816 2:      jmp common_interrupt
 817 .endr
 818 END(irq_entries_start)
 819
 820 .previous
 821 END(interrupt)
 822 .previous
 823
 824 /*
 825  * the CPU automatically disables interrupts when executing an IRQ vector,
 826  * so IRQ-flags tracing has to follow that:
 827  */
 828         .p2align CONFIG_X86_L1_CACHE_SHIFT
 829 common_interrupt:
 830         addl $-0x80,(%esp)      /* Adjust vector into the [-256,-1] range */
 831         SAVE_ALL
 832         TRACE_IRQS_OFF
 833         movl %esp,%eax
 834         call do_IRQ
 835         jmp ret_from_intr
 836 ENDPROC(common_interrupt)
 837         CFI_ENDPROC
 838
 839 /*
 840  *  Irq entries should be protected against kprobes
 841  */
 842         .pushsection .kprobes.text, "ax"
 843 #define BUILD_INTERRUPT3(name, nr, fn)  \
 844 ENTRY(name)                             \
 845         RING0_INT_FRAME;                \
 846         pushl_cfi $~(nr);               \
 847         SAVE_ALL;                       \
 848         TRACE_IRQS_OFF                  \
 849         movl %esp,%eax;                 \
 850         call fn;                        \
 851         jmp ret_from_intr;              \
 852         CFI_ENDPROC;                    \
 853 ENDPROC(name)
 854
 855 #define BUILD_INTERRUPT(name, nr)       BUILD_INTERRUPT3(name, nr, smp_##name)
 856
 857 /* The include is where all of the SMP etc. interrupts come from */
 858 #include <asm/entry_arch.h>
 859
 860 ENTRY(coprocessor_error)
 861         RING0_INT_FRAME
 862         pushl_cfi $0
 863         pushl_cfi $do_coprocessor_error
 864         jmp error_code
 865         CFI_ENDPROC
 866 END(coprocessor_error)
 867
 868 ENTRY(simd_coprocessor_error)
 869         RING0_INT_FRAME
 870         pushl_cfi $0
 871 #ifdef CONFIG_X86_INVD_BUG
 872         /* AMD 486 bug: invd from userspace calls exception 19 instead of #GP */
 873 661:    pushl_cfi $do_general_protection
 874 662:
 875 .section .altinstructions,"a"
 876         altinstruction_entry 661b, 663f, X86_FEATURE_XMM, 662b-661b, 664f-663f
 877 .previous
 878 .section .altinstr_replacement,"ax"
 879 663:    pushl $do_simd_coprocessor_error
 880 664:
 881 .previous
 882 #else
 883         pushl_cfi $do_simd_coprocessor_error
 884 #endif
 885         jmp error_code
 886         CFI_ENDPROC
 887 END(simd_coprocessor_error)
 888
 889 ENTRY(device_not_available)
 890         RING0_INT_FRAME
 891         pushl_cfi $-1                   # mark this as an int
 892         pushl_cfi $do_device_not_available
 893         jmp error_code
 894         CFI_ENDPROC
 895 END(device_not_available)
 896
 897 #ifdef CONFIG_PARAVIRT
 898 ENTRY(native_iret)
 899         iret
 900         _ASM_EXTABLE(native_iret, iret_exc)
 901 END(native_iret)
 902
 903 ENTRY(native_irq_enable_sysexit)
 904         sti
 905         sysexit
 906 END(native_irq_enable_sysexit)
 907 #endif
 908
 909 ENTRY(overflow)
 910         RING0_INT_FRAME
 911         pushl_cfi $0
 912         pushl_cfi $do_overflow
 913         jmp error_code
 914         CFI_ENDPROC
 915 END(overflow)
 916
 917 ENTRY(bounds)
 918         RING0_INT_FRAME
 919         pushl_cfi $0
 920         pushl_cfi $do_bounds
 921         jmp error_code
 922         CFI_ENDPROC
 923 END(bounds)
 924
 925 ENTRY(invalid_op)
 926         RING0_INT_FRAME
 927         pushl_cfi $0
 928         pushl_cfi $do_invalid_op
 929         jmp error_code
 930         CFI_ENDPROC
 931 END(invalid_op)
 932
 933 ENTRY(coprocessor_segment_overrun)
 934         RING0_INT_FRAME
 935         pushl_cfi $0
 936         pushl_cfi $do_coprocessor_segment_overrun
 937         jmp error_code
 938         CFI_ENDPROC
 939 END(coprocessor_segment_overrun)
 940
 941 ENTRY(invalid_TSS)
 942         RING0_EC_FRAME
 943         pushl_cfi $do_invalid_TSS
 944         jmp error_code
 945         CFI_ENDPROC
 946 END(invalid_TSS)
 947
 948 ENTRY(segment_not_present)
 949         RING0_EC_FRAME
 950         pushl_cfi $do_segment_not_present
 951         jmp error_code
 952         CFI_ENDPROC
 953 END(segment_not_present)
 954
 955 ENTRY(stack_segment)
 956         RING0_EC_FRAME
 957         pushl_cfi $do_stack_segment
 958         jmp error_code
 959         CFI_ENDPROC
 960 END(stack_segment)
 961
 962 ENTRY(alignment_check)
 963         RING0_EC_FRAME
 964         pushl_cfi $do_alignment_check
 965         jmp error_code
 966         CFI_ENDPROC
 967 END(alignment_check)
 968
 969 ENTRY(divide_error)
 970         RING0_INT_FRAME
 971         pushl_cfi $0                    # no error code
 972         pushl_cfi $do_divide_error
 973         jmp error_code
 974         CFI_ENDPROC
 975 END(divide_error)
 976
 977 #ifdef CONFIG_X86_MCE
 978 ENTRY(machine_check)
 979         RING0_INT_FRAME
 980         pushl_cfi $0
 981         pushl_cfi machine_check_vector
 982         jmp error_code
 983         CFI_ENDPROC
 984 END(machine_check)
 985 #endif
 986
 987 ENTRY(spurious_interrupt_bug)
 988         RING0_INT_FRAME
 989         pushl_cfi $0
 990         pushl_cfi $do_spurious_interrupt_bug
 991         jmp error_code
 992         CFI_ENDPROC
 993 END(spurious_interrupt_bug)
 994 /*
 995  * End of kprobes section
 996  */
 997         .popsection
 998
 999 ENTRY(kernel_thread_helper)
1000         pushl $0                # fake return address for unwinder
1001         CFI_STARTPROC
1002         movl %edi,%eax
1003         call *%esi
1004         call do_exit
1005         ud2                     # padding for call trace
1006         CFI_ENDPROC
1007 ENDPROC(kernel_thread_helper)
1008
1009 #ifdef CONFIG_XEN
1010 /* Xen doesn't set %esp to be precisely what the normal sysenter
1011    entrypoint expects, so fix it up before using the normal path. */
1012 ENTRY(xen_sysenter_target)
1013         RING0_INT_FRAME
1014         addl $5*4, %esp         /* remove xen-provided frame */
1015         CFI_ADJUST_CFA_OFFSET -5*4
1016         jmp sysenter_past_esp
1017         CFI_ENDPROC
1018
1019 ENTRY(xen_hypervisor_callback)
1020         CFI_STARTPROC
1021         pushl_cfi $0
1022         SAVE_ALL
1023         TRACE_IRQS_OFF
1024
1025         /* Check to see if we got the event in the critical
1026            region in xen_iret_direct, after we've reenabled
1027            events and checked for pending events.  This simulates
1028            iret instruction's behaviour where it delivers a
1029            pending interrupt when enabling interrupts. */
1030         movl PT_EIP(%esp),%eax
1031         cmpl $xen_iret_start_crit,%eax
1032         jb   1f
1033         cmpl $xen_iret_end_crit,%eax
1034         jae  1f
1035
1036         jmp  xen_iret_crit_fixup
1037
1038 ENTRY(xen_do_upcall)
1039 1:      mov %esp, %eax
1040         call xen_evtchn_do_upcall
1041         jmp  ret_from_intr
1042         CFI_ENDPROC
1043 ENDPROC(xen_hypervisor_callback)
1044
1045 # Hypervisor uses this for application faults while it executes.
1046 # We get here for two reasons:
1047 #  1. Fault while reloading DS, ES, FS or GS
1048 #  2. Fault while executing IRET
1049 # Category 1 we fix up by reattempting the load, and zeroing the segment
1050 # register if the load fails.
1051 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
1052 # normal Linux return path in this case because if we use the IRET hypercall
1053 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1054 # We distinguish between categories by maintaining a status value in EAX.
1055 ENTRY(xen_failsafe_callback)
1056         CFI_STARTPROC
1057         pushl_cfi %eax
1058         movl $1,%eax
1059 1:      mov 4(%esp),%ds
1060 2:      mov 8(%esp),%es
1061 3:      mov 12(%esp),%fs
1062 4:      mov 16(%esp),%gs
1063         testl %eax,%eax
1064         popl_cfi %eax
1065         lea 16(%esp),%esp
1066         CFI_ADJUST_CFA_OFFSET -16
1067         jz 5f
1068         addl $16,%esp
1069         jmp iret_exc            # EAX != 0 => Category 2 (Bad IRET)
1070 5:      pushl_cfi $0            # EAX == 0 => Category 1 (Bad segment)
1071         SAVE_ALL
1072         jmp ret_from_exception
1073         CFI_ENDPROC
1074
1075 .section .fixup,"ax"
1076 6:      xorl %eax,%eax
1077         movl %eax,4(%esp)
1078         jmp 1b
1079 7:      xorl %eax,%eax
1080         movl %eax,8(%esp)
1081         jmp 2b
1082 8:      xorl %eax,%eax
1083         movl %eax,12(%esp)
1084         jmp 3b
1085 9:      xorl %eax,%eax
1086         movl %eax,16(%esp)
1087         jmp 4b
1088 .previous
1089         _ASM_EXTABLE(1b,6b)
1090         _ASM_EXTABLE(2b,7b)
1091         _ASM_EXTABLE(3b,8b)
1092         _ASM_EXTABLE(4b,9b)
1093 ENDPROC(xen_failsafe_callback)
1094
1095 BUILD_INTERRUPT3(xen_hvm_callback_vector, XEN_HVM_EVTCHN_CALLBACK,
1096                 xen_evtchn_do_upcall)
1097
1098 #endif  /* CONFIG_XEN */
1099
1100 #ifdef CONFIG_FUNCTION_TRACER
1101 #ifdef CONFIG_DYNAMIC_FTRACE
1102
1103 ENTRY(mcount)
1104         ret
1105 END(mcount)
1106
1107 ENTRY(ftrace_caller)
1108         cmpl $0, function_trace_stop
1109         jne  ftrace_stub
1110
1111         pushl %eax
1112         pushl %ecx
1113         pushl %edx
1114         pushl $0        /* Pass NULL as regs pointer */
1115         movl 4*4(%esp), %eax
1116         movl 0x4(%ebp), %edx
1117         leal function_trace_op, %ecx
1118         subl $MCOUNT_INSN_SIZE, %eax
1119
1120 .globl ftrace_call
1121 ftrace_call:
1122         call ftrace_stub
1123
1124         addl $4,%esp    /* skip NULL pointer */
1125         popl %edx
1126         popl %ecx
1127         popl %eax
1128 ftrace_ret:
1129 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1130 .globl ftrace_graph_call
1131 ftrace_graph_call:
1132         jmp ftrace_stub
1133 #endif
1134
1135 .globl ftrace_stub
1136 ftrace_stub:
1137         ret
1138 END(ftrace_caller)
1139
1140 ENTRY(ftrace_regs_caller)
1141         pushf   /* push flags before compare (in cs location) */
1142         cmpl $0, function_trace_stop
1143         jne ftrace_restore_flags
1144
1145         /*
1146          * i386 does not save SS and ESP when coming from kernel.
1147          * Instead, to get sp, &regs->sp is used (see ptrace.h).
1148          * Unfortunately, that means eflags must be at the same location
1149          * as the current return ip is. We move the return ip into the
1150          * ip location, and move flags into the return ip location.
1151          */
1152         pushl 4(%esp)   /* save return ip into ip slot */
1153         subl $MCOUNT_INSN_SIZE, (%esp)  /* Adjust ip */
1154
1155         pushl $0        /* Load 0 into orig_ax */
1156         pushl %gs
1157         pushl %fs
1158         pushl %es
1159         pushl %ds
1160         pushl %eax
1161         pushl %ebp
1162         pushl %edi
1163         pushl %esi
1164         pushl %edx
1165         pushl %ecx
1166         pushl %ebx
1167
1168         movl 13*4(%esp), %eax   /* Get the saved flags */
1169         movl %eax, 14*4(%esp)   /* Move saved flags into regs->flags location */
1170                                 /* clobbering return ip */
1171         movl $__KERNEL_CS,13*4(%esp)
1172
1173         movl 12*4(%esp), %eax   /* Load ip (1st parameter) */
1174         movl 0x4(%ebp), %edx    /* Load parent ip (2nd parameter) */
1175         leal function_trace_op, %ecx /* Save ftrace_pos in 3rd parameter */
1176         pushl %esp              /* Save pt_regs as 4th parameter */
1177
1178 GLOBAL(ftrace_regs_call)
1179         call ftrace_stub
1180
1181         addl $4, %esp           /* Skip pt_regs */
1182         movl 14*4(%esp), %eax   /* Move flags back into cs */
1183         movl %eax, 13*4(%esp)   /* Needed to keep addl from modifying flags */
1184         movl 12*4(%esp), %eax   /* Get return ip from regs->ip */
1185         addl $MCOUNT_INSN_SIZE, %eax
1186         movl %eax, 14*4(%esp)   /* Put return ip back for ret */
1187
1188         popl %ebx
1189         popl %ecx
1190         popl %edx
1191         popl %esi
1192         popl %edi
1193         popl %ebp
1194         popl %eax
1195         popl %ds
1196         popl %es
1197         popl %fs
1198         popl %gs
1199         addl $8, %esp           /* Skip orig_ax and ip */
1200         popf                    /* Pop flags at end (no addl to corrupt flags) */
1201         jmp ftrace_ret
1202
1203 ftrace_restore_flags:
1204         popf
1205         jmp  ftrace_stub
1206 #else /* ! CONFIG_DYNAMIC_FTRACE */
1207
1208 ENTRY(mcount)
1209         cmpl $0, function_trace_stop
1210         jne  ftrace_stub
1211
1212         cmpl $ftrace_stub, ftrace_trace_function
1213         jnz trace
1214 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1215         cmpl $ftrace_stub, ftrace_graph_return
1216         jnz ftrace_graph_caller
1217
1218         cmpl $ftrace_graph_entry_stub, ftrace_graph_entry
1219         jnz ftrace_graph_caller
1220 #endif
1221 .globl ftrace_stub
1222 ftrace_stub:
1223         ret
1224
1225         /* taken from glibc */
1226 trace:
1227         pushl %eax
1228         pushl %ecx
1229         pushl %edx
1230         movl 0xc(%esp), %eax
1231         movl 0x4(%ebp), %edx
1232         subl $MCOUNT_INSN_SIZE, %eax
1233
1234         call *ftrace_trace_function
1235
1236         popl %edx
1237         popl %ecx
1238         popl %eax
1239         jmp ftrace_stub
1240 END(mcount)
1241 #endif /* CONFIG_DYNAMIC_FTRACE */
1242 #endif /* CONFIG_FUNCTION_TRACER */
1243
1244 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1245 ENTRY(ftrace_graph_caller)
1246         pushl %eax
1247         pushl %ecx
1248         pushl %edx
1249         movl 0xc(%esp), %edx
1250         lea 0x4(%ebp), %eax
1251         movl (%ebp), %ecx
1252         subl $MCOUNT_INSN_SIZE, %edx
1253         call prepare_ftrace_return
1254         popl %edx
1255         popl %ecx
1256         popl %eax
1257         ret
1258 END(ftrace_graph_caller)
1259
1260 .globl return_to_handler
1261 return_to_handler:
1262         pushl %eax
1263         pushl %edx
1264         movl %ebp, %eax
1265         call ftrace_return_to_handler
1266         movl %eax, %ecx
1267         popl %edx
1268         popl %eax
1269         jmp *%ecx
1270 #endif
1271
1272 /*
1273  * Some functions should be protected against kprobes
1274  */
1275         .pushsection .kprobes.text, "ax"
1276
1277 ENTRY(page_fault)
1278         RING0_EC_FRAME
1279         pushl_cfi $do_page_fault
1280         ALIGN
1281 error_code:
1282         /* the function address is in %gs's slot on the stack */
1283         pushl_cfi %fs
1284         /*CFI_REL_OFFSET fs, 0*/
1285         pushl_cfi %es
1286         /*CFI_REL_OFFSET es, 0*/
1287         pushl_cfi %ds
1288         /*CFI_REL_OFFSET ds, 0*/
1289         pushl_cfi %eax
1290         CFI_REL_OFFSET eax, 0
1291         pushl_cfi %ebp
1292         CFI_REL_OFFSET ebp, 0
1293         pushl_cfi %edi
1294         CFI_REL_OFFSET edi, 0
1295         pushl_cfi %esi
1296         CFI_REL_OFFSET esi, 0
1297         pushl_cfi %edx
1298         CFI_REL_OFFSET edx, 0
1299         pushl_cfi %ecx
1300         CFI_REL_OFFSET ecx, 0
1301         pushl_cfi %ebx
1302         CFI_REL_OFFSET ebx, 0
1303         cld
1304         movl $(__KERNEL_PERCPU), %ecx
1305         movl %ecx, %fs
1306         UNWIND_ESPFIX_STACK
1307         GS_TO_REG %ecx
1308         movl PT_GS(%esp), %edi          # get the function address
1309         movl PT_ORIG_EAX(%esp), %edx    # get the error code
1310         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
1311         REG_TO_PTGS %ecx
1312         SET_KERNEL_GS %ecx
1313         movl $(__USER_DS), %ecx
1314         movl %ecx, %ds
1315         movl %ecx, %es
1316         TRACE_IRQS_OFF
1317         movl %esp,%eax                  # pt_regs pointer
1318         call *%edi
1319         jmp ret_from_exception
1320         CFI_ENDPROC
1321 END(page_fault)
1322
1323 /*
1324  * Debug traps and NMI can happen at the one SYSENTER instruction
1325  * that sets up the real kernel stack. Check here, since we can't
1326  * allow the wrong stack to be used.
1327  *
1328  * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
1329  * already pushed 3 words if it hits on the sysenter instruction:
1330  * eflags, cs and eip.
1331  *
1332  * We just load the right stack, and push the three (known) values
1333  * by hand onto the new stack - while updating the return eip past
1334  * the instruction that would have done it for sysenter.
1335  */
1336 .macro FIX_STACK offset ok label
1337         cmpw $__KERNEL_CS, 4(%esp)
1338         jne \ok
1339 \label:
1340         movl TSS_sysenter_sp0 + \offset(%esp), %esp
1341         CFI_DEF_CFA esp, 0
1342         CFI_UNDEFINED eip
1343         pushfl_cfi
1344         pushl_cfi $__KERNEL_CS
1345         pushl_cfi $sysenter_past_esp
1346         CFI_REL_OFFSET eip, 0
1347 .endm
1348
1349 ENTRY(debug)
1350         RING0_INT_FRAME
1351         cmpl $ia32_sysenter_target,(%esp)
1352         jne debug_stack_correct
1353         FIX_STACK 12, debug_stack_correct, debug_esp_fix_insn
1354 debug_stack_correct:
1355         pushl_cfi $-1                   # mark this as an int
1356         SAVE_ALL
1357         TRACE_IRQS_OFF
1358         xorl %edx,%edx                  # error code 0
1359         movl %esp,%eax                  # pt_regs pointer
1360         call do_debug
1361         jmp ret_from_exception
1362         CFI_ENDPROC
1363 END(debug)
1364
1365 /*
1366  * NMI is doubly nasty. It can happen _while_ we're handling
1367  * a debug fault, and the debug fault hasn't yet been able to
1368  * clear up the stack. So we first check whether we got  an
1369  * NMI on the sysenter entry path, but after that we need to
1370  * check whether we got an NMI on the debug path where the debug
1371  * fault happened on the sysenter path.
1372  */
1373 ENTRY(nmi)
1374         RING0_INT_FRAME
1375         pushl_cfi %eax
1376         movl %ss, %eax
1377         cmpw $__ESPFIX_SS, %ax
1378         popl_cfi %eax
1379         je nmi_espfix_stack
1380         cmpl $ia32_sysenter_target,(%esp)
1381         je nmi_stack_fixup
1382         pushl_cfi %eax
1383         movl %esp,%eax
1384         /* Do not access memory above the end of our stack page,
1385          * it might not exist.
1386          */
1387         andl $(THREAD_SIZE-1),%eax
1388         cmpl $(THREAD_SIZE-20),%eax
1389         popl_cfi %eax
1390         jae nmi_stack_correct
1391         cmpl $ia32_sysenter_target,12(%esp)
1392         je nmi_debug_stack_check
1393 nmi_stack_correct:
1394         /* We have a RING0_INT_FRAME here */
1395         pushl_cfi %eax
1396         SAVE_ALL
1397         xorl %edx,%edx          # zero error code
1398         movl %esp,%eax          # pt_regs pointer
1399         call do_nmi
1400         jmp restore_all_notrace
1401         CFI_ENDPROC
1402
1403 nmi_stack_fixup:
1404         RING0_INT_FRAME
1405         FIX_STACK 12, nmi_stack_correct, 1
1406         jmp nmi_stack_correct
1407
1408 nmi_debug_stack_check:
1409         /* We have a RING0_INT_FRAME here */
1410         cmpw $__KERNEL_CS,16(%esp)
1411         jne nmi_stack_correct
1412         cmpl $debug,(%esp)
1413         jb nmi_stack_correct
1414         cmpl $debug_esp_fix_insn,(%esp)
1415         ja nmi_stack_correct
1416         FIX_STACK 24, nmi_stack_correct, 1
1417         jmp nmi_stack_correct
1418
1419 nmi_espfix_stack:
1420         /* We have a RING0_INT_FRAME here.
1421          *
1422          * create the pointer to lss back
1423          */
1424         pushl_cfi %ss
1425         pushl_cfi %esp
1426         addl $4, (%esp)
1427         /* copy the iret frame of 12 bytes */
1428         .rept 3
1429         pushl_cfi 16(%esp)
1430         .endr
1431         pushl_cfi %eax
1432         SAVE_ALL
1433         FIXUP_ESPFIX_STACK              # %eax == %esp
1434         xorl %edx,%edx                  # zero error code
1435         call do_nmi
1436         RESTORE_REGS
1437         lss 12+4(%esp), %esp            # back to espfix stack
1438         CFI_ADJUST_CFA_OFFSET -24
1439         jmp irq_return
1440         CFI_ENDPROC
1441 END(nmi)
1442
1443 ENTRY(int3)
1444         RING0_INT_FRAME
1445         pushl_cfi $-1                   # mark this as an int
1446         SAVE_ALL
1447         TRACE_IRQS_OFF
1448         xorl %edx,%edx          # zero error code
1449         movl %esp,%eax          # pt_regs pointer
1450         call do_int3
1451         jmp ret_from_exception
1452         CFI_ENDPROC
1453 END(int3)
1454
1455 ENTRY(general_protection)
1456         RING0_EC_FRAME
1457         pushl_cfi $do_general_protection
1458         jmp error_code
1459         CFI_ENDPROC
1460 END(general_protection)
1461
1462 #ifdef CONFIG_KVM_GUEST
1463 ENTRY(async_page_fault)
1464         RING0_EC_FRAME
1465         pushl_cfi $do_async_page_fault
1466         jmp error_code
1467         CFI_ENDPROC
1468 END(async_page_fault)
1469 #endif
1470
1471 /*
1472  * End of kprobes section
1473  */
1474         .popsection