arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after an interrupt and after each system call.
  14  *
  15  * Normal syscalls and interrupts don't save a full stack frame, this is
  16  * only done for syscall tracing, signals or fork/exec et.al.
  17  *
  18  * A note on terminology:
  19  * - top of stack: Architecture defined interrupt frame from SS to RIP
  20  * at the top of the kernel process stack.
  21  * - partial stack frame: partially saved registers upto R11.
  22  * - full stack frame: Like partial stack frame, but all register saved.
  23  *
  24  * Some macro usage:
  25  * - CFI macros are used to generate dwarf2 unwind information for better
  26  * backtraces. They don't change any code.
  27  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  28  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  29  * There are unfortunately lots of special cases where some registers
  30  * not touched. The macro is a big mess that should be cleaned up.
  31  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  32  * Gives a full stack frame.
  33  * - ENTRY/END Define functions in the symbol table.
  34  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  35  * frame that is otherwise undefined after a SYSCALL
  36  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  37  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  38  */
  39
  40 #include <linux/linkage.h>
  41 #include <asm/segment.h>
  42 #include <asm/cache.h>
  43 #include <asm/errno.h>
  44 #include <asm/dwarf2.h>
  45 #include <asm/calling.h>
  46 #include <asm/asm-offsets.h>
  47 #include <asm/msr.h>
  48 #include <asm/unistd.h>
  49 #include <asm/thread_info.h>
  50 #include <asm/hw_irq.h>
  51 #include <asm/page_types.h>
  52 #include <asm/irqflags.h>
  53 #include <asm/paravirt.h>
  54 #include <asm/ftrace.h>
  55 #include <asm/percpu.h>
  56
  57 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  58 #include <linux/elf-em.h>
  59 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  60 #define __AUDIT_ARCH_64BIT 0x80000000
  61 #define __AUDIT_ARCH_LE    0x40000000
  62
  63         .code64
  64 #ifdef CONFIG_FUNCTION_TRACER
  65 #ifdef CONFIG_DYNAMIC_FTRACE
  66 ENTRY(mcount)
  67         retq
  68 END(mcount)
  69
  70 ENTRY(ftrace_caller)
  71         cmpl $0, function_trace_stop
  72         jne  ftrace_stub
  73
  74         MCOUNT_SAVE_FRAME
  75
  76         movq 0x38(%rsp), %rdi
  77         movq 8(%rbp), %rsi
  78         subq $MCOUNT_INSN_SIZE, %rdi
  79
  80 GLOBAL(ftrace_call)
  81         call ftrace_stub
  82
  83         MCOUNT_RESTORE_FRAME
  84
  85 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  86 GLOBAL(ftrace_graph_call)
  87         jmp ftrace_stub
  88 #endif
  89
  90 GLOBAL(ftrace_stub)
  91         retq
  92 END(ftrace_caller)
  93
  94 #else /* ! CONFIG_DYNAMIC_FTRACE */
  95 ENTRY(mcount)
  96         cmpl $0, function_trace_stop
  97         jne  ftrace_stub
  98
  99         cmpq $ftrace_stub, ftrace_trace_function
 100         jnz trace
 101
 102 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 103         cmpq $ftrace_stub, ftrace_graph_return
 104         jnz ftrace_graph_caller
 105
 106         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 107         jnz ftrace_graph_caller
 108 #endif
 109
 110 GLOBAL(ftrace_stub)
 111         retq
 112
 113 trace:
 114         MCOUNT_SAVE_FRAME
 115
 116         movq 0x38(%rsp), %rdi
 117         movq 8(%rbp), %rsi
 118         subq $MCOUNT_INSN_SIZE, %rdi
 119
 120         call   *ftrace_trace_function
 121
 122         MCOUNT_RESTORE_FRAME
 123
 124         jmp ftrace_stub
 125 END(mcount)
 126 #endif /* CONFIG_DYNAMIC_FTRACE */
 127 #endif /* CONFIG_FUNCTION_TRACER */
 128
 129 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 130 ENTRY(ftrace_graph_caller)
 131         cmpl $0, function_trace_stop
 132         jne ftrace_stub
 133
 134         MCOUNT_SAVE_FRAME
 135
 136         leaq 8(%rbp), %rdi
 137         movq 0x38(%rsp), %rsi
 138         movq (%rbp), %rdx
 139         subq $MCOUNT_INSN_SIZE, %rsi
 140
 141         call    prepare_ftrace_return
 142
 143         MCOUNT_RESTORE_FRAME
 144
 145         retq
 146 END(ftrace_graph_caller)
 147
 148 GLOBAL(return_to_handler)
 149         subq  $24, %rsp
 150
 151         /* Save the return values */
 152         movq %rax, (%rsp)
 153         movq %rdx, 8(%rsp)
 154         movq %rbp, %rdi
 155
 156         call ftrace_return_to_handler
 157
 158         movq %rax, %rdi
 159         movq 8(%rsp), %rdx
 160         movq (%rsp), %rax
 161         addq $24, %rsp
 162         jmp *%rdi
 163 #endif
 164
 165
 166 #ifndef CONFIG_PREEMPT
 167 #define retint_kernel retint_restore_args
 168 #endif
 169
 170 #ifdef CONFIG_PARAVIRT
 171 ENTRY(native_usergs_sysret64)
 172         swapgs
 173         sysretq
 174 ENDPROC(native_usergs_sysret64)
 175 #endif /* CONFIG_PARAVIRT */
 176
 177
 178 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 179 #ifdef CONFIG_TRACE_IRQFLAGS
 180         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 181         jnc  1f
 182         TRACE_IRQS_ON
 183 1:
 184 #endif
 185 .endm
 186
 187 /*
 188  * C code is not supposed to know about undefined top of stack. Every time
 189  * a C function with an pt_regs argument is called from the SYSCALL based
 190  * fast path FIXUP_TOP_OF_STACK is needed.
 191  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 192  * manipulation.
 193  */
 194
 195         /* %rsp:at FRAMEEND */
 196         .macro FIXUP_TOP_OF_STACK tmp offset=0
 197         movq PER_CPU_VAR(old_rsp),\tmp
 198         movq \tmp,RSP+\offset(%rsp)
 199         movq $__USER_DS,SS+\offset(%rsp)
 200         movq $__USER_CS,CS+\offset(%rsp)
 201         movq $-1,RCX+\offset(%rsp)
 202         movq R11+\offset(%rsp),\tmp  /* get eflags */
 203         movq \tmp,EFLAGS+\offset(%rsp)
 204         .endm
 205
 206         .macro RESTORE_TOP_OF_STACK tmp offset=0
 207         movq RSP+\offset(%rsp),\tmp
 208         movq \tmp,PER_CPU_VAR(old_rsp)
 209         movq EFLAGS+\offset(%rsp),\tmp
 210         movq \tmp,R11+\offset(%rsp)
 211         .endm
 212
 213         .macro FAKE_STACK_FRAME child_rip
 214         /* push in order ss, rsp, eflags, cs, rip */
 215         xorl %eax, %eax
 216         pushq_cfi $__KERNEL_DS /* ss */
 217         /*CFI_REL_OFFSET        ss,0*/
 218         pushq_cfi %rax /* rsp */
 219         CFI_REL_OFFSET  rsp,0
 220         pushq_cfi $X86_EFLAGS_IF /* eflags - interrupts on */
 221         /*CFI_REL_OFFSET        rflags,0*/
 222         pushq_cfi $__KERNEL_CS /* cs */
 223         /*CFI_REL_OFFSET        cs,0*/
 224         pushq_cfi \child_rip /* rip */
 225         CFI_REL_OFFSET  rip,0
 226         pushq_cfi %rax /* orig rax */
 227         .endm
 228
 229         .macro UNFAKE_STACK_FRAME
 230         addq $8*6, %rsp
 231         CFI_ADJUST_CFA_OFFSET   -(6*8)
 232         .endm
 233
 234 /*
 235  * initial frame state for interrupts (and exceptions without error code)
 236  */
 237         .macro EMPTY_FRAME start=1 offset=0
 238         .if \start
 239         CFI_STARTPROC simple
 240         CFI_SIGNAL_FRAME
 241         CFI_DEF_CFA rsp,8+\offset
 242         .else
 243         CFI_DEF_CFA_OFFSET 8+\offset
 244         .endif
 245         .endm
 246
 247 /*
 248  * initial frame state for interrupts (and exceptions without error code)
 249  */
 250         .macro INTR_FRAME start=1 offset=0
 251         EMPTY_FRAME \start, SS+8+\offset-RIP
 252         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 253         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 254         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 255         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 256         CFI_REL_OFFSET rip, RIP+\offset-RIP
 257         .endm
 258
 259 /*
 260  * initial frame state for exceptions with error code (and interrupts
 261  * with vector already pushed)
 262  */
 263         .macro XCPT_FRAME start=1 offset=0
 264         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 265         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 266         .endm
 267
 268 /*
 269  * frame that enables calling into C.
 270  */
 271         .macro PARTIAL_FRAME start=1 offset=0
 272         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 273         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 274         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 275         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 276         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 277         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 278         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 279         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 280         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 281         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 282         .endm
 283
 284 /*
 285  * frame that enables passing a complete pt_regs to a C function.
 286  */
 287         .macro DEFAULT_FRAME start=1 offset=0
 288         PARTIAL_FRAME \start, R11+\offset-R15
 289         CFI_REL_OFFSET rbx, RBX+\offset
 290         CFI_REL_OFFSET rbp, RBP+\offset
 291         CFI_REL_OFFSET r12, R12+\offset
 292         CFI_REL_OFFSET r13, R13+\offset
 293         CFI_REL_OFFSET r14, R14+\offset
 294         CFI_REL_OFFSET r15, R15+\offset
 295         .endm
 296
 297 /* save partial stack frame */
 298         .pushsection .kprobes.text, "ax"
 299 ENTRY(save_args)
 300         XCPT_FRAME
 301         cld
 302         /*
 303          * start from rbp in pt_regs and jump over
 304          * return address.
 305          */
 306         movq_cfi rdi, RDI+8-RBP
 307         movq_cfi rsi, RSI+8-RBP
 308         movq_cfi rdx, RDX+8-RBP
 309         movq_cfi rcx, RCX+8-RBP
 310         movq_cfi rax, RAX+8-RBP
 311         movq_cfi  r8,  R8+8-RBP
 312         movq_cfi  r9,  R9+8-RBP
 313         movq_cfi r10, R10+8-RBP
 314         movq_cfi r11, R11+8-RBP
 315
 316         leaq -RBP+8(%rsp),%rdi  /* arg1 for handler */
 317         movq_cfi rbp, 8         /* push %rbp */
 318         leaq 8(%rsp), %rbp              /* mov %rsp, %ebp */
 319         testl $3, CS(%rdi)
 320         je 1f
 321         SWAPGS
 322         /*
 323          * irq_count is used to check if a CPU is already on an interrupt stack
 324          * or not. While this is essentially redundant with preempt_count it is
 325          * a little cheaper to use a separate counter in the PDA (short of
 326          * moving irq_enter into assembly, which would be too much work)
 327          */
 328 1:      incl PER_CPU_VAR(irq_count)
 329         jne 2f
 330         popq_cfi %rax                   /* move return address... */
 331         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 332         EMPTY_FRAME 0
 333         pushq_cfi %rbp                  /* backlink for unwinder */
 334         pushq_cfi %rax                  /* ... to the new stack */
 335         /*
 336          * We entered an interrupt context - irqs are off:
 337          */
 338 2:      TRACE_IRQS_OFF
 339         ret
 340         CFI_ENDPROC
 341 END(save_args)
 342         .popsection
 343
 344 ENTRY(save_rest)
 345         PARTIAL_FRAME 1 REST_SKIP+8
 346         movq 5*8+16(%rsp), %r11 /* save return address */
 347         movq_cfi rbx, RBX+16
 348         movq_cfi rbp, RBP+16
 349         movq_cfi r12, R12+16
 350         movq_cfi r13, R13+16
 351         movq_cfi r14, R14+16
 352         movq_cfi r15, R15+16
 353         movq %r11, 8(%rsp)      /* return address */
 354         FIXUP_TOP_OF_STACK %r11, 16
 355         ret
 356         CFI_ENDPROC
 357 END(save_rest)
 358
 359 /* save complete stack frame */
 360         .pushsection .kprobes.text, "ax"
 361 ENTRY(save_paranoid)
 362         XCPT_FRAME 1 RDI+8
 363         cld
 364         movq_cfi rdi, RDI+8
 365         movq_cfi rsi, RSI+8
 366         movq_cfi rdx, RDX+8
 367         movq_cfi rcx, RCX+8
 368         movq_cfi rax, RAX+8
 369         movq_cfi r8, R8+8
 370         movq_cfi r9, R9+8
 371         movq_cfi r10, R10+8
 372         movq_cfi r11, R11+8
 373         movq_cfi rbx, RBX+8
 374         movq_cfi rbp, RBP+8
 375         movq_cfi r12, R12+8
 376         movq_cfi r13, R13+8
 377         movq_cfi r14, R14+8
 378         movq_cfi r15, R15+8
 379         movl $1,%ebx
 380         movl $MSR_GS_BASE,%ecx
 381         rdmsr
 382         testl %edx,%edx
 383         js 1f   /* negative -> in kernel */
 384         SWAPGS
 385         xorl %ebx,%ebx
 386 1:      ret
 387         CFI_ENDPROC
 388 END(save_paranoid)
 389         .popsection
 390
 391 /*
 392  * A newly forked process directly context switches into this address.
 393  *
 394  * rdi: prev task we switched from
 395  */
 396 ENTRY(ret_from_fork)
 397         DEFAULT_FRAME
 398
 399         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 400
 401         pushq_cfi kernel_eflags(%rip)
 402         popfq_cfi                               # reset kernel eflags
 403
 404         call schedule_tail                      # rdi: 'prev' task parameter
 405
 406         GET_THREAD_INFO(%rcx)
 407
 408         RESTORE_REST
 409
 410         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 411         je   int_ret_from_sys_call
 412
 413         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 414         jnz  int_ret_from_sys_call
 415
 416         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 417         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 418
 419         CFI_ENDPROC
 420 END(ret_from_fork)
 421
 422 /*
 423  * System call entry. Upto 6 arguments in registers are supported.
 424  *
 425  * SYSCALL does not save anything on the stack and does not change the
 426  * stack pointer.
 427  */
 428
 429 /*
 430  * Register setup:
 431  * rax  system call number
 432  * rdi  arg0
 433  * rcx  return address for syscall/sysret, C arg3
 434  * rsi  arg1
 435  * rdx  arg2
 436  * r10  arg3    (--> moved to rcx for C)
 437  * r8   arg4
 438  * r9   arg5
 439  * r11  eflags for syscall/sysret, temporary for C
 440  * r12-r15,rbp,rbx saved by C code, not touched.
 441  *
 442  * Interrupts are off on entry.
 443  * Only called from user space.
 444  *
 445  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 446  *      and report it properly in ps. Unfortunately we haven't.
 447  *
 448  * When user can change the frames always force IRET. That is because
 449  * it deals with uncanonical addresses better. SYSRET has trouble
 450  * with them due to bugs in both AMD and Intel CPUs.
 451  */
 452
 453 ENTRY(system_call)
 454         CFI_STARTPROC   simple
 455         CFI_SIGNAL_FRAME
 456         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 457         CFI_REGISTER    rip,rcx
 458         /*CFI_REGISTER  rflags,r11*/
 459         SWAPGS_UNSAFE_STACK
 460         /*
 461          * A hypervisor implementation might want to use a label
 462          * after the swapgs, so that it can do the swapgs
 463          * for the guest and jump here on syscall.
 464          */
 465 ENTRY(system_call_after_swapgs)
 466
 467         movq    %rsp,PER_CPU_VAR(old_rsp)
 468         movq    PER_CPU_VAR(kernel_stack),%rsp
 469         /*
 470          * No need to follow this irqs off/on section - it's straight
 471          * and short:
 472          */
 473         ENABLE_INTERRUPTS(CLBR_NONE)
 474         SAVE_ARGS 8,1
 475         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 476         movq  %rcx,RIP-ARGOFFSET(%rsp)
 477         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 478         GET_THREAD_INFO(%rcx)
 479         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 480         jnz tracesys
 481 system_call_fastpath:
 482         cmpq $__NR_syscall_max,%rax
 483         ja badsys
 484         movq %r10,%rcx
 485         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 486         movq %rax,RAX-ARGOFFSET(%rsp)
 487 /*
 488  * Syscall return path ending with SYSRET (fast path)
 489  * Has incomplete stack frame and undefined top of stack.
 490  */
 491 ret_from_sys_call:
 492         movl $_TIF_ALLWORK_MASK,%edi
 493         /* edi: flagmask */
 494 sysret_check:
 495         LOCKDEP_SYS_EXIT
 496         GET_THREAD_INFO(%rcx)
 497         DISABLE_INTERRUPTS(CLBR_NONE)
 498         TRACE_IRQS_OFF
 499         movl TI_flags(%rcx),%edx
 500         andl %edi,%edx
 501         jnz  sysret_careful
 502         CFI_REMEMBER_STATE
 503         /*
 504          * sysretq will re-enable interrupts:
 505          */
 506         TRACE_IRQS_ON
 507         movq RIP-ARGOFFSET(%rsp),%rcx
 508         CFI_REGISTER    rip,rcx
 509         RESTORE_ARGS 0,-ARG_SKIP,1
 510         /*CFI_REGISTER  rflags,r11*/
 511         movq    PER_CPU_VAR(old_rsp), %rsp
 512         USERGS_SYSRET64
 513
 514         CFI_RESTORE_STATE
 515         /* Handle reschedules */
 516         /* edx: work, edi: workmask */
 517 sysret_careful:
 518         bt $TIF_NEED_RESCHED,%edx
 519         jnc sysret_signal
 520         TRACE_IRQS_ON
 521         ENABLE_INTERRUPTS(CLBR_NONE)
 522         pushq_cfi %rdi
 523         call schedule
 524         popq_cfi %rdi
 525         jmp sysret_check
 526
 527         /* Handle a signal */
 528 sysret_signal:
 529         TRACE_IRQS_ON
 530         ENABLE_INTERRUPTS(CLBR_NONE)
 531 #ifdef CONFIG_AUDITSYSCALL
 532         bt $TIF_SYSCALL_AUDIT,%edx
 533         jc sysret_audit
 534 #endif
 535         /*
 536          * We have a signal, or exit tracing or single-step.
 537          * These all wind up with the iret return path anyway,
 538          * so just join that path right now.
 539          */
 540         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 541         jmp int_check_syscall_exit_work
 542
 543 badsys:
 544         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 545         jmp ret_from_sys_call
 546
 547 #ifdef CONFIG_AUDITSYSCALL
 548         /*
 549          * Fast path for syscall audit without full syscall trace.
 550          * We just call audit_syscall_entry() directly, and then
 551          * jump back to the normal fast path.
 552          */
 553 auditsys:
 554         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 555         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 556         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 557         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 558         movq %rax,%rsi                  /* 2nd arg: syscall number */
 559         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 560         call audit_syscall_entry
 561         LOAD_ARGS 0             /* reload call-clobbered registers */
 562         jmp system_call_fastpath
 563
 564         /*
 565          * Return fast path for syscall audit.  Call audit_syscall_exit()
 566          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 567          * masked off.
 568          */
 569 sysret_audit:
 570         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 571         cmpq $0,%rsi            /* is it < 0? */
 572         setl %al                /* 1 if so, 0 if not */
 573         movzbl %al,%edi         /* zero-extend that into %edi */
 574         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 575         call audit_syscall_exit
 576         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 577         jmp sysret_check
 578 #endif  /* CONFIG_AUDITSYSCALL */
 579
 580         /* Do syscall tracing */
 581 tracesys:
 582 #ifdef CONFIG_AUDITSYSCALL
 583         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 584         jz auditsys
 585 #endif
 586         SAVE_REST
 587         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 588         FIXUP_TOP_OF_STACK %rdi
 589         movq %rsp,%rdi
 590         call syscall_trace_enter
 591         /*
 592          * Reload arg registers from stack in case ptrace changed them.
 593          * We don't reload %rax because syscall_trace_enter() returned
 594          * the value it wants us to use in the table lookup.
 595          */
 596         LOAD_ARGS ARGOFFSET, 1
 597         RESTORE_REST
 598         cmpq $__NR_syscall_max,%rax
 599         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 600         movq %r10,%rcx  /* fixup for C */
 601         call *sys_call_table(,%rax,8)
 602         movq %rax,RAX-ARGOFFSET(%rsp)
 603         /* Use IRET because user could have changed frame */
 604
 605 /*
 606  * Syscall return path ending with IRET.
 607  * Has correct top of stack, but partial stack frame.
 608  */
 609 GLOBAL(int_ret_from_sys_call)
 610         DISABLE_INTERRUPTS(CLBR_NONE)
 611         TRACE_IRQS_OFF
 612         testl $3,CS-ARGOFFSET(%rsp)
 613         je retint_restore_args
 614         movl $_TIF_ALLWORK_MASK,%edi
 615         /* edi: mask to check */
 616 GLOBAL(int_with_check)
 617         LOCKDEP_SYS_EXIT_IRQ
 618         GET_THREAD_INFO(%rcx)
 619         movl TI_flags(%rcx),%edx
 620         andl %edi,%edx
 621         jnz   int_careful
 622         andl    $~TS_COMPAT,TI_status(%rcx)
 623         jmp   retint_swapgs
 624
 625         /* Either reschedule or signal or syscall exit tracking needed. */
 626         /* First do a reschedule test. */
 627         /* edx: work, edi: workmask */
 628 int_careful:
 629         bt $TIF_NEED_RESCHED,%edx
 630         jnc  int_very_careful
 631         TRACE_IRQS_ON
 632         ENABLE_INTERRUPTS(CLBR_NONE)
 633         pushq_cfi %rdi
 634         call schedule
 635         popq_cfi %rdi
 636         DISABLE_INTERRUPTS(CLBR_NONE)
 637         TRACE_IRQS_OFF
 638         jmp int_with_check
 639
 640         /* handle signals and tracing -- both require a full stack frame */
 641 int_very_careful:
 642         TRACE_IRQS_ON
 643         ENABLE_INTERRUPTS(CLBR_NONE)
 644 int_check_syscall_exit_work:
 645         SAVE_REST
 646         /* Check for syscall exit trace */
 647         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 648         jz int_signal
 649         pushq_cfi %rdi
 650         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 651         call syscall_trace_leave
 652         popq_cfi %rdi
 653         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 654         jmp int_restore_rest
 655
 656 int_signal:
 657         testl $_TIF_DO_NOTIFY_MASK,%edx
 658         jz 1f
 659         movq %rsp,%rdi          # &ptregs -> arg1
 660         xorl %esi,%esi          # oldset -> arg2
 661         call do_notify_resume
 662 1:      movl $_TIF_WORK_MASK,%edi
 663 int_restore_rest:
 664         RESTORE_REST
 665         DISABLE_INTERRUPTS(CLBR_NONE)
 666         TRACE_IRQS_OFF
 667         jmp int_with_check
 668         CFI_ENDPROC
 669 END(system_call)
 670
 671 /*
 672  * Certain special system calls that need to save a complete full stack frame.
 673  */
 674         .macro PTREGSCALL label,func,arg
 675 ENTRY(\label)
 676         PARTIAL_FRAME 1 8               /* offset 8: return address */
 677         subq $REST_SKIP, %rsp
 678         CFI_ADJUST_CFA_OFFSET REST_SKIP
 679         call save_rest
 680         DEFAULT_FRAME 0 8               /* offset 8: return address */
 681         leaq 8(%rsp), \arg      /* pt_regs pointer */
 682         call \func
 683         jmp ptregscall_common
 684         CFI_ENDPROC
 685 END(\label)
 686         .endm
 687
 688         PTREGSCALL stub_clone, sys_clone, %r8
 689         PTREGSCALL stub_fork, sys_fork, %rdi
 690         PTREGSCALL stub_vfork, sys_vfork, %rdi
 691         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 692         PTREGSCALL stub_iopl, sys_iopl, %rsi
 693
 694 ENTRY(ptregscall_common)
 695         DEFAULT_FRAME 1 8       /* offset 8: return address */
 696         RESTORE_TOP_OF_STACK %r11, 8
 697         movq_cfi_restore R15+8, r15
 698         movq_cfi_restore R14+8, r14
 699         movq_cfi_restore R13+8, r13
 700         movq_cfi_restore R12+8, r12
 701         movq_cfi_restore RBP+8, rbp
 702         movq_cfi_restore RBX+8, rbx
 703         ret $REST_SKIP          /* pop extended registers */
 704         CFI_ENDPROC
 705 END(ptregscall_common)
 706
 707 ENTRY(stub_execve)
 708         CFI_STARTPROC
 709         addq $8, %rsp
 710         PARTIAL_FRAME 0
 711         SAVE_REST
 712         FIXUP_TOP_OF_STACK %r11
 713         movq %rsp, %rcx
 714         call sys_execve
 715         RESTORE_TOP_OF_STACK %r11
 716         movq %rax,RAX(%rsp)
 717         RESTORE_REST
 718         jmp int_ret_from_sys_call
 719         CFI_ENDPROC
 720 END(stub_execve)
 721
 722 /*
 723  * sigreturn is special because it needs to restore all registers on return.
 724  * This cannot be done with SYSRET, so use the IRET return path instead.
 725  */
 726 ENTRY(stub_rt_sigreturn)
 727         CFI_STARTPROC
 728         addq $8, %rsp
 729         PARTIAL_FRAME 0
 730         SAVE_REST
 731         movq %rsp,%rdi
 732         FIXUP_TOP_OF_STACK %r11
 733         call sys_rt_sigreturn
 734         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 735         RESTORE_REST
 736         jmp int_ret_from_sys_call
 737         CFI_ENDPROC
 738 END(stub_rt_sigreturn)
 739
 740 /*
 741  * Build the entry stubs and pointer table with some assembler magic.
 742  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 743  * single cache line on all modern x86 implementations.
 744  */
 745         .section .init.rodata,"a"
 746 ENTRY(interrupt)
 747         .text
 748         .p2align 5
 749         .p2align CONFIG_X86_L1_CACHE_SHIFT
 750 ENTRY(irq_entries_start)
 751         INTR_FRAME
 752 vector=FIRST_EXTERNAL_VECTOR
 753 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 754         .balign 32
 755   .rept 7
 756     .if vector < NR_VECTORS
 757       .if vector <> FIRST_EXTERNAL_VECTOR
 758         CFI_ADJUST_CFA_OFFSET -8
 759       .endif
 760 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 761       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 762         jmp 2f
 763       .endif
 764       .previous
 765         .quad 1b
 766       .text
 767 vector=vector+1
 768     .endif
 769   .endr
 770 2:      jmp common_interrupt
 771 .endr
 772         CFI_ENDPROC
 773 END(irq_entries_start)
 774
 775 .previous
 776 END(interrupt)
 777 .previous
 778
 779 /*
 780  * Interrupt entry/exit.
 781  *
 782  * Interrupt entry points save only callee clobbered registers in fast path.
 783  *
 784  * Entry runs with interrupts off.
 785  */
 786
 787 /* 0(%rsp): ~(interrupt number) */
 788         .macro interrupt func
 789         /* reserve pt_regs for scratch regs and rbp */
 790         subq $ORIG_RAX-RBP, %rsp
 791         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 792         call save_args
 793         PARTIAL_FRAME 0
 794         call \func
 795         .endm
 796
 797 /*
 798  * Interrupt entry/exit should be protected against kprobes
 799  */
 800         .pushsection .kprobes.text, "ax"
 801         /*
 802          * The interrupt stubs push (~vector+0x80) onto the stack and
 803          * then jump to common_interrupt.
 804          */
 805         .p2align CONFIG_X86_L1_CACHE_SHIFT
 806 common_interrupt:
 807         XCPT_FRAME
 808         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 809         interrupt do_IRQ
 810         /* 0(%rsp): old_rsp-ARGOFFSET */
 811 ret_from_intr:
 812         DISABLE_INTERRUPTS(CLBR_NONE)
 813         TRACE_IRQS_OFF
 814         decl PER_CPU_VAR(irq_count)
 815         leaveq
 816
 817         CFI_RESTORE             rbp
 818         CFI_DEF_CFA_REGISTER    rsp
 819         CFI_ADJUST_CFA_OFFSET   -8
 820
 821         /* we did not save rbx, restore only from ARGOFFSET */
 822         addq $8, %rsp
 823         CFI_ADJUST_CFA_OFFSET   -8
 824 exit_intr:
 825         GET_THREAD_INFO(%rcx)
 826         testl $3,CS-ARGOFFSET(%rsp)
 827         je retint_kernel
 828
 829         /* Interrupt came from user space */
 830         /*
 831          * Has a correct top of stack, but a partial stack frame
 832          * %rcx: thread info. Interrupts off.
 833          */
 834 retint_with_reschedule:
 835         movl $_TIF_WORK_MASK,%edi
 836 retint_check:
 837         LOCKDEP_SYS_EXIT_IRQ
 838         movl TI_flags(%rcx),%edx
 839         andl %edi,%edx
 840         CFI_REMEMBER_STATE
 841         jnz  retint_careful
 842
 843 retint_swapgs:          /* return to user-space */
 844         /*
 845          * The iretq could re-enable interrupts:
 846          */
 847         DISABLE_INTERRUPTS(CLBR_ANY)
 848         TRACE_IRQS_IRETQ
 849         SWAPGS
 850         jmp restore_args
 851
 852 retint_restore_args:    /* return to kernel space */
 853         DISABLE_INTERRUPTS(CLBR_ANY)
 854         /*
 855          * The iretq could re-enable interrupts:
 856          */
 857         TRACE_IRQS_IRETQ
 858 restore_args:
 859         RESTORE_ARGS 0,8,0
 860
 861 irq_return:
 862         INTERRUPT_RETURN
 863
 864         .section __ex_table, "a"
 865         .quad irq_return, bad_iret
 866         .previous
 867
 868 #ifdef CONFIG_PARAVIRT
 869 ENTRY(native_iret)
 870         iretq
 871
 872         .section __ex_table,"a"
 873         .quad native_iret, bad_iret
 874         .previous
 875 #endif
 876
 877         .section .fixup,"ax"
 878 bad_iret:
 879         /*
 880          * The iret traps when the %cs or %ss being restored is bogus.
 881          * We've lost the original trap vector and error code.
 882          * #GPF is the most likely one to get for an invalid selector.
 883          * So pretend we completed the iret and took the #GPF in user mode.
 884          *
 885          * We are now running with the kernel GS after exception recovery.
 886          * But error_entry expects us to have user GS to match the user %cs,
 887          * so swap back.
 888          */
 889         pushq $0
 890
 891         SWAPGS
 892         jmp general_protection
 893
 894         .previous
 895
 896         /* edi: workmask, edx: work */
 897 retint_careful:
 898         CFI_RESTORE_STATE
 899         bt    $TIF_NEED_RESCHED,%edx
 900         jnc   retint_signal
 901         TRACE_IRQS_ON
 902         ENABLE_INTERRUPTS(CLBR_NONE)
 903         pushq_cfi %rdi
 904         call  schedule
 905         popq_cfi %rdi
 906         GET_THREAD_INFO(%rcx)
 907         DISABLE_INTERRUPTS(CLBR_NONE)
 908         TRACE_IRQS_OFF
 909         jmp retint_check
 910
 911 retint_signal:
 912         testl $_TIF_DO_NOTIFY_MASK,%edx
 913         jz    retint_swapgs
 914         TRACE_IRQS_ON
 915         ENABLE_INTERRUPTS(CLBR_NONE)
 916         SAVE_REST
 917         movq $-1,ORIG_RAX(%rsp)
 918         xorl %esi,%esi          # oldset
 919         movq %rsp,%rdi          # &pt_regs
 920         call do_notify_resume
 921         RESTORE_REST
 922         DISABLE_INTERRUPTS(CLBR_NONE)
 923         TRACE_IRQS_OFF
 924         GET_THREAD_INFO(%rcx)
 925         jmp retint_with_reschedule
 926
 927 #ifdef CONFIG_PREEMPT
 928         /* Returning to kernel space. Check if we need preemption */
 929         /* rcx:  threadinfo. interrupts off. */
 930 ENTRY(retint_kernel)
 931         cmpl $0,TI_preempt_count(%rcx)
 932         jnz  retint_restore_args
 933         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 934         jnc  retint_restore_args
 935         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 936         jnc  retint_restore_args
 937         call preempt_schedule_irq
 938         jmp exit_intr
 939 #endif
 940
 941         CFI_ENDPROC
 942 END(common_interrupt)
 943 /*
 944  * End of kprobes section
 945  */
 946        .popsection
 947
 948 /*
 949  * APIC interrupts.
 950  */
 951 .macro apicinterrupt num sym do_sym
 952 ENTRY(\sym)
 953         INTR_FRAME
 954         pushq_cfi $~(\num)
 955         interrupt \do_sym
 956         jmp ret_from_intr
 957         CFI_ENDPROC
 958 END(\sym)
 959 .endm
 960
 961 #ifdef CONFIG_SMP
 962 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 963         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 964 apicinterrupt REBOOT_VECTOR \
 965         reboot_interrupt smp_reboot_interrupt
 966 #endif
 967
 968 #ifdef CONFIG_X86_UV
 969 apicinterrupt UV_BAU_MESSAGE \
 970         uv_bau_message_intr1 uv_bau_message_interrupt
 971 #endif
 972 apicinterrupt LOCAL_TIMER_VECTOR \
 973         apic_timer_interrupt smp_apic_timer_interrupt
 974 apicinterrupt X86_PLATFORM_IPI_VECTOR \
 975         x86_platform_ipi smp_x86_platform_ipi
 976
 977 #ifdef CONFIG_SMP
 978 .irpc idx, "01234567"
 979 apicinterrupt (INVALIDATE_TLB_VECTOR_START)+\idx \
 980         invalidate_interrupt\idx smp_invalidate_interrupt
 981 .endr
 982 #endif
 983
 984 apicinterrupt THRESHOLD_APIC_VECTOR \
 985         threshold_interrupt smp_threshold_interrupt
 986 apicinterrupt THERMAL_APIC_VECTOR \
 987         thermal_interrupt smp_thermal_interrupt
 988
 989 #ifdef CONFIG_X86_MCE
 990 apicinterrupt MCE_SELF_VECTOR \
 991         mce_self_interrupt smp_mce_self_interrupt
 992 #endif
 993
 994 #ifdef CONFIG_SMP
 995 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
 996         call_function_single_interrupt smp_call_function_single_interrupt
 997 apicinterrupt CALL_FUNCTION_VECTOR \
 998         call_function_interrupt smp_call_function_interrupt
 999 apicinterrupt RESCHEDULE_VECTOR \
1000         reschedule_interrupt smp_reschedule_interrupt
1001 #endif
1002
1003 apicinterrupt ERROR_APIC_VECTOR \
1004         error_interrupt smp_error_interrupt
1005 apicinterrupt SPURIOUS_APIC_VECTOR \
1006         spurious_interrupt smp_spurious_interrupt
1007
1008 #ifdef CONFIG_IRQ_WORK
1009 apicinterrupt IRQ_WORK_VECTOR \
1010         irq_work_interrupt smp_irq_work_interrupt
1011 #endif
1012
1013 /*
1014  * Exception entry points.
1015  */
1016 .macro zeroentry sym do_sym
1017 ENTRY(\sym)
1018         INTR_FRAME
1019         PARAVIRT_ADJUST_EXCEPTION_FRAME
1020         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1021         subq $ORIG_RAX-R15, %rsp
1022         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1023         call error_entry
1024         DEFAULT_FRAME 0
1025         movq %rsp,%rdi          /* pt_regs pointer */
1026         xorl %esi,%esi          /* no error code */
1027         call \do_sym
1028         jmp error_exit          /* %ebx: no swapgs flag */
1029         CFI_ENDPROC
1030 END(\sym)
1031 .endm
1032
1033 .macro paranoidzeroentry sym do_sym
1034 ENTRY(\sym)
1035         INTR_FRAME
1036         PARAVIRT_ADJUST_EXCEPTION_FRAME
1037         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1038         subq $ORIG_RAX-R15, %rsp
1039         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1040         call save_paranoid
1041         TRACE_IRQS_OFF
1042         movq %rsp,%rdi          /* pt_regs pointer */
1043         xorl %esi,%esi          /* no error code */
1044         call \do_sym
1045         jmp paranoid_exit       /* %ebx: no swapgs flag */
1046         CFI_ENDPROC
1047 END(\sym)
1048 .endm
1049
1050 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1051 .macro paranoidzeroentry_ist sym do_sym ist
1052 ENTRY(\sym)
1053         INTR_FRAME
1054         PARAVIRT_ADJUST_EXCEPTION_FRAME
1055         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1056         subq $ORIG_RAX-R15, %rsp
1057         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1058         call save_paranoid
1059         TRACE_IRQS_OFF
1060         movq %rsp,%rdi          /* pt_regs pointer */
1061         xorl %esi,%esi          /* no error code */
1062         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1063         call \do_sym
1064         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1065         jmp paranoid_exit       /* %ebx: no swapgs flag */
1066         CFI_ENDPROC
1067 END(\sym)
1068 .endm
1069
1070 .macro errorentry sym do_sym
1071 ENTRY(\sym)
1072         XCPT_FRAME
1073         PARAVIRT_ADJUST_EXCEPTION_FRAME
1074         subq $ORIG_RAX-R15, %rsp
1075         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1076         call error_entry
1077         DEFAULT_FRAME 0
1078         movq %rsp,%rdi                  /* pt_regs pointer */
1079         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1080         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1081         call \do_sym
1082         jmp error_exit                  /* %ebx: no swapgs flag */
1083         CFI_ENDPROC
1084 END(\sym)
1085 .endm
1086
1087         /* error code is on the stack already */
1088 .macro paranoiderrorentry sym do_sym
1089 ENTRY(\sym)
1090         XCPT_FRAME
1091         PARAVIRT_ADJUST_EXCEPTION_FRAME
1092         subq $ORIG_RAX-R15, %rsp
1093         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1094         call save_paranoid
1095         DEFAULT_FRAME 0
1096         TRACE_IRQS_OFF
1097         movq %rsp,%rdi                  /* pt_regs pointer */
1098         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1099         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1100         call \do_sym
1101         jmp paranoid_exit               /* %ebx: no swapgs flag */
1102         CFI_ENDPROC
1103 END(\sym)
1104 .endm
1105
1106 zeroentry divide_error do_divide_error
1107 zeroentry overflow do_overflow
1108 zeroentry bounds do_bounds
1109 zeroentry invalid_op do_invalid_op
1110 zeroentry device_not_available do_device_not_available
1111 paranoiderrorentry double_fault do_double_fault
1112 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1113 errorentry invalid_TSS do_invalid_TSS
1114 errorentry segment_not_present do_segment_not_present
1115 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1116 zeroentry coprocessor_error do_coprocessor_error
1117 errorentry alignment_check do_alignment_check
1118 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1119
1120         /* Reload gs selector with exception handling */
1121         /* edi:  new selector */
1122 ENTRY(native_load_gs_index)
1123         CFI_STARTPROC
1124         pushfq_cfi
1125         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1126         SWAPGS
1127 gs_change:
1128         movl %edi,%gs
1129 2:      mfence          /* workaround */
1130         SWAPGS
1131         popfq_cfi
1132         ret
1133         CFI_ENDPROC
1134 END(native_load_gs_index)
1135
1136         .section __ex_table,"a"
1137         .align 8
1138         .quad gs_change,bad_gs
1139         .previous
1140         .section .fixup,"ax"
1141         /* running with kernelgs */
1142 bad_gs:
1143         SWAPGS                  /* switch back to user gs */
1144         xorl %eax,%eax
1145         movl %eax,%gs
1146         jmp  2b
1147         .previous
1148
1149 ENTRY(kernel_thread_helper)
1150         pushq $0                # fake return address
1151         CFI_STARTPROC
1152         /*
1153          * Here we are in the child and the registers are set as they were
1154          * at kernel_thread() invocation in the parent.
1155          */
1156         call *%rsi
1157         # exit
1158         mov %eax, %edi
1159         call do_exit
1160         ud2                     # padding for call trace
1161         CFI_ENDPROC
1162 END(kernel_thread_helper)
1163
1164 /*
1165  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1166  *
1167  * C extern interface:
1168  *       extern long execve(const char *name, char **argv, char **envp)
1169  *
1170  * asm input arguments:
1171  *      rdi: name, rsi: argv, rdx: envp
1172  *
1173  * We want to fallback into:
1174  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1175  *
1176  * do_sys_execve asm fallback arguments:
1177  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1178  */
1179 ENTRY(kernel_execve)
1180         CFI_STARTPROC
1181         FAKE_STACK_FRAME $0
1182         SAVE_ALL
1183         movq %rsp,%rcx
1184         call sys_execve
1185         movq %rax, RAX(%rsp)
1186         RESTORE_REST
1187         testq %rax,%rax
1188         je int_ret_from_sys_call
1189         RESTORE_ARGS
1190         UNFAKE_STACK_FRAME
1191         ret
1192         CFI_ENDPROC
1193 END(kernel_execve)
1194
1195 /* Call softirq on interrupt stack. Interrupts are off. */
1196 ENTRY(call_softirq)
1197         CFI_STARTPROC
1198         pushq_cfi %rbp
1199         CFI_REL_OFFSET rbp,0
1200         mov  %rsp,%rbp
1201         CFI_DEF_CFA_REGISTER rbp
1202         incl PER_CPU_VAR(irq_count)
1203         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1204         push  %rbp                      # backlink for old unwinder
1205         call __do_softirq
1206         leaveq
1207         CFI_RESTORE             rbp
1208         CFI_DEF_CFA_REGISTER    rsp
1209         CFI_ADJUST_CFA_OFFSET   -8
1210         decl PER_CPU_VAR(irq_count)
1211         ret
1212         CFI_ENDPROC
1213 END(call_softirq)
1214
1215 #ifdef CONFIG_XEN
1216 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1217
1218 /*
1219  * A note on the "critical region" in our callback handler.
1220  * We want to avoid stacking callback handlers due to events occurring
1221  * during handling of the last event. To do this, we keep events disabled
1222  * until we've done all processing. HOWEVER, we must enable events before
1223  * popping the stack frame (can't be done atomically) and so it would still
1224  * be possible to get enough handler activations to overflow the stack.
1225  * Although unlikely, bugs of that kind are hard to track down, so we'd
1226  * like to avoid the possibility.
1227  * So, on entry to the handler we detect whether we interrupted an
1228  * existing activation in its critical region -- if so, we pop the current
1229  * activation and restart the handler using the previous one.
1230  */
1231 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1232         CFI_STARTPROC
1233 /*
1234  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1235  * see the correct pointer to the pt_regs
1236  */
1237         movq %rdi, %rsp            # we don't return, adjust the stack frame
1238         CFI_ENDPROC
1239         DEFAULT_FRAME
1240 11:     incl PER_CPU_VAR(irq_count)
1241         movq %rsp,%rbp
1242         CFI_DEF_CFA_REGISTER rbp
1243         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1244         pushq %rbp                      # backlink for old unwinder
1245         call xen_evtchn_do_upcall
1246         popq %rsp
1247         CFI_DEF_CFA_REGISTER rsp
1248         decl PER_CPU_VAR(irq_count)
1249         jmp  error_exit
1250         CFI_ENDPROC
1251 END(do_hypervisor_callback)
1252
1253 /*
1254  * Hypervisor uses this for application faults while it executes.
1255  * We get here for two reasons:
1256  *  1. Fault while reloading DS, ES, FS or GS
1257  *  2. Fault while executing IRET
1258  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1259  * registers that could be reloaded and zeroed the others.
1260  * Category 2 we fix up by killing the current process. We cannot use the
1261  * normal Linux return path in this case because if we use the IRET hypercall
1262  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1263  * We distinguish between categories by comparing each saved segment register
1264  * with its current contents: any discrepancy means we in category 1.
1265  */
1266 ENTRY(xen_failsafe_callback)
1267         INTR_FRAME 1 (6*8)
1268         /*CFI_REL_OFFSET gs,GS*/
1269         /*CFI_REL_OFFSET fs,FS*/
1270         /*CFI_REL_OFFSET es,ES*/
1271         /*CFI_REL_OFFSET ds,DS*/
1272         CFI_REL_OFFSET r11,8
1273         CFI_REL_OFFSET rcx,0
1274         movw %ds,%cx
1275         cmpw %cx,0x10(%rsp)
1276         CFI_REMEMBER_STATE
1277         jne 1f
1278         movw %es,%cx
1279         cmpw %cx,0x18(%rsp)
1280         jne 1f
1281         movw %fs,%cx
1282         cmpw %cx,0x20(%rsp)
1283         jne 1f
1284         movw %gs,%cx
1285         cmpw %cx,0x28(%rsp)
1286         jne 1f
1287         /* All segments match their saved values => Category 2 (Bad IRET). */
1288         movq (%rsp),%rcx
1289         CFI_RESTORE rcx
1290         movq 8(%rsp),%r11
1291         CFI_RESTORE r11
1292         addq $0x30,%rsp
1293         CFI_ADJUST_CFA_OFFSET -0x30
1294         pushq_cfi $0    /* RIP */
1295         pushq_cfi %r11
1296         pushq_cfi %rcx
1297         jmp general_protection
1298         CFI_RESTORE_STATE
1299 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1300         movq (%rsp),%rcx
1301         CFI_RESTORE rcx
1302         movq 8(%rsp),%r11
1303         CFI_RESTORE r11
1304         addq $0x30,%rsp
1305         CFI_ADJUST_CFA_OFFSET -0x30
1306         pushq_cfi $0
1307         SAVE_ALL
1308         jmp error_exit
1309         CFI_ENDPROC
1310 END(xen_failsafe_callback)
1311
1312 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1313         xen_hvm_callback_vector xen_evtchn_do_upcall
1314
1315 #endif /* CONFIG_XEN */
1316
1317 /*
1318  * Some functions should be protected against kprobes
1319  */
1320         .pushsection .kprobes.text, "ax"
1321
1322 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1323 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1324 paranoiderrorentry stack_segment do_stack_segment
1325 #ifdef CONFIG_XEN
1326 zeroentry xen_debug do_debug
1327 zeroentry xen_int3 do_int3
1328 errorentry xen_stack_segment do_stack_segment
1329 #endif
1330 errorentry general_protection do_general_protection
1331 errorentry page_fault do_page_fault
1332 #ifdef CONFIG_KVM_GUEST
1333 errorentry async_page_fault do_async_page_fault
1334 #endif
1335 #ifdef CONFIG_X86_MCE
1336 paranoidzeroentry machine_check *machine_check_vector(%rip)
1337 #endif
1338
1339         /*
1340          * "Paranoid" exit path from exception stack.
1341          * Paranoid because this is used by NMIs and cannot take
1342          * any kernel state for granted.
1343          * We don't do kernel preemption checks here, because only
1344          * NMI should be common and it does not enable IRQs and
1345          * cannot get reschedule ticks.
1346          *
1347          * "trace" is 0 for the NMI handler only, because irq-tracing
1348          * is fundamentally NMI-unsafe. (we cannot change the soft and
1349          * hard flags at once, atomically)
1350          */
1351
1352         /* ebx: no swapgs flag */
1353 ENTRY(paranoid_exit)
1354         DEFAULT_FRAME
1355         DISABLE_INTERRUPTS(CLBR_NONE)
1356         TRACE_IRQS_OFF
1357         testl %ebx,%ebx                         /* swapgs needed? */
1358         jnz paranoid_restore
1359         testl $3,CS(%rsp)
1360         jnz   paranoid_userspace
1361 paranoid_swapgs:
1362         TRACE_IRQS_IRETQ 0
1363         SWAPGS_UNSAFE_STACK
1364         RESTORE_ALL 8
1365         jmp irq_return
1366 paranoid_restore:
1367         TRACE_IRQS_IRETQ 0
1368         RESTORE_ALL 8
1369         jmp irq_return
1370 paranoid_userspace:
1371         GET_THREAD_INFO(%rcx)
1372         movl TI_flags(%rcx),%ebx
1373         andl $_TIF_WORK_MASK,%ebx
1374         jz paranoid_swapgs
1375         movq %rsp,%rdi                  /* &pt_regs */
1376         call sync_regs
1377         movq %rax,%rsp                  /* switch stack for scheduling */
1378         testl $_TIF_NEED_RESCHED,%ebx
1379         jnz paranoid_schedule
1380         movl %ebx,%edx                  /* arg3: thread flags */
1381         TRACE_IRQS_ON
1382         ENABLE_INTERRUPTS(CLBR_NONE)
1383         xorl %esi,%esi                  /* arg2: oldset */
1384         movq %rsp,%rdi                  /* arg1: &pt_regs */
1385         call do_notify_resume
1386         DISABLE_INTERRUPTS(CLBR_NONE)
1387         TRACE_IRQS_OFF
1388         jmp paranoid_userspace
1389 paranoid_schedule:
1390         TRACE_IRQS_ON
1391         ENABLE_INTERRUPTS(CLBR_ANY)
1392         call schedule
1393         DISABLE_INTERRUPTS(CLBR_ANY)
1394         TRACE_IRQS_OFF
1395         jmp paranoid_userspace
1396         CFI_ENDPROC
1397 END(paranoid_exit)
1398
1399 /*
1400  * Exception entry point. This expects an error code/orig_rax on the stack.
1401  * returns in "no swapgs flag" in %ebx.
1402  */
1403 ENTRY(error_entry)
1404         XCPT_FRAME
1405         CFI_ADJUST_CFA_OFFSET 15*8
1406         /* oldrax contains error code */
1407         cld
1408         movq_cfi rdi, RDI+8
1409         movq_cfi rsi, RSI+8
1410         movq_cfi rdx, RDX+8
1411         movq_cfi rcx, RCX+8
1412         movq_cfi rax, RAX+8
1413         movq_cfi  r8,  R8+8
1414         movq_cfi  r9,  R9+8
1415         movq_cfi r10, R10+8
1416         movq_cfi r11, R11+8
1417         movq_cfi rbx, RBX+8
1418         movq_cfi rbp, RBP+8
1419         movq_cfi r12, R12+8
1420         movq_cfi r13, R13+8
1421         movq_cfi r14, R14+8
1422         movq_cfi r15, R15+8
1423         xorl %ebx,%ebx
1424         testl $3,CS+8(%rsp)
1425         je error_kernelspace
1426 error_swapgs:
1427         SWAPGS
1428 error_sti:
1429         TRACE_IRQS_OFF
1430         ret
1431
1432 /*
1433  * There are two places in the kernel that can potentially fault with
1434  * usergs. Handle them here. The exception handlers after iret run with
1435  * kernel gs again, so don't set the user space flag. B stepping K8s
1436  * sometimes report an truncated RIP for IRET exceptions returning to
1437  * compat mode. Check for these here too.
1438  */
1439 error_kernelspace:
1440         incl %ebx
1441         leaq irq_return(%rip),%rcx
1442         cmpq %rcx,RIP+8(%rsp)
1443         je error_swapgs
1444         movl %ecx,%eax  /* zero extend */
1445         cmpq %rax,RIP+8(%rsp)
1446         je bstep_iret
1447         cmpq $gs_change,RIP+8(%rsp)
1448         je error_swapgs
1449         jmp error_sti
1450
1451 bstep_iret:
1452         /* Fix truncated RIP */
1453         movq %rcx,RIP+8(%rsp)
1454         jmp error_swapgs
1455         CFI_ENDPROC
1456 END(error_entry)
1457
1458
1459 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1460 ENTRY(error_exit)
1461         DEFAULT_FRAME
1462         movl %ebx,%eax
1463         RESTORE_REST
1464         DISABLE_INTERRUPTS(CLBR_NONE)
1465         TRACE_IRQS_OFF
1466         GET_THREAD_INFO(%rcx)
1467         testl %eax,%eax
1468         jne retint_kernel
1469         LOCKDEP_SYS_EXIT_IRQ
1470         movl TI_flags(%rcx),%edx
1471         movl $_TIF_WORK_MASK,%edi
1472         andl %edi,%edx
1473         jnz retint_careful
1474         jmp retint_swapgs
1475         CFI_ENDPROC
1476 END(error_exit)
1477
1478
1479         /* runs on exception stack */
1480 ENTRY(nmi)
1481         INTR_FRAME
1482         PARAVIRT_ADJUST_EXCEPTION_FRAME
1483         pushq_cfi $-1
1484         subq $ORIG_RAX-R15, %rsp
1485         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1486         call save_paranoid
1487         DEFAULT_FRAME 0
1488         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1489         movq %rsp,%rdi
1490         movq $-1,%rsi
1491         call do_nmi
1492 #ifdef CONFIG_TRACE_IRQFLAGS
1493         /* paranoidexit; without TRACE_IRQS_OFF */
1494         /* ebx: no swapgs flag */
1495         DISABLE_INTERRUPTS(CLBR_NONE)
1496         testl %ebx,%ebx                         /* swapgs needed? */
1497         jnz nmi_restore
1498         testl $3,CS(%rsp)
1499         jnz nmi_userspace
1500 nmi_swapgs:
1501         SWAPGS_UNSAFE_STACK
1502 nmi_restore:
1503         RESTORE_ALL 8
1504         jmp irq_return
1505 nmi_userspace:
1506         GET_THREAD_INFO(%rcx)
1507         movl TI_flags(%rcx),%ebx
1508         andl $_TIF_WORK_MASK,%ebx
1509         jz nmi_swapgs
1510         movq %rsp,%rdi                  /* &pt_regs */
1511         call sync_regs
1512         movq %rax,%rsp                  /* switch stack for scheduling */
1513         testl $_TIF_NEED_RESCHED,%ebx
1514         jnz nmi_schedule
1515         movl %ebx,%edx                  /* arg3: thread flags */
1516         ENABLE_INTERRUPTS(CLBR_NONE)
1517         xorl %esi,%esi                  /* arg2: oldset */
1518         movq %rsp,%rdi                  /* arg1: &pt_regs */
1519         call do_notify_resume
1520         DISABLE_INTERRUPTS(CLBR_NONE)
1521         jmp nmi_userspace
1522 nmi_schedule:
1523         ENABLE_INTERRUPTS(CLBR_ANY)
1524         call schedule
1525         DISABLE_INTERRUPTS(CLBR_ANY)
1526         jmp nmi_userspace
1527         CFI_ENDPROC
1528 #else
1529         jmp paranoid_exit
1530         CFI_ENDPROC
1531 #endif
1532 END(nmi)
1533
1534 ENTRY(ignore_sysret)
1535         CFI_STARTPROC
1536         mov $-ENOSYS,%eax
1537         sysret
1538         CFI_ENDPROC
1539 END(ignore_sysret)
1540
1541 /*
1542  * End of kprobes section
1543  */
1544         .popsection