arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after an interrupt and after each system call.
  14  *
  15  * Normal syscalls and interrupts don't save a full stack frame, this is
  16  * only done for syscall tracing, signals or fork/exec et.al.
  17  *
  18  * A note on terminology:
  19  * - top of stack: Architecture defined interrupt frame from SS to RIP
  20  * at the top of the kernel process stack.
  21  * - partial stack frame: partially saved registers upto R11.
  22  * - full stack frame: Like partial stack frame, but all register saved.
  23  *
  24  * Some macro usage:
  25  * - CFI macros are used to generate dwarf2 unwind information for better
  26  * backtraces. They don't change any code.
  27  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  28  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  29  * There are unfortunately lots of special cases where some registers
  30  * not touched. The macro is a big mess that should be cleaned up.
  31  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  32  * Gives a full stack frame.
  33  * - ENTRY/END Define functions in the symbol table.
  34  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  35  * frame that is otherwise undefined after a SYSCALL
  36  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  37  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  38  */
  39
  40 #include <linux/linkage.h>
  41 #include <asm/segment.h>
  42 #include <asm/cache.h>
  43 #include <asm/errno.h>
  44 #include <asm/dwarf2.h>
  45 #include <asm/calling.h>
  46 #include <asm/asm-offsets.h>
  47 #include <asm/msr.h>
  48 #include <asm/unistd.h>
  49 #include <asm/thread_info.h>
  50 #include <asm/hw_irq.h>
  51 #include <asm/page.h>
  52 #include <asm/irqflags.h>
  53 #include <asm/paravirt.h>
  54 #include <asm/ftrace.h>
  55
  56 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  57 #include <linux/elf-em.h>
  58 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  59 #define __AUDIT_ARCH_64BIT 0x80000000
  60 #define __AUDIT_ARCH_LE    0x40000000
  61
  62         .code64
  63 #ifdef CONFIG_FUNCTION_TRACER
  64 #ifdef CONFIG_DYNAMIC_FTRACE
  65 ENTRY(mcount)
  66         retq
  67 END(mcount)
  68
  69 ENTRY(ftrace_caller)
  70         cmpl $0, function_trace_stop
  71         jne  ftrace_stub
  72
  73         MCOUNT_SAVE_FRAME
  74
  75         movq 0x38(%rsp), %rdi
  76         movq 8(%rbp), %rsi
  77         subq $MCOUNT_INSN_SIZE, %rdi
  78
  79 .globl ftrace_call
  80 ftrace_call:
  81         call ftrace_stub
  82
  83         MCOUNT_RESTORE_FRAME
  84
  85 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  86 .globl ftrace_graph_call
  87 ftrace_graph_call:
  88         jmp ftrace_stub
  89 #endif
  90
  91 .globl ftrace_stub
  92 ftrace_stub:
  93         retq
  94 END(ftrace_caller)
  95
  96 #else /* ! CONFIG_DYNAMIC_FTRACE */
  97 ENTRY(mcount)
  98         cmpl $0, function_trace_stop
  99         jne  ftrace_stub
 100
 101         cmpq $ftrace_stub, ftrace_trace_function
 102         jnz trace
 103
 104 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 105         cmpq $ftrace_stub, ftrace_graph_return
 106         jnz ftrace_graph_caller
 107
 108         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 109         jnz ftrace_graph_caller
 110 #endif
 111
 112 .globl ftrace_stub
 113 ftrace_stub:
 114         retq
 115
 116 trace:
 117         MCOUNT_SAVE_FRAME
 118
 119         movq 0x38(%rsp), %rdi
 120         movq 8(%rbp), %rsi
 121         subq $MCOUNT_INSN_SIZE, %rdi
 122
 123         call   *ftrace_trace_function
 124
 125         MCOUNT_RESTORE_FRAME
 126
 127         jmp ftrace_stub
 128 END(mcount)
 129 #endif /* CONFIG_DYNAMIC_FTRACE */
 130 #endif /* CONFIG_FUNCTION_TRACER */
 131
 132 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 133 ENTRY(ftrace_graph_caller)
 134         cmpl $0, function_trace_stop
 135         jne ftrace_stub
 136
 137         MCOUNT_SAVE_FRAME
 138
 139         leaq 8(%rbp), %rdi
 140         movq 0x38(%rsp), %rsi
 141         subq $MCOUNT_INSN_SIZE, %rsi
 142
 143         call    prepare_ftrace_return
 144
 145         MCOUNT_RESTORE_FRAME
 146
 147         retq
 148 END(ftrace_graph_caller)
 149
 150
 151 .globl return_to_handler
 152 return_to_handler:
 153         subq  $80, %rsp
 154
 155         movq %rax, (%rsp)
 156         movq %rcx, 8(%rsp)
 157         movq %rdx, 16(%rsp)
 158         movq %rsi, 24(%rsp)
 159         movq %rdi, 32(%rsp)
 160         movq %r8, 40(%rsp)
 161         movq %r9, 48(%rsp)
 162         movq %r10, 56(%rsp)
 163         movq %r11, 64(%rsp)
 164
 165         call ftrace_return_to_handler
 166
 167         movq %rax, 72(%rsp)
 168         movq 64(%rsp), %r11
 169         movq 56(%rsp), %r10
 170         movq 48(%rsp), %r9
 171         movq 40(%rsp), %r8
 172         movq 32(%rsp), %rdi
 173         movq 24(%rsp), %rsi
 174         movq 16(%rsp), %rdx
 175         movq 8(%rsp), %rcx
 176         movq (%rsp), %rax
 177         addq $72, %rsp
 178         retq
 179 #endif
 180
 181
 182 #ifndef CONFIG_PREEMPT
 183 #define retint_kernel retint_restore_args
 184 #endif
 185
 186 #ifdef CONFIG_PARAVIRT
 187 ENTRY(native_usergs_sysret64)
 188         swapgs
 189         sysretq
 190 #endif /* CONFIG_PARAVIRT */
 191
 192
 193 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 194 #ifdef CONFIG_TRACE_IRQFLAGS
 195         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 196         jnc  1f
 197         TRACE_IRQS_ON
 198 1:
 199 #endif
 200 .endm
 201
 202 /*
 203  * C code is not supposed to know about undefined top of stack. Every time
 204  * a C function with an pt_regs argument is called from the SYSCALL based
 205  * fast path FIXUP_TOP_OF_STACK is needed.
 206  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 207  * manipulation.
 208  */
 209
 210         /* %rsp:at FRAMEEND */
 211         .macro FIXUP_TOP_OF_STACK tmp offset=0
 212         movq %gs:pda_oldrsp,\tmp
 213         movq \tmp,RSP+\offset(%rsp)
 214         movq $__USER_DS,SS+\offset(%rsp)
 215         movq $__USER_CS,CS+\offset(%rsp)
 216         movq $-1,RCX+\offset(%rsp)
 217         movq R11+\offset(%rsp),\tmp  /* get eflags */
 218         movq \tmp,EFLAGS+\offset(%rsp)
 219         .endm
 220
 221         .macro RESTORE_TOP_OF_STACK tmp offset=0
 222         movq RSP+\offset(%rsp),\tmp
 223         movq \tmp,%gs:pda_oldrsp
 224         movq EFLAGS+\offset(%rsp),\tmp
 225         movq \tmp,R11+\offset(%rsp)
 226         .endm
 227
 228         .macro FAKE_STACK_FRAME child_rip
 229         /* push in order ss, rsp, eflags, cs, rip */
 230         xorl %eax, %eax
 231         pushq $__KERNEL_DS /* ss */
 232         CFI_ADJUST_CFA_OFFSET   8
 233         /*CFI_REL_OFFSET        ss,0*/
 234         pushq %rax /* rsp */
 235         CFI_ADJUST_CFA_OFFSET   8
 236         CFI_REL_OFFSET  rsp,0
 237         pushq $X86_EFLAGS_IF /* eflags - interrupts on */
 238         CFI_ADJUST_CFA_OFFSET   8
 239         /*CFI_REL_OFFSET        rflags,0*/
 240         pushq $__KERNEL_CS /* cs */
 241         CFI_ADJUST_CFA_OFFSET   8
 242         /*CFI_REL_OFFSET        cs,0*/
 243         pushq \child_rip /* rip */
 244         CFI_ADJUST_CFA_OFFSET   8
 245         CFI_REL_OFFSET  rip,0
 246         pushq   %rax /* orig rax */
 247         CFI_ADJUST_CFA_OFFSET   8
 248         .endm
 249
 250         .macro UNFAKE_STACK_FRAME
 251         addq $8*6, %rsp
 252         CFI_ADJUST_CFA_OFFSET   -(6*8)
 253         .endm
 254
 255 /*
 256  * initial frame state for interrupts (and exceptions without error code)
 257  */
 258         .macro EMPTY_FRAME start=1 offset=0
 259         .if \start
 260         CFI_STARTPROC simple
 261         CFI_SIGNAL_FRAME
 262         CFI_DEF_CFA rsp,8+\offset
 263         .else
 264         CFI_DEF_CFA_OFFSET 8+\offset
 265         .endif
 266         .endm
 267
 268 /*
 269  * initial frame state for interrupts (and exceptions without error code)
 270  */
 271         .macro INTR_FRAME start=1 offset=0
 272         EMPTY_FRAME \start, SS+8+\offset-RIP
 273         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 274         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 275         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 276         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 277         CFI_REL_OFFSET rip, RIP+\offset-RIP
 278         .endm
 279
 280 /*
 281  * initial frame state for exceptions with error code (and interrupts
 282  * with vector already pushed)
 283  */
 284         .macro XCPT_FRAME start=1 offset=0
 285         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 286         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 287         .endm
 288
 289 /*
 290  * frame that enables calling into C.
 291  */
 292         .macro PARTIAL_FRAME start=1 offset=0
 293         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 294         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 295         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 296         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 297         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 298         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 299         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 300         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 301         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 302         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 303         .endm
 304
 305 /*
 306  * frame that enables passing a complete pt_regs to a C function.
 307  */
 308         .macro DEFAULT_FRAME start=1 offset=0
 309         PARTIAL_FRAME \start, R11+\offset-R15
 310         CFI_REL_OFFSET rbx, RBX+\offset
 311         CFI_REL_OFFSET rbp, RBP+\offset
 312         CFI_REL_OFFSET r12, R12+\offset
 313         CFI_REL_OFFSET r13, R13+\offset
 314         CFI_REL_OFFSET r14, R14+\offset
 315         CFI_REL_OFFSET r15, R15+\offset
 316         .endm
 317
 318 /* save partial stack frame */
 319 ENTRY(save_args)
 320         XCPT_FRAME
 321         cld
 322         movq_cfi rdi, RDI+16-ARGOFFSET
 323         movq_cfi rsi, RSI+16-ARGOFFSET
 324         movq_cfi rdx, RDX+16-ARGOFFSET
 325         movq_cfi rcx, RCX+16-ARGOFFSET
 326         movq_cfi rax, RAX+16-ARGOFFSET
 327         movq_cfi  r8,  R8+16-ARGOFFSET
 328         movq_cfi  r9,  R9+16-ARGOFFSET
 329         movq_cfi r10, R10+16-ARGOFFSET
 330         movq_cfi r11, R11+16-ARGOFFSET
 331
 332         leaq -ARGOFFSET+16(%rsp),%rdi   /* arg1 for handler */
 333         movq_cfi rbp, 8         /* push %rbp */
 334         leaq 8(%rsp), %rbp              /* mov %rsp, %ebp */
 335         testl $3, CS(%rdi)
 336         je 1f
 337         SWAPGS
 338         /*
 339          * irqcount is used to check if a CPU is already on an interrupt stack
 340          * or not. While this is essentially redundant with preempt_count it is
 341          * a little cheaper to use a separate counter in the PDA (short of
 342          * moving irq_enter into assembly, which would be too much work)
 343          */
 344 1:      incl %gs:pda_irqcount
 345         jne 2f
 346         popq_cfi %rax                   /* move return address... */
 347         mov %gs:pda_irqstackptr,%rsp
 348         EMPTY_FRAME 0
 349         pushq_cfi %rax                  /* ... to the new stack */
 350         /*
 351          * We entered an interrupt context - irqs are off:
 352          */
 353 2:      TRACE_IRQS_OFF
 354         ret
 355         CFI_ENDPROC
 356 END(save_args)
 357
 358 ENTRY(save_rest)
 359         PARTIAL_FRAME 1 REST_SKIP+8
 360         movq 5*8+16(%rsp), %r11 /* save return address */
 361         movq_cfi rbx, RBX+16
 362         movq_cfi rbp, RBP+16
 363         movq_cfi r12, R12+16
 364         movq_cfi r13, R13+16
 365         movq_cfi r14, R14+16
 366         movq_cfi r15, R15+16
 367         movq %r11, 8(%rsp)      /* return address */
 368         FIXUP_TOP_OF_STACK %r11, 16
 369         ret
 370         CFI_ENDPROC
 371 END(save_rest)
 372
 373 /* save complete stack frame */
 374 ENTRY(save_paranoid)
 375         XCPT_FRAME 1 RDI+8
 376         cld
 377         movq_cfi rdi, RDI+8
 378         movq_cfi rsi, RSI+8
 379         movq_cfi rdx, RDX+8
 380         movq_cfi rcx, RCX+8
 381         movq_cfi rax, RAX+8
 382         movq_cfi r8, R8+8
 383         movq_cfi r9, R9+8
 384         movq_cfi r10, R10+8
 385         movq_cfi r11, R11+8
 386         movq_cfi rbx, RBX+8
 387         movq_cfi rbp, RBP+8
 388         movq_cfi r12, R12+8
 389         movq_cfi r13, R13+8
 390         movq_cfi r14, R14+8
 391         movq_cfi r15, R15+8
 392         movl $1,%ebx
 393         movl $MSR_GS_BASE,%ecx
 394         rdmsr
 395         testl %edx,%edx
 396         js 1f   /* negative -> in kernel */
 397         SWAPGS
 398         xorl %ebx,%ebx
 399 1:      ret
 400         CFI_ENDPROC
 401 END(save_paranoid)
 402
 403 /*
 404  * A newly forked process directly context switches into this address.
 405  *
 406  * rdi: prev task we switched from
 407  */
 408 ENTRY(ret_from_fork)
 409         DEFAULT_FRAME
 410
 411         push kernel_eflags(%rip)
 412         CFI_ADJUST_CFA_OFFSET 8
 413         popf                                    # reset kernel eflags
 414         CFI_ADJUST_CFA_OFFSET -8
 415
 416         call schedule_tail                      # rdi: 'prev' task parameter
 417
 418         GET_THREAD_INFO(%rcx)
 419
 420         CFI_REMEMBER_STATE
 421         RESTORE_REST
 422
 423         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 424         je   int_ret_from_sys_call
 425
 426         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 427         jnz  int_ret_from_sys_call
 428
 429         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 430         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 431
 432         CFI_RESTORE_STATE
 433         CFI_ENDPROC
 434 END(ret_from_fork)
 435
 436 /*
 437  * System call entry. Upto 6 arguments in registers are supported.
 438  *
 439  * SYSCALL does not save anything on the stack and does not change the
 440  * stack pointer.
 441  */
 442
 443 /*
 444  * Register setup:
 445  * rax  system call number
 446  * rdi  arg0
 447  * rcx  return address for syscall/sysret, C arg3
 448  * rsi  arg1
 449  * rdx  arg2
 450  * r10  arg3    (--> moved to rcx for C)
 451  * r8   arg4
 452  * r9   arg5
 453  * r11  eflags for syscall/sysret, temporary for C
 454  * r12-r15,rbp,rbx saved by C code, not touched.
 455  *
 456  * Interrupts are off on entry.
 457  * Only called from user space.
 458  *
 459  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 460  *      and report it properly in ps. Unfortunately we haven't.
 461  *
 462  * When user can change the frames always force IRET. That is because
 463  * it deals with uncanonical addresses better. SYSRET has trouble
 464  * with them due to bugs in both AMD and Intel CPUs.
 465  */
 466
 467 ENTRY(system_call)
 468         CFI_STARTPROC   simple
 469         CFI_SIGNAL_FRAME
 470         CFI_DEF_CFA     rsp,PDA_STACKOFFSET
 471         CFI_REGISTER    rip,rcx
 472         /*CFI_REGISTER  rflags,r11*/
 473         SWAPGS_UNSAFE_STACK
 474         /*
 475          * A hypervisor implementation might want to use a label
 476          * after the swapgs, so that it can do the swapgs
 477          * for the guest and jump here on syscall.
 478          */
 479 ENTRY(system_call_after_swapgs)
 480
 481         movq    %rsp,%gs:pda_oldrsp
 482         movq    %gs:pda_kernelstack,%rsp
 483         /*
 484          * No need to follow this irqs off/on section - it's straight
 485          * and short:
 486          */
 487         ENABLE_INTERRUPTS(CLBR_NONE)
 488         SAVE_ARGS 8,1
 489         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 490         movq  %rcx,RIP-ARGOFFSET(%rsp)
 491         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 492         GET_THREAD_INFO(%rcx)
 493         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 494         jnz tracesys
 495 system_call_fastpath:
 496         cmpq $__NR_syscall_max,%rax
 497         ja badsys
 498         movq %r10,%rcx
 499         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 500         movq %rax,RAX-ARGOFFSET(%rsp)
 501 /*
 502  * Syscall return path ending with SYSRET (fast path)
 503  * Has incomplete stack frame and undefined top of stack.
 504  */
 505 ret_from_sys_call:
 506         movl $_TIF_ALLWORK_MASK,%edi
 507         /* edi: flagmask */
 508 sysret_check:
 509         LOCKDEP_SYS_EXIT
 510         GET_THREAD_INFO(%rcx)
 511         DISABLE_INTERRUPTS(CLBR_NONE)
 512         TRACE_IRQS_OFF
 513         movl TI_flags(%rcx),%edx
 514         andl %edi,%edx
 515         jnz  sysret_careful
 516         CFI_REMEMBER_STATE
 517         /*
 518          * sysretq will re-enable interrupts:
 519          */
 520         TRACE_IRQS_ON
 521         movq RIP-ARGOFFSET(%rsp),%rcx
 522         CFI_REGISTER    rip,rcx
 523         RESTORE_ARGS 0,-ARG_SKIP,1
 524         /*CFI_REGISTER  rflags,r11*/
 525         movq    %gs:pda_oldrsp, %rsp
 526         USERGS_SYSRET64
 527
 528         CFI_RESTORE_STATE
 529         /* Handle reschedules */
 530         /* edx: work, edi: workmask */
 531 sysret_careful:
 532         bt $TIF_NEED_RESCHED,%edx
 533         jnc sysret_signal
 534         TRACE_IRQS_ON
 535         ENABLE_INTERRUPTS(CLBR_NONE)
 536         pushq %rdi
 537         CFI_ADJUST_CFA_OFFSET 8
 538         call schedule
 539         popq  %rdi
 540         CFI_ADJUST_CFA_OFFSET -8
 541         jmp sysret_check
 542
 543         /* Handle a signal */
 544 sysret_signal:
 545         TRACE_IRQS_ON
 546         ENABLE_INTERRUPTS(CLBR_NONE)
 547 #ifdef CONFIG_AUDITSYSCALL
 548         bt $TIF_SYSCALL_AUDIT,%edx
 549         jc sysret_audit
 550 #endif
 551         /* edx: work flags (arg3) */
 552         leaq -ARGOFFSET(%rsp),%rdi # &pt_regs -> arg1
 553         xorl %esi,%esi # oldset -> arg2
 554         SAVE_REST
 555         FIXUP_TOP_OF_STACK %r11
 556         call do_notify_resume
 557         RESTORE_TOP_OF_STACK %r11
 558         RESTORE_REST
 559         movl $_TIF_WORK_MASK,%edi
 560         /* Use IRET because user could have changed frame. This
 561            works because ptregscall_common has called FIXUP_TOP_OF_STACK. */
 562         DISABLE_INTERRUPTS(CLBR_NONE)
 563         TRACE_IRQS_OFF
 564         jmp int_with_check
 565
 566 badsys:
 567         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 568         jmp ret_from_sys_call
 569
 570 #ifdef CONFIG_AUDITSYSCALL
 571         /*
 572          * Fast path for syscall audit without full syscall trace.
 573          * We just call audit_syscall_entry() directly, and then
 574          * jump back to the normal fast path.
 575          */
 576 auditsys:
 577         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 578         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 579         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 580         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 581         movq %rax,%rsi                  /* 2nd arg: syscall number */
 582         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 583         call audit_syscall_entry
 584         LOAD_ARGS 0             /* reload call-clobbered registers */
 585         jmp system_call_fastpath
 586
 587         /*
 588          * Return fast path for syscall audit.  Call audit_syscall_exit()
 589          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 590          * masked off.
 591          */
 592 sysret_audit:
 593         movq %rax,%rsi          /* second arg, syscall return value */
 594         cmpq $0,%rax            /* is it < 0? */
 595         setl %al                /* 1 if so, 0 if not */
 596         movzbl %al,%edi         /* zero-extend that into %edi */
 597         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 598         call audit_syscall_exit
 599         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 600         jmp sysret_check
 601 #endif  /* CONFIG_AUDITSYSCALL */
 602
 603         /* Do syscall tracing */
 604 tracesys:
 605 #ifdef CONFIG_AUDITSYSCALL
 606         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 607         jz auditsys
 608 #endif
 609         SAVE_REST
 610         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 611         FIXUP_TOP_OF_STACK %rdi
 612         movq %rsp,%rdi
 613         call syscall_trace_enter
 614         /*
 615          * Reload arg registers from stack in case ptrace changed them.
 616          * We don't reload %rax because syscall_trace_enter() returned
 617          * the value it wants us to use in the table lookup.
 618          */
 619         LOAD_ARGS ARGOFFSET, 1
 620         RESTORE_REST
 621         cmpq $__NR_syscall_max,%rax
 622         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 623         movq %r10,%rcx  /* fixup for C */
 624         call *sys_call_table(,%rax,8)
 625         movq %rax,RAX-ARGOFFSET(%rsp)
 626         /* Use IRET because user could have changed frame */
 627
 628 /*
 629  * Syscall return path ending with IRET.
 630  * Has correct top of stack, but partial stack frame.
 631  */
 632         .globl int_ret_from_sys_call
 633         .globl int_with_check
 634 int_ret_from_sys_call:
 635         DISABLE_INTERRUPTS(CLBR_NONE)
 636         TRACE_IRQS_OFF
 637         testl $3,CS-ARGOFFSET(%rsp)
 638         je retint_restore_args
 639         movl $_TIF_ALLWORK_MASK,%edi
 640         /* edi: mask to check */
 641 int_with_check:
 642         LOCKDEP_SYS_EXIT_IRQ
 643         GET_THREAD_INFO(%rcx)
 644         movl TI_flags(%rcx),%edx
 645         andl %edi,%edx
 646         jnz   int_careful
 647         andl    $~TS_COMPAT,TI_status(%rcx)
 648         jmp   retint_swapgs
 649
 650         /* Either reschedule or signal or syscall exit tracking needed. */
 651         /* First do a reschedule test. */
 652         /* edx: work, edi: workmask */
 653 int_careful:
 654         bt $TIF_NEED_RESCHED,%edx
 655         jnc  int_very_careful
 656         TRACE_IRQS_ON
 657         ENABLE_INTERRUPTS(CLBR_NONE)
 658         pushq %rdi
 659         CFI_ADJUST_CFA_OFFSET 8
 660         call schedule
 661         popq %rdi
 662         CFI_ADJUST_CFA_OFFSET -8
 663         DISABLE_INTERRUPTS(CLBR_NONE)
 664         TRACE_IRQS_OFF
 665         jmp int_with_check
 666
 667         /* handle signals and tracing -- both require a full stack frame */
 668 int_very_careful:
 669         TRACE_IRQS_ON
 670         ENABLE_INTERRUPTS(CLBR_NONE)
 671         SAVE_REST
 672         /* Check for syscall exit trace */
 673         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 674         jz int_signal
 675         pushq %rdi
 676         CFI_ADJUST_CFA_OFFSET 8
 677         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 678         call syscall_trace_leave
 679         popq %rdi
 680         CFI_ADJUST_CFA_OFFSET -8
 681         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 682         jmp int_restore_rest
 683
 684 int_signal:
 685         testl $_TIF_DO_NOTIFY_MASK,%edx
 686         jz 1f
 687         movq %rsp,%rdi          # &ptregs -> arg1
 688         xorl %esi,%esi          # oldset -> arg2
 689         call do_notify_resume
 690 1:      movl $_TIF_WORK_MASK,%edi
 691 int_restore_rest:
 692         RESTORE_REST
 693         DISABLE_INTERRUPTS(CLBR_NONE)
 694         TRACE_IRQS_OFF
 695         jmp int_with_check
 696         CFI_ENDPROC
 697 END(system_call)
 698
 699 /*
 700  * Certain special system calls that need to save a complete full stack frame.
 701  */
 702         .macro PTREGSCALL label,func,arg
 703 ENTRY(\label)
 704         PARTIAL_FRAME 1 8               /* offset 8: return address */
 705         subq $REST_SKIP, %rsp
 706         CFI_ADJUST_CFA_OFFSET REST_SKIP
 707         call save_rest
 708         DEFAULT_FRAME 0 8               /* offset 8: return address */
 709         leaq 8(%rsp), \arg      /* pt_regs pointer */
 710         call \func
 711         jmp ptregscall_common
 712         CFI_ENDPROC
 713 END(\label)
 714         .endm
 715
 716         PTREGSCALL stub_clone, sys_clone, %r8
 717         PTREGSCALL stub_fork, sys_fork, %rdi
 718         PTREGSCALL stub_vfork, sys_vfork, %rdi
 719         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 720         PTREGSCALL stub_iopl, sys_iopl, %rsi
 721
 722 ENTRY(ptregscall_common)
 723         DEFAULT_FRAME 1 8       /* offset 8: return address */
 724         RESTORE_TOP_OF_STACK %r11, 8
 725         movq_cfi_restore R15+8, r15
 726         movq_cfi_restore R14+8, r14
 727         movq_cfi_restore R13+8, r13
 728         movq_cfi_restore R12+8, r12
 729         movq_cfi_restore RBP+8, rbp
 730         movq_cfi_restore RBX+8, rbx
 731         ret $REST_SKIP          /* pop extended registers */
 732         CFI_ENDPROC
 733 END(ptregscall_common)
 734
 735 ENTRY(stub_execve)
 736         CFI_STARTPROC
 737         popq %r11
 738         CFI_ADJUST_CFA_OFFSET -8
 739         CFI_REGISTER rip, r11
 740         SAVE_REST
 741         FIXUP_TOP_OF_STACK %r11
 742         movq %rsp, %rcx
 743         call sys_execve
 744         RESTORE_TOP_OF_STACK %r11
 745         movq %rax,RAX(%rsp)
 746         RESTORE_REST
 747         jmp int_ret_from_sys_call
 748         CFI_ENDPROC
 749 END(stub_execve)
 750
 751 /*
 752  * sigreturn is special because it needs to restore all registers on return.
 753  * This cannot be done with SYSRET, so use the IRET return path instead.
 754  */
 755 ENTRY(stub_rt_sigreturn)
 756         CFI_STARTPROC
 757         addq $8, %rsp
 758         CFI_ADJUST_CFA_OFFSET   -8
 759         SAVE_REST
 760         movq %rsp,%rdi
 761         FIXUP_TOP_OF_STACK %r11
 762         call sys_rt_sigreturn
 763         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 764         RESTORE_REST
 765         jmp int_ret_from_sys_call
 766         CFI_ENDPROC
 767 END(stub_rt_sigreturn)
 768
 769 /*
 770  * Build the entry stubs and pointer table with some assembler magic.
 771  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 772  * single cache line on all modern x86 implementations.
 773  */
 774         .section .init.rodata,"a"
 775 ENTRY(interrupt)
 776         .text
 777         .p2align 5
 778         .p2align CONFIG_X86_L1_CACHE_SHIFT
 779 ENTRY(irq_entries_start)
 780         INTR_FRAME
 781 vector=FIRST_EXTERNAL_VECTOR
 782 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 783         .balign 32
 784   .rept 7
 785     .if vector < NR_VECTORS
 786       .if vector <> FIRST_EXTERNAL_VECTOR
 787         CFI_ADJUST_CFA_OFFSET -8
 788       .endif
 789 1:      pushq $(~vector+0x80)   /* Note: always in signed byte range */
 790         CFI_ADJUST_CFA_OFFSET 8
 791       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 792         jmp 2f
 793       .endif
 794       .previous
 795         .quad 1b
 796       .text
 797 vector=vector+1
 798     .endif
 799   .endr
 800 2:      jmp common_interrupt
 801 .endr
 802         CFI_ENDPROC
 803 END(irq_entries_start)
 804
 805 .previous
 806 END(interrupt)
 807 .previous
 808
 809 /*
 810  * Interrupt entry/exit.
 811  *
 812  * Interrupt entry points save only callee clobbered registers in fast path.
 813  *
 814  * Entry runs with interrupts off.
 815  */
 816
 817 /* 0(%rsp): ~(interrupt number) */
 818         .macro interrupt func
 819         subq $10*8, %rsp
 820         CFI_ADJUST_CFA_OFFSET 10*8
 821         call save_args
 822         PARTIAL_FRAME 0
 823         call \func
 824         .endm
 825
 826         /*
 827          * The interrupt stubs push (~vector+0x80) onto the stack and
 828          * then jump to common_interrupt.
 829          */
 830         .p2align CONFIG_X86_L1_CACHE_SHIFT
 831 common_interrupt:
 832         XCPT_FRAME
 833         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 834         interrupt do_IRQ
 835         /* 0(%rsp): oldrsp-ARGOFFSET */
 836 ret_from_intr:
 837         DISABLE_INTERRUPTS(CLBR_NONE)
 838         TRACE_IRQS_OFF
 839         decl %gs:pda_irqcount
 840         leaveq
 841         CFI_DEF_CFA_REGISTER    rsp
 842         CFI_ADJUST_CFA_OFFSET   -8
 843 exit_intr:
 844         GET_THREAD_INFO(%rcx)
 845         testl $3,CS-ARGOFFSET(%rsp)
 846         je retint_kernel
 847
 848         /* Interrupt came from user space */
 849         /*
 850          * Has a correct top of stack, but a partial stack frame
 851          * %rcx: thread info. Interrupts off.
 852          */
 853 retint_with_reschedule:
 854         movl $_TIF_WORK_MASK,%edi
 855 retint_check:
 856         LOCKDEP_SYS_EXIT_IRQ
 857         movl TI_flags(%rcx),%edx
 858         andl %edi,%edx
 859         CFI_REMEMBER_STATE
 860         jnz  retint_careful
 861
 862 retint_swapgs:          /* return to user-space */
 863         /*
 864          * The iretq could re-enable interrupts:
 865          */
 866         DISABLE_INTERRUPTS(CLBR_ANY)
 867         TRACE_IRQS_IRETQ
 868         SWAPGS
 869         jmp restore_args
 870
 871 retint_restore_args:    /* return to kernel space */
 872         DISABLE_INTERRUPTS(CLBR_ANY)
 873         /*
 874          * The iretq could re-enable interrupts:
 875          */
 876         TRACE_IRQS_IRETQ
 877 restore_args:
 878         RESTORE_ARGS 0,8,0
 879
 880 irq_return:
 881         INTERRUPT_RETURN
 882
 883         .section __ex_table, "a"
 884         .quad irq_return, bad_iret
 885         .previous
 886
 887 #ifdef CONFIG_PARAVIRT
 888 ENTRY(native_iret)
 889         iretq
 890
 891         .section __ex_table,"a"
 892         .quad native_iret, bad_iret
 893         .previous
 894 #endif
 895
 896         .section .fixup,"ax"
 897 bad_iret:
 898         /*
 899          * The iret traps when the %cs or %ss being restored is bogus.
 900          * We've lost the original trap vector and error code.
 901          * #GPF is the most likely one to get for an invalid selector.
 902          * So pretend we completed the iret and took the #GPF in user mode.
 903          *
 904          * We are now running with the kernel GS after exception recovery.
 905          * But error_entry expects us to have user GS to match the user %cs,
 906          * so swap back.
 907          */
 908         pushq $0
 909
 910         SWAPGS
 911         jmp general_protection
 912
 913         .previous
 914
 915         /* edi: workmask, edx: work */
 916 retint_careful:
 917         CFI_RESTORE_STATE
 918         bt    $TIF_NEED_RESCHED,%edx
 919         jnc   retint_signal
 920         TRACE_IRQS_ON
 921         ENABLE_INTERRUPTS(CLBR_NONE)
 922         pushq %rdi
 923         CFI_ADJUST_CFA_OFFSET   8
 924         call  schedule
 925         popq %rdi
 926         CFI_ADJUST_CFA_OFFSET   -8
 927         GET_THREAD_INFO(%rcx)
 928         DISABLE_INTERRUPTS(CLBR_NONE)
 929         TRACE_IRQS_OFF
 930         jmp retint_check
 931
 932 retint_signal:
 933         testl $_TIF_DO_NOTIFY_MASK,%edx
 934         jz    retint_swapgs
 935         TRACE_IRQS_ON
 936         ENABLE_INTERRUPTS(CLBR_NONE)
 937         SAVE_REST
 938         movq $-1,ORIG_RAX(%rsp)
 939         xorl %esi,%esi          # oldset
 940         movq %rsp,%rdi          # &pt_regs
 941         call do_notify_resume
 942         RESTORE_REST
 943         DISABLE_INTERRUPTS(CLBR_NONE)
 944         TRACE_IRQS_OFF
 945         GET_THREAD_INFO(%rcx)
 946         jmp retint_with_reschedule
 947
 948 #ifdef CONFIG_PREEMPT
 949         /* Returning to kernel space. Check if we need preemption */
 950         /* rcx:  threadinfo. interrupts off. */
 951 ENTRY(retint_kernel)
 952         cmpl $0,TI_preempt_count(%rcx)
 953         jnz  retint_restore_args
 954         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 955         jnc  retint_restore_args
 956         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 957         jnc  retint_restore_args
 958         call preempt_schedule_irq
 959         jmp exit_intr
 960 #endif
 961
 962         CFI_ENDPROC
 963 END(common_interrupt)
 964
 965 /*
 966  * APIC interrupts.
 967  */
 968 .macro apicinterrupt num sym do_sym
 969 ENTRY(\sym)
 970         INTR_FRAME
 971         pushq $~(\num)
 972         CFI_ADJUST_CFA_OFFSET 8
 973         interrupt \do_sym
 974         jmp ret_from_intr
 975         CFI_ENDPROC
 976 END(\sym)
 977 .endm
 978
 979 #ifdef CONFIG_SMP
 980 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 981         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 982 #endif
 983
 984 apicinterrupt UV_BAU_MESSAGE \
 985         uv_bau_message_intr1 uv_bau_message_interrupt
 986 apicinterrupt LOCAL_TIMER_VECTOR \
 987         apic_timer_interrupt smp_apic_timer_interrupt
 988
 989 #ifdef CONFIG_SMP
 990 apicinterrupt INVALIDATE_TLB_VECTOR_START+0 \
 991         invalidate_interrupt0 smp_invalidate_interrupt
 992 apicinterrupt INVALIDATE_TLB_VECTOR_START+1 \
 993         invalidate_interrupt1 smp_invalidate_interrupt
 994 apicinterrupt INVALIDATE_TLB_VECTOR_START+2 \
 995         invalidate_interrupt2 smp_invalidate_interrupt
 996 apicinterrupt INVALIDATE_TLB_VECTOR_START+3 \
 997         invalidate_interrupt3 smp_invalidate_interrupt
 998 apicinterrupt INVALIDATE_TLB_VECTOR_START+4 \
 999         invalidate_interrupt4 smp_invalidate_interrupt
1000 apicinterrupt INVALIDATE_TLB_VECTOR_START+5 \
1001         invalidate_interrupt5 smp_invalidate_interrupt
1002 apicinterrupt INVALIDATE_TLB_VECTOR_START+6 \
1003         invalidate_interrupt6 smp_invalidate_interrupt
1004 apicinterrupt INVALIDATE_TLB_VECTOR_START+7 \
1005         invalidate_interrupt7 smp_invalidate_interrupt
1006 #endif
1007
1008 apicinterrupt THRESHOLD_APIC_VECTOR \
1009         threshold_interrupt mce_threshold_interrupt
1010 apicinterrupt THERMAL_APIC_VECTOR \
1011         thermal_interrupt smp_thermal_interrupt
1012
1013 #ifdef CONFIG_SMP
1014 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1015         call_function_single_interrupt smp_call_function_single_interrupt
1016 apicinterrupt CALL_FUNCTION_VECTOR \
1017         call_function_interrupt smp_call_function_interrupt
1018 apicinterrupt RESCHEDULE_VECTOR \
1019         reschedule_interrupt smp_reschedule_interrupt
1020 #endif
1021
1022 apicinterrupt ERROR_APIC_VECTOR \
1023         error_interrupt smp_error_interrupt
1024 apicinterrupt SPURIOUS_APIC_VECTOR \
1025         spurious_interrupt smp_spurious_interrupt
1026
1027 #ifdef CONFIG_PERF_COUNTERS
1028 apicinterrupt LOCAL_PERF_VECTOR \
1029         perf_counter_interrupt smp_perf_counter_interrupt
1030 #endif
1031
1032 /*
1033  * Exception entry points.
1034  */
1035 .macro zeroentry sym do_sym
1036 ENTRY(\sym)
1037         INTR_FRAME
1038         PARAVIRT_ADJUST_EXCEPTION_FRAME
1039         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1040         subq $15*8,%rsp
1041         CFI_ADJUST_CFA_OFFSET 15*8
1042         call error_entry
1043         DEFAULT_FRAME 0
1044         movq %rsp,%rdi          /* pt_regs pointer */
1045         xorl %esi,%esi          /* no error code */
1046         call \do_sym
1047         jmp error_exit          /* %ebx: no swapgs flag */
1048         CFI_ENDPROC
1049 END(\sym)
1050 .endm
1051
1052 .macro paranoidzeroentry sym do_sym
1053 ENTRY(\sym)
1054         INTR_FRAME
1055         PARAVIRT_ADJUST_EXCEPTION_FRAME
1056         pushq $-1               /* ORIG_RAX: no syscall to restart */
1057         CFI_ADJUST_CFA_OFFSET 8
1058         subq $15*8, %rsp
1059         call save_paranoid
1060         TRACE_IRQS_OFF
1061         movq %rsp,%rdi          /* pt_regs pointer */
1062         xorl %esi,%esi          /* no error code */
1063         call \do_sym
1064         jmp paranoid_exit       /* %ebx: no swapgs flag */
1065         CFI_ENDPROC
1066 END(\sym)
1067 .endm
1068
1069 .macro paranoidzeroentry_ist sym do_sym ist
1070 ENTRY(\sym)
1071         INTR_FRAME
1072         PARAVIRT_ADJUST_EXCEPTION_FRAME
1073         pushq $-1               /* ORIG_RAX: no syscall to restart */
1074         CFI_ADJUST_CFA_OFFSET 8
1075         subq $15*8, %rsp
1076         call save_paranoid
1077         TRACE_IRQS_OFF
1078         movq %rsp,%rdi          /* pt_regs pointer */
1079         xorl %esi,%esi          /* no error code */
1080         movq %gs:pda_data_offset, %rbp
1081         subq $EXCEPTION_STKSZ, per_cpu__init_tss + TSS_ist + (\ist - 1) * 8(%rbp)
1082         call \do_sym
1083         addq $EXCEPTION_STKSZ, per_cpu__init_tss + TSS_ist + (\ist - 1) * 8(%rbp)
1084         jmp paranoid_exit       /* %ebx: no swapgs flag */
1085         CFI_ENDPROC
1086 END(\sym)
1087 .endm
1088
1089 .macro errorentry sym do_sym
1090 ENTRY(\sym)
1091         XCPT_FRAME
1092         PARAVIRT_ADJUST_EXCEPTION_FRAME
1093         subq $15*8,%rsp
1094         CFI_ADJUST_CFA_OFFSET 15*8
1095         call error_entry
1096         DEFAULT_FRAME 0
1097         movq %rsp,%rdi                  /* pt_regs pointer */
1098         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1099         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1100         call \do_sym
1101         jmp error_exit                  /* %ebx: no swapgs flag */
1102         CFI_ENDPROC
1103 END(\sym)
1104 .endm
1105
1106         /* error code is on the stack already */
1107 .macro paranoiderrorentry sym do_sym
1108 ENTRY(\sym)
1109         XCPT_FRAME
1110         PARAVIRT_ADJUST_EXCEPTION_FRAME
1111         subq $15*8,%rsp
1112         CFI_ADJUST_CFA_OFFSET 15*8
1113         call save_paranoid
1114         DEFAULT_FRAME 0
1115         TRACE_IRQS_OFF
1116         movq %rsp,%rdi                  /* pt_regs pointer */
1117         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1118         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1119         call \do_sym
1120         jmp paranoid_exit               /* %ebx: no swapgs flag */
1121         CFI_ENDPROC
1122 END(\sym)
1123 .endm
1124
1125 zeroentry divide_error do_divide_error
1126 zeroentry overflow do_overflow
1127 zeroentry bounds do_bounds
1128 zeroentry invalid_op do_invalid_op
1129 zeroentry device_not_available do_device_not_available
1130 paranoiderrorentry double_fault do_double_fault
1131 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1132 errorentry invalid_TSS do_invalid_TSS
1133 errorentry segment_not_present do_segment_not_present
1134 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1135 zeroentry coprocessor_error do_coprocessor_error
1136 errorentry alignment_check do_alignment_check
1137 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1138
1139         /* Reload gs selector with exception handling */
1140         /* edi:  new selector */
1141 ENTRY(native_load_gs_index)
1142         CFI_STARTPROC
1143         pushf
1144         CFI_ADJUST_CFA_OFFSET 8
1145         DISABLE_INTERRUPTS(CLBR_ANY | ~(CLBR_RDI))
1146         SWAPGS
1147 gs_change:
1148         movl %edi,%gs
1149 2:      mfence          /* workaround */
1150         SWAPGS
1151         popf
1152         CFI_ADJUST_CFA_OFFSET -8
1153         ret
1154         CFI_ENDPROC
1155 END(native_load_gs_index)
1156
1157         .section __ex_table,"a"
1158         .align 8
1159         .quad gs_change,bad_gs
1160         .previous
1161         .section .fixup,"ax"
1162         /* running with kernelgs */
1163 bad_gs:
1164         SWAPGS                  /* switch back to user gs */
1165         xorl %eax,%eax
1166         movl %eax,%gs
1167         jmp  2b
1168         .previous
1169
1170 /*
1171  * Create a kernel thread.
1172  *
1173  * C extern interface:
1174  *      extern long kernel_thread(int (*fn)(void *), void * arg, unsigned long flags)
1175  *
1176  * asm input arguments:
1177  *      rdi: fn, rsi: arg, rdx: flags
1178  */
1179 ENTRY(kernel_thread)
1180         CFI_STARTPROC
1181         FAKE_STACK_FRAME $child_rip
1182         SAVE_ALL
1183
1184         # rdi: flags, rsi: usp, rdx: will be &pt_regs
1185         movq %rdx,%rdi
1186         orq  kernel_thread_flags(%rip),%rdi
1187         movq $-1, %rsi
1188         movq %rsp, %rdx
1189
1190         xorl %r8d,%r8d
1191         xorl %r9d,%r9d
1192
1193         # clone now
1194         call do_fork
1195         movq %rax,RAX(%rsp)
1196         xorl %edi,%edi
1197
1198         /*
1199          * It isn't worth to check for reschedule here,
1200          * so internally to the x86_64 port you can rely on kernel_thread()
1201          * not to reschedule the child before returning, this avoids the need
1202          * of hacks for example to fork off the per-CPU idle tasks.
1203          * [Hopefully no generic code relies on the reschedule -AK]
1204          */
1205         RESTORE_ALL
1206         UNFAKE_STACK_FRAME
1207         ret
1208         CFI_ENDPROC
1209 END(kernel_thread)
1210
1211 ENTRY(child_rip)
1212         pushq $0                # fake return address
1213         CFI_STARTPROC
1214         /*
1215          * Here we are in the child and the registers are set as they were
1216          * at kernel_thread() invocation in the parent.
1217          */
1218         movq %rdi, %rax
1219         movq %rsi, %rdi
1220         call *%rax
1221         # exit
1222         mov %eax, %edi
1223         call do_exit
1224         ud2                     # padding for call trace
1225         CFI_ENDPROC
1226 END(child_rip)
1227
1228 /*
1229  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1230  *
1231  * C extern interface:
1232  *       extern long execve(char *name, char **argv, char **envp)
1233  *
1234  * asm input arguments:
1235  *      rdi: name, rsi: argv, rdx: envp
1236  *
1237  * We want to fallback into:
1238  *      extern long sys_execve(char *name, char **argv,char **envp, struct pt_regs *regs)
1239  *
1240  * do_sys_execve asm fallback arguments:
1241  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1242  */
1243 ENTRY(kernel_execve)
1244         CFI_STARTPROC
1245         FAKE_STACK_FRAME $0
1246         SAVE_ALL
1247         movq %rsp,%rcx
1248         call sys_execve
1249         movq %rax, RAX(%rsp)
1250         RESTORE_REST
1251         testq %rax,%rax
1252         je int_ret_from_sys_call
1253         RESTORE_ARGS
1254         UNFAKE_STACK_FRAME
1255         ret
1256         CFI_ENDPROC
1257 END(kernel_execve)
1258
1259 /* Call softirq on interrupt stack. Interrupts are off. */
1260 ENTRY(call_softirq)
1261         CFI_STARTPROC
1262         push %rbp
1263         CFI_ADJUST_CFA_OFFSET   8
1264         CFI_REL_OFFSET rbp,0
1265         mov  %rsp,%rbp
1266         CFI_DEF_CFA_REGISTER rbp
1267         incl %gs:pda_irqcount
1268         cmove %gs:pda_irqstackptr,%rsp
1269         push  %rbp                      # backlink for old unwinder
1270         call __do_softirq
1271         leaveq
1272         CFI_DEF_CFA_REGISTER    rsp
1273         CFI_ADJUST_CFA_OFFSET   -8
1274         decl %gs:pda_irqcount
1275         ret
1276         CFI_ENDPROC
1277 END(call_softirq)
1278
1279 #ifdef CONFIG_XEN
1280 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1281
1282 /*
1283  * A note on the "critical region" in our callback handler.
1284  * We want to avoid stacking callback handlers due to events occurring
1285  * during handling of the last event. To do this, we keep events disabled
1286  * until we've done all processing. HOWEVER, we must enable events before
1287  * popping the stack frame (can't be done atomically) and so it would still
1288  * be possible to get enough handler activations to overflow the stack.
1289  * Although unlikely, bugs of that kind are hard to track down, so we'd
1290  * like to avoid the possibility.
1291  * So, on entry to the handler we detect whether we interrupted an
1292  * existing activation in its critical region -- if so, we pop the current
1293  * activation and restart the handler using the previous one.
1294  */
1295 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1296         CFI_STARTPROC
1297 /*
1298  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1299  * see the correct pointer to the pt_regs
1300  */
1301         movq %rdi, %rsp            # we don't return, adjust the stack frame
1302         CFI_ENDPROC
1303         DEFAULT_FRAME
1304 11:     incl %gs:pda_irqcount
1305         movq %rsp,%rbp
1306         CFI_DEF_CFA_REGISTER rbp
1307         cmovzq %gs:pda_irqstackptr,%rsp
1308         pushq %rbp                      # backlink for old unwinder
1309         call xen_evtchn_do_upcall
1310         popq %rsp
1311         CFI_DEF_CFA_REGISTER rsp
1312         decl %gs:pda_irqcount
1313         jmp  error_exit
1314         CFI_ENDPROC
1315 END(do_hypervisor_callback)
1316
1317 /*
1318  * Hypervisor uses this for application faults while it executes.
1319  * We get here for two reasons:
1320  *  1. Fault while reloading DS, ES, FS or GS
1321  *  2. Fault while executing IRET
1322  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1323  * registers that could be reloaded and zeroed the others.
1324  * Category 2 we fix up by killing the current process. We cannot use the
1325  * normal Linux return path in this case because if we use the IRET hypercall
1326  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1327  * We distinguish between categories by comparing each saved segment register
1328  * with its current contents: any discrepancy means we in category 1.
1329  */
1330 ENTRY(xen_failsafe_callback)
1331         INTR_FRAME 1 (6*8)
1332         /*CFI_REL_OFFSET gs,GS*/
1333         /*CFI_REL_OFFSET fs,FS*/
1334         /*CFI_REL_OFFSET es,ES*/
1335         /*CFI_REL_OFFSET ds,DS*/
1336         CFI_REL_OFFSET r11,8
1337         CFI_REL_OFFSET rcx,0
1338         movw %ds,%cx
1339         cmpw %cx,0x10(%rsp)
1340         CFI_REMEMBER_STATE
1341         jne 1f
1342         movw %es,%cx
1343         cmpw %cx,0x18(%rsp)
1344         jne 1f
1345         movw %fs,%cx
1346         cmpw %cx,0x20(%rsp)
1347         jne 1f
1348         movw %gs,%cx
1349         cmpw %cx,0x28(%rsp)
1350         jne 1f
1351         /* All segments match their saved values => Category 2 (Bad IRET). */
1352         movq (%rsp),%rcx
1353         CFI_RESTORE rcx
1354         movq 8(%rsp),%r11
1355         CFI_RESTORE r11
1356         addq $0x30,%rsp
1357         CFI_ADJUST_CFA_OFFSET -0x30
1358         pushq_cfi $0    /* RIP */
1359         pushq_cfi %r11
1360         pushq_cfi %rcx
1361         jmp general_protection
1362         CFI_RESTORE_STATE
1363 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1364         movq (%rsp),%rcx
1365         CFI_RESTORE rcx
1366         movq 8(%rsp),%r11
1367         CFI_RESTORE r11
1368         addq $0x30,%rsp
1369         CFI_ADJUST_CFA_OFFSET -0x30
1370         pushq_cfi $0
1371         SAVE_ALL
1372         jmp error_exit
1373         CFI_ENDPROC
1374 END(xen_failsafe_callback)
1375
1376 #endif /* CONFIG_XEN */
1377
1378 /*
1379  * Some functions should be protected against kprobes
1380  */
1381         .pushsection .kprobes.text, "ax"
1382
1383 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1384 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1385 paranoiderrorentry stack_segment do_stack_segment
1386 errorentry general_protection do_general_protection
1387 errorentry page_fault do_page_fault
1388 #ifdef CONFIG_X86_MCE
1389 paranoidzeroentry machine_check do_machine_check
1390 #endif
1391
1392         /*
1393          * "Paranoid" exit path from exception stack.
1394          * Paranoid because this is used by NMIs and cannot take
1395          * any kernel state for granted.
1396          * We don't do kernel preemption checks here, because only
1397          * NMI should be common and it does not enable IRQs and
1398          * cannot get reschedule ticks.
1399          *
1400          * "trace" is 0 for the NMI handler only, because irq-tracing
1401          * is fundamentally NMI-unsafe. (we cannot change the soft and
1402          * hard flags at once, atomically)
1403          */
1404
1405         /* ebx: no swapgs flag */
1406 ENTRY(paranoid_exit)
1407         INTR_FRAME
1408         DISABLE_INTERRUPTS(CLBR_NONE)
1409         TRACE_IRQS_OFF
1410         testl %ebx,%ebx                         /* swapgs needed? */
1411         jnz paranoid_restore
1412         testl $3,CS(%rsp)
1413         jnz   paranoid_userspace
1414 paranoid_swapgs:
1415         TRACE_IRQS_IRETQ 0
1416         SWAPGS_UNSAFE_STACK
1417 paranoid_restore:
1418         RESTORE_ALL 8
1419         jmp irq_return
1420 paranoid_userspace:
1421         GET_THREAD_INFO(%rcx)
1422         movl TI_flags(%rcx),%ebx
1423         andl $_TIF_WORK_MASK,%ebx
1424         jz paranoid_swapgs
1425         movq %rsp,%rdi                  /* &pt_regs */
1426         call sync_regs
1427         movq %rax,%rsp                  /* switch stack for scheduling */
1428         testl $_TIF_NEED_RESCHED,%ebx
1429         jnz paranoid_schedule
1430         movl %ebx,%edx                  /* arg3: thread flags */
1431         TRACE_IRQS_ON
1432         ENABLE_INTERRUPTS(CLBR_NONE)
1433         xorl %esi,%esi                  /* arg2: oldset */
1434         movq %rsp,%rdi                  /* arg1: &pt_regs */
1435         call do_notify_resume
1436         DISABLE_INTERRUPTS(CLBR_NONE)
1437         TRACE_IRQS_OFF
1438         jmp paranoid_userspace
1439 paranoid_schedule:
1440         TRACE_IRQS_ON
1441         ENABLE_INTERRUPTS(CLBR_ANY)
1442         call schedule
1443         DISABLE_INTERRUPTS(CLBR_ANY)
1444         TRACE_IRQS_OFF
1445         jmp paranoid_userspace
1446         CFI_ENDPROC
1447 END(paranoid_exit)
1448
1449 /*
1450  * Exception entry point. This expects an error code/orig_rax on the stack.
1451  * returns in "no swapgs flag" in %ebx.
1452  */
1453 ENTRY(error_entry)
1454         XCPT_FRAME
1455         CFI_ADJUST_CFA_OFFSET 15*8
1456         /* oldrax contains error code */
1457         cld
1458         movq_cfi rdi, RDI+8
1459         movq_cfi rsi, RSI+8
1460         movq_cfi rdx, RDX+8
1461         movq_cfi rcx, RCX+8
1462         movq_cfi rax, RAX+8
1463         movq_cfi  r8,  R8+8
1464         movq_cfi  r9,  R9+8
1465         movq_cfi r10, R10+8
1466         movq_cfi r11, R11+8
1467         movq_cfi rbx, RBX+8
1468         movq_cfi rbp, RBP+8
1469         movq_cfi r12, R12+8
1470         movq_cfi r13, R13+8
1471         movq_cfi r14, R14+8
1472         movq_cfi r15, R15+8
1473         xorl %ebx,%ebx
1474         testl $3,CS+8(%rsp)
1475         je error_kernelspace
1476 error_swapgs:
1477         SWAPGS
1478 error_sti:
1479         TRACE_IRQS_OFF
1480         ret
1481         CFI_ENDPROC
1482
1483 /*
1484  * There are two places in the kernel that can potentially fault with
1485  * usergs. Handle them here. The exception handlers after iret run with
1486  * kernel gs again, so don't set the user space flag. B stepping K8s
1487  * sometimes report an truncated RIP for IRET exceptions returning to
1488  * compat mode. Check for these here too.
1489  */
1490 error_kernelspace:
1491         incl %ebx
1492         leaq irq_return(%rip),%rcx
1493         cmpq %rcx,RIP+8(%rsp)
1494         je error_swapgs
1495         movl %ecx,%ecx  /* zero extend */
1496         cmpq %rcx,RIP+8(%rsp)
1497         je error_swapgs
1498         cmpq $gs_change,RIP+8(%rsp)
1499         je error_swapgs
1500         jmp error_sti
1501 END(error_entry)
1502
1503
1504 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1505 ENTRY(error_exit)
1506         DEFAULT_FRAME
1507         movl %ebx,%eax
1508         RESTORE_REST
1509         DISABLE_INTERRUPTS(CLBR_NONE)
1510         TRACE_IRQS_OFF
1511         GET_THREAD_INFO(%rcx)
1512         testl %eax,%eax
1513         jne retint_kernel
1514         LOCKDEP_SYS_EXIT_IRQ
1515         movl TI_flags(%rcx),%edx
1516         movl $_TIF_WORK_MASK,%edi
1517         andl %edi,%edx
1518         jnz retint_careful
1519         jmp retint_swapgs
1520         CFI_ENDPROC
1521 END(error_exit)
1522
1523
1524         /* runs on exception stack */
1525 ENTRY(nmi)
1526         INTR_FRAME
1527         PARAVIRT_ADJUST_EXCEPTION_FRAME
1528         pushq_cfi $-1
1529         subq $15*8, %rsp
1530         CFI_ADJUST_CFA_OFFSET 15*8
1531         call save_paranoid
1532         DEFAULT_FRAME 0
1533         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1534         movq %rsp,%rdi
1535         movq $-1,%rsi
1536         call do_nmi
1537 #ifdef CONFIG_TRACE_IRQFLAGS
1538         /* paranoidexit; without TRACE_IRQS_OFF */
1539         /* ebx: no swapgs flag */
1540         DISABLE_INTERRUPTS(CLBR_NONE)
1541         testl %ebx,%ebx                         /* swapgs needed? */
1542         jnz nmi_restore
1543         testl $3,CS(%rsp)
1544         jnz nmi_userspace
1545 nmi_swapgs:
1546         SWAPGS_UNSAFE_STACK
1547 nmi_restore:
1548         RESTORE_ALL 8
1549         jmp irq_return
1550 nmi_userspace:
1551         GET_THREAD_INFO(%rcx)
1552         movl TI_flags(%rcx),%ebx
1553         andl $_TIF_WORK_MASK,%ebx
1554         jz nmi_swapgs
1555         movq %rsp,%rdi                  /* &pt_regs */
1556         call sync_regs
1557         movq %rax,%rsp                  /* switch stack for scheduling */
1558         testl $_TIF_NEED_RESCHED,%ebx
1559         jnz nmi_schedule
1560         movl %ebx,%edx                  /* arg3: thread flags */
1561         ENABLE_INTERRUPTS(CLBR_NONE)
1562         xorl %esi,%esi                  /* arg2: oldset */
1563         movq %rsp,%rdi                  /* arg1: &pt_regs */
1564         call do_notify_resume
1565         DISABLE_INTERRUPTS(CLBR_NONE)
1566         jmp nmi_userspace
1567 nmi_schedule:
1568         ENABLE_INTERRUPTS(CLBR_ANY)
1569         call schedule
1570         DISABLE_INTERRUPTS(CLBR_ANY)
1571         jmp nmi_userspace
1572         CFI_ENDPROC
1573 #else
1574         jmp paranoid_exit
1575         CFI_ENDPROC
1576 #endif
1577 END(nmi)
1578
1579 ENTRY(ignore_sysret)
1580         CFI_STARTPROC
1581         mov $-ENOSYS,%eax
1582         sysret
1583         CFI_ENDPROC
1584 END(ignore_sysret)
1585
1586 /*
1587  * End of kprobes section
1588  */
1589         .popsection