arch/x86/kernel/vmlinux.lds.S

   1 /*
   2  * ld script for the x86 kernel
   3  *
   4  * Historic 32-bit version written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5  *
   6  * Modernisation, unification and other changes and fixes:
   7  *   Copyright (C) 2007-2009  Sam Ravnborg <sam@ravnborg.org>
   8  *
   9  *
  10  * Don't define absolute symbols until and unless you know that symbol
  11  * value is should remain constant even if kernel image is relocated
  12  * at run time. Absolute symbols are not relocated. If symbol value should
  13  * change if kernel is relocated, make the symbol section relative and
  14  * put it inside the section definition.
  15  */
  16
  17 #ifdef CONFIG_X86_32
  18 #define LOAD_OFFSET __PAGE_OFFSET
  19 #else
  20 #define LOAD_OFFSET __START_KERNEL_map
  21 #endif
  22
  23 #include <asm-generic/vmlinux.lds.h>
  24 #include <asm/asm-offsets.h>
  25 #include <asm/thread_info.h>
  26 #include <asm/page_types.h>
  27 #include <asm/cache.h>
  28 #include <asm/boot.h>
  29
  30 #undef i386     /* in case the preprocessor is a 32bit one */
  31
  32 OUTPUT_FORMAT(CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT)
  33
  34 #ifdef CONFIG_X86_32
  35 OUTPUT_ARCH(i386)
  36 ENTRY(phys_startup_32)
  37 jiffies = jiffies_64;
  38 #else
  39 OUTPUT_ARCH(i386:x86-64)
  40 ENTRY(phys_startup_64)
  41 jiffies_64 = jiffies;
  42 #endif
  43
  44 #if defined(CONFIG_X86_64) && defined(CONFIG_DEBUG_RODATA)
  45 /*
  46  * On 64-bit, align RODATA to 2MB so that even with CONFIG_DEBUG_RODATA
  47  * we retain large page mappings for boundaries spanning kernel text, rodata
  48  * and data sections.
  49  *
  50  * However, kernel identity mappings will have different RWX permissions
  51  * to the pages mapping to text and to the pages padding (which are freed) the
  52  * text section. Hence kernel identity mappings will be broken to smaller
  53  * pages. For 64-bit, kernel text and kernel identity mappings are different,
  54  * so we can enable protection checks that come with CONFIG_DEBUG_RODATA,
  55  * as well as retain 2MB large page mappings for kernel text.
  56  */
  57 #define X64_ALIGN_DEBUG_RODATA_BEGIN    . = ALIGN(HPAGE_SIZE);
  58
  59 #define X64_ALIGN_DEBUG_RODATA_END                              \
  60                 . = ALIGN(HPAGE_SIZE);                          \
  61                 __end_rodata_hpage_align = .;
  62
  63 #else
  64
  65 #define X64_ALIGN_DEBUG_RODATA_BEGIN
  66 #define X64_ALIGN_DEBUG_RODATA_END
  67
  68 #endif
  69
  70 PHDRS {
  71         text PT_LOAD FLAGS(5);          /* R_E */
  72         data PT_LOAD FLAGS(6);          /* RW_ */
  73 #ifdef CONFIG_X86_64
  74         user PT_LOAD FLAGS(5);          /* R_E */
  75 #ifdef CONFIG_SMP
  76         percpu PT_LOAD FLAGS(6);        /* RW_ */
  77 #endif
  78         init PT_LOAD FLAGS(7);          /* RWE */
  79 #endif
  80         note PT_NOTE FLAGS(0);          /* ___ */
  81 }
  82
  83 SECTIONS
  84 {
  85 #ifdef CONFIG_X86_32
  86         . = LOAD_OFFSET + LOAD_PHYSICAL_ADDR;
  87         phys_startup_32 = startup_32 - LOAD_OFFSET;
  88 #else
  89         . = __START_KERNEL;
  90         phys_startup_64 = startup_64 - LOAD_OFFSET;
  91 #endif
  92
  93         /* Text and read-only data */
  94         .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  95                 _text = .;
  96                 /* bootstrapping code */
  97                 HEAD_TEXT
  98 #ifdef CONFIG_X86_32
  99                 . = ALIGN(PAGE_SIZE);
 100                 *(.text..page_aligned)
 101 #endif
 102                 . = ALIGN(8);
 103                 _stext = .;
 104                 TEXT_TEXT
 105                 SCHED_TEXT
 106                 LOCK_TEXT
 107                 KPROBES_TEXT
 108                 ENTRY_TEXT
 109                 IRQENTRY_TEXT
 110                 *(.fixup)
 111                 *(.gnu.warning)
 112                 /* End of text section */
 113                 _etext = .;
 114         } :text = 0x9090
 115
 116         NOTES :text :note
 117
 118         EXCEPTION_TABLE(16) :text = 0x9090
 119
 120 #if defined(CONFIG_DEBUG_RODATA)
 121         /* .text should occupy whole number of pages */
 122         . = ALIGN(PAGE_SIZE);
 123 #endif
 124         X64_ALIGN_DEBUG_RODATA_BEGIN
 125         RO_DATA(PAGE_SIZE)
 126         X64_ALIGN_DEBUG_RODATA_END
 127
 128         /* Data */
 129         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 130                 /* Start of data section */
 131                 _sdata = .;
 132
 133                 /* init_task */
 134                 INIT_TASK_DATA(THREAD_SIZE)
 135
 136 #ifdef CONFIG_X86_32
 137                 /* 32 bit has nosave before _edata */
 138                 NOSAVE_DATA
 139 #endif
 140
 141                 PAGE_ALIGNED_DATA(PAGE_SIZE)
 142
 143                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 144
 145                 DATA_DATA
 146                 CONSTRUCTORS
 147
 148                 /* rarely changed data like cpu maps */
 149                 READ_MOSTLY_DATA(INTERNODE_CACHE_BYTES)
 150
 151                 /* End of data section */
 152                 _edata = .;
 153         } :data
 154
 155 #ifdef CONFIG_X86_64
 156
 157 #define VSYSCALL_ADDR (-10*1024*1024)
 158
 159 #define VLOAD_OFFSET (VSYSCALL_ADDR - __vsyscall_0 + LOAD_OFFSET)
 160 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
 161
 162 #define VVIRT_OFFSET (VSYSCALL_ADDR - __vsyscall_0)
 163 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
 164
 165         . = ALIGN(4096);
 166         __vsyscall_0 = .;
 167
 168         . = VSYSCALL_ADDR;
 169         .vsyscall_0 : AT(VLOAD(.vsyscall_0)) {
 170                 *(.vsyscall_0)
 171         } :user
 172
 173         . = ALIGN(L1_CACHE_BYTES);
 174         .vsyscall_fn : AT(VLOAD(.vsyscall_fn)) {
 175                 *(.vsyscall_fn)
 176         }
 177
 178         .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1)) {
 179                 *(.vsyscall_1)
 180         }
 181         .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2)) {
 182                 *(.vsyscall_2)
 183         }
 184
 185         . = ALIGN(__vsyscall_0 + PAGE_SIZE, PAGE_SIZE);
 186
 187 #undef VSYSCALL_ADDR
 188 #undef VLOAD_OFFSET
 189 #undef VLOAD
 190 #undef VVIRT_OFFSET
 191 #undef VVIRT
 192
 193         __vvar_page = .;
 194
 195         .vvar : AT(ADDR(.vvar) - LOAD_OFFSET) {
 196
 197               /* Place all vvars at the offsets in asm/vvar.h. */
 198 #define EMIT_VVAR(name, offset)                 \
 199                 . = offset;             \
 200                 *(.vvar_ ## name)
 201 #define __VVAR_KERNEL_LDS
 202 #include <asm/vvar.h>
 203 #undef __VVAR_KERNEL_LDS
 204 #undef EMIT_VVAR
 205
 206         } :data
 207
 208        . = ALIGN(__vvar_page + PAGE_SIZE, PAGE_SIZE);
 209
 210 #endif /* CONFIG_X86_64 */
 211
 212         /* Init code and data - will be freed after init */
 213         . = ALIGN(PAGE_SIZE);
 214         .init.begin : AT(ADDR(.init.begin) - LOAD_OFFSET) {
 215                 __init_begin = .; /* paired with __init_end */
 216         }
 217
 218 #if defined(CONFIG_X86_64) && defined(CONFIG_SMP)
 219         /*
 220          * percpu offsets are zero-based on SMP.  PERCPU_VADDR() changes the
 221          * output PHDR, so the next output section - .init.text - should
 222          * start another segment - init.
 223          */
 224         PERCPU_VADDR(INTERNODE_CACHE_BYTES, 0, :percpu)
 225 #endif
 226
 227         INIT_TEXT_SECTION(PAGE_SIZE)
 228 #ifdef CONFIG_X86_64
 229         :init
 230 #endif
 231
 232         INIT_DATA_SECTION(16)
 233
 234         /*
 235          * Code and data for a variety of lowlevel trampolines, to be
 236          * copied into base memory (< 1 MiB) during initialization.
 237          * Since it is copied early, the main copy can be discarded
 238          * afterwards.
 239          */
 240          .x86_trampoline : AT(ADDR(.x86_trampoline) - LOAD_OFFSET) {
 241                 x86_trampoline_start = .;
 242                 *(.x86_trampoline)
 243                 x86_trampoline_end = .;
 244         }
 245
 246         .x86_cpu_dev.init : AT(ADDR(.x86_cpu_dev.init) - LOAD_OFFSET) {
 247                 __x86_cpu_dev_start = .;
 248                 *(.x86_cpu_dev.init)
 249                 __x86_cpu_dev_end = .;
 250         }
 251
 252         /*
 253          * start address and size of operations which during runtime
 254          * can be patched with virtualization friendly instructions or
 255          * baremetal native ones. Think page table operations.
 256          * Details in paravirt_types.h
 257          */
 258         . = ALIGN(8);
 259         .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
 260                 __parainstructions = .;
 261                 *(.parainstructions)
 262                 __parainstructions_end = .;
 263         }
 264
 265         /*
 266          * struct alt_inst entries. From the header (alternative.h):
 267          * "Alternative instructions for different CPU types or capabilities"
 268          * Think locking instructions on spinlocks.
 269          */
 270         . = ALIGN(8);
 271         .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 272                 __alt_instructions = .;
 273                 *(.altinstructions)
 274                 __alt_instructions_end = .;
 275         }
 276
 277         /*
 278          * And here are the replacement instructions. The linker sticks
 279          * them as binary blobs. The .altinstructions has enough data to
 280          * get the address and the length of them to patch the kernel safely.
 281          */
 282         .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 283                 *(.altinstr_replacement)
 284         }
 285
 286         /*
 287          * struct iommu_table_entry entries are injected in this section.
 288          * It is an array of IOMMUs which during run time gets sorted depending
 289          * on its dependency order. After rootfs_initcall is complete
 290          * this section can be safely removed.
 291          */
 292         .iommu_table : AT(ADDR(.iommu_table) - LOAD_OFFSET) {
 293                 __iommu_table = .;
 294                 *(.iommu_table)
 295                 __iommu_table_end = .;
 296         }
 297
 298         . = ALIGN(8);
 299         .apicdrivers : AT(ADDR(.apicdrivers) - LOAD_OFFSET) {
 300                 __apicdrivers = .;
 301                 *(.apicdrivers);
 302                 __apicdrivers_end = .;
 303         }
 304
 305         . = ALIGN(8);
 306         /*
 307          * .exit.text is discard at runtime, not link time, to deal with
 308          *  references from .altinstructions and .eh_frame
 309          */
 310         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 311                 EXIT_TEXT
 312         }
 313
 314         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 315                 EXIT_DATA
 316         }
 317
 318 #if !defined(CONFIG_X86_64) || !defined(CONFIG_SMP)
 319         PERCPU_SECTION(INTERNODE_CACHE_BYTES)
 320 #endif
 321
 322         . = ALIGN(PAGE_SIZE);
 323
 324         /* freed after init ends here */
 325         .init.end : AT(ADDR(.init.end) - LOAD_OFFSET) {
 326                 __init_end = .;
 327         }
 328
 329         /*
 330          * smp_locks might be freed after init
 331          * start/end must be page aligned
 332          */
 333         . = ALIGN(PAGE_SIZE);
 334         .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 335                 __smp_locks = .;
 336                 *(.smp_locks)
 337                 . = ALIGN(PAGE_SIZE);
 338                 __smp_locks_end = .;
 339         }
 340
 341 #ifdef CONFIG_X86_64
 342         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 343                 NOSAVE_DATA
 344         }
 345 #endif
 346
 347         /* BSS */
 348         . = ALIGN(PAGE_SIZE);
 349         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 350                 __bss_start = .;
 351                 *(.bss..page_aligned)
 352                 *(.bss)
 353                 . = ALIGN(PAGE_SIZE);
 354                 __bss_stop = .;
 355         }
 356
 357         . = ALIGN(PAGE_SIZE);
 358         .brk : AT(ADDR(.brk) - LOAD_OFFSET) {
 359                 __brk_base = .;
 360                 . += 64 * 1024;         /* 64k alignment slop space */
 361                 *(.brk_reservation)     /* areas brk users have reserved */
 362                 __brk_limit = .;
 363         }
 364
 365         _end = .;
 366
 367         STABS_DEBUG
 368         DWARF_DEBUG
 369
 370         /* Sections to be discarded */
 371         DISCARDS
 372         /DISCARD/ : { *(.eh_frame) }
 373 }
 374
 375
 376 #ifdef CONFIG_X86_32
 377 /*
 378  * The ASSERT() sink to . is intentional, for binutils 2.14 compatibility:
 379  */
 380 . = ASSERT((_end - LOAD_OFFSET <= KERNEL_IMAGE_SIZE),
 381            "kernel image bigger than KERNEL_IMAGE_SIZE");
 382 #else
 383 /*
 384  * Per-cpu symbols which need to be offset from __per_cpu_load
 385  * for the boot processor.
 386  */
 387 #define INIT_PER_CPU(x) init_per_cpu__##x = x + __per_cpu_load
 388 INIT_PER_CPU(gdt_page);
 389 INIT_PER_CPU(irq_stack_union);
 390
 391 /*
 392  * Build-time check on the image size:
 393  */
 394 . = ASSERT((_end - _text <= KERNEL_IMAGE_SIZE),
 395            "kernel image bigger than KERNEL_IMAGE_SIZE");
 396
 397 #ifdef CONFIG_SMP
 398 . = ASSERT((irq_stack_union == 0),
 399            "irq_stack_union is not at start of per-cpu area");
 400 #endif
 401
 402 #endif /* CONFIG_X86_32 */
 403
 404 #ifdef CONFIG_KEXEC
 405 #include <asm/kexec.h>
 406
 407 . = ASSERT(kexec_control_code_size <= KEXEC_CONTROL_CODE_MAX_SIZE,
 408            "kexec control code size is too big");
 409 #endif
 410