arch/x86/kernel/head_32.S

   1 /*
   2  *
   3  *  Copyright (C) 1991, 1992  Linus Torvalds
   4  *
   5  *  Enhanced CPU detection and feature setting code by Mike Jagdis
   6  *  and Martin Mares, November 1997.
   7  */
   8
   9 .text
  10 #include <linux/threads.h>
  11 #include <linux/init.h>
  12 #include <linux/linkage.h>
  13 #include <asm/segment.h>
  14 #include <asm/page_types.h>
  15 #include <asm/pgtable_types.h>
  16 #include <asm/cache.h>
  17 #include <asm/thread_info.h>
  18 #include <asm/asm-offsets.h>
  19 #include <asm/setup.h>
  20 #include <asm/processor-flags.h>
  21 #include <asm/msr-index.h>
  22 #include <asm/cpufeature.h>
  23 #include <asm/percpu.h>
  24 #include <asm/nops.h>
  25
  26 /* Physical address */
  27 #define pa(X) ((X) - __PAGE_OFFSET)
  28
  29 /*
  30  * References to members of the new_cpu_data structure.
  31  */
  32
  33 #define X86             new_cpu_data+CPUINFO_x86
  34 #define X86_VENDOR      new_cpu_data+CPUINFO_x86_vendor
  35 #define X86_MODEL       new_cpu_data+CPUINFO_x86_model
  36 #define X86_MASK        new_cpu_data+CPUINFO_x86_mask
  37 #define X86_HARD_MATH   new_cpu_data+CPUINFO_hard_math
  38 #define X86_CPUID       new_cpu_data+CPUINFO_cpuid_level
  39 #define X86_CAPABILITY  new_cpu_data+CPUINFO_x86_capability
  40 #define X86_VENDOR_ID   new_cpu_data+CPUINFO_x86_vendor_id
  41
  42 /*
  43  * This is how much memory in addition to the memory covered up to
  44  * and including _end we need mapped initially.
  45  * We need:
  46  *     (KERNEL_IMAGE_SIZE/4096) / 1024 pages (worst case, non PAE)
  47  *     (KERNEL_IMAGE_SIZE/4096) / 512 + 4 pages (worst case for PAE)
  48  *
  49  * Modulo rounding, each megabyte assigned here requires a kilobyte of
  50  * memory, which is currently unreclaimed.
  51  *
  52  * This should be a multiple of a page.
  53  *
  54  * KERNEL_IMAGE_SIZE should be greater than pa(_end)
  55  * and small than max_low_pfn, otherwise will waste some page table entries
  56  */
  57
  58 #if PTRS_PER_PMD > 1
  59 #define PAGE_TABLE_SIZE(pages) (((pages) / PTRS_PER_PMD) + PTRS_PER_PGD)
  60 #else
  61 #define PAGE_TABLE_SIZE(pages) ((pages) / PTRS_PER_PGD)
  62 #endif
  63
  64 /* Number of possible pages in the lowmem region */
  65 LOWMEM_PAGES = (((1<<32) - __PAGE_OFFSET) >> PAGE_SHIFT)
  66
  67 /* Enough space to fit pagetables for the low memory linear map */
  68 MAPPING_BEYOND_END = PAGE_TABLE_SIZE(LOWMEM_PAGES) << PAGE_SHIFT
  69
  70 /*
  71  * Worst-case size of the kernel mapping we need to make:
  72  * a relocatable kernel can live anywhere in lowmem, so we need to be able
  73  * to map all of lowmem.
  74  */
  75 KERNEL_PAGES = LOWMEM_PAGES
  76
  77 INIT_MAP_SIZE = PAGE_TABLE_SIZE(KERNEL_PAGES) * PAGE_SIZE
  78 RESERVE_BRK(pagetables, INIT_MAP_SIZE)
  79
  80 /*
  81  * 32-bit kernel entrypoint; only used by the boot CPU.  On entry,
  82  * %esi points to the real-mode code as a 32-bit pointer.
  83  * CS and DS must be 4 GB flat segments, but we don't depend on
  84  * any particular GDT layout, because we load our own as soon as we
  85  * can.
  86  */
  87 __HEAD
  88 ENTRY(startup_32)
  89         movl pa(stack_start),%ecx
  90
  91         /* test KEEP_SEGMENTS flag to see if the bootloader is asking
  92                 us to not reload segments */
  93         testb $(1<<6), BP_loadflags(%esi)
  94         jnz 2f
  95
  96 /*
  97  * Set segments to known values.
  98  */
  99         lgdt pa(boot_gdt_descr)
 100         movl $(__BOOT_DS),%eax
 101         movl %eax,%ds
 102         movl %eax,%es
 103         movl %eax,%fs
 104         movl %eax,%gs
 105         movl %eax,%ss
 106 2:
 107         leal -__PAGE_OFFSET(%ecx),%esp
 108
 109 /*
 110  * Clear BSS first so that there are no surprises...
 111  */
 112         cld
 113         xorl %eax,%eax
 114         movl $pa(__bss_start),%edi
 115         movl $pa(__bss_stop),%ecx
 116         subl %edi,%ecx
 117         shrl $2,%ecx
 118         rep ; stosl
 119 /*
 120  * Copy bootup parameters out of the way.
 121  * Note: %esi still has the pointer to the real-mode data.
 122  * With the kexec as boot loader, parameter segment might be loaded beyond
 123  * kernel image and might not even be addressable by early boot page tables.
 124  * (kexec on panic case). Hence copy out the parameters before initializing
 125  * page tables.
 126  */
 127         movl $pa(boot_params),%edi
 128         movl $(PARAM_SIZE/4),%ecx
 129         cld
 130         rep
 131         movsl
 132         movl pa(boot_params) + NEW_CL_POINTER,%esi
 133         andl %esi,%esi
 134         jz 1f                   # No command line
 135         movl $pa(boot_command_line),%edi
 136         movl $(COMMAND_LINE_SIZE/4),%ecx
 137         rep
 138         movsl
 139 1:
 140
 141 #ifdef CONFIG_OLPC
 142         /* save OFW's pgdir table for later use when calling into OFW */
 143         movl %cr3, %eax
 144         movl %eax, pa(olpc_ofw_pgd)
 145 #endif
 146
 147 /*
 148  * Initialize page tables.  This creates a PDE and a set of page
 149  * tables, which are located immediately beyond __brk_base.  The variable
 150  * _brk_end is set up to point to the first "safe" location.
 151  * Mappings are created both at virtual address 0 (identity mapping)
 152  * and PAGE_OFFSET for up to _end.
 153  */
 154 #ifdef CONFIG_X86_PAE
 155
 156         /*
 157          * In PAE mode initial_page_table is statically defined to contain
 158          * enough entries to cover the VMSPLIT option (that is the top 1, 2 or 3
 159          * entries). The identity mapping is handled by pointing two PGD entries
 160          * to the first kernel PMD.
 161          *
 162          * Note the upper half of each PMD or PTE are always zero at this stage.
 163          */
 164
 165 #define KPMDS (((-__PAGE_OFFSET) >> 30) & 3) /* Number of kernel PMDs */
 166
 167         xorl %ebx,%ebx                          /* %ebx is kept at zero */
 168
 169         movl $pa(__brk_base), %edi
 170         movl $pa(initial_pg_pmd), %edx
 171         movl $PTE_IDENT_ATTR, %eax
 172 10:
 173         leal PDE_IDENT_ATTR(%edi),%ecx          /* Create PMD entry */
 174         movl %ecx,(%edx)                        /* Store PMD entry */
 175                                                 /* Upper half already zero */
 176         addl $8,%edx
 177         movl $512,%ecx
 178 11:
 179         stosl
 180         xchgl %eax,%ebx
 181         stosl
 182         xchgl %eax,%ebx
 183         addl $0x1000,%eax
 184         loop 11b
 185
 186         /*
 187          * End condition: we must map up to the end + MAPPING_BEYOND_END.
 188          */
 189         movl $pa(_end) + MAPPING_BEYOND_END + PTE_IDENT_ATTR, %ebp
 190         cmpl %ebp,%eax
 191         jb 10b
 192 1:
 193         addl $__PAGE_OFFSET, %edi
 194         movl %edi, pa(_brk_end)
 195         shrl $12, %eax
 196         movl %eax, pa(max_pfn_mapped)
 197
 198         /* Do early initialization of the fixmap area */
 199         movl $pa(initial_pg_fixmap)+PDE_IDENT_ATTR,%eax
 200         movl %eax,pa(initial_pg_pmd+0x1000*KPMDS-8)
 201 #else   /* Not PAE */
 202
 203 page_pde_offset = (__PAGE_OFFSET >> 20);
 204
 205         movl $pa(__brk_base), %edi
 206         movl $pa(initial_page_table), %edx
 207         movl $PTE_IDENT_ATTR, %eax
 208 10:
 209         leal PDE_IDENT_ATTR(%edi),%ecx          /* Create PDE entry */
 210         movl %ecx,(%edx)                        /* Store identity PDE entry */
 211         movl %ecx,page_pde_offset(%edx)         /* Store kernel PDE entry */
 212         addl $4,%edx
 213         movl $1024, %ecx
 214 11:
 215         stosl
 216         addl $0x1000,%eax
 217         loop 11b
 218         /*
 219          * End condition: we must map up to the end + MAPPING_BEYOND_END.
 220          */
 221         movl $pa(_end) + MAPPING_BEYOND_END + PTE_IDENT_ATTR, %ebp
 222         cmpl %ebp,%eax
 223         jb 10b
 224         addl $__PAGE_OFFSET, %edi
 225         movl %edi, pa(_brk_end)
 226         shrl $12, %eax
 227         movl %eax, pa(max_pfn_mapped)
 228
 229         /* Do early initialization of the fixmap area */
 230         movl $pa(initial_pg_fixmap)+PDE_IDENT_ATTR,%eax
 231         movl %eax,pa(initial_page_table+0xffc)
 232 #endif
 233
 234 #ifdef CONFIG_PARAVIRT
 235         /* This is can only trip for a broken bootloader... */
 236         cmpw $0x207, pa(boot_params + BP_version)
 237         jb default_entry
 238
 239         /* Paravirt-compatible boot parameters.  Look to see what architecture
 240                 we're booting under. */
 241         movl pa(boot_params + BP_hardware_subarch), %eax
 242         cmpl $num_subarch_entries, %eax
 243         jae bad_subarch
 244
 245         movl pa(subarch_entries)(,%eax,4), %eax
 246         subl $__PAGE_OFFSET, %eax
 247         jmp *%eax
 248
 249 bad_subarch:
 250 WEAK(lguest_entry)
 251 WEAK(xen_entry)
 252         /* Unknown implementation; there's really
 253            nothing we can do at this point. */
 254         ud2a
 255
 256         __INITDATA
 257
 258 subarch_entries:
 259         .long default_entry             /* normal x86/PC */
 260         .long lguest_entry              /* lguest hypervisor */
 261         .long xen_entry                 /* Xen hypervisor */
 262         .long default_entry             /* Moorestown MID */
 263 num_subarch_entries = (. - subarch_entries) / 4
 264 .previous
 265 #else
 266         jmp default_entry
 267 #endif /* CONFIG_PARAVIRT */
 268
 269 /*
 270  * Non-boot CPU entry point; entered from trampoline.S
 271  * We can't lgdt here, because lgdt itself uses a data segment, but
 272  * we know the trampoline has already loaded the boot_gdt for us.
 273  *
 274  * If cpu hotplug is not supported then this code can go in init section
 275  * which will be freed later
 276  */
 277 __CPUINIT
 278 ENTRY(startup_32_smp)
 279         cld
 280         movl $(__BOOT_DS),%eax
 281         movl %eax,%ds
 282         movl %eax,%es
 283         movl %eax,%fs
 284         movl %eax,%gs
 285         movl pa(stack_start),%ecx
 286         movl %eax,%ss
 287         leal -__PAGE_OFFSET(%ecx),%esp
 288
 289 default_entry:
 290 /*
 291  *      New page tables may be in 4Mbyte page mode and may
 292  *      be using the global pages.
 293  *
 294  *      NOTE! If we are on a 486 we may have no cr4 at all!
 295  *      Specifically, cr4 exists if and only if CPUID exists
 296  *      and has flags other than the FPU flag set.
 297  */
 298         movl $X86_EFLAGS_ID,%ecx
 299         pushl %ecx
 300         popfl
 301         pushfl
 302         popl %eax
 303         pushl $0
 304         popfl
 305         pushfl
 306         popl %edx
 307         xorl %edx,%eax
 308         testl %ecx,%eax
 309         jz 6f                   # No ID flag = no CPUID = no CR4
 310
 311         movl $1,%eax
 312         cpuid
 313         andl $~1,%edx           # Ignore CPUID.FPU
 314         jz 6f                   # No flags or only CPUID.FPU = no CR4
 315
 316         movl pa(mmu_cr4_features),%eax
 317         movl %eax,%cr4
 318
 319         testb $X86_CR4_PAE, %al         # check if PAE is enabled
 320         jz 6f
 321
 322         /* Check if extended functions are implemented */
 323         movl $0x80000000, %eax
 324         cpuid
 325         /* Value must be in the range 0x80000001 to 0x8000ffff */
 326         subl $0x80000001, %eax
 327         cmpl $(0x8000ffff-0x80000001), %eax
 328         ja 6f
 329
 330         /* Clear bogus XD_DISABLE bits */
 331         call verify_cpu
 332
 333         mov $0x80000001, %eax
 334         cpuid
 335         /* Execute Disable bit supported? */
 336         btl $(X86_FEATURE_NX & 31), %edx
 337         jnc 6f
 338
 339         /* Setup EFER (Extended Feature Enable Register) */
 340         movl $MSR_EFER, %ecx
 341         rdmsr
 342
 343         btsl $_EFER_NX, %eax
 344         /* Make changes effective */
 345         wrmsr
 346
 347 6:
 348
 349 /*
 350  * Enable paging
 351  */
 352         movl $pa(initial_page_table), %eax
 353         movl %eax,%cr3          /* set the page table pointer.. */
 354         movl %cr0,%eax
 355         orl  $X86_CR0_PG,%eax
 356         movl %eax,%cr0          /* ..and set paging (PG) bit */
 357         ljmp $__BOOT_CS,$1f     /* Clear prefetch and normalize %eip */
 358 1:
 359         /* Shift the stack pointer to a virtual address */
 360         addl $__PAGE_OFFSET, %esp
 361
 362 /*
 363  * Initialize eflags.  Some BIOS's leave bits like NT set.  This would
 364  * confuse the debugger if this code is traced.
 365  * XXX - best to initialize before switching to protected mode.
 366  */
 367         pushl $0
 368         popfl
 369
 370 /*
 371  * start system 32-bit setup. We need to re-do some of the things done
 372  * in 16-bit mode for the "real" operations.
 373  */
 374         movl setup_once_ref,%eax
 375         andl %eax,%eax
 376         jz 1f                           # Did we do this already?
 377         call *%eax
 378 1:
 379
 380 /* check if it is 486 or 386. */
 381 /*
 382  * XXX - this does a lot of unnecessary setup.  Alignment checks don't
 383  * apply at our cpl of 0 and the stack ought to be aligned already, and
 384  * we don't need to preserve eflags.
 385  */
 386         movl $-1,X86_CPUID      # -1 for no CPUID initially
 387         movb $3,X86             # at least 386
 388         pushfl                  # push EFLAGS
 389         popl %eax               # get EFLAGS
 390         movl %eax,%ecx          # save original EFLAGS
 391         xorl $0x240000,%eax     # flip AC and ID bits in EFLAGS
 392         pushl %eax              # copy to EFLAGS
 393         popfl                   # set EFLAGS
 394         pushfl                  # get new EFLAGS
 395         popl %eax               # put it in eax
 396         xorl %ecx,%eax          # change in flags
 397         pushl %ecx              # restore original EFLAGS
 398         popfl
 399         testl $0x40000,%eax     # check if AC bit changed
 400         je is386
 401
 402         movb $4,X86             # at least 486
 403         testl $0x200000,%eax    # check if ID bit changed
 404         je is486
 405
 406         /* get vendor info */
 407         xorl %eax,%eax                  # call CPUID with 0 -> return vendor ID
 408         cpuid
 409         movl %eax,X86_CPUID             # save CPUID level
 410         movl %ebx,X86_VENDOR_ID         # lo 4 chars
 411         movl %edx,X86_VENDOR_ID+4       # next 4 chars
 412         movl %ecx,X86_VENDOR_ID+8       # last 4 chars
 413
 414         orl %eax,%eax                   # do we have processor info as well?
 415         je is486
 416
 417         movl $1,%eax            # Use the CPUID instruction to get CPU type
 418         cpuid
 419         movb %al,%cl            # save reg for future use
 420         andb $0x0f,%ah          # mask processor family
 421         movb %ah,X86
 422         andb $0xf0,%al          # mask model
 423         shrb $4,%al
 424         movb %al,X86_MODEL
 425         andb $0x0f,%cl          # mask mask revision
 426         movb %cl,X86_MASK
 427         movl %edx,X86_CAPABILITY
 428
 429 is486:  movl $0x50022,%ecx      # set AM, WP, NE and MP
 430         jmp 2f
 431
 432 is386:  movl $2,%ecx            # set MP
 433 2:      movl %cr0,%eax
 434         andl $0x80000011,%eax   # Save PG,PE,ET
 435         orl %ecx,%eax
 436         movl %eax,%cr0
 437
 438         call check_x87
 439         lgdt early_gdt_descr
 440         lidt idt_descr
 441         ljmp $(__KERNEL_CS),$1f
 442 1:      movl $(__KERNEL_DS),%eax        # reload all the segment registers
 443         movl %eax,%ss                   # after changing gdt.
 444
 445         movl $(__USER_DS),%eax          # DS/ES contains default USER segment
 446         movl %eax,%ds
 447         movl %eax,%es
 448
 449         movl $(__KERNEL_PERCPU), %eax
 450         movl %eax,%fs                   # set this cpu's percpu
 451
 452         movl $(__KERNEL_STACK_CANARY),%eax
 453         movl %eax,%gs
 454
 455         xorl %eax,%eax                  # Clear LDT
 456         lldt %ax
 457
 458         cld                     # gcc2 wants the direction flag cleared at all times
 459         pushl $0                # fake return address for unwinder
 460         jmp *(initial_code)
 461
 462 /*
 463  * We depend on ET to be correct. This checks for 287/387.
 464  */
 465 check_x87:
 466         movb $0,X86_HARD_MATH
 467         clts
 468         fninit
 469         fstsw %ax
 470         cmpb $0,%al
 471         je 1f
 472         movl %cr0,%eax          /* no coprocessor: have to set bits */
 473         xorl $4,%eax            /* set EM */
 474         movl %eax,%cr0
 475         ret
 476         ALIGN
 477 1:      movb $1,X86_HARD_MATH
 478         .byte 0xDB,0xE4         /* fsetpm for 287, ignored by 387 */
 479         ret
 480
 481
 482 #include "verify_cpu.S"
 483
 484 /*
 485  *  setup_once
 486  *
 487  *  The setup work we only want to run on the BSP.
 488  *
 489  *  Warning: %esi is live across this function.
 490  */
 491 __INIT
 492 setup_once:
 493         /*
 494          * Set up a idt with 256 entries pointing to ignore_int,
 495          * interrupt gates. It doesn't actually load idt - that needs
 496          * to be done on each CPU. Interrupts are enabled elsewhere,
 497          * when we can be relatively sure everything is ok.
 498          */
 499
 500         movl $idt_table,%edi
 501         movl $early_idt_handlers,%eax
 502         movl $NUM_EXCEPTION_VECTORS,%ecx
 503 1:
 504         movl %eax,(%edi)
 505         movl %eax,4(%edi)
 506         /* interrupt gate, dpl=0, present */
 507         movl $(0x8E000000 + __KERNEL_CS),2(%edi)
 508         addl $9,%eax
 509         addl $8,%edi
 510         loop 1b
 511
 512         movl $256 - NUM_EXCEPTION_VECTORS,%ecx
 513         movl $ignore_int,%edx
 514         movl $(__KERNEL_CS << 16),%eax
 515         movw %dx,%ax            /* selector = 0x0010 = cs */
 516         movw $0x8E00,%dx        /* interrupt gate - dpl=0, present */
 517 2:
 518         movl %eax,(%edi)
 519         movl %edx,4(%edi)
 520         addl $8,%edi
 521         loop 2b
 522
 523 #ifdef CONFIG_CC_STACKPROTECTOR
 524         /*
 525          * Configure the stack canary. The linker can't handle this by
 526          * relocation.  Manually set base address in stack canary
 527          * segment descriptor.
 528          */
 529         movl $gdt_page,%eax
 530         movl $stack_canary,%ecx
 531         movw %cx, 8 * GDT_ENTRY_STACK_CANARY + 2(%eax)
 532         shrl $16, %ecx
 533         movb %cl, 8 * GDT_ENTRY_STACK_CANARY + 4(%eax)
 534         movb %ch, 8 * GDT_ENTRY_STACK_CANARY + 7(%eax)
 535 #endif
 536
 537         andl $0,setup_once_ref  /* Once is enough, thanks */
 538         ret
 539
 540 ENTRY(early_idt_handlers)
 541         # 36(%esp) %eflags
 542         # 32(%esp) %cs
 543         # 28(%esp) %eip
 544         # 24(%rsp) error code
 545         i = 0
 546         .rept NUM_EXCEPTION_VECTORS
 547         .if (EXCEPTION_ERRCODE_MASK >> i) & 1
 548         ASM_NOP2
 549         .else
 550         pushl $0                # Dummy error code, to make stack frame uniform
 551         .endif
 552         pushl $i                # 20(%esp) Vector number
 553         jmp early_idt_handler
 554         i = i + 1
 555         .endr
 556 ENDPROC(early_idt_handlers)
 557
 558         /* This is global to keep gas from relaxing the jumps */
 559 ENTRY(early_idt_handler)
 560         cld
 561         cmpl $2,%ss:early_recursion_flag
 562         je hlt_loop
 563         incl %ss:early_recursion_flag
 564
 565         push %eax               # 16(%esp)
 566         push %ecx               # 12(%esp)
 567         push %edx               #  8(%esp)
 568         push %ds                #  4(%esp)
 569         push %es                #  0(%esp)
 570         movl $(__KERNEL_DS),%eax
 571         movl %eax,%ds
 572         movl %eax,%es
 573
 574         cmpl $(__KERNEL_CS),32(%esp)
 575         jne 10f
 576
 577         leal 28(%esp),%eax      # Pointer to %eip
 578         call early_fixup_exception
 579         andl %eax,%eax
 580         jnz ex_entry            /* found an exception entry */
 581
 582 10:
 583 #ifdef CONFIG_PRINTK
 584         xorl %eax,%eax
 585         movw %ax,2(%esp)        /* clean up the segment values on some cpus */
 586         movw %ax,6(%esp)
 587         movw %ax,34(%esp)
 588         leal  40(%esp),%eax
 589         pushl %eax              /* %esp before the exception */
 590         pushl %ebx
 591         pushl %ebp
 592         pushl %esi
 593         pushl %edi
 594         movl %cr2,%eax
 595         pushl %eax
 596         pushl (20+6*4)(%esp)    /* trapno */
 597         pushl $fault_msg
 598         call printk
 599 #endif
 600         call dump_stack
 601 hlt_loop:
 602         hlt
 603         jmp hlt_loop
 604
 605 ex_entry:
 606         pop %es
 607         pop %ds
 608         pop %edx
 609         pop %ecx
 610         pop %eax
 611         addl $8,%esp            /* drop vector number and error code */
 612         decl %ss:early_recursion_flag
 613         iret
 614 ENDPROC(early_idt_handler)
 615
 616 /* This is the default interrupt "handler" :-) */
 617         ALIGN
 618 ignore_int:
 619         cld
 620 #ifdef CONFIG_PRINTK
 621         pushl %eax
 622         pushl %ecx
 623         pushl %edx
 624         pushl %es
 625         pushl %ds
 626         movl $(__KERNEL_DS),%eax
 627         movl %eax,%ds
 628         movl %eax,%es
 629         cmpl $2,early_recursion_flag
 630         je hlt_loop
 631         incl early_recursion_flag
 632         pushl 16(%esp)
 633         pushl 24(%esp)
 634         pushl 32(%esp)
 635         pushl 40(%esp)
 636         pushl $int_msg
 637         call printk
 638
 639         call dump_stack
 640
 641         addl $(5*4),%esp
 642         popl %ds
 643         popl %es
 644         popl %edx
 645         popl %ecx
 646         popl %eax
 647 #endif
 648         iret
 649 ENDPROC(ignore_int)
 650 __INITDATA
 651         .align 4
 652 early_recursion_flag:
 653         .long 0
 654
 655 __REFDATA
 656         .align 4
 657 ENTRY(initial_code)
 658         .long i386_start_kernel
 659 ENTRY(setup_once_ref)
 660         .long setup_once
 661
 662 /*
 663  * BSS section
 664  */
 665 __PAGE_ALIGNED_BSS
 666         .align PAGE_SIZE
 667 #ifdef CONFIG_X86_PAE
 668 initial_pg_pmd:
 669         .fill 1024*KPMDS,4,0
 670 #else
 671 ENTRY(initial_page_table)
 672         .fill 1024,4,0
 673 #endif
 674 initial_pg_fixmap:
 675         .fill 1024,4,0
 676 ENTRY(empty_zero_page)
 677         .fill 4096,1,0
 678 ENTRY(swapper_pg_dir)
 679         .fill 1024,4,0
 680
 681 /*
 682  * This starts the data section.
 683  */
 684 #ifdef CONFIG_X86_PAE
 685 __PAGE_ALIGNED_DATA
 686         /* Page-aligned for the benefit of paravirt? */
 687         .align PAGE_SIZE
 688 ENTRY(initial_page_table)
 689         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0     /* low identity map */
 690 # if KPMDS == 3
 691         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
 692         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x1000),0
 693         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x2000),0
 694 # elif KPMDS == 2
 695         .long   0,0
 696         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
 697         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x1000),0
 698 # elif KPMDS == 1
 699         .long   0,0
 700         .long   0,0
 701         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
 702 # else
 703 #  error "Kernel PMDs should be 1, 2 or 3"
 704 # endif
 705         .align PAGE_SIZE                /* needs to be page-sized too */
 706 #endif
 707
 708 .data
 709 .balign 4
 710 ENTRY(stack_start)
 711         .long init_thread_union+THREAD_SIZE
 712
 713 __INITRODATA
 714 int_msg:
 715         .asciz "Unknown interrupt or fault at: %p %p %p\n"
 716
 717 fault_msg:
 718 /* fault info: */
 719         .ascii "BUG: Int %d: CR2 %p\n"
 720 /* regs pushed in early_idt_handler: */
 721         .ascii "     EDI %p  ESI %p  EBP %p  EBX %p\n"
 722         .ascii "     ESP %p   ES %p   DS %p\n"
 723         .ascii "     EDX %p  ECX %p  EAX %p\n"
 724 /* fault frame: */
 725         .ascii "     vec %p  err %p  EIP %p   CS %p  flg %p\n"
 726         .ascii "Stack: %p %p %p %p %p %p %p %p\n"
 727         .ascii "       %p %p %p %p %p %p %p %p\n"
 728         .asciz "       %p %p %p %p %p %p %p %p\n"
 729
 730 #include "../../x86/xen/xen-head.S"
 731
 732 /*
 733  * The IDT and GDT 'descriptors' are a strange 48-bit object
 734  * only used by the lidt and lgdt instructions. They are not
 735  * like usual segment descriptors - they consist of a 16-bit
 736  * segment size, and 32-bit linear address value:
 737  */
 738
 739         .data
 740 .globl boot_gdt_descr
 741 .globl idt_descr
 742
 743         ALIGN
 744 # early boot GDT descriptor (must use 1:1 address mapping)
 745         .word 0                         # 32 bit align gdt_desc.address
 746 boot_gdt_descr:
 747         .word __BOOT_DS+7
 748         .long boot_gdt - __PAGE_OFFSET
 749
 750         .word 0                         # 32-bit align idt_desc.address
 751 idt_descr:
 752         .word IDT_ENTRIES*8-1           # idt contains 256 entries
 753         .long idt_table
 754
 755 # boot GDT descriptor (later on used by CPU#0):
 756         .word 0                         # 32 bit align gdt_desc.address
 757 ENTRY(early_gdt_descr)
 758         .word GDT_ENTRIES*8-1
 759         .long gdt_page                  /* Overwritten for secondary CPUs */
 760
 761 /*
 762  * The boot_gdt must mirror the equivalent in setup.S and is
 763  * used only for booting.
 764  */
 765         .align L1_CACHE_BYTES
 766 ENTRY(boot_gdt)
 767         .fill GDT_ENTRY_BOOT_CS,8,0
 768         .quad 0x00cf9a000000ffff        /* kernel 4GB code at 0x00000000 */
 769         .quad 0x00cf92000000ffff        /* kernel 4GB data at 0x00000000 */