arch/x86/kernel/head_32.S

   1 /*
   2  *
   3  *  Copyright (C) 1991, 1992  Linus Torvalds
   4  *
   5  *  Enhanced CPU detection and feature setting code by Mike Jagdis
   6  *  and Martin Mares, November 1997.
   7  */
   8
   9 .text
  10 #include <linux/threads.h>
  11 #include <linux/init.h>
  12 #include <linux/linkage.h>
  13 #include <asm/segment.h>
  14 #include <asm/page_types.h>
  15 #include <asm/pgtable_types.h>
  16 #include <asm/cache.h>
  17 #include <asm/thread_info.h>
  18 #include <asm/asm-offsets.h>
  19 #include <asm/setup.h>
  20 #include <asm/processor-flags.h>
  21 #include <asm/msr-index.h>
  22 #include <asm/cpufeature.h>
  23 #include <asm/percpu.h>
  24 #include <asm/nops.h>
  25
  26 /* Physical address */
  27 #define pa(X) ((X) - __PAGE_OFFSET)
  28
  29 /*
  30  * References to members of the new_cpu_data structure.
  31  */
  32
  33 #define X86             new_cpu_data+CPUINFO_x86
  34 #define X86_VENDOR      new_cpu_data+CPUINFO_x86_vendor
  35 #define X86_MODEL       new_cpu_data+CPUINFO_x86_model
  36 #define X86_MASK        new_cpu_data+CPUINFO_x86_mask
  37 #define X86_HARD_MATH   new_cpu_data+CPUINFO_hard_math
  38 #define X86_CPUID       new_cpu_data+CPUINFO_cpuid_level
  39 #define X86_CAPABILITY  new_cpu_data+CPUINFO_x86_capability
  40 #define X86_VENDOR_ID   new_cpu_data+CPUINFO_x86_vendor_id
  41
  42 /*
  43  * This is how much memory in addition to the memory covered up to
  44  * and including _end we need mapped initially.
  45  * We need:
  46  *     (KERNEL_IMAGE_SIZE/4096) / 1024 pages (worst case, non PAE)
  47  *     (KERNEL_IMAGE_SIZE/4096) / 512 + 4 pages (worst case for PAE)
  48  *
  49  * Modulo rounding, each megabyte assigned here requires a kilobyte of
  50  * memory, which is currently unreclaimed.
  51  *
  52  * This should be a multiple of a page.
  53  *
  54  * KERNEL_IMAGE_SIZE should be greater than pa(_end)
  55  * and small than max_low_pfn, otherwise will waste some page table entries
  56  */
  57
  58 #if PTRS_PER_PMD > 1
  59 #define PAGE_TABLE_SIZE(pages) (((pages) / PTRS_PER_PMD) + PTRS_PER_PGD)
  60 #else
  61 #define PAGE_TABLE_SIZE(pages) ((pages) / PTRS_PER_PGD)
  62 #endif
  63
  64 /* Number of possible pages in the lowmem region */
  65 LOWMEM_PAGES = (((1<<32) - __PAGE_OFFSET) >> PAGE_SHIFT)
  66
  67 /* Enough space to fit pagetables for the low memory linear map */
  68 MAPPING_BEYOND_END = PAGE_TABLE_SIZE(LOWMEM_PAGES) << PAGE_SHIFT
  69
  70 /*
  71  * Worst-case size of the kernel mapping we need to make:
  72  * a relocatable kernel can live anywhere in lowmem, so we need to be able
  73  * to map all of lowmem.
  74  */
  75 KERNEL_PAGES = LOWMEM_PAGES
  76
  77 INIT_MAP_SIZE = PAGE_TABLE_SIZE(KERNEL_PAGES) * PAGE_SIZE
  78 RESERVE_BRK(pagetables, INIT_MAP_SIZE)
  79
  80 /*
  81  * 32-bit kernel entrypoint; only used by the boot CPU.  On entry,
  82  * %esi points to the real-mode code as a 32-bit pointer.
  83  * CS and DS must be 4 GB flat segments, but we don't depend on
  84  * any particular GDT layout, because we load our own as soon as we
  85  * can.
  86  */
  87 __HEAD
  88 ENTRY(startup_32)
  89         movl pa(stack_start),%ecx
  90
  91         /* test KEEP_SEGMENTS flag to see if the bootloader is asking
  92                 us to not reload segments */
  93         testb $(1<<6), BP_loadflags(%esi)
  94         jnz 2f
  95
  96 /*
  97  * Set segments to known values.
  98  */
  99         lgdt pa(boot_gdt_descr)
 100         movl $(__BOOT_DS),%eax
 101         movl %eax,%ds
 102         movl %eax,%es
 103         movl %eax,%fs
 104         movl %eax,%gs
 105         movl %eax,%ss
 106 2:
 107         leal -__PAGE_OFFSET(%ecx),%esp
 108
 109 /*
 110  * Clear BSS first so that there are no surprises...
 111  */
 112         cld
 113         xorl %eax,%eax
 114         movl $pa(__bss_start),%edi
 115         movl $pa(__bss_stop),%ecx
 116         subl %edi,%ecx
 117         shrl $2,%ecx
 118         rep ; stosl
 119 /*
 120  * Copy bootup parameters out of the way.
 121  * Note: %esi still has the pointer to the real-mode data.
 122  * With the kexec as boot loader, parameter segment might be loaded beyond
 123  * kernel image and might not even be addressable by early boot page tables.
 124  * (kexec on panic case). Hence copy out the parameters before initializing
 125  * page tables.
 126  */
 127         movl $pa(boot_params),%edi
 128         movl $(PARAM_SIZE/4),%ecx
 129         cld
 130         rep
 131         movsl
 132         movl pa(boot_params) + NEW_CL_POINTER,%esi
 133         andl %esi,%esi
 134         jz 1f                   # No command line
 135         movl $pa(boot_command_line),%edi
 136         movl $(COMMAND_LINE_SIZE/4),%ecx
 137         rep
 138         movsl
 139 1:
 140
 141 #ifdef CONFIG_OLPC
 142         /* save OFW's pgdir table for later use when calling into OFW */
 143         movl %cr3, %eax
 144         movl %eax, pa(olpc_ofw_pgd)
 145 #endif
 146
 147 /*
 148  * Initialize page tables.  This creates a PDE and a set of page
 149  * tables, which are located immediately beyond __brk_base.  The variable
 150  * _brk_end is set up to point to the first "safe" location.
 151  * Mappings are created both at virtual address 0 (identity mapping)
 152  * and PAGE_OFFSET for up to _end.
 153  */
 154 #ifdef CONFIG_X86_PAE
 155
 156         /*
 157          * In PAE mode initial_page_table is statically defined to contain
 158          * enough entries to cover the VMSPLIT option (that is the top 1, 2 or 3
 159          * entries). The identity mapping is handled by pointing two PGD entries
 160          * to the first kernel PMD.
 161          *
 162          * Note the upper half of each PMD or PTE are always zero at this stage.
 163          */
 164
 165 #define KPMDS (((-__PAGE_OFFSET) >> 30) & 3) /* Number of kernel PMDs */
 166
 167         xorl %ebx,%ebx                          /* %ebx is kept at zero */
 168
 169         movl $pa(__brk_base), %edi
 170         movl $pa(initial_pg_pmd), %edx
 171         movl $PTE_IDENT_ATTR, %eax
 172 10:
 173         leal PDE_IDENT_ATTR(%edi),%ecx          /* Create PMD entry */
 174         movl %ecx,(%edx)                        /* Store PMD entry */
 175                                                 /* Upper half already zero */
 176         addl $8,%edx
 177         movl $512,%ecx
 178 11:
 179         stosl
 180         xchgl %eax,%ebx
 181         stosl
 182         xchgl %eax,%ebx
 183         addl $0x1000,%eax
 184         loop 11b
 185
 186         /*
 187          * End condition: we must map up to the end + MAPPING_BEYOND_END.
 188          */
 189         movl $pa(_end) + MAPPING_BEYOND_END + PTE_IDENT_ATTR, %ebp
 190         cmpl %ebp,%eax
 191         jb 10b
 192 1:
 193         addl $__PAGE_OFFSET, %edi
 194         movl %edi, pa(_brk_end)
 195         shrl $12, %eax
 196         movl %eax, pa(max_pfn_mapped)
 197
 198         /* Do early initialization of the fixmap area */
 199         movl $pa(initial_pg_fixmap)+PDE_IDENT_ATTR,%eax
 200         movl %eax,pa(initial_pg_pmd+0x1000*KPMDS-8)
 201 #else   /* Not PAE */
 202
 203 page_pde_offset = (__PAGE_OFFSET >> 20);
 204
 205         movl $pa(__brk_base), %edi
 206         movl $pa(initial_page_table), %edx
 207         movl $PTE_IDENT_ATTR, %eax
 208 10:
 209         leal PDE_IDENT_ATTR(%edi),%ecx          /* Create PDE entry */
 210         movl %ecx,(%edx)                        /* Store identity PDE entry */
 211         movl %ecx,page_pde_offset(%edx)         /* Store kernel PDE entry */
 212         addl $4,%edx
 213         movl $1024, %ecx
 214 11:
 215         stosl
 216         addl $0x1000,%eax
 217         loop 11b
 218         /*
 219          * End condition: we must map up to the end + MAPPING_BEYOND_END.
 220          */
 221         movl $pa(_end) + MAPPING_BEYOND_END + PTE_IDENT_ATTR, %ebp
 222         cmpl %ebp,%eax
 223         jb 10b
 224         addl $__PAGE_OFFSET, %edi
 225         movl %edi, pa(_brk_end)
 226         shrl $12, %eax
 227         movl %eax, pa(max_pfn_mapped)
 228
 229         /* Do early initialization of the fixmap area */
 230         movl $pa(initial_pg_fixmap)+PDE_IDENT_ATTR,%eax
 231         movl %eax,pa(initial_page_table+0xffc)
 232 #endif
 233
 234 #ifdef CONFIG_PARAVIRT
 235         /* This is can only trip for a broken bootloader... */
 236         cmpw $0x207, pa(boot_params + BP_version)
 237         jb default_entry
 238
 239         /* Paravirt-compatible boot parameters.  Look to see what architecture
 240                 we're booting under. */
 241         movl pa(boot_params + BP_hardware_subarch), %eax
 242         cmpl $num_subarch_entries, %eax
 243         jae bad_subarch
 244
 245         movl pa(subarch_entries)(,%eax,4), %eax
 246         subl $__PAGE_OFFSET, %eax
 247         jmp *%eax
 248
 249 bad_subarch:
 250 WEAK(lguest_entry)
 251 WEAK(xen_entry)
 252         /* Unknown implementation; there's really
 253            nothing we can do at this point. */
 254         ud2a
 255
 256         __INITDATA
 257
 258 subarch_entries:
 259         .long default_entry             /* normal x86/PC */
 260         .long lguest_entry              /* lguest hypervisor */
 261         .long xen_entry                 /* Xen hypervisor */
 262         .long default_entry             /* Moorestown MID */
 263 num_subarch_entries = (. - subarch_entries) / 4
 264 .previous
 265 #else
 266         jmp default_entry
 267 #endif /* CONFIG_PARAVIRT */
 268
 269 #ifdef CONFIG_HOTPLUG_CPU
 270 /*
 271  * Boot CPU0 entry point. It's called from play_dead(). Everything has been set
 272  * up already except stack. We just set up stack here. Then call
 273  * start_secondary().
 274  */
 275 ENTRY(start_cpu0)
 276         movl stack_start, %ecx
 277         movl %ecx, %esp
 278         jmp  *(initial_code)
 279 ENDPROC(start_cpu0)
 280 #endif
 281
 282 /*
 283  * Non-boot CPU entry point; entered from trampoline.S
 284  * We can't lgdt here, because lgdt itself uses a data segment, but
 285  * we know the trampoline has already loaded the boot_gdt for us.
 286  *
 287  * If cpu hotplug is not supported then this code can go in init section
 288  * which will be freed later
 289  */
 290 __CPUINIT
 291 ENTRY(startup_32_smp)
 292         cld
 293         movl $(__BOOT_DS),%eax
 294         movl %eax,%ds
 295         movl %eax,%es
 296         movl %eax,%fs
 297         movl %eax,%gs
 298         movl pa(stack_start),%ecx
 299         movl %eax,%ss
 300         leal -__PAGE_OFFSET(%ecx),%esp
 301
 302 default_entry:
 303 /*
 304  *      New page tables may be in 4Mbyte page mode and may
 305  *      be using the global pages.
 306  *
 307  *      NOTE! If we are on a 486 we may have no cr4 at all!
 308  *      Specifically, cr4 exists if and only if CPUID exists,
 309  *      which in turn exists if and only if EFLAGS.ID exists.
 310  */
 311         movl $X86_EFLAGS_ID,%ecx
 312         pushl %ecx
 313         popfl
 314         pushfl
 315         popl %eax
 316         pushl $0
 317         popfl
 318         pushfl
 319         popl %edx
 320         xorl %edx,%eax
 321         testl %ecx,%eax
 322         jz 6f                   # No ID flag = no CPUID = no CR4
 323
 324         movl pa(mmu_cr4_features),%eax
 325         movl %eax,%cr4
 326
 327         testb $X86_CR4_PAE, %al         # check if PAE is enabled
 328         jz 6f
 329
 330         /* Check if extended functions are implemented */
 331         movl $0x80000000, %eax
 332         cpuid
 333         /* Value must be in the range 0x80000001 to 0x8000ffff */
 334         subl $0x80000001, %eax
 335         cmpl $(0x8000ffff-0x80000001), %eax
 336         ja 6f
 337
 338         /* Clear bogus XD_DISABLE bits */
 339         call verify_cpu
 340
 341         mov $0x80000001, %eax
 342         cpuid
 343         /* Execute Disable bit supported? */
 344         btl $(X86_FEATURE_NX & 31), %edx
 345         jnc 6f
 346
 347         /* Setup EFER (Extended Feature Enable Register) */
 348         movl $MSR_EFER, %ecx
 349         rdmsr
 350
 351         btsl $_EFER_NX, %eax
 352         /* Make changes effective */
 353         wrmsr
 354
 355 6:
 356
 357 /*
 358  * Enable paging
 359  */
 360         movl $pa(initial_page_table), %eax
 361         movl %eax,%cr3          /* set the page table pointer.. */
 362         movl %cr0,%eax
 363         orl  $X86_CR0_PG,%eax
 364         movl %eax,%cr0          /* ..and set paging (PG) bit */
 365         ljmp $__BOOT_CS,$1f     /* Clear prefetch and normalize %eip */
 366 1:
 367         /* Shift the stack pointer to a virtual address */
 368         addl $__PAGE_OFFSET, %esp
 369
 370 /*
 371  * Initialize eflags.  Some BIOS's leave bits like NT set.  This would
 372  * confuse the debugger if this code is traced.
 373  * XXX - best to initialize before switching to protected mode.
 374  */
 375         pushl $0
 376         popfl
 377
 378 /*
 379  * start system 32-bit setup. We need to re-do some of the things done
 380  * in 16-bit mode for the "real" operations.
 381  */
 382         movl setup_once_ref,%eax
 383         andl %eax,%eax
 384         jz 1f                           # Did we do this already?
 385         call *%eax
 386 1:
 387
 388 /* check if it is 486 or 386. */
 389 /*
 390  * XXX - this does a lot of unnecessary setup.  Alignment checks don't
 391  * apply at our cpl of 0 and the stack ought to be aligned already, and
 392  * we don't need to preserve eflags.
 393  */
 394         movl $-1,X86_CPUID      # -1 for no CPUID initially
 395         movb $3,X86             # at least 386
 396         pushfl                  # push EFLAGS
 397         popl %eax               # get EFLAGS
 398         movl %eax,%ecx          # save original EFLAGS
 399         xorl $0x240000,%eax     # flip AC and ID bits in EFLAGS
 400         pushl %eax              # copy to EFLAGS
 401         popfl                   # set EFLAGS
 402         pushfl                  # get new EFLAGS
 403         popl %eax               # put it in eax
 404         xorl %ecx,%eax          # change in flags
 405         pushl %ecx              # restore original EFLAGS
 406         popfl
 407         testl $0x40000,%eax     # check if AC bit changed
 408         je is386
 409
 410         movb $4,X86             # at least 486
 411         testl $0x200000,%eax    # check if ID bit changed
 412         je is486
 413
 414         /* get vendor info */
 415         xorl %eax,%eax                  # call CPUID with 0 -> return vendor ID
 416         cpuid
 417         movl %eax,X86_CPUID             # save CPUID level
 418         movl %ebx,X86_VENDOR_ID         # lo 4 chars
 419         movl %edx,X86_VENDOR_ID+4       # next 4 chars
 420         movl %ecx,X86_VENDOR_ID+8       # last 4 chars
 421
 422         orl %eax,%eax                   # do we have processor info as well?
 423         je is486
 424
 425         movl $1,%eax            # Use the CPUID instruction to get CPU type
 426         cpuid
 427         movb %al,%cl            # save reg for future use
 428         andb $0x0f,%ah          # mask processor family
 429         movb %ah,X86
 430         andb $0xf0,%al          # mask model
 431         shrb $4,%al
 432         movb %al,X86_MODEL
 433         andb $0x0f,%cl          # mask mask revision
 434         movb %cl,X86_MASK
 435         movl %edx,X86_CAPABILITY
 436
 437 is486:  movl $0x50022,%ecx      # set AM, WP, NE and MP
 438         jmp 2f
 439
 440 is386:  movl $2,%ecx            # set MP
 441 2:      movl %cr0,%eax
 442         andl $0x80000011,%eax   # Save PG,PE,ET
 443         orl %ecx,%eax
 444         movl %eax,%cr0
 445
 446         call check_x87
 447         lgdt early_gdt_descr
 448         lidt idt_descr
 449         ljmp $(__KERNEL_CS),$1f
 450 1:      movl $(__KERNEL_DS),%eax        # reload all the segment registers
 451         movl %eax,%ss                   # after changing gdt.
 452
 453         movl $(__USER_DS),%eax          # DS/ES contains default USER segment
 454         movl %eax,%ds
 455         movl %eax,%es
 456
 457         movl $(__KERNEL_PERCPU), %eax
 458         movl %eax,%fs                   # set this cpu's percpu
 459
 460         movl $(__KERNEL_STACK_CANARY),%eax
 461         movl %eax,%gs
 462
 463         xorl %eax,%eax                  # Clear LDT
 464         lldt %ax
 465
 466         cld                     # gcc2 wants the direction flag cleared at all times
 467         pushl $0                # fake return address for unwinder
 468         jmp *(initial_code)
 469
 470 /*
 471  * We depend on ET to be correct. This checks for 287/387.
 472  */
 473 check_x87:
 474         movb $0,X86_HARD_MATH
 475         clts
 476         fninit
 477         fstsw %ax
 478         cmpb $0,%al
 479         je 1f
 480         movl %cr0,%eax          /* no coprocessor: have to set bits */
 481         xorl $4,%eax            /* set EM */
 482         movl %eax,%cr0
 483         ret
 484         ALIGN
 485 1:      movb $1,X86_HARD_MATH
 486         .byte 0xDB,0xE4         /* fsetpm for 287, ignored by 387 */
 487         ret
 488
 489
 490 #include "verify_cpu.S"
 491
 492 /*
 493  *  setup_once
 494  *
 495  *  The setup work we only want to run on the BSP.
 496  *
 497  *  Warning: %esi is live across this function.
 498  */
 499 __INIT
 500 setup_once:
 501         /*
 502          * Set up a idt with 256 entries pointing to ignore_int,
 503          * interrupt gates. It doesn't actually load idt - that needs
 504          * to be done on each CPU. Interrupts are enabled elsewhere,
 505          * when we can be relatively sure everything is ok.
 506          */
 507
 508         movl $idt_table,%edi
 509         movl $early_idt_handlers,%eax
 510         movl $NUM_EXCEPTION_VECTORS,%ecx
 511 1:
 512         movl %eax,(%edi)
 513         movl %eax,4(%edi)
 514         /* interrupt gate, dpl=0, present */
 515         movl $(0x8E000000 + __KERNEL_CS),2(%edi)
 516         addl $9,%eax
 517         addl $8,%edi
 518         loop 1b
 519
 520         movl $256 - NUM_EXCEPTION_VECTORS,%ecx
 521         movl $ignore_int,%edx
 522         movl $(__KERNEL_CS << 16),%eax
 523         movw %dx,%ax            /* selector = 0x0010 = cs */
 524         movw $0x8E00,%dx        /* interrupt gate - dpl=0, present */
 525 2:
 526         movl %eax,(%edi)
 527         movl %edx,4(%edi)
 528         addl $8,%edi
 529         loop 2b
 530
 531 #ifdef CONFIG_CC_STACKPROTECTOR
 532         /*
 533          * Configure the stack canary. The linker can't handle this by
 534          * relocation.  Manually set base address in stack canary
 535          * segment descriptor.
 536          */
 537         movl $gdt_page,%eax
 538         movl $stack_canary,%ecx
 539         movw %cx, 8 * GDT_ENTRY_STACK_CANARY + 2(%eax)
 540         shrl $16, %ecx
 541         movb %cl, 8 * GDT_ENTRY_STACK_CANARY + 4(%eax)
 542         movb %ch, 8 * GDT_ENTRY_STACK_CANARY + 7(%eax)
 543 #endif
 544
 545         andl $0,setup_once_ref  /* Once is enough, thanks */
 546         ret
 547
 548 ENTRY(early_idt_handlers)
 549         # 36(%esp) %eflags
 550         # 32(%esp) %cs
 551         # 28(%esp) %eip
 552         # 24(%rsp) error code
 553         i = 0
 554         .rept NUM_EXCEPTION_VECTORS
 555         .if (EXCEPTION_ERRCODE_MASK >> i) & 1
 556         ASM_NOP2
 557         .else
 558         pushl $0                # Dummy error code, to make stack frame uniform
 559         .endif
 560         pushl $i                # 20(%esp) Vector number
 561         jmp early_idt_handler
 562         i = i + 1
 563         .endr
 564 ENDPROC(early_idt_handlers)
 565
 566         /* This is global to keep gas from relaxing the jumps */
 567 ENTRY(early_idt_handler)
 568         cld
 569         cmpl $2,%ss:early_recursion_flag
 570         je hlt_loop
 571         incl %ss:early_recursion_flag
 572
 573         push %eax               # 16(%esp)
 574         push %ecx               # 12(%esp)
 575         push %edx               #  8(%esp)
 576         push %ds                #  4(%esp)
 577         push %es                #  0(%esp)
 578         movl $(__KERNEL_DS),%eax
 579         movl %eax,%ds
 580         movl %eax,%es
 581
 582         cmpl $(__KERNEL_CS),32(%esp)
 583         jne 10f
 584
 585         leal 28(%esp),%eax      # Pointer to %eip
 586         call early_fixup_exception
 587         andl %eax,%eax
 588         jnz ex_entry            /* found an exception entry */
 589
 590 10:
 591 #ifdef CONFIG_PRINTK
 592         xorl %eax,%eax
 593         movw %ax,2(%esp)        /* clean up the segment values on some cpus */
 594         movw %ax,6(%esp)
 595         movw %ax,34(%esp)
 596         leal  40(%esp),%eax
 597         pushl %eax              /* %esp before the exception */
 598         pushl %ebx
 599         pushl %ebp
 600         pushl %esi
 601         pushl %edi
 602         movl %cr2,%eax
 603         pushl %eax
 604         pushl (20+6*4)(%esp)    /* trapno */
 605         pushl $fault_msg
 606         call printk
 607 #endif
 608         call dump_stack
 609 hlt_loop:
 610         hlt
 611         jmp hlt_loop
 612
 613 ex_entry:
 614         pop %es
 615         pop %ds
 616         pop %edx
 617         pop %ecx
 618         pop %eax
 619         addl $8,%esp            /* drop vector number and error code */
 620         decl %ss:early_recursion_flag
 621         iret
 622 ENDPROC(early_idt_handler)
 623
 624 /* This is the default interrupt "handler" :-) */
 625         ALIGN
 626 ignore_int:
 627         cld
 628 #ifdef CONFIG_PRINTK
 629         pushl %eax
 630         pushl %ecx
 631         pushl %edx
 632         pushl %es
 633         pushl %ds
 634         movl $(__KERNEL_DS),%eax
 635         movl %eax,%ds
 636         movl %eax,%es
 637         cmpl $2,early_recursion_flag
 638         je hlt_loop
 639         incl early_recursion_flag
 640         pushl 16(%esp)
 641         pushl 24(%esp)
 642         pushl 32(%esp)
 643         pushl 40(%esp)
 644         pushl $int_msg
 645         call printk
 646
 647         call dump_stack
 648
 649         addl $(5*4),%esp
 650         popl %ds
 651         popl %es
 652         popl %edx
 653         popl %ecx
 654         popl %eax
 655 #endif
 656         iret
 657 ENDPROC(ignore_int)
 658 __INITDATA
 659         .align 4
 660 early_recursion_flag:
 661         .long 0
 662
 663 __REFDATA
 664         .align 4
 665 ENTRY(initial_code)
 666         .long i386_start_kernel
 667 ENTRY(setup_once_ref)
 668         .long setup_once
 669
 670 /*
 671  * BSS section
 672  */
 673 __PAGE_ALIGNED_BSS
 674         .align PAGE_SIZE
 675 #ifdef CONFIG_X86_PAE
 676 initial_pg_pmd:
 677         .fill 1024*KPMDS,4,0
 678 #else
 679 ENTRY(initial_page_table)
 680         .fill 1024,4,0
 681 #endif
 682 initial_pg_fixmap:
 683         .fill 1024,4,0
 684 ENTRY(empty_zero_page)
 685         .fill 4096,1,0
 686 ENTRY(swapper_pg_dir)
 687         .fill 1024,4,0
 688
 689 /*
 690  * This starts the data section.
 691  */
 692 #ifdef CONFIG_X86_PAE
 693 __PAGE_ALIGNED_DATA
 694         /* Page-aligned for the benefit of paravirt? */
 695         .align PAGE_SIZE
 696 ENTRY(initial_page_table)
 697         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0     /* low identity map */
 698 # if KPMDS == 3
 699         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
 700         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x1000),0
 701         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x2000),0
 702 # elif KPMDS == 2
 703         .long   0,0
 704         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
 705         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x1000),0
 706 # elif KPMDS == 1
 707         .long   0,0
 708         .long   0,0
 709         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
 710 # else
 711 #  error "Kernel PMDs should be 1, 2 or 3"
 712 # endif
 713         .align PAGE_SIZE                /* needs to be page-sized too */
 714 #endif
 715
 716 .data
 717 .balign 4
 718 ENTRY(stack_start)
 719         .long init_thread_union+THREAD_SIZE
 720
 721 __INITRODATA
 722 int_msg:
 723         .asciz "Unknown interrupt or fault at: %p %p %p\n"
 724
 725 fault_msg:
 726 /* fault info: */
 727         .ascii "BUG: Int %d: CR2 %p\n"
 728 /* regs pushed in early_idt_handler: */
 729         .ascii "     EDI %p  ESI %p  EBP %p  EBX %p\n"
 730         .ascii "     ESP %p   ES %p   DS %p\n"
 731         .ascii "     EDX %p  ECX %p  EAX %p\n"
 732 /* fault frame: */
 733         .ascii "     vec %p  err %p  EIP %p   CS %p  flg %p\n"
 734         .ascii "Stack: %p %p %p %p %p %p %p %p\n"
 735         .ascii "       %p %p %p %p %p %p %p %p\n"
 736         .asciz "       %p %p %p %p %p %p %p %p\n"
 737
 738 #include "../../x86/xen/xen-head.S"
 739
 740 /*
 741  * The IDT and GDT 'descriptors' are a strange 48-bit object
 742  * only used by the lidt and lgdt instructions. They are not
 743  * like usual segment descriptors - they consist of a 16-bit
 744  * segment size, and 32-bit linear address value:
 745  */
 746
 747         .data
 748 .globl boot_gdt_descr
 749 .globl idt_descr
 750
 751         ALIGN
 752 # early boot GDT descriptor (must use 1:1 address mapping)
 753         .word 0                         # 32 bit align gdt_desc.address
 754 boot_gdt_descr:
 755         .word __BOOT_DS+7
 756         .long boot_gdt - __PAGE_OFFSET
 757
 758         .word 0                         # 32-bit align idt_desc.address
 759 idt_descr:
 760         .word IDT_ENTRIES*8-1           # idt contains 256 entries
 761         .long idt_table
 762
 763 # boot GDT descriptor (later on used by CPU#0):
 764         .word 0                         # 32 bit align gdt_desc.address
 765 ENTRY(early_gdt_descr)
 766         .word GDT_ENTRIES*8-1
 767         .long gdt_page                  /* Overwritten for secondary CPUs */
 768
 769 /*
 770  * The boot_gdt must mirror the equivalent in setup.S and is
 771  * used only for booting.
 772  */
 773         .align L1_CACHE_BYTES
 774 ENTRY(boot_gdt)
 775         .fill GDT_ENTRY_BOOT_CS,8,0
 776         .quad 0x00cf9a000000ffff        /* kernel 4GB code at 0x00000000 */
 777         .quad 0x00cf92000000ffff        /* kernel 4GB data at 0x00000000 */