arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/ftrace.h>
  57 #include <asm/percpu.h>
  58 #include <asm/asm.h>
  59 #include <asm/context_tracking.h>
  60 #include <asm/smap.h>
  61 #include <linux/err.h>
  62
  63 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  64 #include <linux/elf-em.h>
  65 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  66 #define __AUDIT_ARCH_64BIT 0x80000000
  67 #define __AUDIT_ARCH_LE    0x40000000
  68
  69         .code64
  70         .section .entry.text, "ax"
  71
  72 #ifdef CONFIG_FUNCTION_TRACER
  73
  74 #ifdef CC_USING_FENTRY
  75 # define function_hook  __fentry__
  76 #else
  77 # define function_hook  mcount
  78 #endif
  79
  80 #ifdef CONFIG_DYNAMIC_FTRACE
  81
  82 ENTRY(function_hook)
  83         retq
  84 END(function_hook)
  85
  86 /* skip is set if stack has been adjusted */
  87 .macro ftrace_caller_setup skip=0
  88         MCOUNT_SAVE_FRAME \skip
  89
  90         /* Load the ftrace_ops into the 3rd parameter */
  91         leaq function_trace_op, %rdx
  92
  93         /* Load ip into the first parameter */
  94         movq RIP(%rsp), %rdi
  95         subq $MCOUNT_INSN_SIZE, %rdi
  96         /* Load the parent_ip into the second parameter */
  97 #ifdef CC_USING_FENTRY
  98         movq SS+16(%rsp), %rsi
  99 #else
 100         movq 8(%rbp), %rsi
 101 #endif
 102 .endm
 103
 104 ENTRY(ftrace_caller)
 105         /* Check if tracing was disabled (quick check) */
 106         cmpl $0, function_trace_stop
 107         jne  ftrace_stub
 108
 109         ftrace_caller_setup
 110         /* regs go into 4th parameter (but make it NULL) */
 111         movq $0, %rcx
 112
 113 GLOBAL(ftrace_call)
 114         call ftrace_stub
 115
 116         MCOUNT_RESTORE_FRAME
 117 ftrace_return:
 118
 119 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 120 GLOBAL(ftrace_graph_call)
 121         jmp ftrace_stub
 122 #endif
 123
 124 GLOBAL(ftrace_stub)
 125         retq
 126 END(ftrace_caller)
 127
 128 ENTRY(ftrace_regs_caller)
 129         /* Save the current flags before compare (in SS location)*/
 130         pushfq
 131
 132         /* Check if tracing was disabled (quick check) */
 133         cmpl $0, function_trace_stop
 134         jne  ftrace_restore_flags
 135
 136         /* skip=8 to skip flags saved in SS */
 137         ftrace_caller_setup 8
 138
 139         /* Save the rest of pt_regs */
 140         movq %r15, R15(%rsp)
 141         movq %r14, R14(%rsp)
 142         movq %r13, R13(%rsp)
 143         movq %r12, R12(%rsp)
 144         movq %r11, R11(%rsp)
 145         movq %r10, R10(%rsp)
 146         movq %rbp, RBP(%rsp)
 147         movq %rbx, RBX(%rsp)
 148         /* Copy saved flags */
 149         movq SS(%rsp), %rcx
 150         movq %rcx, EFLAGS(%rsp)
 151         /* Kernel segments */
 152         movq $__KERNEL_DS, %rcx
 153         movq %rcx, SS(%rsp)
 154         movq $__KERNEL_CS, %rcx
 155         movq %rcx, CS(%rsp)
 156         /* Stack - skipping return address */
 157         leaq SS+16(%rsp), %rcx
 158         movq %rcx, RSP(%rsp)
 159
 160         /* regs go into 4th parameter */
 161         leaq (%rsp), %rcx
 162
 163 GLOBAL(ftrace_regs_call)
 164         call ftrace_stub
 165
 166         /* Copy flags back to SS, to restore them */
 167         movq EFLAGS(%rsp), %rax
 168         movq %rax, SS(%rsp)
 169
 170         /* Handlers can change the RIP */
 171         movq RIP(%rsp), %rax
 172         movq %rax, SS+8(%rsp)
 173
 174         /* restore the rest of pt_regs */
 175         movq R15(%rsp), %r15
 176         movq R14(%rsp), %r14
 177         movq R13(%rsp), %r13
 178         movq R12(%rsp), %r12
 179         movq R10(%rsp), %r10
 180         movq RBP(%rsp), %rbp
 181         movq RBX(%rsp), %rbx
 182
 183         /* skip=8 to skip flags saved in SS */
 184         MCOUNT_RESTORE_FRAME 8
 185
 186         /* Restore flags */
 187         popfq
 188
 189         jmp ftrace_return
 190 ftrace_restore_flags:
 191         popfq
 192         jmp  ftrace_stub
 193
 194 END(ftrace_regs_caller)
 195
 196
 197 #else /* ! CONFIG_DYNAMIC_FTRACE */
 198
 199 ENTRY(function_hook)
 200         cmpl $0, function_trace_stop
 201         jne  ftrace_stub
 202
 203         cmpq $ftrace_stub, ftrace_trace_function
 204         jnz trace
 205
 206 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 207         cmpq $ftrace_stub, ftrace_graph_return
 208         jnz ftrace_graph_caller
 209
 210         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 211         jnz ftrace_graph_caller
 212 #endif
 213
 214 GLOBAL(ftrace_stub)
 215         retq
 216
 217 trace:
 218         MCOUNT_SAVE_FRAME
 219
 220         movq RIP(%rsp), %rdi
 221 #ifdef CC_USING_FENTRY
 222         movq SS+16(%rsp), %rsi
 223 #else
 224         movq 8(%rbp), %rsi
 225 #endif
 226         subq $MCOUNT_INSN_SIZE, %rdi
 227
 228         call   *ftrace_trace_function
 229
 230         MCOUNT_RESTORE_FRAME
 231
 232         jmp ftrace_stub
 233 END(function_hook)
 234 #endif /* CONFIG_DYNAMIC_FTRACE */
 235 #endif /* CONFIG_FUNCTION_TRACER */
 236
 237 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 238 ENTRY(ftrace_graph_caller)
 239         MCOUNT_SAVE_FRAME
 240
 241 #ifdef CC_USING_FENTRY
 242         leaq SS+16(%rsp), %rdi
 243         movq $0, %rdx   /* No framepointers needed */
 244 #else
 245         leaq 8(%rbp), %rdi
 246         movq (%rbp), %rdx
 247 #endif
 248         movq RIP(%rsp), %rsi
 249         subq $MCOUNT_INSN_SIZE, %rsi
 250
 251         call    prepare_ftrace_return
 252
 253         MCOUNT_RESTORE_FRAME
 254
 255         retq
 256 END(ftrace_graph_caller)
 257
 258 GLOBAL(return_to_handler)
 259         subq  $24, %rsp
 260
 261         /* Save the return values */
 262         movq %rax, (%rsp)
 263         movq %rdx, 8(%rsp)
 264         movq %rbp, %rdi
 265
 266         call ftrace_return_to_handler
 267
 268         movq %rax, %rdi
 269         movq 8(%rsp), %rdx
 270         movq (%rsp), %rax
 271         addq $24, %rsp
 272         jmp *%rdi
 273 #endif
 274
 275
 276 #ifndef CONFIG_PREEMPT
 277 #define retint_kernel retint_restore_args
 278 #endif
 279
 280 #ifdef CONFIG_PARAVIRT
 281 ENTRY(native_usergs_sysret64)
 282         swapgs
 283         sysretq
 284 ENDPROC(native_usergs_sysret64)
 285 #endif /* CONFIG_PARAVIRT */
 286
 287
 288 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 289 #ifdef CONFIG_TRACE_IRQFLAGS
 290         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 291         jnc  1f
 292         TRACE_IRQS_ON
 293 1:
 294 #endif
 295 .endm
 296
 297 /*
 298  * When dynamic function tracer is enabled it will add a breakpoint
 299  * to all locations that it is about to modify, sync CPUs, update
 300  * all the code, sync CPUs, then remove the breakpoints. In this time
 301  * if lockdep is enabled, it might jump back into the debug handler
 302  * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
 303  *
 304  * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
 305  * make sure the stack pointer does not get reset back to the top
 306  * of the debug stack, and instead just reuses the current stack.
 307  */
 308 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
 309
 310 .macro TRACE_IRQS_OFF_DEBUG
 311         call debug_stack_set_zero
 312         TRACE_IRQS_OFF
 313         call debug_stack_reset
 314 .endm
 315
 316 .macro TRACE_IRQS_ON_DEBUG
 317         call debug_stack_set_zero
 318         TRACE_IRQS_ON
 319         call debug_stack_reset
 320 .endm
 321
 322 .macro TRACE_IRQS_IRETQ_DEBUG offset=ARGOFFSET
 323         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 324         jnc  1f
 325         TRACE_IRQS_ON_DEBUG
 326 1:
 327 .endm
 328
 329 #else
 330 # define TRACE_IRQS_OFF_DEBUG           TRACE_IRQS_OFF
 331 # define TRACE_IRQS_ON_DEBUG            TRACE_IRQS_ON
 332 # define TRACE_IRQS_IRETQ_DEBUG         TRACE_IRQS_IRETQ
 333 #endif
 334
 335 /*
 336  * C code is not supposed to know about undefined top of stack. Every time
 337  * a C function with an pt_regs argument is called from the SYSCALL based
 338  * fast path FIXUP_TOP_OF_STACK is needed.
 339  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 340  * manipulation.
 341  */
 342
 343         /* %rsp:at FRAMEEND */
 344         .macro FIXUP_TOP_OF_STACK tmp offset=0
 345         movq PER_CPU_VAR(old_rsp),\tmp
 346         movq \tmp,RSP+\offset(%rsp)
 347         movq $__USER_DS,SS+\offset(%rsp)
 348         movq $__USER_CS,CS+\offset(%rsp)
 349         movq $-1,RCX+\offset(%rsp)
 350         movq R11+\offset(%rsp),\tmp  /* get eflags */
 351         movq \tmp,EFLAGS+\offset(%rsp)
 352         .endm
 353
 354         .macro RESTORE_TOP_OF_STACK tmp offset=0
 355         movq RSP+\offset(%rsp),\tmp
 356         movq \tmp,PER_CPU_VAR(old_rsp)
 357         movq EFLAGS+\offset(%rsp),\tmp
 358         movq \tmp,R11+\offset(%rsp)
 359         .endm
 360
 361         .macro FAKE_STACK_FRAME child_rip
 362         /* push in order ss, rsp, eflags, cs, rip */
 363         xorl %eax, %eax
 364         pushq_cfi $__KERNEL_DS /* ss */
 365         /*CFI_REL_OFFSET        ss,0*/
 366         pushq_cfi %rax /* rsp */
 367         CFI_REL_OFFSET  rsp,0
 368         pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_FIXED) /* eflags - interrupts on */
 369         /*CFI_REL_OFFSET        rflags,0*/
 370         pushq_cfi $__KERNEL_CS /* cs */
 371         /*CFI_REL_OFFSET        cs,0*/
 372         pushq_cfi \child_rip /* rip */
 373         CFI_REL_OFFSET  rip,0
 374         pushq_cfi %rax /* orig rax */
 375         .endm
 376
 377         .macro UNFAKE_STACK_FRAME
 378         addq $8*6, %rsp
 379         CFI_ADJUST_CFA_OFFSET   -(6*8)
 380         .endm
 381
 382 /*
 383  * initial frame state for interrupts (and exceptions without error code)
 384  */
 385         .macro EMPTY_FRAME start=1 offset=0
 386         .if \start
 387         CFI_STARTPROC simple
 388         CFI_SIGNAL_FRAME
 389         CFI_DEF_CFA rsp,8+\offset
 390         .else
 391         CFI_DEF_CFA_OFFSET 8+\offset
 392         .endif
 393         .endm
 394
 395 /*
 396  * initial frame state for interrupts (and exceptions without error code)
 397  */
 398         .macro INTR_FRAME start=1 offset=0
 399         EMPTY_FRAME \start, SS+8+\offset-RIP
 400         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 401         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 402         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 403         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 404         CFI_REL_OFFSET rip, RIP+\offset-RIP
 405         .endm
 406
 407 /*
 408  * initial frame state for exceptions with error code (and interrupts
 409  * with vector already pushed)
 410  */
 411         .macro XCPT_FRAME start=1 offset=0
 412         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 413         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 414         .endm
 415
 416 /*
 417  * frame that enables calling into C.
 418  */
 419         .macro PARTIAL_FRAME start=1 offset=0
 420         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 421         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 422         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 423         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 424         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 425         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 426         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 427         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 428         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 429         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 430         .endm
 431
 432 /*
 433  * frame that enables passing a complete pt_regs to a C function.
 434  */
 435         .macro DEFAULT_FRAME start=1 offset=0
 436         PARTIAL_FRAME \start, R11+\offset-R15
 437         CFI_REL_OFFSET rbx, RBX+\offset
 438         CFI_REL_OFFSET rbp, RBP+\offset
 439         CFI_REL_OFFSET r12, R12+\offset
 440         CFI_REL_OFFSET r13, R13+\offset
 441         CFI_REL_OFFSET r14, R14+\offset
 442         CFI_REL_OFFSET r15, R15+\offset
 443         .endm
 444
 445 /* save partial stack frame */
 446         .macro SAVE_ARGS_IRQ
 447         cld
 448         /* start from rbp in pt_regs and jump over */
 449         movq_cfi rdi, (RDI-RBP)
 450         movq_cfi rsi, (RSI-RBP)
 451         movq_cfi rdx, (RDX-RBP)
 452         movq_cfi rcx, (RCX-RBP)
 453         movq_cfi rax, (RAX-RBP)
 454         movq_cfi  r8,  (R8-RBP)
 455         movq_cfi  r9,  (R9-RBP)
 456         movq_cfi r10, (R10-RBP)
 457         movq_cfi r11, (R11-RBP)
 458
 459         /* Save rbp so that we can unwind from get_irq_regs() */
 460         movq_cfi rbp, 0
 461
 462         /* Save previous stack value */
 463         movq %rsp, %rsi
 464
 465         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 466         testl $3, CS-RBP(%rsi)
 467         je 1f
 468         SWAPGS
 469         /*
 470          * irq_count is used to check if a CPU is already on an interrupt stack
 471          * or not. While this is essentially redundant with preempt_count it is
 472          * a little cheaper to use a separate counter in the PDA (short of
 473          * moving irq_enter into assembly, which would be too much work)
 474          */
 475 1:      incl PER_CPU_VAR(irq_count)
 476         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
 477         CFI_DEF_CFA_REGISTER    rsi
 478
 479         /* Store previous stack value */
 480         pushq %rsi
 481         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 482                         0x77 /* DW_OP_breg7 */, 0, \
 483                         0x06 /* DW_OP_deref */, \
 484                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 485                         0x22 /* DW_OP_plus */
 486         /* We entered an interrupt context - irqs are off: */
 487         TRACE_IRQS_OFF
 488         .endm
 489
 490 ENTRY(save_rest)
 491         PARTIAL_FRAME 1 (REST_SKIP+8)
 492         movq 5*8+16(%rsp), %r11 /* save return address */
 493         movq_cfi rbx, RBX+16
 494         movq_cfi rbp, RBP+16
 495         movq_cfi r12, R12+16
 496         movq_cfi r13, R13+16
 497         movq_cfi r14, R14+16
 498         movq_cfi r15, R15+16
 499         movq %r11, 8(%rsp)      /* return address */
 500         FIXUP_TOP_OF_STACK %r11, 16
 501         ret
 502         CFI_ENDPROC
 503 END(save_rest)
 504
 505 /* save complete stack frame */
 506         .pushsection .kprobes.text, "ax"
 507 ENTRY(save_paranoid)
 508         XCPT_FRAME 1 RDI+8
 509         cld
 510         movq_cfi rdi, RDI+8
 511         movq_cfi rsi, RSI+8
 512         movq_cfi rdx, RDX+8
 513         movq_cfi rcx, RCX+8
 514         movq_cfi rax, RAX+8
 515         movq_cfi r8, R8+8
 516         movq_cfi r9, R9+8
 517         movq_cfi r10, R10+8
 518         movq_cfi r11, R11+8
 519         movq_cfi rbx, RBX+8
 520         movq_cfi rbp, RBP+8
 521         movq_cfi r12, R12+8
 522         movq_cfi r13, R13+8
 523         movq_cfi r14, R14+8
 524         movq_cfi r15, R15+8
 525         movl $1,%ebx
 526         movl $MSR_GS_BASE,%ecx
 527         rdmsr
 528         testl %edx,%edx
 529         js 1f   /* negative -> in kernel */
 530         SWAPGS
 531         xorl %ebx,%ebx
 532 1:      ret
 533         CFI_ENDPROC
 534 END(save_paranoid)
 535         .popsection
 536
 537 /*
 538  * A newly forked process directly context switches into this address.
 539  *
 540  * rdi: prev task we switched from
 541  */
 542 ENTRY(ret_from_fork)
 543         DEFAULT_FRAME
 544
 545         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 546
 547         pushq_cfi $0x0002
 548         popfq_cfi                               # reset kernel eflags
 549
 550         call schedule_tail                      # rdi: 'prev' task parameter
 551
 552         GET_THREAD_INFO(%rcx)
 553
 554         RESTORE_REST
 555
 556         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 557         jz   1f
 558
 559         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 560         jnz  int_ret_from_sys_call
 561
 562         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 563         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 564
 565 1:
 566         subq $REST_SKIP, %rsp   # leave space for volatiles
 567         CFI_ADJUST_CFA_OFFSET   REST_SKIP
 568         movq %rbp, %rdi
 569         call *%rbx
 570         movl $0, RAX(%rsp)
 571         RESTORE_REST
 572         jmp int_ret_from_sys_call
 573         CFI_ENDPROC
 574 END(ret_from_fork)
 575
 576 /*
 577  * System call entry. Up to 6 arguments in registers are supported.
 578  *
 579  * SYSCALL does not save anything on the stack and does not change the
 580  * stack pointer.  However, it does mask the flags register for us, so
 581  * CLD and CLAC are not needed.
 582  */
 583
 584 /*
 585  * Register setup:
 586  * rax  system call number
 587  * rdi  arg0
 588  * rcx  return address for syscall/sysret, C arg3
 589  * rsi  arg1
 590  * rdx  arg2
 591  * r10  arg3    (--> moved to rcx for C)
 592  * r8   arg4
 593  * r9   arg5
 594  * r11  eflags for syscall/sysret, temporary for C
 595  * r12-r15,rbp,rbx saved by C code, not touched.
 596  *
 597  * Interrupts are off on entry.
 598  * Only called from user space.
 599  *
 600  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 601  *      and report it properly in ps. Unfortunately we haven't.
 602  *
 603  * When user can change the frames always force IRET. That is because
 604  * it deals with uncanonical addresses better. SYSRET has trouble
 605  * with them due to bugs in both AMD and Intel CPUs.
 606  */
 607
 608 ENTRY(system_call)
 609         CFI_STARTPROC   simple
 610         CFI_SIGNAL_FRAME
 611         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 612         CFI_REGISTER    rip,rcx
 613         /*CFI_REGISTER  rflags,r11*/
 614         SWAPGS_UNSAFE_STACK
 615         /*
 616          * A hypervisor implementation might want to use a label
 617          * after the swapgs, so that it can do the swapgs
 618          * for the guest and jump here on syscall.
 619          */
 620 GLOBAL(system_call_after_swapgs)
 621
 622         movq    %rsp,PER_CPU_VAR(old_rsp)
 623         movq    PER_CPU_VAR(kernel_stack),%rsp
 624         /*
 625          * No need to follow this irqs off/on section - it's straight
 626          * and short:
 627          */
 628         ENABLE_INTERRUPTS(CLBR_NONE)
 629         SAVE_ARGS 8,0
 630         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 631         movq  %rcx,RIP-ARGOFFSET(%rsp)
 632         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 633         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 634         jnz tracesys
 635 system_call_fastpath:
 636 #if __SYSCALL_MASK == ~0
 637         cmpq $__NR_syscall_max,%rax
 638 #else
 639         andl $__SYSCALL_MASK,%eax
 640         cmpl $__NR_syscall_max,%eax
 641 #endif
 642         ja badsys
 643         movq %r10,%rcx
 644         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 645         movq %rax,RAX-ARGOFFSET(%rsp)
 646 /*
 647  * Syscall return path ending with SYSRET (fast path)
 648  * Has incomplete stack frame and undefined top of stack.
 649  */
 650 ret_from_sys_call:
 651         movl $_TIF_ALLWORK_MASK,%edi
 652         /* edi: flagmask */
 653 sysret_check:
 654         LOCKDEP_SYS_EXIT
 655         DISABLE_INTERRUPTS(CLBR_NONE)
 656         TRACE_IRQS_OFF
 657         movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
 658         andl %edi,%edx
 659         jnz  sysret_careful
 660         CFI_REMEMBER_STATE
 661         /*
 662          * sysretq will re-enable interrupts:
 663          */
 664         TRACE_IRQS_ON
 665         movq RIP-ARGOFFSET(%rsp),%rcx
 666         CFI_REGISTER    rip,rcx
 667         RESTORE_ARGS 1,-ARG_SKIP,0
 668         /*CFI_REGISTER  rflags,r11*/
 669         movq    PER_CPU_VAR(old_rsp), %rsp
 670         USERGS_SYSRET64
 671
 672         CFI_RESTORE_STATE
 673         /* Handle reschedules */
 674         /* edx: work, edi: workmask */
 675 sysret_careful:
 676         bt $TIF_NEED_RESCHED,%edx
 677         jnc sysret_signal
 678         TRACE_IRQS_ON
 679         ENABLE_INTERRUPTS(CLBR_NONE)
 680         pushq_cfi %rdi
 681         SCHEDULE_USER
 682         popq_cfi %rdi
 683         jmp sysret_check
 684
 685         /* Handle a signal */
 686 sysret_signal:
 687         TRACE_IRQS_ON
 688         ENABLE_INTERRUPTS(CLBR_NONE)
 689 #ifdef CONFIG_AUDITSYSCALL
 690         bt $TIF_SYSCALL_AUDIT,%edx
 691         jc sysret_audit
 692 #endif
 693         /*
 694          * We have a signal, or exit tracing or single-step.
 695          * These all wind up with the iret return path anyway,
 696          * so just join that path right now.
 697          */
 698         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 699         jmp int_check_syscall_exit_work
 700
 701 badsys:
 702         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 703         jmp ret_from_sys_call
 704
 705 #ifdef CONFIG_AUDITSYSCALL
 706         /*
 707          * Fast path for syscall audit without full syscall trace.
 708          * We just call __audit_syscall_entry() directly, and then
 709          * jump back to the normal fast path.
 710          */
 711 auditsys:
 712         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 713         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 714         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 715         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 716         movq %rax,%rsi                  /* 2nd arg: syscall number */
 717         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 718         call __audit_syscall_entry
 719         LOAD_ARGS 0             /* reload call-clobbered registers */
 720         jmp system_call_fastpath
 721
 722         /*
 723          * Return fast path for syscall audit.  Call __audit_syscall_exit()
 724          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 725          * masked off.
 726          */
 727 sysret_audit:
 728         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 729         cmpq $-MAX_ERRNO,%rsi   /* is it < -MAX_ERRNO? */
 730         setbe %al               /* 1 if so, 0 if not */
 731         movzbl %al,%edi         /* zero-extend that into %edi */
 732         call __audit_syscall_exit
 733         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 734         jmp sysret_check
 735 #endif  /* CONFIG_AUDITSYSCALL */
 736
 737         /* Do syscall tracing */
 738 tracesys:
 739 #ifdef CONFIG_AUDITSYSCALL
 740         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 741         jz auditsys
 742 #endif
 743         SAVE_REST
 744         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 745         FIXUP_TOP_OF_STACK %rdi
 746         movq %rsp,%rdi
 747         call syscall_trace_enter
 748         /*
 749          * Reload arg registers from stack in case ptrace changed them.
 750          * We don't reload %rax because syscall_trace_enter() returned
 751          * the value it wants us to use in the table lookup.
 752          */
 753         LOAD_ARGS ARGOFFSET, 1
 754         RESTORE_REST
 755 #if __SYSCALL_MASK == ~0
 756         cmpq $__NR_syscall_max,%rax
 757 #else
 758         andl $__SYSCALL_MASK,%eax
 759         cmpl $__NR_syscall_max,%eax
 760 #endif
 761         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 762         movq %r10,%rcx  /* fixup for C */
 763         call *sys_call_table(,%rax,8)
 764         movq %rax,RAX-ARGOFFSET(%rsp)
 765         /* Use IRET because user could have changed frame */
 766
 767 /*
 768  * Syscall return path ending with IRET.
 769  * Has correct top of stack, but partial stack frame.
 770  */
 771 GLOBAL(int_ret_from_sys_call)
 772         DISABLE_INTERRUPTS(CLBR_NONE)
 773         TRACE_IRQS_OFF
 774         movl $_TIF_ALLWORK_MASK,%edi
 775         /* edi: mask to check */
 776 GLOBAL(int_with_check)
 777         LOCKDEP_SYS_EXIT_IRQ
 778         GET_THREAD_INFO(%rcx)
 779         movl TI_flags(%rcx),%edx
 780         andl %edi,%edx
 781         jnz   int_careful
 782         andl    $~TS_COMPAT,TI_status(%rcx)
 783         jmp   retint_swapgs
 784
 785         /* Either reschedule or signal or syscall exit tracking needed. */
 786         /* First do a reschedule test. */
 787         /* edx: work, edi: workmask */
 788 int_careful:
 789         bt $TIF_NEED_RESCHED,%edx
 790         jnc  int_very_careful
 791         TRACE_IRQS_ON
 792         ENABLE_INTERRUPTS(CLBR_NONE)
 793         pushq_cfi %rdi
 794         SCHEDULE_USER
 795         popq_cfi %rdi
 796         DISABLE_INTERRUPTS(CLBR_NONE)
 797         TRACE_IRQS_OFF
 798         jmp int_with_check
 799
 800         /* handle signals and tracing -- both require a full stack frame */
 801 int_very_careful:
 802         TRACE_IRQS_ON
 803         ENABLE_INTERRUPTS(CLBR_NONE)
 804 int_check_syscall_exit_work:
 805         SAVE_REST
 806         /* Check for syscall exit trace */
 807         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 808         jz int_signal
 809         pushq_cfi %rdi
 810         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 811         call syscall_trace_leave
 812         popq_cfi %rdi
 813         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 814         jmp int_restore_rest
 815
 816 int_signal:
 817         testl $_TIF_DO_NOTIFY_MASK,%edx
 818         jz 1f
 819         movq %rsp,%rdi          # &ptregs -> arg1
 820         xorl %esi,%esi          # oldset -> arg2
 821         call do_notify_resume
 822 1:      movl $_TIF_WORK_MASK,%edi
 823 int_restore_rest:
 824         RESTORE_REST
 825         DISABLE_INTERRUPTS(CLBR_NONE)
 826         TRACE_IRQS_OFF
 827         jmp int_with_check
 828         CFI_ENDPROC
 829 END(system_call)
 830
 831         .macro FORK_LIKE func
 832 ENTRY(stub_\func)
 833         CFI_STARTPROC
 834         popq    %r11                    /* save return address */
 835         PARTIAL_FRAME 0
 836         SAVE_REST
 837         pushq   %r11                    /* put it back on stack */
 838         FIXUP_TOP_OF_STACK %r11, 8
 839         DEFAULT_FRAME 0 8               /* offset 8: return address */
 840         call sys_\func
 841         RESTORE_TOP_OF_STACK %r11, 8
 842         ret $REST_SKIP          /* pop extended registers */
 843         CFI_ENDPROC
 844 END(stub_\func)
 845         .endm
 846
 847         .macro FIXED_FRAME label,func
 848 ENTRY(\label)
 849         CFI_STARTPROC
 850         PARTIAL_FRAME 0 8               /* offset 8: return address */
 851         FIXUP_TOP_OF_STACK %r11, 8-ARGOFFSET
 852         call \func
 853         RESTORE_TOP_OF_STACK %r11, 8-ARGOFFSET
 854         ret
 855         CFI_ENDPROC
 856 END(\label)
 857         .endm
 858
 859         FORK_LIKE  clone
 860         FORK_LIKE  fork
 861         FORK_LIKE  vfork
 862         FIXED_FRAME stub_iopl, sys_iopl
 863
 864 ENTRY(ptregscall_common)
 865         DEFAULT_FRAME 1 8       /* offset 8: return address */
 866         RESTORE_TOP_OF_STACK %r11, 8
 867         movq_cfi_restore R15+8, r15
 868         movq_cfi_restore R14+8, r14
 869         movq_cfi_restore R13+8, r13
 870         movq_cfi_restore R12+8, r12
 871         movq_cfi_restore RBP+8, rbp
 872         movq_cfi_restore RBX+8, rbx
 873         ret $REST_SKIP          /* pop extended registers */
 874         CFI_ENDPROC
 875 END(ptregscall_common)
 876
 877 ENTRY(stub_execve)
 878         CFI_STARTPROC
 879         addq $8, %rsp
 880         PARTIAL_FRAME 0
 881         SAVE_REST
 882         FIXUP_TOP_OF_STACK %r11
 883         call sys_execve
 884         movq %rax,RAX(%rsp)
 885         RESTORE_REST
 886         jmp int_ret_from_sys_call
 887         CFI_ENDPROC
 888 END(stub_execve)
 889
 890 /*
 891  * sigreturn is special because it needs to restore all registers on return.
 892  * This cannot be done with SYSRET, so use the IRET return path instead.
 893  */
 894 ENTRY(stub_rt_sigreturn)
 895         CFI_STARTPROC
 896         addq $8, %rsp
 897         PARTIAL_FRAME 0
 898         SAVE_REST
 899         FIXUP_TOP_OF_STACK %r11
 900         call sys_rt_sigreturn
 901         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 902         RESTORE_REST
 903         jmp int_ret_from_sys_call
 904         CFI_ENDPROC
 905 END(stub_rt_sigreturn)
 906
 907 #ifdef CONFIG_X86_X32_ABI
 908 ENTRY(stub_x32_rt_sigreturn)
 909         CFI_STARTPROC
 910         addq $8, %rsp
 911         PARTIAL_FRAME 0
 912         SAVE_REST
 913         FIXUP_TOP_OF_STACK %r11
 914         call sys32_x32_rt_sigreturn
 915         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 916         RESTORE_REST
 917         jmp int_ret_from_sys_call
 918         CFI_ENDPROC
 919 END(stub_x32_rt_sigreturn)
 920
 921 ENTRY(stub_x32_execve)
 922         CFI_STARTPROC
 923         addq $8, %rsp
 924         PARTIAL_FRAME 0
 925         SAVE_REST
 926         FIXUP_TOP_OF_STACK %r11
 927         call compat_sys_execve
 928         RESTORE_TOP_OF_STACK %r11
 929         movq %rax,RAX(%rsp)
 930         RESTORE_REST
 931         jmp int_ret_from_sys_call
 932         CFI_ENDPROC
 933 END(stub_x32_execve)
 934
 935 #endif
 936
 937 /*
 938  * Build the entry stubs and pointer table with some assembler magic.
 939  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 940  * single cache line on all modern x86 implementations.
 941  */
 942         .section .init.rodata,"a"
 943 ENTRY(interrupt)
 944         .section .entry.text
 945         .p2align 5
 946         .p2align CONFIG_X86_L1_CACHE_SHIFT
 947 ENTRY(irq_entries_start)
 948         INTR_FRAME
 949 vector=FIRST_EXTERNAL_VECTOR
 950 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 951         .balign 32
 952   .rept 7
 953     .if vector < NR_VECTORS
 954       .if vector <> FIRST_EXTERNAL_VECTOR
 955         CFI_ADJUST_CFA_OFFSET -8
 956       .endif
 957 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 958       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 959         jmp 2f
 960       .endif
 961       .previous
 962         .quad 1b
 963       .section .entry.text
 964 vector=vector+1
 965     .endif
 966   .endr
 967 2:      jmp common_interrupt
 968 .endr
 969         CFI_ENDPROC
 970 END(irq_entries_start)
 971
 972 .previous
 973 END(interrupt)
 974 .previous
 975
 976 /*
 977  * Interrupt entry/exit.
 978  *
 979  * Interrupt entry points save only callee clobbered registers in fast path.
 980  *
 981  * Entry runs with interrupts off.
 982  */
 983
 984 /* 0(%rsp): ~(interrupt number) */
 985         .macro interrupt func
 986         /* reserve pt_regs for scratch regs and rbp */
 987         subq $ORIG_RAX-RBP, %rsp
 988         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 989         SAVE_ARGS_IRQ
 990         call \func
 991         .endm
 992
 993 /*
 994  * Interrupt entry/exit should be protected against kprobes
 995  */
 996         .pushsection .kprobes.text, "ax"
 997         /*
 998          * The interrupt stubs push (~vector+0x80) onto the stack and
 999          * then jump to common_interrupt.
1000          */
1001         .p2align CONFIG_X86_L1_CACHE_SHIFT
1002 common_interrupt:
1003         XCPT_FRAME
1004         ASM_CLAC
1005         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
1006         interrupt do_IRQ
1007         /* 0(%rsp): old_rsp-ARGOFFSET */
1008 ret_from_intr:
1009         DISABLE_INTERRUPTS(CLBR_NONE)
1010         TRACE_IRQS_OFF
1011         decl PER_CPU_VAR(irq_count)
1012
1013         /* Restore saved previous stack */
1014         popq %rsi
1015         CFI_DEF_CFA rsi,SS+8-RBP        /* reg/off reset after def_cfa_expr */
1016         leaq ARGOFFSET-RBP(%rsi), %rsp
1017         CFI_DEF_CFA_REGISTER    rsp
1018         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
1019
1020 exit_intr:
1021         GET_THREAD_INFO(%rcx)
1022         testl $3,CS-ARGOFFSET(%rsp)
1023         je retint_kernel
1024
1025         /* Interrupt came from user space */
1026         /*
1027          * Has a correct top of stack, but a partial stack frame
1028          * %rcx: thread info. Interrupts off.
1029          */
1030 retint_with_reschedule:
1031         movl $_TIF_WORK_MASK,%edi
1032 retint_check:
1033         LOCKDEP_SYS_EXIT_IRQ
1034         movl TI_flags(%rcx),%edx
1035         andl %edi,%edx
1036         CFI_REMEMBER_STATE
1037         jnz  retint_careful
1038
1039 retint_swapgs:          /* return to user-space */
1040         /*
1041          * The iretq could re-enable interrupts:
1042          */
1043         DISABLE_INTERRUPTS(CLBR_ANY)
1044         TRACE_IRQS_IRETQ
1045         SWAPGS
1046         jmp restore_args
1047
1048 retint_restore_args:    /* return to kernel space */
1049         DISABLE_INTERRUPTS(CLBR_ANY)
1050         /*
1051          * The iretq could re-enable interrupts:
1052          */
1053         TRACE_IRQS_IRETQ
1054 restore_args:
1055         RESTORE_ARGS 1,8,1
1056
1057 irq_return:
1058         INTERRUPT_RETURN
1059         _ASM_EXTABLE(irq_return, bad_iret)
1060
1061 #ifdef CONFIG_PARAVIRT
1062 ENTRY(native_iret)
1063         iretq
1064         _ASM_EXTABLE(native_iret, bad_iret)
1065 #endif
1066
1067         .section .fixup,"ax"
1068 bad_iret:
1069         /*
1070          * The iret traps when the %cs or %ss being restored is bogus.
1071          * We've lost the original trap vector and error code.
1072          * #GPF is the most likely one to get for an invalid selector.
1073          * So pretend we completed the iret and took the #GPF in user mode.
1074          *
1075          * We are now running with the kernel GS after exception recovery.
1076          * But error_entry expects us to have user GS to match the user %cs,
1077          * so swap back.
1078          */
1079         pushq $0
1080
1081         SWAPGS
1082         jmp general_protection
1083
1084         .previous
1085
1086         /* edi: workmask, edx: work */
1087 retint_careful:
1088         CFI_RESTORE_STATE
1089         bt    $TIF_NEED_RESCHED,%edx
1090         jnc   retint_signal
1091         TRACE_IRQS_ON
1092         ENABLE_INTERRUPTS(CLBR_NONE)
1093         pushq_cfi %rdi
1094         SCHEDULE_USER
1095         popq_cfi %rdi
1096         GET_THREAD_INFO(%rcx)
1097         DISABLE_INTERRUPTS(CLBR_NONE)
1098         TRACE_IRQS_OFF
1099         jmp retint_check
1100
1101 retint_signal:
1102         testl $_TIF_DO_NOTIFY_MASK,%edx
1103         jz    retint_swapgs
1104         TRACE_IRQS_ON
1105         ENABLE_INTERRUPTS(CLBR_NONE)
1106         SAVE_REST
1107         movq $-1,ORIG_RAX(%rsp)
1108         xorl %esi,%esi          # oldset
1109         movq %rsp,%rdi          # &pt_regs
1110         call do_notify_resume
1111         RESTORE_REST
1112         DISABLE_INTERRUPTS(CLBR_NONE)
1113         TRACE_IRQS_OFF
1114         GET_THREAD_INFO(%rcx)
1115         jmp retint_with_reschedule
1116
1117 #ifdef CONFIG_PREEMPT
1118         /* Returning to kernel space. Check if we need preemption */
1119         /* rcx:  threadinfo. interrupts off. */
1120 ENTRY(retint_kernel)
1121         cmpl $0,TI_preempt_count(%rcx)
1122         jnz  retint_restore_args
1123         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
1124         jnc  retint_restore_args
1125         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
1126         jnc  retint_restore_args
1127         call preempt_schedule_irq
1128         jmp exit_intr
1129 #endif
1130
1131         CFI_ENDPROC
1132 END(common_interrupt)
1133 /*
1134  * End of kprobes section
1135  */
1136        .popsection
1137
1138 /*
1139  * APIC interrupts.
1140  */
1141 .macro apicinterrupt3 num sym do_sym
1142 ENTRY(\sym)
1143         INTR_FRAME
1144         ASM_CLAC
1145         pushq_cfi $~(\num)
1146 .Lcommon_\sym:
1147         interrupt \do_sym
1148         jmp ret_from_intr
1149         CFI_ENDPROC
1150 END(\sym)
1151 .endm
1152
1153 #ifdef CONFIG_TRACING
1154 #define trace(sym) trace_##sym
1155 #define smp_trace(sym) smp_trace_##sym
1156
1157 .macro trace_apicinterrupt num sym
1158 apicinterrupt3 \num trace(\sym) smp_trace(\sym)
1159 .endm
1160 #else
1161 .macro trace_apicinterrupt num sym do_sym
1162 .endm
1163 #endif
1164
1165 .macro apicinterrupt num sym do_sym
1166 apicinterrupt3 \num \sym \do_sym
1167 trace_apicinterrupt \num \sym
1168 .endm
1169
1170 #ifdef CONFIG_SMP
1171 apicinterrupt3 IRQ_MOVE_CLEANUP_VECTOR \
1172         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1173 apicinterrupt3 REBOOT_VECTOR \
1174         reboot_interrupt smp_reboot_interrupt
1175 #endif
1176
1177 #ifdef CONFIG_X86_UV
1178 apicinterrupt3 UV_BAU_MESSAGE \
1179         uv_bau_message_intr1 uv_bau_message_interrupt
1180 #endif
1181 apicinterrupt LOCAL_TIMER_VECTOR \
1182         apic_timer_interrupt smp_apic_timer_interrupt
1183 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1184         x86_platform_ipi smp_x86_platform_ipi
1185
1186 #ifdef CONFIG_HAVE_KVM
1187 apicinterrupt3 POSTED_INTR_VECTOR \
1188         kvm_posted_intr_ipi smp_kvm_posted_intr_ipi
1189 #endif
1190
1191 #ifdef CONFIG_X86_MCE_THRESHOLD
1192 apicinterrupt THRESHOLD_APIC_VECTOR \
1193         threshold_interrupt smp_threshold_interrupt
1194 #endif
1195
1196 #ifdef CONFIG_X86_THERMAL_VECTOR
1197 apicinterrupt THERMAL_APIC_VECTOR \
1198         thermal_interrupt smp_thermal_interrupt
1199 #endif
1200
1201 #ifdef CONFIG_SMP
1202 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1203         call_function_single_interrupt smp_call_function_single_interrupt
1204 apicinterrupt CALL_FUNCTION_VECTOR \
1205         call_function_interrupt smp_call_function_interrupt
1206 apicinterrupt RESCHEDULE_VECTOR \
1207         reschedule_interrupt smp_reschedule_interrupt
1208 #endif
1209
1210 apicinterrupt ERROR_APIC_VECTOR \
1211         error_interrupt smp_error_interrupt
1212 apicinterrupt SPURIOUS_APIC_VECTOR \
1213         spurious_interrupt smp_spurious_interrupt
1214
1215 #ifdef CONFIG_IRQ_WORK
1216 apicinterrupt IRQ_WORK_VECTOR \
1217         irq_work_interrupt smp_irq_work_interrupt
1218 #endif
1219
1220 /*
1221  * Exception entry points.
1222  */
1223 .macro zeroentry sym do_sym
1224 ENTRY(\sym)
1225         INTR_FRAME
1226         ASM_CLAC
1227         PARAVIRT_ADJUST_EXCEPTION_FRAME
1228         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1229         subq $ORIG_RAX-R15, %rsp
1230         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1231         call error_entry
1232         DEFAULT_FRAME 0
1233         movq %rsp,%rdi          /* pt_regs pointer */
1234         xorl %esi,%esi          /* no error code */
1235         call \do_sym
1236         jmp error_exit          /* %ebx: no swapgs flag */
1237         CFI_ENDPROC
1238 END(\sym)
1239 .endm
1240
1241 .macro paranoidzeroentry sym do_sym
1242 ENTRY(\sym)
1243         INTR_FRAME
1244         ASM_CLAC
1245         PARAVIRT_ADJUST_EXCEPTION_FRAME
1246         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1247         subq $ORIG_RAX-R15, %rsp
1248         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1249         call save_paranoid
1250         TRACE_IRQS_OFF
1251         movq %rsp,%rdi          /* pt_regs pointer */
1252         xorl %esi,%esi          /* no error code */
1253         call \do_sym
1254         jmp paranoid_exit       /* %ebx: no swapgs flag */
1255         CFI_ENDPROC
1256 END(\sym)
1257 .endm
1258
1259 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1260 .macro paranoidzeroentry_ist sym do_sym ist
1261 ENTRY(\sym)
1262         INTR_FRAME
1263         ASM_CLAC
1264         PARAVIRT_ADJUST_EXCEPTION_FRAME
1265         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1266         subq $ORIG_RAX-R15, %rsp
1267         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1268         call save_paranoid
1269         TRACE_IRQS_OFF_DEBUG
1270         movq %rsp,%rdi          /* pt_regs pointer */
1271         xorl %esi,%esi          /* no error code */
1272         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1273         call \do_sym
1274         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1275         jmp paranoid_exit       /* %ebx: no swapgs flag */
1276         CFI_ENDPROC
1277 END(\sym)
1278 .endm
1279
1280 .macro errorentry sym do_sym
1281 ENTRY(\sym)
1282         XCPT_FRAME
1283         ASM_CLAC
1284         PARAVIRT_ADJUST_EXCEPTION_FRAME
1285         subq $ORIG_RAX-R15, %rsp
1286         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1287         call error_entry
1288         DEFAULT_FRAME 0
1289         movq %rsp,%rdi                  /* pt_regs pointer */
1290         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1291         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1292         call \do_sym
1293         jmp error_exit                  /* %ebx: no swapgs flag */
1294         CFI_ENDPROC
1295 END(\sym)
1296 .endm
1297
1298         /* error code is on the stack already */
1299 .macro paranoiderrorentry sym do_sym
1300 ENTRY(\sym)
1301         XCPT_FRAME
1302         ASM_CLAC
1303         PARAVIRT_ADJUST_EXCEPTION_FRAME
1304         subq $ORIG_RAX-R15, %rsp
1305         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1306         call save_paranoid
1307         DEFAULT_FRAME 0
1308         TRACE_IRQS_OFF
1309         movq %rsp,%rdi                  /* pt_regs pointer */
1310         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1311         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1312         call \do_sym
1313         jmp paranoid_exit               /* %ebx: no swapgs flag */
1314         CFI_ENDPROC
1315 END(\sym)
1316 .endm
1317
1318 zeroentry divide_error do_divide_error
1319 zeroentry overflow do_overflow
1320 zeroentry bounds do_bounds
1321 zeroentry invalid_op do_invalid_op
1322 zeroentry device_not_available do_device_not_available
1323 paranoiderrorentry double_fault do_double_fault
1324 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1325 errorentry invalid_TSS do_invalid_TSS
1326 errorentry segment_not_present do_segment_not_present
1327 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1328 zeroentry coprocessor_error do_coprocessor_error
1329 errorentry alignment_check do_alignment_check
1330 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1331
1332
1333         /* Reload gs selector with exception handling */
1334         /* edi:  new selector */
1335 ENTRY(native_load_gs_index)
1336         CFI_STARTPROC
1337         pushfq_cfi
1338         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1339         SWAPGS
1340 gs_change:
1341         movl %edi,%gs
1342 2:      mfence          /* workaround */
1343         SWAPGS
1344         popfq_cfi
1345         ret
1346         CFI_ENDPROC
1347 END(native_load_gs_index)
1348
1349         _ASM_EXTABLE(gs_change,bad_gs)
1350         .section .fixup,"ax"
1351         /* running with kernelgs */
1352 bad_gs:
1353         SWAPGS                  /* switch back to user gs */
1354         xorl %eax,%eax
1355         movl %eax,%gs
1356         jmp  2b
1357         .previous
1358
1359 /* Call softirq on interrupt stack. Interrupts are off. */
1360 ENTRY(call_softirq)
1361         CFI_STARTPROC
1362         pushq_cfi %rbp
1363         CFI_REL_OFFSET rbp,0
1364         mov  %rsp,%rbp
1365         CFI_DEF_CFA_REGISTER rbp
1366         incl PER_CPU_VAR(irq_count)
1367         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1368         push  %rbp                      # backlink for old unwinder
1369         call __do_softirq
1370         leaveq
1371         CFI_RESTORE             rbp
1372         CFI_DEF_CFA_REGISTER    rsp
1373         CFI_ADJUST_CFA_OFFSET   -8
1374         decl PER_CPU_VAR(irq_count)
1375         ret
1376         CFI_ENDPROC
1377 END(call_softirq)
1378
1379 #ifdef CONFIG_XEN
1380 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1381
1382 /*
1383  * A note on the "critical region" in our callback handler.
1384  * We want to avoid stacking callback handlers due to events occurring
1385  * during handling of the last event. To do this, we keep events disabled
1386  * until we've done all processing. HOWEVER, we must enable events before
1387  * popping the stack frame (can't be done atomically) and so it would still
1388  * be possible to get enough handler activations to overflow the stack.
1389  * Although unlikely, bugs of that kind are hard to track down, so we'd
1390  * like to avoid the possibility.
1391  * So, on entry to the handler we detect whether we interrupted an
1392  * existing activation in its critical region -- if so, we pop the current
1393  * activation and restart the handler using the previous one.
1394  */
1395 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1396         CFI_STARTPROC
1397 /*
1398  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1399  * see the correct pointer to the pt_regs
1400  */
1401         movq %rdi, %rsp            # we don't return, adjust the stack frame
1402         CFI_ENDPROC
1403         DEFAULT_FRAME
1404 11:     incl PER_CPU_VAR(irq_count)
1405         movq %rsp,%rbp
1406         CFI_DEF_CFA_REGISTER rbp
1407         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1408         pushq %rbp                      # backlink for old unwinder
1409         call xen_evtchn_do_upcall
1410         popq %rsp
1411         CFI_DEF_CFA_REGISTER rsp
1412         decl PER_CPU_VAR(irq_count)
1413         jmp  error_exit
1414         CFI_ENDPROC
1415 END(xen_do_hypervisor_callback)
1416
1417 /*
1418  * Hypervisor uses this for application faults while it executes.
1419  * We get here for two reasons:
1420  *  1. Fault while reloading DS, ES, FS or GS
1421  *  2. Fault while executing IRET
1422  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1423  * registers that could be reloaded and zeroed the others.
1424  * Category 2 we fix up by killing the current process. We cannot use the
1425  * normal Linux return path in this case because if we use the IRET hypercall
1426  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1427  * We distinguish between categories by comparing each saved segment register
1428  * with its current contents: any discrepancy means we in category 1.
1429  */
1430 ENTRY(xen_failsafe_callback)
1431         INTR_FRAME 1 (6*8)
1432         /*CFI_REL_OFFSET gs,GS*/
1433         /*CFI_REL_OFFSET fs,FS*/
1434         /*CFI_REL_OFFSET es,ES*/
1435         /*CFI_REL_OFFSET ds,DS*/
1436         CFI_REL_OFFSET r11,8
1437         CFI_REL_OFFSET rcx,0
1438         movw %ds,%cx
1439         cmpw %cx,0x10(%rsp)
1440         CFI_REMEMBER_STATE
1441         jne 1f
1442         movw %es,%cx
1443         cmpw %cx,0x18(%rsp)
1444         jne 1f
1445         movw %fs,%cx
1446         cmpw %cx,0x20(%rsp)
1447         jne 1f
1448         movw %gs,%cx
1449         cmpw %cx,0x28(%rsp)
1450         jne 1f
1451         /* All segments match their saved values => Category 2 (Bad IRET). */
1452         movq (%rsp),%rcx
1453         CFI_RESTORE rcx
1454         movq 8(%rsp),%r11
1455         CFI_RESTORE r11
1456         addq $0x30,%rsp
1457         CFI_ADJUST_CFA_OFFSET -0x30
1458         pushq_cfi $0    /* RIP */
1459         pushq_cfi %r11
1460         pushq_cfi %rcx
1461         jmp general_protection
1462         CFI_RESTORE_STATE
1463 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1464         movq (%rsp),%rcx
1465         CFI_RESTORE rcx
1466         movq 8(%rsp),%r11
1467         CFI_RESTORE r11
1468         addq $0x30,%rsp
1469         CFI_ADJUST_CFA_OFFSET -0x30
1470         pushq_cfi $-1 /* orig_ax = -1 => not a system call */
1471         SAVE_ALL
1472         jmp error_exit
1473         CFI_ENDPROC
1474 END(xen_failsafe_callback)
1475
1476 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1477         xen_hvm_callback_vector xen_evtchn_do_upcall
1478
1479 #endif /* CONFIG_XEN */
1480
1481 #if IS_ENABLED(CONFIG_HYPERV)
1482 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1483         hyperv_callback_vector hyperv_vector_handler
1484 #endif /* CONFIG_HYPERV */
1485
1486 /*
1487  * Some functions should be protected against kprobes
1488  */
1489         .pushsection .kprobes.text, "ax"
1490
1491 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1492 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1493 paranoiderrorentry stack_segment do_stack_segment
1494 #ifdef CONFIG_XEN
1495 zeroentry xen_debug do_debug
1496 zeroentry xen_int3 do_int3
1497 errorentry xen_stack_segment do_stack_segment
1498 #endif
1499 errorentry general_protection do_general_protection
1500 errorentry page_fault do_page_fault
1501 #ifdef CONFIG_KVM_GUEST
1502 errorentry async_page_fault do_async_page_fault
1503 #endif
1504 #ifdef CONFIG_X86_MCE
1505 paranoidzeroentry machine_check *machine_check_vector(%rip)
1506 #endif
1507
1508         /*
1509          * "Paranoid" exit path from exception stack.
1510          * Paranoid because this is used by NMIs and cannot take
1511          * any kernel state for granted.
1512          * We don't do kernel preemption checks here, because only
1513          * NMI should be common and it does not enable IRQs and
1514          * cannot get reschedule ticks.
1515          *
1516          * "trace" is 0 for the NMI handler only, because irq-tracing
1517          * is fundamentally NMI-unsafe. (we cannot change the soft and
1518          * hard flags at once, atomically)
1519          */
1520
1521         /* ebx: no swapgs flag */
1522 ENTRY(paranoid_exit)
1523         DEFAULT_FRAME
1524         DISABLE_INTERRUPTS(CLBR_NONE)
1525         TRACE_IRQS_OFF_DEBUG
1526         testl %ebx,%ebx                         /* swapgs needed? */
1527         jnz paranoid_restore
1528         testl $3,CS(%rsp)
1529         jnz   paranoid_userspace
1530 paranoid_swapgs:
1531         TRACE_IRQS_IRETQ 0
1532         SWAPGS_UNSAFE_STACK
1533         RESTORE_ALL 8
1534         jmp irq_return
1535 paranoid_restore:
1536         TRACE_IRQS_IRETQ_DEBUG 0
1537         RESTORE_ALL 8
1538         jmp irq_return
1539 paranoid_userspace:
1540         GET_THREAD_INFO(%rcx)
1541         movl TI_flags(%rcx),%ebx
1542         andl $_TIF_WORK_MASK,%ebx
1543         jz paranoid_swapgs
1544         movq %rsp,%rdi                  /* &pt_regs */
1545         call sync_regs
1546         movq %rax,%rsp                  /* switch stack for scheduling */
1547         testl $_TIF_NEED_RESCHED,%ebx
1548         jnz paranoid_schedule
1549         movl %ebx,%edx                  /* arg3: thread flags */
1550         TRACE_IRQS_ON
1551         ENABLE_INTERRUPTS(CLBR_NONE)
1552         xorl %esi,%esi                  /* arg2: oldset */
1553         movq %rsp,%rdi                  /* arg1: &pt_regs */
1554         call do_notify_resume
1555         DISABLE_INTERRUPTS(CLBR_NONE)
1556         TRACE_IRQS_OFF
1557         jmp paranoid_userspace
1558 paranoid_schedule:
1559         TRACE_IRQS_ON
1560         ENABLE_INTERRUPTS(CLBR_ANY)
1561         SCHEDULE_USER
1562         DISABLE_INTERRUPTS(CLBR_ANY)
1563         TRACE_IRQS_OFF
1564         jmp paranoid_userspace
1565         CFI_ENDPROC
1566 END(paranoid_exit)
1567
1568 /*
1569  * Exception entry point. This expects an error code/orig_rax on the stack.
1570  * returns in "no swapgs flag" in %ebx.
1571  */
1572 ENTRY(error_entry)
1573         XCPT_FRAME
1574         CFI_ADJUST_CFA_OFFSET 15*8
1575         /* oldrax contains error code */
1576         cld
1577         movq_cfi rdi, RDI+8
1578         movq_cfi rsi, RSI+8
1579         movq_cfi rdx, RDX+8
1580         movq_cfi rcx, RCX+8
1581         movq_cfi rax, RAX+8
1582         movq_cfi  r8,  R8+8
1583         movq_cfi  r9,  R9+8
1584         movq_cfi r10, R10+8
1585         movq_cfi r11, R11+8
1586         movq_cfi rbx, RBX+8
1587         movq_cfi rbp, RBP+8
1588         movq_cfi r12, R12+8
1589         movq_cfi r13, R13+8
1590         movq_cfi r14, R14+8
1591         movq_cfi r15, R15+8
1592         xorl %ebx,%ebx
1593         testl $3,CS+8(%rsp)
1594         je error_kernelspace
1595 error_swapgs:
1596         SWAPGS
1597 error_sti:
1598         TRACE_IRQS_OFF
1599         ret
1600
1601 /*
1602  * There are two places in the kernel that can potentially fault with
1603  * usergs. Handle them here. The exception handlers after iret run with
1604  * kernel gs again, so don't set the user space flag. B stepping K8s
1605  * sometimes report an truncated RIP for IRET exceptions returning to
1606  * compat mode. Check for these here too.
1607  */
1608 error_kernelspace:
1609         incl %ebx
1610         leaq irq_return(%rip),%rcx
1611         cmpq %rcx,RIP+8(%rsp)
1612         je error_swapgs
1613         movl %ecx,%eax  /* zero extend */
1614         cmpq %rax,RIP+8(%rsp)
1615         je bstep_iret
1616         cmpq $gs_change,RIP+8(%rsp)
1617         je error_swapgs
1618         jmp error_sti
1619
1620 bstep_iret:
1621         /* Fix truncated RIP */
1622         movq %rcx,RIP+8(%rsp)
1623         jmp error_swapgs
1624         CFI_ENDPROC
1625 END(error_entry)
1626
1627
1628 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1629 ENTRY(error_exit)
1630         DEFAULT_FRAME
1631         movl %ebx,%eax
1632         RESTORE_REST
1633         DISABLE_INTERRUPTS(CLBR_NONE)
1634         TRACE_IRQS_OFF
1635         GET_THREAD_INFO(%rcx)
1636         testl %eax,%eax
1637         jne retint_kernel
1638         LOCKDEP_SYS_EXIT_IRQ
1639         movl TI_flags(%rcx),%edx
1640         movl $_TIF_WORK_MASK,%edi
1641         andl %edi,%edx
1642         jnz retint_careful
1643         jmp retint_swapgs
1644         CFI_ENDPROC
1645 END(error_exit)
1646
1647 /*
1648  * Test if a given stack is an NMI stack or not.
1649  */
1650         .macro test_in_nmi reg stack nmi_ret normal_ret
1651         cmpq %\reg, \stack
1652         ja \normal_ret
1653         subq $EXCEPTION_STKSZ, %\reg
1654         cmpq %\reg, \stack
1655         jb \normal_ret
1656         jmp \nmi_ret
1657         .endm
1658
1659         /* runs on exception stack */
1660 ENTRY(nmi)
1661         INTR_FRAME
1662         PARAVIRT_ADJUST_EXCEPTION_FRAME
1663         /*
1664          * We allow breakpoints in NMIs. If a breakpoint occurs, then
1665          * the iretq it performs will take us out of NMI context.
1666          * This means that we can have nested NMIs where the next
1667          * NMI is using the top of the stack of the previous NMI. We
1668          * can't let it execute because the nested NMI will corrupt the
1669          * stack of the previous NMI. NMI handlers are not re-entrant
1670          * anyway.
1671          *
1672          * To handle this case we do the following:
1673          *  Check the a special location on the stack that contains
1674          *  a variable that is set when NMIs are executing.
1675          *  The interrupted task's stack is also checked to see if it
1676          *  is an NMI stack.
1677          *  If the variable is not set and the stack is not the NMI
1678          *  stack then:
1679          *    o Set the special variable on the stack
1680          *    o Copy the interrupt frame into a "saved" location on the stack
1681          *    o Copy the interrupt frame into a "copy" location on the stack
1682          *    o Continue processing the NMI
1683          *  If the variable is set or the previous stack is the NMI stack:
1684          *    o Modify the "copy" location to jump to the repeate_nmi
1685          *    o return back to the first NMI
1686          *
1687          * Now on exit of the first NMI, we first clear the stack variable
1688          * The NMI stack will tell any nested NMIs at that point that it is
1689          * nested. Then we pop the stack normally with iret, and if there was
1690          * a nested NMI that updated the copy interrupt stack frame, a
1691          * jump will be made to the repeat_nmi code that will handle the second
1692          * NMI.
1693          */
1694
1695         /* Use %rdx as out temp variable throughout */
1696         pushq_cfi %rdx
1697         CFI_REL_OFFSET rdx, 0
1698
1699         /*
1700          * If %cs was not the kernel segment, then the NMI triggered in user
1701          * space, which means it is definitely not nested.
1702          */
1703         cmpl $__KERNEL_CS, 16(%rsp)
1704         jne first_nmi
1705
1706         /*
1707          * Check the special variable on the stack to see if NMIs are
1708          * executing.
1709          */
1710         cmpl $1, -8(%rsp)
1711         je nested_nmi
1712
1713         /*
1714          * Now test if the previous stack was an NMI stack.
1715          * We need the double check. We check the NMI stack to satisfy the
1716          * race when the first NMI clears the variable before returning.
1717          * We check the variable because the first NMI could be in a
1718          * breakpoint routine using a breakpoint stack.
1719          */
1720         lea 6*8(%rsp), %rdx
1721         test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1722         CFI_REMEMBER_STATE
1723
1724 nested_nmi:
1725         /*
1726          * Do nothing if we interrupted the fixup in repeat_nmi.
1727          * It's about to repeat the NMI handler, so we are fine
1728          * with ignoring this one.
1729          */
1730         movq $repeat_nmi, %rdx
1731         cmpq 8(%rsp), %rdx
1732         ja 1f
1733         movq $end_repeat_nmi, %rdx
1734         cmpq 8(%rsp), %rdx
1735         ja nested_nmi_out
1736
1737 1:
1738         /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1739         leaq -1*8(%rsp), %rdx
1740         movq %rdx, %rsp
1741         CFI_ADJUST_CFA_OFFSET 1*8
1742         leaq -10*8(%rsp), %rdx
1743         pushq_cfi $__KERNEL_DS
1744         pushq_cfi %rdx
1745         pushfq_cfi
1746         pushq_cfi $__KERNEL_CS
1747         pushq_cfi $repeat_nmi
1748
1749         /* Put stack back */
1750         addq $(6*8), %rsp
1751         CFI_ADJUST_CFA_OFFSET -6*8
1752
1753 nested_nmi_out:
1754         popq_cfi %rdx
1755         CFI_RESTORE rdx
1756
1757         /* No need to check faults here */
1758         INTERRUPT_RETURN
1759
1760         CFI_RESTORE_STATE
1761 first_nmi:
1762         /*
1763          * Because nested NMIs will use the pushed location that we
1764          * stored in rdx, we must keep that space available.
1765          * Here's what our stack frame will look like:
1766          * +-------------------------+
1767          * | original SS             |
1768          * | original Return RSP     |
1769          * | original RFLAGS         |
1770          * | original CS             |
1771          * | original RIP            |
1772          * +-------------------------+
1773          * | temp storage for rdx    |
1774          * +-------------------------+
1775          * | NMI executing variable  |
1776          * +-------------------------+
1777          * | copied SS               |
1778          * | copied Return RSP       |
1779          * | copied RFLAGS           |
1780          * | copied CS               |
1781          * | copied RIP              |
1782          * +-------------------------+
1783          * | Saved SS                |
1784          * | Saved Return RSP        |
1785          * | Saved RFLAGS            |
1786          * | Saved CS                |
1787          * | Saved RIP               |
1788          * +-------------------------+
1789          * | pt_regs                 |
1790          * +-------------------------+
1791          *
1792          * The saved stack frame is used to fix up the copied stack frame
1793          * that a nested NMI may change to make the interrupted NMI iret jump
1794          * to the repeat_nmi. The original stack frame and the temp storage
1795          * is also used by nested NMIs and can not be trusted on exit.
1796          */
1797         /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1798         movq (%rsp), %rdx
1799         CFI_RESTORE rdx
1800
1801         /* Set the NMI executing variable on the stack. */
1802         pushq_cfi $1
1803
1804         /*
1805          * Leave room for the "copied" frame
1806          */
1807         subq $(5*8), %rsp
1808         CFI_ADJUST_CFA_OFFSET 5*8
1809
1810         /* Copy the stack frame to the Saved frame */
1811         .rept 5
1812         pushq_cfi 11*8(%rsp)
1813         .endr
1814         CFI_DEF_CFA_OFFSET SS+8-RIP
1815
1816         /* Everything up to here is safe from nested NMIs */
1817
1818         /*
1819          * If there was a nested NMI, the first NMI's iret will return
1820          * here. But NMIs are still enabled and we can take another
1821          * nested NMI. The nested NMI checks the interrupted RIP to see
1822          * if it is between repeat_nmi and end_repeat_nmi, and if so
1823          * it will just return, as we are about to repeat an NMI anyway.
1824          * This makes it safe to copy to the stack frame that a nested
1825          * NMI will update.
1826          */
1827 repeat_nmi:
1828         /*
1829          * Update the stack variable to say we are still in NMI (the update
1830          * is benign for the non-repeat case, where 1 was pushed just above
1831          * to this very stack slot).
1832          */
1833         movq $1, 10*8(%rsp)
1834
1835         /* Make another copy, this one may be modified by nested NMIs */
1836         addq $(10*8), %rsp
1837         CFI_ADJUST_CFA_OFFSET -10*8
1838         .rept 5
1839         pushq_cfi -6*8(%rsp)
1840         .endr
1841         subq $(5*8), %rsp
1842         CFI_DEF_CFA_OFFSET SS+8-RIP
1843 end_repeat_nmi:
1844
1845         /*
1846          * Everything below this point can be preempted by a nested
1847          * NMI if the first NMI took an exception and reset our iret stack
1848          * so that we repeat another NMI.
1849          */
1850         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1851         subq $ORIG_RAX-R15, %rsp
1852         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1853         /*
1854          * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1855          * as we should not be calling schedule in NMI context.
1856          * Even with normal interrupts enabled. An NMI should not be
1857          * setting NEED_RESCHED or anything that normal interrupts and
1858          * exceptions might do.
1859          */
1860         call save_paranoid
1861         DEFAULT_FRAME 0
1862
1863         /*
1864          * Save off the CR2 register. If we take a page fault in the NMI then
1865          * it could corrupt the CR2 value. If the NMI preempts a page fault
1866          * handler before it was able to read the CR2 register, and then the
1867          * NMI itself takes a page fault, the page fault that was preempted
1868          * will read the information from the NMI page fault and not the
1869          * origin fault. Save it off and restore it if it changes.
1870          * Use the r12 callee-saved register.
1871          */
1872         movq %cr2, %r12
1873
1874         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1875         movq %rsp,%rdi
1876         movq $-1,%rsi
1877         call do_nmi
1878
1879         /* Did the NMI take a page fault? Restore cr2 if it did */
1880         movq %cr2, %rcx
1881         cmpq %rcx, %r12
1882         je 1f
1883         movq %r12, %cr2
1884 1:
1885
1886         testl %ebx,%ebx                         /* swapgs needed? */
1887         jnz nmi_restore
1888 nmi_swapgs:
1889         SWAPGS_UNSAFE_STACK
1890 nmi_restore:
1891         /* Pop the extra iret frame at once */
1892         RESTORE_ALL 6*8
1893
1894         /* Clear the NMI executing stack variable */
1895         movq $0, 5*8(%rsp)
1896         jmp irq_return
1897         CFI_ENDPROC
1898 END(nmi)
1899
1900 ENTRY(ignore_sysret)
1901         CFI_STARTPROC
1902         mov $-ENOSYS,%eax
1903         sysret
1904         CFI_ENDPROC
1905 END(ignore_sysret)
1906
1907 /*
1908  * End of kprobes section
1909  */
1910         .popsection