arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/ftrace.h>
  57 #include <asm/percpu.h>
  58 #include <asm/asm.h>
  59 #include <linux/err.h>
  60
  61 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  62 #include <linux/elf-em.h>
  63 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  64 #define __AUDIT_ARCH_64BIT 0x80000000
  65 #define __AUDIT_ARCH_LE    0x40000000
  66
  67         .code64
  68         .section .entry.text, "ax"
  69
  70 #ifdef CONFIG_FUNCTION_TRACER
  71 #ifdef CONFIG_DYNAMIC_FTRACE
  72 ENTRY(mcount)
  73         retq
  74 END(mcount)
  75
  76 ENTRY(ftrace_caller)
  77         cmpl $0, function_trace_stop
  78         jne  ftrace_stub
  79
  80         MCOUNT_SAVE_FRAME
  81
  82         movq 0x38(%rsp), %rdi
  83         movq 8(%rbp), %rsi
  84         subq $MCOUNT_INSN_SIZE, %rdi
  85
  86 GLOBAL(ftrace_call)
  87         call ftrace_stub
  88
  89         MCOUNT_RESTORE_FRAME
  90
  91 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  92 GLOBAL(ftrace_graph_call)
  93         jmp ftrace_stub
  94 #endif
  95
  96 GLOBAL(ftrace_stub)
  97         retq
  98 END(ftrace_caller)
  99
 100 #else /* ! CONFIG_DYNAMIC_FTRACE */
 101 ENTRY(mcount)
 102         cmpl $0, function_trace_stop
 103         jne  ftrace_stub
 104
 105         cmpq $ftrace_stub, ftrace_trace_function
 106         jnz trace
 107
 108 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 109         cmpq $ftrace_stub, ftrace_graph_return
 110         jnz ftrace_graph_caller
 111
 112         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 113         jnz ftrace_graph_caller
 114 #endif
 115
 116 GLOBAL(ftrace_stub)
 117         retq
 118
 119 trace:
 120         MCOUNT_SAVE_FRAME
 121
 122         movq 0x38(%rsp), %rdi
 123         movq 8(%rbp), %rsi
 124         subq $MCOUNT_INSN_SIZE, %rdi
 125
 126         call   *ftrace_trace_function
 127
 128         MCOUNT_RESTORE_FRAME
 129
 130         jmp ftrace_stub
 131 END(mcount)
 132 #endif /* CONFIG_DYNAMIC_FTRACE */
 133 #endif /* CONFIG_FUNCTION_TRACER */
 134
 135 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 136 ENTRY(ftrace_graph_caller)
 137         cmpl $0, function_trace_stop
 138         jne ftrace_stub
 139
 140         MCOUNT_SAVE_FRAME
 141
 142         leaq 8(%rbp), %rdi
 143         movq 0x38(%rsp), %rsi
 144         movq (%rbp), %rdx
 145         subq $MCOUNT_INSN_SIZE, %rsi
 146
 147         call    prepare_ftrace_return
 148
 149         MCOUNT_RESTORE_FRAME
 150
 151         retq
 152 END(ftrace_graph_caller)
 153
 154 GLOBAL(return_to_handler)
 155         subq  $24, %rsp
 156
 157         /* Save the return values */
 158         movq %rax, (%rsp)
 159         movq %rdx, 8(%rsp)
 160         movq %rbp, %rdi
 161
 162         call ftrace_return_to_handler
 163
 164         movq %rax, %rdi
 165         movq 8(%rsp), %rdx
 166         movq (%rsp), %rax
 167         addq $24, %rsp
 168         jmp *%rdi
 169 #endif
 170
 171
 172 #ifndef CONFIG_PREEMPT
 173 #define retint_kernel retint_restore_args
 174 #endif
 175
 176 #ifdef CONFIG_PARAVIRT
 177 ENTRY(native_usergs_sysret64)
 178         swapgs
 179         sysretq
 180 ENDPROC(native_usergs_sysret64)
 181 #endif /* CONFIG_PARAVIRT */
 182
 183
 184 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 185 #ifdef CONFIG_TRACE_IRQFLAGS
 186         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 187         jnc  1f
 188         TRACE_IRQS_ON
 189 1:
 190 #endif
 191 .endm
 192
 193 /*
 194  * C code is not supposed to know about undefined top of stack. Every time
 195  * a C function with an pt_regs argument is called from the SYSCALL based
 196  * fast path FIXUP_TOP_OF_STACK is needed.
 197  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 198  * manipulation.
 199  */
 200
 201         /* %rsp:at FRAMEEND */
 202         .macro FIXUP_TOP_OF_STACK tmp offset=0
 203         movq PER_CPU_VAR(old_rsp),\tmp
 204         movq \tmp,RSP+\offset(%rsp)
 205         movq $__USER_DS,SS+\offset(%rsp)
 206         movq $__USER_CS,CS+\offset(%rsp)
 207         movq $-1,RCX+\offset(%rsp)
 208         movq R11+\offset(%rsp),\tmp  /* get eflags */
 209         movq \tmp,EFLAGS+\offset(%rsp)
 210         .endm
 211
 212         .macro RESTORE_TOP_OF_STACK tmp offset=0
 213         movq RSP+\offset(%rsp),\tmp
 214         movq \tmp,PER_CPU_VAR(old_rsp)
 215         movq EFLAGS+\offset(%rsp),\tmp
 216         movq \tmp,R11+\offset(%rsp)
 217         .endm
 218
 219         .macro FAKE_STACK_FRAME child_rip
 220         /* push in order ss, rsp, eflags, cs, rip */
 221         xorl %eax, %eax
 222         pushq_cfi $__KERNEL_DS /* ss */
 223         /*CFI_REL_OFFSET        ss,0*/
 224         pushq_cfi %rax /* rsp */
 225         CFI_REL_OFFSET  rsp,0
 226         pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_BIT1) /* eflags - interrupts on */
 227         /*CFI_REL_OFFSET        rflags,0*/
 228         pushq_cfi $__KERNEL_CS /* cs */
 229         /*CFI_REL_OFFSET        cs,0*/
 230         pushq_cfi \child_rip /* rip */
 231         CFI_REL_OFFSET  rip,0
 232         pushq_cfi %rax /* orig rax */
 233         .endm
 234
 235         .macro UNFAKE_STACK_FRAME
 236         addq $8*6, %rsp
 237         CFI_ADJUST_CFA_OFFSET   -(6*8)
 238         .endm
 239
 240 /*
 241  * initial frame state for interrupts (and exceptions without error code)
 242  */
 243         .macro EMPTY_FRAME start=1 offset=0
 244         .if \start
 245         CFI_STARTPROC simple
 246         CFI_SIGNAL_FRAME
 247         CFI_DEF_CFA rsp,8+\offset
 248         .else
 249         CFI_DEF_CFA_OFFSET 8+\offset
 250         .endif
 251         .endm
 252
 253 /*
 254  * initial frame state for interrupts (and exceptions without error code)
 255  */
 256         .macro INTR_FRAME start=1 offset=0
 257         EMPTY_FRAME \start, SS+8+\offset-RIP
 258         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 259         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 260         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 261         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 262         CFI_REL_OFFSET rip, RIP+\offset-RIP
 263         .endm
 264
 265 /*
 266  * initial frame state for exceptions with error code (and interrupts
 267  * with vector already pushed)
 268  */
 269         .macro XCPT_FRAME start=1 offset=0
 270         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 271         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 272         .endm
 273
 274 /*
 275  * frame that enables calling into C.
 276  */
 277         .macro PARTIAL_FRAME start=1 offset=0
 278         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 279         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 280         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 281         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 282         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 283         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 284         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 285         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 286         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 287         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 288         .endm
 289
 290 /*
 291  * frame that enables passing a complete pt_regs to a C function.
 292  */
 293         .macro DEFAULT_FRAME start=1 offset=0
 294         PARTIAL_FRAME \start, R11+\offset-R15
 295         CFI_REL_OFFSET rbx, RBX+\offset
 296         CFI_REL_OFFSET rbp, RBP+\offset
 297         CFI_REL_OFFSET r12, R12+\offset
 298         CFI_REL_OFFSET r13, R13+\offset
 299         CFI_REL_OFFSET r14, R14+\offset
 300         CFI_REL_OFFSET r15, R15+\offset
 301         .endm
 302
 303 /* save partial stack frame */
 304         .macro SAVE_ARGS_IRQ
 305         cld
 306         /* start from rbp in pt_regs and jump over */
 307         movq_cfi rdi, RDI-RBP
 308         movq_cfi rsi, RSI-RBP
 309         movq_cfi rdx, RDX-RBP
 310         movq_cfi rcx, RCX-RBP
 311         movq_cfi rax, RAX-RBP
 312         movq_cfi  r8,  R8-RBP
 313         movq_cfi  r9,  R9-RBP
 314         movq_cfi r10, R10-RBP
 315         movq_cfi r11, R11-RBP
 316
 317         /* Save rbp so that we can unwind from get_irq_regs() */
 318         movq_cfi rbp, 0
 319
 320         /* Save previous stack value */
 321         movq %rsp, %rsi
 322
 323         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 324         testl $3, CS-RBP(%rsi)
 325         je 1f
 326         SWAPGS
 327         /*
 328          * irq_count is used to check if a CPU is already on an interrupt stack
 329          * or not. While this is essentially redundant with preempt_count it is
 330          * a little cheaper to use a separate counter in the PDA (short of
 331          * moving irq_enter into assembly, which would be too much work)
 332          */
 333 1:      incl PER_CPU_VAR(irq_count)
 334         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
 335         CFI_DEF_CFA_REGISTER    rsi
 336
 337         /* Store previous stack value */
 338         pushq %rsi
 339         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 340                         0x77 /* DW_OP_breg7 */, 0, \
 341                         0x06 /* DW_OP_deref */, \
 342                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 343                         0x22 /* DW_OP_plus */
 344         /* We entered an interrupt context - irqs are off: */
 345         TRACE_IRQS_OFF
 346         .endm
 347
 348 ENTRY(save_rest)
 349         PARTIAL_FRAME 1 REST_SKIP+8
 350         movq 5*8+16(%rsp), %r11 /* save return address */
 351         movq_cfi rbx, RBX+16
 352         movq_cfi rbp, RBP+16
 353         movq_cfi r12, R12+16
 354         movq_cfi r13, R13+16
 355         movq_cfi r14, R14+16
 356         movq_cfi r15, R15+16
 357         movq %r11, 8(%rsp)      /* return address */
 358         FIXUP_TOP_OF_STACK %r11, 16
 359         ret
 360         CFI_ENDPROC
 361 END(save_rest)
 362
 363 /* save complete stack frame */
 364         .pushsection .kprobes.text, "ax"
 365 ENTRY(save_paranoid)
 366         XCPT_FRAME 1 RDI+8
 367         cld
 368         movq_cfi rdi, RDI+8
 369         movq_cfi rsi, RSI+8
 370         movq_cfi rdx, RDX+8
 371         movq_cfi rcx, RCX+8
 372         movq_cfi rax, RAX+8
 373         movq_cfi r8, R8+8
 374         movq_cfi r9, R9+8
 375         movq_cfi r10, R10+8
 376         movq_cfi r11, R11+8
 377         movq_cfi rbx, RBX+8
 378         movq_cfi rbp, RBP+8
 379         movq_cfi r12, R12+8
 380         movq_cfi r13, R13+8
 381         movq_cfi r14, R14+8
 382         movq_cfi r15, R15+8
 383         movl $1,%ebx
 384         movl $MSR_GS_BASE,%ecx
 385         rdmsr
 386         testl %edx,%edx
 387         js 1f   /* negative -> in kernel */
 388         SWAPGS
 389         xorl %ebx,%ebx
 390 1:      ret
 391         CFI_ENDPROC
 392 END(save_paranoid)
 393         .popsection
 394
 395 /*
 396  * A newly forked process directly context switches into this address.
 397  *
 398  * rdi: prev task we switched from
 399  */
 400 ENTRY(ret_from_fork)
 401         DEFAULT_FRAME
 402
 403         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 404
 405         pushq_cfi kernel_eflags(%rip)
 406         popfq_cfi                               # reset kernel eflags
 407
 408         call schedule_tail                      # rdi: 'prev' task parameter
 409
 410         GET_THREAD_INFO(%rcx)
 411
 412         RESTORE_REST
 413
 414         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 415         jz   retint_restore_args
 416
 417         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 418         jnz  int_ret_from_sys_call
 419
 420         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 421         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 422
 423         CFI_ENDPROC
 424 END(ret_from_fork)
 425
 426 /*
 427  * System call entry. Up to 6 arguments in registers are supported.
 428  *
 429  * SYSCALL does not save anything on the stack and does not change the
 430  * stack pointer.
 431  */
 432
 433 /*
 434  * Register setup:
 435  * rax  system call number
 436  * rdi  arg0
 437  * rcx  return address for syscall/sysret, C arg3
 438  * rsi  arg1
 439  * rdx  arg2
 440  * r10  arg3    (--> moved to rcx for C)
 441  * r8   arg4
 442  * r9   arg5
 443  * r11  eflags for syscall/sysret, temporary for C
 444  * r12-r15,rbp,rbx saved by C code, not touched.
 445  *
 446  * Interrupts are off on entry.
 447  * Only called from user space.
 448  *
 449  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 450  *      and report it properly in ps. Unfortunately we haven't.
 451  *
 452  * When user can change the frames always force IRET. That is because
 453  * it deals with uncanonical addresses better. SYSRET has trouble
 454  * with them due to bugs in both AMD and Intel CPUs.
 455  */
 456
 457 ENTRY(system_call)
 458         CFI_STARTPROC   simple
 459         CFI_SIGNAL_FRAME
 460         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 461         CFI_REGISTER    rip,rcx
 462         /*CFI_REGISTER  rflags,r11*/
 463         SWAPGS_UNSAFE_STACK
 464         /*
 465          * A hypervisor implementation might want to use a label
 466          * after the swapgs, so that it can do the swapgs
 467          * for the guest and jump here on syscall.
 468          */
 469 GLOBAL(system_call_after_swapgs)
 470
 471         movq    %rsp,PER_CPU_VAR(old_rsp)
 472         movq    PER_CPU_VAR(kernel_stack),%rsp
 473         /*
 474          * No need to follow this irqs off/on section - it's straight
 475          * and short:
 476          */
 477         ENABLE_INTERRUPTS(CLBR_NONE)
 478         SAVE_ARGS 8,0
 479         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 480         movq  %rcx,RIP-ARGOFFSET(%rsp)
 481         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 482         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 483         jnz tracesys
 484 system_call_fastpath:
 485 #if __SYSCALL_MASK == ~0
 486         cmpq $__NR_syscall_max,%rax
 487 #else
 488         andl $__SYSCALL_MASK,%eax
 489         cmpl $__NR_syscall_max,%eax
 490 #endif
 491         ja badsys
 492         movq %r10,%rcx
 493         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 494         movq %rax,RAX-ARGOFFSET(%rsp)
 495 /*
 496  * Syscall return path ending with SYSRET (fast path)
 497  * Has incomplete stack frame and undefined top of stack.
 498  */
 499 ret_from_sys_call:
 500         movl $_TIF_ALLWORK_MASK,%edi
 501         /* edi: flagmask */
 502 sysret_check:
 503         LOCKDEP_SYS_EXIT
 504         DISABLE_INTERRUPTS(CLBR_NONE)
 505         TRACE_IRQS_OFF
 506         movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
 507         andl %edi,%edx
 508         jnz  sysret_careful
 509         CFI_REMEMBER_STATE
 510         /*
 511          * sysretq will re-enable interrupts:
 512          */
 513         TRACE_IRQS_ON
 514         movq RIP-ARGOFFSET(%rsp),%rcx
 515         CFI_REGISTER    rip,rcx
 516         RESTORE_ARGS 1,-ARG_SKIP,0
 517         /*CFI_REGISTER  rflags,r11*/
 518         movq    PER_CPU_VAR(old_rsp), %rsp
 519         USERGS_SYSRET64
 520
 521         CFI_RESTORE_STATE
 522         /* Handle reschedules */
 523         /* edx: work, edi: workmask */
 524 sysret_careful:
 525         bt $TIF_NEED_RESCHED,%edx
 526         jnc sysret_signal
 527         TRACE_IRQS_ON
 528         ENABLE_INTERRUPTS(CLBR_NONE)
 529         pushq_cfi %rdi
 530         call schedule
 531         popq_cfi %rdi
 532         jmp sysret_check
 533
 534         /* Handle a signal */
 535 sysret_signal:
 536         TRACE_IRQS_ON
 537         ENABLE_INTERRUPTS(CLBR_NONE)
 538 #ifdef CONFIG_AUDITSYSCALL
 539         bt $TIF_SYSCALL_AUDIT,%edx
 540         jc sysret_audit
 541 #endif
 542         /*
 543          * We have a signal, or exit tracing or single-step.
 544          * These all wind up with the iret return path anyway,
 545          * so just join that path right now.
 546          */
 547         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 548         jmp int_check_syscall_exit_work
 549
 550 badsys:
 551         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 552         jmp ret_from_sys_call
 553
 554 #ifdef CONFIG_AUDITSYSCALL
 555         /*
 556          * Fast path for syscall audit without full syscall trace.
 557          * We just call __audit_syscall_entry() directly, and then
 558          * jump back to the normal fast path.
 559          */
 560 auditsys:
 561         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 562         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 563         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 564         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 565         movq %rax,%rsi                  /* 2nd arg: syscall number */
 566         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 567         call __audit_syscall_entry
 568         LOAD_ARGS 0             /* reload call-clobbered registers */
 569         jmp system_call_fastpath
 570
 571         /*
 572          * Return fast path for syscall audit.  Call __audit_syscall_exit()
 573          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 574          * masked off.
 575          */
 576 sysret_audit:
 577         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 578         cmpq $-MAX_ERRNO,%rsi   /* is it < -MAX_ERRNO? */
 579         setbe %al               /* 1 if so, 0 if not */
 580         movzbl %al,%edi         /* zero-extend that into %edi */
 581         call __audit_syscall_exit
 582         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 583         jmp sysret_check
 584 #endif  /* CONFIG_AUDITSYSCALL */
 585
 586         /* Do syscall tracing */
 587 tracesys:
 588 #ifdef CONFIG_AUDITSYSCALL
 589         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 590         jz auditsys
 591 #endif
 592         SAVE_REST
 593         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 594         FIXUP_TOP_OF_STACK %rdi
 595         movq %rsp,%rdi
 596         call syscall_trace_enter
 597         /*
 598          * Reload arg registers from stack in case ptrace changed them.
 599          * We don't reload %rax because syscall_trace_enter() returned
 600          * the value it wants us to use in the table lookup.
 601          */
 602         LOAD_ARGS ARGOFFSET, 1
 603         RESTORE_REST
 604 #if __SYSCALL_MASK == ~0
 605         cmpq $__NR_syscall_max,%rax
 606 #else
 607         andl $__SYSCALL_MASK,%eax
 608         cmpl $__NR_syscall_max,%eax
 609 #endif
 610         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 611         movq %r10,%rcx  /* fixup for C */
 612         call *sys_call_table(,%rax,8)
 613         movq %rax,RAX-ARGOFFSET(%rsp)
 614         /* Use IRET because user could have changed frame */
 615
 616 /*
 617  * Syscall return path ending with IRET.
 618  * Has correct top of stack, but partial stack frame.
 619  */
 620 GLOBAL(int_ret_from_sys_call)
 621         DISABLE_INTERRUPTS(CLBR_NONE)
 622         TRACE_IRQS_OFF
 623         movl $_TIF_ALLWORK_MASK,%edi
 624         /* edi: mask to check */
 625 GLOBAL(int_with_check)
 626         LOCKDEP_SYS_EXIT_IRQ
 627         GET_THREAD_INFO(%rcx)
 628         movl TI_flags(%rcx),%edx
 629         andl %edi,%edx
 630         jnz   int_careful
 631         andl    $~TS_COMPAT,TI_status(%rcx)
 632         jmp   retint_swapgs
 633
 634         /* Either reschedule or signal or syscall exit tracking needed. */
 635         /* First do a reschedule test. */
 636         /* edx: work, edi: workmask */
 637 int_careful:
 638         bt $TIF_NEED_RESCHED,%edx
 639         jnc  int_very_careful
 640         TRACE_IRQS_ON
 641         ENABLE_INTERRUPTS(CLBR_NONE)
 642         pushq_cfi %rdi
 643         call schedule
 644         popq_cfi %rdi
 645         DISABLE_INTERRUPTS(CLBR_NONE)
 646         TRACE_IRQS_OFF
 647         jmp int_with_check
 648
 649         /* handle signals and tracing -- both require a full stack frame */
 650 int_very_careful:
 651         TRACE_IRQS_ON
 652         ENABLE_INTERRUPTS(CLBR_NONE)
 653 int_check_syscall_exit_work:
 654         SAVE_REST
 655         /* Check for syscall exit trace */
 656         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 657         jz int_signal
 658         pushq_cfi %rdi
 659         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 660         call syscall_trace_leave
 661         popq_cfi %rdi
 662         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 663         jmp int_restore_rest
 664
 665 int_signal:
 666         testl $_TIF_DO_NOTIFY_MASK,%edx
 667         jz 1f
 668         movq %rsp,%rdi          # &ptregs -> arg1
 669         xorl %esi,%esi          # oldset -> arg2
 670         call do_notify_resume
 671 1:      movl $_TIF_WORK_MASK,%edi
 672 int_restore_rest:
 673         RESTORE_REST
 674         DISABLE_INTERRUPTS(CLBR_NONE)
 675         TRACE_IRQS_OFF
 676         jmp int_with_check
 677         CFI_ENDPROC
 678 END(system_call)
 679
 680 /*
 681  * Certain special system calls that need to save a complete full stack frame.
 682  */
 683         .macro PTREGSCALL label,func,arg
 684 ENTRY(\label)
 685         PARTIAL_FRAME 1 8               /* offset 8: return address */
 686         subq $REST_SKIP, %rsp
 687         CFI_ADJUST_CFA_OFFSET REST_SKIP
 688         call save_rest
 689         DEFAULT_FRAME 0 8               /* offset 8: return address */
 690         leaq 8(%rsp), \arg      /* pt_regs pointer */
 691         call \func
 692         jmp ptregscall_common
 693         CFI_ENDPROC
 694 END(\label)
 695         .endm
 696
 697         PTREGSCALL stub_clone, sys_clone, %r8
 698         PTREGSCALL stub_fork, sys_fork, %rdi
 699         PTREGSCALL stub_vfork, sys_vfork, %rdi
 700         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 701         PTREGSCALL stub_iopl, sys_iopl, %rsi
 702
 703 ENTRY(ptregscall_common)
 704         DEFAULT_FRAME 1 8       /* offset 8: return address */
 705         RESTORE_TOP_OF_STACK %r11, 8
 706         movq_cfi_restore R15+8, r15
 707         movq_cfi_restore R14+8, r14
 708         movq_cfi_restore R13+8, r13
 709         movq_cfi_restore R12+8, r12
 710         movq_cfi_restore RBP+8, rbp
 711         movq_cfi_restore RBX+8, rbx
 712         ret $REST_SKIP          /* pop extended registers */
 713         CFI_ENDPROC
 714 END(ptregscall_common)
 715
 716 ENTRY(stub_execve)
 717         CFI_STARTPROC
 718         addq $8, %rsp
 719         PARTIAL_FRAME 0
 720         SAVE_REST
 721         FIXUP_TOP_OF_STACK %r11
 722         movq %rsp, %rcx
 723         call sys_execve
 724         RESTORE_TOP_OF_STACK %r11
 725         movq %rax,RAX(%rsp)
 726         RESTORE_REST
 727         jmp int_ret_from_sys_call
 728         CFI_ENDPROC
 729 END(stub_execve)
 730
 731 /*
 732  * sigreturn is special because it needs to restore all registers on return.
 733  * This cannot be done with SYSRET, so use the IRET return path instead.
 734  */
 735 ENTRY(stub_rt_sigreturn)
 736         CFI_STARTPROC
 737         addq $8, %rsp
 738         PARTIAL_FRAME 0
 739         SAVE_REST
 740         movq %rsp,%rdi
 741         FIXUP_TOP_OF_STACK %r11
 742         call sys_rt_sigreturn
 743         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 744         RESTORE_REST
 745         jmp int_ret_from_sys_call
 746         CFI_ENDPROC
 747 END(stub_rt_sigreturn)
 748
 749 #ifdef CONFIG_X86_X32_ABI
 750         PTREGSCALL stub_x32_sigaltstack, sys32_sigaltstack, %rdx
 751
 752 ENTRY(stub_x32_rt_sigreturn)
 753         CFI_STARTPROC
 754         addq $8, %rsp
 755         PARTIAL_FRAME 0
 756         SAVE_REST
 757         movq %rsp,%rdi
 758         FIXUP_TOP_OF_STACK %r11
 759         call sys32_x32_rt_sigreturn
 760         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 761         RESTORE_REST
 762         jmp int_ret_from_sys_call
 763         CFI_ENDPROC
 764 END(stub_x32_rt_sigreturn)
 765
 766 ENTRY(stub_x32_execve)
 767         CFI_STARTPROC
 768         addq $8, %rsp
 769         PARTIAL_FRAME 0
 770         SAVE_REST
 771         FIXUP_TOP_OF_STACK %r11
 772         movq %rsp, %rcx
 773         call sys32_execve
 774         RESTORE_TOP_OF_STACK %r11
 775         movq %rax,RAX(%rsp)
 776         RESTORE_REST
 777         jmp int_ret_from_sys_call
 778         CFI_ENDPROC
 779 END(stub_x32_execve)
 780
 781 #endif
 782
 783 /*
 784  * Build the entry stubs and pointer table with some assembler magic.
 785  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 786  * single cache line on all modern x86 implementations.
 787  */
 788         .section .init.rodata,"a"
 789 ENTRY(interrupt)
 790         .section .entry.text
 791         .p2align 5
 792         .p2align CONFIG_X86_L1_CACHE_SHIFT
 793 ENTRY(irq_entries_start)
 794         INTR_FRAME
 795 vector=FIRST_EXTERNAL_VECTOR
 796 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 797         .balign 32
 798   .rept 7
 799     .if vector < NR_VECTORS
 800       .if vector <> FIRST_EXTERNAL_VECTOR
 801         CFI_ADJUST_CFA_OFFSET -8
 802       .endif
 803 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 804       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 805         jmp 2f
 806       .endif
 807       .previous
 808         .quad 1b
 809       .section .entry.text
 810 vector=vector+1
 811     .endif
 812   .endr
 813 2:      jmp common_interrupt
 814 .endr
 815         CFI_ENDPROC
 816 END(irq_entries_start)
 817
 818 .previous
 819 END(interrupt)
 820 .previous
 821
 822 /*
 823  * Interrupt entry/exit.
 824  *
 825  * Interrupt entry points save only callee clobbered registers in fast path.
 826  *
 827  * Entry runs with interrupts off.
 828  */
 829
 830 /* 0(%rsp): ~(interrupt number) */
 831         .macro interrupt func
 832         /* reserve pt_regs for scratch regs and rbp */
 833         subq $ORIG_RAX-RBP, %rsp
 834         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 835         SAVE_ARGS_IRQ
 836         call \func
 837         .endm
 838
 839 /*
 840  * Interrupt entry/exit should be protected against kprobes
 841  */
 842         .pushsection .kprobes.text, "ax"
 843         /*
 844          * The interrupt stubs push (~vector+0x80) onto the stack and
 845          * then jump to common_interrupt.
 846          */
 847         .p2align CONFIG_X86_L1_CACHE_SHIFT
 848 common_interrupt:
 849         XCPT_FRAME
 850         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 851         interrupt do_IRQ
 852         /* 0(%rsp): old_rsp-ARGOFFSET */
 853 ret_from_intr:
 854         DISABLE_INTERRUPTS(CLBR_NONE)
 855         TRACE_IRQS_OFF
 856         decl PER_CPU_VAR(irq_count)
 857
 858         /* Restore saved previous stack */
 859         popq %rsi
 860         CFI_DEF_CFA rsi,SS+8-RBP        /* reg/off reset after def_cfa_expr */
 861         leaq ARGOFFSET-RBP(%rsi), %rsp
 862         CFI_DEF_CFA_REGISTER    rsp
 863         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
 864
 865 exit_intr:
 866         GET_THREAD_INFO(%rcx)
 867         testl $3,CS-ARGOFFSET(%rsp)
 868         je retint_kernel
 869
 870         /* Interrupt came from user space */
 871         /*
 872          * Has a correct top of stack, but a partial stack frame
 873          * %rcx: thread info. Interrupts off.
 874          */
 875 retint_with_reschedule:
 876         movl $_TIF_WORK_MASK,%edi
 877 retint_check:
 878         LOCKDEP_SYS_EXIT_IRQ
 879         movl TI_flags(%rcx),%edx
 880         andl %edi,%edx
 881         CFI_REMEMBER_STATE
 882         jnz  retint_careful
 883
 884 retint_swapgs:          /* return to user-space */
 885         /*
 886          * The iretq could re-enable interrupts:
 887          */
 888         DISABLE_INTERRUPTS(CLBR_ANY)
 889         TRACE_IRQS_IRETQ
 890         SWAPGS
 891         jmp restore_args
 892
 893 retint_restore_args:    /* return to kernel space */
 894         DISABLE_INTERRUPTS(CLBR_ANY)
 895         /*
 896          * The iretq could re-enable interrupts:
 897          */
 898         TRACE_IRQS_IRETQ
 899 restore_args:
 900         RESTORE_ARGS 1,8,1
 901
 902 irq_return:
 903         INTERRUPT_RETURN
 904         _ASM_EXTABLE(irq_return, bad_iret)
 905
 906 #ifdef CONFIG_PARAVIRT
 907 ENTRY(native_iret)
 908         iretq
 909         _ASM_EXTABLE(native_iret, bad_iret)
 910 #endif
 911
 912         .section .fixup,"ax"
 913 bad_iret:
 914         /*
 915          * The iret traps when the %cs or %ss being restored is bogus.
 916          * We've lost the original trap vector and error code.
 917          * #GPF is the most likely one to get for an invalid selector.
 918          * So pretend we completed the iret and took the #GPF in user mode.
 919          *
 920          * We are now running with the kernel GS after exception recovery.
 921          * But error_entry expects us to have user GS to match the user %cs,
 922          * so swap back.
 923          */
 924         pushq $0
 925
 926         SWAPGS
 927         jmp general_protection
 928
 929         .previous
 930
 931         /* edi: workmask, edx: work */
 932 retint_careful:
 933         CFI_RESTORE_STATE
 934         bt    $TIF_NEED_RESCHED,%edx
 935         jnc   retint_signal
 936         TRACE_IRQS_ON
 937         ENABLE_INTERRUPTS(CLBR_NONE)
 938         pushq_cfi %rdi
 939         call  schedule
 940         popq_cfi %rdi
 941         GET_THREAD_INFO(%rcx)
 942         DISABLE_INTERRUPTS(CLBR_NONE)
 943         TRACE_IRQS_OFF
 944         jmp retint_check
 945
 946 retint_signal:
 947         testl $_TIF_DO_NOTIFY_MASK,%edx
 948         jz    retint_swapgs
 949         TRACE_IRQS_ON
 950         ENABLE_INTERRUPTS(CLBR_NONE)
 951         SAVE_REST
 952         movq $-1,ORIG_RAX(%rsp)
 953         xorl %esi,%esi          # oldset
 954         movq %rsp,%rdi          # &pt_regs
 955         call do_notify_resume
 956         RESTORE_REST
 957         DISABLE_INTERRUPTS(CLBR_NONE)
 958         TRACE_IRQS_OFF
 959         GET_THREAD_INFO(%rcx)
 960         jmp retint_with_reschedule
 961
 962 #ifdef CONFIG_PREEMPT
 963         /* Returning to kernel space. Check if we need preemption */
 964         /* rcx:  threadinfo. interrupts off. */
 965 ENTRY(retint_kernel)
 966         cmpl $0,TI_preempt_count(%rcx)
 967         jnz  retint_restore_args
 968         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 969         jnc  retint_restore_args
 970         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 971         jnc  retint_restore_args
 972         call preempt_schedule_irq
 973         jmp exit_intr
 974 #endif
 975
 976         CFI_ENDPROC
 977 END(common_interrupt)
 978 /*
 979  * End of kprobes section
 980  */
 981        .popsection
 982
 983 /*
 984  * APIC interrupts.
 985  */
 986 .macro apicinterrupt num sym do_sym
 987 ENTRY(\sym)
 988         INTR_FRAME
 989         pushq_cfi $~(\num)
 990 .Lcommon_\sym:
 991         interrupt \do_sym
 992         jmp ret_from_intr
 993         CFI_ENDPROC
 994 END(\sym)
 995 .endm
 996
 997 #ifdef CONFIG_SMP
 998 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 999         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1000 apicinterrupt REBOOT_VECTOR \
1001         reboot_interrupt smp_reboot_interrupt
1002 #endif
1003
1004 #ifdef CONFIG_X86_UV
1005 apicinterrupt UV_BAU_MESSAGE \
1006         uv_bau_message_intr1 uv_bau_message_interrupt
1007 #endif
1008 apicinterrupt LOCAL_TIMER_VECTOR \
1009         apic_timer_interrupt smp_apic_timer_interrupt
1010 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1011         x86_platform_ipi smp_x86_platform_ipi
1012
1013 #ifdef CONFIG_SMP
1014         ALIGN
1015         INTR_FRAME
1016 .irp idx,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15, \
1017         16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
1018 .if NUM_INVALIDATE_TLB_VECTORS > \idx
1019 ENTRY(invalidate_interrupt\idx)
1020         pushq_cfi $~(INVALIDATE_TLB_VECTOR_START+\idx)
1021         jmp .Lcommon_invalidate_interrupt0
1022         CFI_ADJUST_CFA_OFFSET -8
1023 END(invalidate_interrupt\idx)
1024 .endif
1025 .endr
1026         CFI_ENDPROC
1027 apicinterrupt INVALIDATE_TLB_VECTOR_START, \
1028         invalidate_interrupt0, smp_invalidate_interrupt
1029 #endif
1030
1031 apicinterrupt THRESHOLD_APIC_VECTOR \
1032         threshold_interrupt smp_threshold_interrupt
1033 apicinterrupt THERMAL_APIC_VECTOR \
1034         thermal_interrupt smp_thermal_interrupt
1035
1036 #ifdef CONFIG_SMP
1037 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1038         call_function_single_interrupt smp_call_function_single_interrupt
1039 apicinterrupt CALL_FUNCTION_VECTOR \
1040         call_function_interrupt smp_call_function_interrupt
1041 apicinterrupt RESCHEDULE_VECTOR \
1042         reschedule_interrupt smp_reschedule_interrupt
1043 #endif
1044
1045 apicinterrupt ERROR_APIC_VECTOR \
1046         error_interrupt smp_error_interrupt
1047 apicinterrupt SPURIOUS_APIC_VECTOR \
1048         spurious_interrupt smp_spurious_interrupt
1049
1050 #ifdef CONFIG_IRQ_WORK
1051 apicinterrupt IRQ_WORK_VECTOR \
1052         irq_work_interrupt smp_irq_work_interrupt
1053 #endif
1054
1055 /*
1056  * Exception entry points.
1057  */
1058 .macro zeroentry sym do_sym
1059 ENTRY(\sym)
1060         INTR_FRAME
1061         PARAVIRT_ADJUST_EXCEPTION_FRAME
1062         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1063         subq $ORIG_RAX-R15, %rsp
1064         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1065         call error_entry
1066         DEFAULT_FRAME 0
1067         movq %rsp,%rdi          /* pt_regs pointer */
1068         xorl %esi,%esi          /* no error code */
1069         call \do_sym
1070         jmp error_exit          /* %ebx: no swapgs flag */
1071         CFI_ENDPROC
1072 END(\sym)
1073 .endm
1074
1075 .macro paranoidzeroentry sym do_sym
1076 ENTRY(\sym)
1077         INTR_FRAME
1078         PARAVIRT_ADJUST_EXCEPTION_FRAME
1079         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1080         subq $ORIG_RAX-R15, %rsp
1081         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1082         call save_paranoid
1083         TRACE_IRQS_OFF
1084         movq %rsp,%rdi          /* pt_regs pointer */
1085         xorl %esi,%esi          /* no error code */
1086         call \do_sym
1087         jmp paranoid_exit       /* %ebx: no swapgs flag */
1088         CFI_ENDPROC
1089 END(\sym)
1090 .endm
1091
1092 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1093 .macro paranoidzeroentry_ist sym do_sym ist
1094 ENTRY(\sym)
1095         INTR_FRAME
1096         PARAVIRT_ADJUST_EXCEPTION_FRAME
1097         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1098         subq $ORIG_RAX-R15, %rsp
1099         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1100         call save_paranoid
1101         TRACE_IRQS_OFF
1102         movq %rsp,%rdi          /* pt_regs pointer */
1103         xorl %esi,%esi          /* no error code */
1104         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1105         call \do_sym
1106         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1107         jmp paranoid_exit       /* %ebx: no swapgs flag */
1108         CFI_ENDPROC
1109 END(\sym)
1110 .endm
1111
1112 .macro errorentry sym do_sym
1113 ENTRY(\sym)
1114         XCPT_FRAME
1115         PARAVIRT_ADJUST_EXCEPTION_FRAME
1116         subq $ORIG_RAX-R15, %rsp
1117         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1118         call error_entry
1119         DEFAULT_FRAME 0
1120         movq %rsp,%rdi                  /* pt_regs pointer */
1121         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1122         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1123         call \do_sym
1124         jmp error_exit                  /* %ebx: no swapgs flag */
1125         CFI_ENDPROC
1126 END(\sym)
1127 .endm
1128
1129         /* error code is on the stack already */
1130 .macro paranoiderrorentry sym do_sym
1131 ENTRY(\sym)
1132         XCPT_FRAME
1133         PARAVIRT_ADJUST_EXCEPTION_FRAME
1134         subq $ORIG_RAX-R15, %rsp
1135         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1136         call save_paranoid
1137         DEFAULT_FRAME 0
1138         TRACE_IRQS_OFF
1139         movq %rsp,%rdi                  /* pt_regs pointer */
1140         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1141         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1142         call \do_sym
1143         jmp paranoid_exit               /* %ebx: no swapgs flag */
1144         CFI_ENDPROC
1145 END(\sym)
1146 .endm
1147
1148 zeroentry divide_error do_divide_error
1149 zeroentry overflow do_overflow
1150 zeroentry bounds do_bounds
1151 zeroentry invalid_op do_invalid_op
1152 zeroentry device_not_available do_device_not_available
1153 paranoiderrorentry double_fault do_double_fault
1154 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1155 errorentry invalid_TSS do_invalid_TSS
1156 errorentry segment_not_present do_segment_not_present
1157 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1158 zeroentry coprocessor_error do_coprocessor_error
1159 errorentry alignment_check do_alignment_check
1160 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1161
1162
1163         /* Reload gs selector with exception handling */
1164         /* edi:  new selector */
1165 ENTRY(native_load_gs_index)
1166         CFI_STARTPROC
1167         pushfq_cfi
1168         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1169         SWAPGS
1170 gs_change:
1171         movl %edi,%gs
1172 2:      mfence          /* workaround */
1173         SWAPGS
1174         popfq_cfi
1175         ret
1176         CFI_ENDPROC
1177 END(native_load_gs_index)
1178
1179         _ASM_EXTABLE(gs_change,bad_gs)
1180         .section .fixup,"ax"
1181         /* running with kernelgs */
1182 bad_gs:
1183         SWAPGS                  /* switch back to user gs */
1184         xorl %eax,%eax
1185         movl %eax,%gs
1186         jmp  2b
1187         .previous
1188
1189 ENTRY(kernel_thread_helper)
1190         pushq $0                # fake return address
1191         CFI_STARTPROC
1192         /*
1193          * Here we are in the child and the registers are set as they were
1194          * at kernel_thread() invocation in the parent.
1195          */
1196         call *%rsi
1197         # exit
1198         mov %eax, %edi
1199         call do_exit
1200         ud2                     # padding for call trace
1201         CFI_ENDPROC
1202 END(kernel_thread_helper)
1203
1204 /*
1205  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1206  *
1207  * C extern interface:
1208  *       extern long execve(const char *name, char **argv, char **envp)
1209  *
1210  * asm input arguments:
1211  *      rdi: name, rsi: argv, rdx: envp
1212  *
1213  * We want to fallback into:
1214  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1215  *
1216  * do_sys_execve asm fallback arguments:
1217  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1218  */
1219 ENTRY(kernel_execve)
1220         CFI_STARTPROC
1221         FAKE_STACK_FRAME $0
1222         SAVE_ALL
1223         movq %rsp,%rcx
1224         call sys_execve
1225         movq %rax, RAX(%rsp)
1226         RESTORE_REST
1227         testq %rax,%rax
1228         je int_ret_from_sys_call
1229         RESTORE_ARGS
1230         UNFAKE_STACK_FRAME
1231         ret
1232         CFI_ENDPROC
1233 END(kernel_execve)
1234
1235 /* Call softirq on interrupt stack. Interrupts are off. */
1236 ENTRY(call_softirq)
1237         CFI_STARTPROC
1238         pushq_cfi %rbp
1239         CFI_REL_OFFSET rbp,0
1240         mov  %rsp,%rbp
1241         CFI_DEF_CFA_REGISTER rbp
1242         incl PER_CPU_VAR(irq_count)
1243         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1244         push  %rbp                      # backlink for old unwinder
1245         call __do_softirq
1246         leaveq
1247         CFI_RESTORE             rbp
1248         CFI_DEF_CFA_REGISTER    rsp
1249         CFI_ADJUST_CFA_OFFSET   -8
1250         decl PER_CPU_VAR(irq_count)
1251         ret
1252         CFI_ENDPROC
1253 END(call_softirq)
1254
1255 #ifdef CONFIG_XEN
1256 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1257
1258 /*
1259  * A note on the "critical region" in our callback handler.
1260  * We want to avoid stacking callback handlers due to events occurring
1261  * during handling of the last event. To do this, we keep events disabled
1262  * until we've done all processing. HOWEVER, we must enable events before
1263  * popping the stack frame (can't be done atomically) and so it would still
1264  * be possible to get enough handler activations to overflow the stack.
1265  * Although unlikely, bugs of that kind are hard to track down, so we'd
1266  * like to avoid the possibility.
1267  * So, on entry to the handler we detect whether we interrupted an
1268  * existing activation in its critical region -- if so, we pop the current
1269  * activation and restart the handler using the previous one.
1270  */
1271 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1272         CFI_STARTPROC
1273 /*
1274  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1275  * see the correct pointer to the pt_regs
1276  */
1277         movq %rdi, %rsp            # we don't return, adjust the stack frame
1278         CFI_ENDPROC
1279         DEFAULT_FRAME
1280 11:     incl PER_CPU_VAR(irq_count)
1281         movq %rsp,%rbp
1282         CFI_DEF_CFA_REGISTER rbp
1283         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1284         pushq %rbp                      # backlink for old unwinder
1285         call xen_evtchn_do_upcall
1286         popq %rsp
1287         CFI_DEF_CFA_REGISTER rsp
1288         decl PER_CPU_VAR(irq_count)
1289         jmp  error_exit
1290         CFI_ENDPROC
1291 END(xen_do_hypervisor_callback)
1292
1293 /*
1294  * Hypervisor uses this for application faults while it executes.
1295  * We get here for two reasons:
1296  *  1. Fault while reloading DS, ES, FS or GS
1297  *  2. Fault while executing IRET
1298  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1299  * registers that could be reloaded and zeroed the others.
1300  * Category 2 we fix up by killing the current process. We cannot use the
1301  * normal Linux return path in this case because if we use the IRET hypercall
1302  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1303  * We distinguish between categories by comparing each saved segment register
1304  * with its current contents: any discrepancy means we in category 1.
1305  */
1306 ENTRY(xen_failsafe_callback)
1307         INTR_FRAME 1 (6*8)
1308         /*CFI_REL_OFFSET gs,GS*/
1309         /*CFI_REL_OFFSET fs,FS*/
1310         /*CFI_REL_OFFSET es,ES*/
1311         /*CFI_REL_OFFSET ds,DS*/
1312         CFI_REL_OFFSET r11,8
1313         CFI_REL_OFFSET rcx,0
1314         movw %ds,%cx
1315         cmpw %cx,0x10(%rsp)
1316         CFI_REMEMBER_STATE
1317         jne 1f
1318         movw %es,%cx
1319         cmpw %cx,0x18(%rsp)
1320         jne 1f
1321         movw %fs,%cx
1322         cmpw %cx,0x20(%rsp)
1323         jne 1f
1324         movw %gs,%cx
1325         cmpw %cx,0x28(%rsp)
1326         jne 1f
1327         /* All segments match their saved values => Category 2 (Bad IRET). */
1328         movq (%rsp),%rcx
1329         CFI_RESTORE rcx
1330         movq 8(%rsp),%r11
1331         CFI_RESTORE r11
1332         addq $0x30,%rsp
1333         CFI_ADJUST_CFA_OFFSET -0x30
1334         pushq_cfi $0    /* RIP */
1335         pushq_cfi %r11
1336         pushq_cfi %rcx
1337         jmp general_protection
1338         CFI_RESTORE_STATE
1339 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1340         movq (%rsp),%rcx
1341         CFI_RESTORE rcx
1342         movq 8(%rsp),%r11
1343         CFI_RESTORE r11
1344         addq $0x30,%rsp
1345         CFI_ADJUST_CFA_OFFSET -0x30
1346         pushq_cfi $0
1347         SAVE_ALL
1348         jmp error_exit
1349         CFI_ENDPROC
1350 END(xen_failsafe_callback)
1351
1352 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1353         xen_hvm_callback_vector xen_evtchn_do_upcall
1354
1355 #endif /* CONFIG_XEN */
1356
1357 /*
1358  * Some functions should be protected against kprobes
1359  */
1360         .pushsection .kprobes.text, "ax"
1361
1362 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1363 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1364 paranoiderrorentry stack_segment do_stack_segment
1365 #ifdef CONFIG_XEN
1366 zeroentry xen_debug do_debug
1367 zeroentry xen_int3 do_int3
1368 errorentry xen_stack_segment do_stack_segment
1369 #endif
1370 errorentry general_protection do_general_protection
1371 errorentry page_fault do_page_fault
1372 #ifdef CONFIG_KVM_GUEST
1373 errorentry async_page_fault do_async_page_fault
1374 #endif
1375 #ifdef CONFIG_X86_MCE
1376 paranoidzeroentry machine_check *machine_check_vector(%rip)
1377 #endif
1378
1379         /*
1380          * "Paranoid" exit path from exception stack.
1381          * Paranoid because this is used by NMIs and cannot take
1382          * any kernel state for granted.
1383          * We don't do kernel preemption checks here, because only
1384          * NMI should be common and it does not enable IRQs and
1385          * cannot get reschedule ticks.
1386          *
1387          * "trace" is 0 for the NMI handler only, because irq-tracing
1388          * is fundamentally NMI-unsafe. (we cannot change the soft and
1389          * hard flags at once, atomically)
1390          */
1391
1392         /* ebx: no swapgs flag */
1393 ENTRY(paranoid_exit)
1394         DEFAULT_FRAME
1395         DISABLE_INTERRUPTS(CLBR_NONE)
1396         TRACE_IRQS_OFF
1397         testl %ebx,%ebx                         /* swapgs needed? */
1398         jnz paranoid_restore
1399         testl $3,CS(%rsp)
1400         jnz   paranoid_userspace
1401 paranoid_swapgs:
1402         TRACE_IRQS_IRETQ 0
1403         SWAPGS_UNSAFE_STACK
1404         RESTORE_ALL 8
1405         jmp irq_return
1406 paranoid_restore:
1407         TRACE_IRQS_IRETQ 0
1408         RESTORE_ALL 8
1409         jmp irq_return
1410 paranoid_userspace:
1411         GET_THREAD_INFO(%rcx)
1412         movl TI_flags(%rcx),%ebx
1413         andl $_TIF_WORK_MASK,%ebx
1414         jz paranoid_swapgs
1415         movq %rsp,%rdi                  /* &pt_regs */
1416         call sync_regs
1417         movq %rax,%rsp                  /* switch stack for scheduling */
1418         testl $_TIF_NEED_RESCHED,%ebx
1419         jnz paranoid_schedule
1420         movl %ebx,%edx                  /* arg3: thread flags */
1421         TRACE_IRQS_ON
1422         ENABLE_INTERRUPTS(CLBR_NONE)
1423         xorl %esi,%esi                  /* arg2: oldset */
1424         movq %rsp,%rdi                  /* arg1: &pt_regs */
1425         call do_notify_resume
1426         DISABLE_INTERRUPTS(CLBR_NONE)
1427         TRACE_IRQS_OFF
1428         jmp paranoid_userspace
1429 paranoid_schedule:
1430         TRACE_IRQS_ON
1431         ENABLE_INTERRUPTS(CLBR_ANY)
1432         call schedule
1433         DISABLE_INTERRUPTS(CLBR_ANY)
1434         TRACE_IRQS_OFF
1435         jmp paranoid_userspace
1436         CFI_ENDPROC
1437 END(paranoid_exit)
1438
1439 /*
1440  * Exception entry point. This expects an error code/orig_rax on the stack.
1441  * returns in "no swapgs flag" in %ebx.
1442  */
1443 ENTRY(error_entry)
1444         XCPT_FRAME
1445         CFI_ADJUST_CFA_OFFSET 15*8
1446         /* oldrax contains error code */
1447         cld
1448         movq_cfi rdi, RDI+8
1449         movq_cfi rsi, RSI+8
1450         movq_cfi rdx, RDX+8
1451         movq_cfi rcx, RCX+8
1452         movq_cfi rax, RAX+8
1453         movq_cfi  r8,  R8+8
1454         movq_cfi  r9,  R9+8
1455         movq_cfi r10, R10+8
1456         movq_cfi r11, R11+8
1457         movq_cfi rbx, RBX+8
1458         movq_cfi rbp, RBP+8
1459         movq_cfi r12, R12+8
1460         movq_cfi r13, R13+8
1461         movq_cfi r14, R14+8
1462         movq_cfi r15, R15+8
1463         xorl %ebx,%ebx
1464         testl $3,CS+8(%rsp)
1465         je error_kernelspace
1466 error_swapgs:
1467         SWAPGS
1468 error_sti:
1469         TRACE_IRQS_OFF
1470         ret
1471
1472 /*
1473  * There are two places in the kernel that can potentially fault with
1474  * usergs. Handle them here. The exception handlers after iret run with
1475  * kernel gs again, so don't set the user space flag. B stepping K8s
1476  * sometimes report an truncated RIP for IRET exceptions returning to
1477  * compat mode. Check for these here too.
1478  */
1479 error_kernelspace:
1480         incl %ebx
1481         leaq irq_return(%rip),%rcx
1482         cmpq %rcx,RIP+8(%rsp)
1483         je error_swapgs
1484         movl %ecx,%eax  /* zero extend */
1485         cmpq %rax,RIP+8(%rsp)
1486         je bstep_iret
1487         cmpq $gs_change,RIP+8(%rsp)
1488         je error_swapgs
1489         jmp error_sti
1490
1491 bstep_iret:
1492         /* Fix truncated RIP */
1493         movq %rcx,RIP+8(%rsp)
1494         jmp error_swapgs
1495         CFI_ENDPROC
1496 END(error_entry)
1497
1498
1499 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1500 ENTRY(error_exit)
1501         DEFAULT_FRAME
1502         movl %ebx,%eax
1503         RESTORE_REST
1504         DISABLE_INTERRUPTS(CLBR_NONE)
1505         TRACE_IRQS_OFF
1506         GET_THREAD_INFO(%rcx)
1507         testl %eax,%eax
1508         jne retint_kernel
1509         LOCKDEP_SYS_EXIT_IRQ
1510         movl TI_flags(%rcx),%edx
1511         movl $_TIF_WORK_MASK,%edi
1512         andl %edi,%edx
1513         jnz retint_careful
1514         jmp retint_swapgs
1515         CFI_ENDPROC
1516 END(error_exit)
1517
1518 /*
1519  * Test if a given stack is an NMI stack or not.
1520  */
1521         .macro test_in_nmi reg stack nmi_ret normal_ret
1522         cmpq %\reg, \stack
1523         ja \normal_ret
1524         subq $EXCEPTION_STKSZ, %\reg
1525         cmpq %\reg, \stack
1526         jb \normal_ret
1527         jmp \nmi_ret
1528         .endm
1529
1530         /* runs on exception stack */
1531 ENTRY(nmi)
1532         INTR_FRAME
1533         PARAVIRT_ADJUST_EXCEPTION_FRAME
1534         /*
1535          * We allow breakpoints in NMIs. If a breakpoint occurs, then
1536          * the iretq it performs will take us out of NMI context.
1537          * This means that we can have nested NMIs where the next
1538          * NMI is using the top of the stack of the previous NMI. We
1539          * can't let it execute because the nested NMI will corrupt the
1540          * stack of the previous NMI. NMI handlers are not re-entrant
1541          * anyway.
1542          *
1543          * To handle this case we do the following:
1544          *  Check the a special location on the stack that contains
1545          *  a variable that is set when NMIs are executing.
1546          *  The interrupted task's stack is also checked to see if it
1547          *  is an NMI stack.
1548          *  If the variable is not set and the stack is not the NMI
1549          *  stack then:
1550          *    o Set the special variable on the stack
1551          *    o Copy the interrupt frame into a "saved" location on the stack
1552          *    o Copy the interrupt frame into a "copy" location on the stack
1553          *    o Continue processing the NMI
1554          *  If the variable is set or the previous stack is the NMI stack:
1555          *    o Modify the "copy" location to jump to the repeate_nmi
1556          *    o return back to the first NMI
1557          *
1558          * Now on exit of the first NMI, we first clear the stack variable
1559          * The NMI stack will tell any nested NMIs at that point that it is
1560          * nested. Then we pop the stack normally with iret, and if there was
1561          * a nested NMI that updated the copy interrupt stack frame, a
1562          * jump will be made to the repeat_nmi code that will handle the second
1563          * NMI.
1564          */
1565
1566         /* Use %rdx as out temp variable throughout */
1567         pushq_cfi %rdx
1568         CFI_REL_OFFSET rdx, 0
1569
1570         /*
1571          * If %cs was not the kernel segment, then the NMI triggered in user
1572          * space, which means it is definitely not nested.
1573          */
1574         cmpl $__KERNEL_CS, 16(%rsp)
1575         jne first_nmi
1576
1577         /*
1578          * Check the special variable on the stack to see if NMIs are
1579          * executing.
1580          */
1581         cmpl $1, -8(%rsp)
1582         je nested_nmi
1583
1584         /*
1585          * Now test if the previous stack was an NMI stack.
1586          * We need the double check. We check the NMI stack to satisfy the
1587          * race when the first NMI clears the variable before returning.
1588          * We check the variable because the first NMI could be in a
1589          * breakpoint routine using a breakpoint stack.
1590          */
1591         lea 6*8(%rsp), %rdx
1592         test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1593         CFI_REMEMBER_STATE
1594
1595 nested_nmi:
1596         /*
1597          * Do nothing if we interrupted the fixup in repeat_nmi.
1598          * It's about to repeat the NMI handler, so we are fine
1599          * with ignoring this one.
1600          */
1601         movq $repeat_nmi, %rdx
1602         cmpq 8(%rsp), %rdx
1603         ja 1f
1604         movq $end_repeat_nmi, %rdx
1605         cmpq 8(%rsp), %rdx
1606         ja nested_nmi_out
1607
1608 1:
1609         /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1610         leaq -6*8(%rsp), %rdx
1611         movq %rdx, %rsp
1612         CFI_ADJUST_CFA_OFFSET 6*8
1613         pushq_cfi $__KERNEL_DS
1614         pushq_cfi %rdx
1615         pushfq_cfi
1616         pushq_cfi $__KERNEL_CS
1617         pushq_cfi $repeat_nmi
1618
1619         /* Put stack back */
1620         addq $(11*8), %rsp
1621         CFI_ADJUST_CFA_OFFSET -11*8
1622
1623 nested_nmi_out:
1624         popq_cfi %rdx
1625         CFI_RESTORE rdx
1626
1627         /* No need to check faults here */
1628         INTERRUPT_RETURN
1629
1630         CFI_RESTORE_STATE
1631 first_nmi:
1632         /*
1633          * Because nested NMIs will use the pushed location that we
1634          * stored in rdx, we must keep that space available.
1635          * Here's what our stack frame will look like:
1636          * +-------------------------+
1637          * | original SS             |
1638          * | original Return RSP     |
1639          * | original RFLAGS         |
1640          * | original CS             |
1641          * | original RIP            |
1642          * +-------------------------+
1643          * | temp storage for rdx    |
1644          * +-------------------------+
1645          * | NMI executing variable  |
1646          * +-------------------------+
1647          * | Saved SS                |
1648          * | Saved Return RSP        |
1649          * | Saved RFLAGS            |
1650          * | Saved CS                |
1651          * | Saved RIP               |
1652          * +-------------------------+
1653          * | copied SS               |
1654          * | copied Return RSP       |
1655          * | copied RFLAGS           |
1656          * | copied CS               |
1657          * | copied RIP              |
1658          * +-------------------------+
1659          * | pt_regs                 |
1660          * +-------------------------+
1661          *
1662          * The saved stack frame is used to fix up the copied stack frame
1663          * that a nested NMI may change to make the interrupted NMI iret jump
1664          * to the repeat_nmi. The original stack frame and the temp storage
1665          * is also used by nested NMIs and can not be trusted on exit.
1666          */
1667         /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1668         movq (%rsp), %rdx
1669         CFI_RESTORE rdx
1670
1671         /* Set the NMI executing variable on the stack. */
1672         pushq_cfi $1
1673
1674         /* Copy the stack frame to the Saved frame */
1675         .rept 5
1676         pushq_cfi 6*8(%rsp)
1677         .endr
1678         CFI_DEF_CFA_OFFSET SS+8-RIP
1679
1680         /* Everything up to here is safe from nested NMIs */
1681
1682         /*
1683          * If there was a nested NMI, the first NMI's iret will return
1684          * here. But NMIs are still enabled and we can take another
1685          * nested NMI. The nested NMI checks the interrupted RIP to see
1686          * if it is between repeat_nmi and end_repeat_nmi, and if so
1687          * it will just return, as we are about to repeat an NMI anyway.
1688          * This makes it safe to copy to the stack frame that a nested
1689          * NMI will update.
1690          */
1691 repeat_nmi:
1692         /*
1693          * Update the stack variable to say we are still in NMI (the update
1694          * is benign for the non-repeat case, where 1 was pushed just above
1695          * to this very stack slot).
1696          */
1697         movq $1, 5*8(%rsp)
1698
1699         /* Make another copy, this one may be modified by nested NMIs */
1700         .rept 5
1701         pushq_cfi 4*8(%rsp)
1702         .endr
1703         CFI_DEF_CFA_OFFSET SS+8-RIP
1704 end_repeat_nmi:
1705
1706         /*
1707          * Everything below this point can be preempted by a nested
1708          * NMI if the first NMI took an exception and reset our iret stack
1709          * so that we repeat another NMI.
1710          */
1711         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1712         subq $ORIG_RAX-R15, %rsp
1713         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1714         /*
1715          * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1716          * as we should not be calling schedule in NMI context.
1717          * Even with normal interrupts enabled. An NMI should not be
1718          * setting NEED_RESCHED or anything that normal interrupts and
1719          * exceptions might do.
1720          */
1721         call save_paranoid
1722         DEFAULT_FRAME 0
1723         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1724         movq %rsp,%rdi
1725         movq $-1,%rsi
1726         call do_nmi
1727         testl %ebx,%ebx                         /* swapgs needed? */
1728         jnz nmi_restore
1729 nmi_swapgs:
1730         SWAPGS_UNSAFE_STACK
1731 nmi_restore:
1732         RESTORE_ALL 8
1733         /* Clear the NMI executing stack variable */
1734         movq $0, 10*8(%rsp)
1735         jmp irq_return
1736         CFI_ENDPROC
1737 END(nmi)
1738
1739 ENTRY(ignore_sysret)
1740         CFI_STARTPROC
1741         mov $-ENOSYS,%eax
1742         sysret
1743         CFI_ENDPROC
1744 END(ignore_sysret)
1745
1746 /*
1747  * End of kprobes section
1748  */
1749         .popsection