board/MAI/AmigaOneG3SE/u-boot.lds

   1 /*
   2  * (C) Copyright 2001
   3  * Josh Huber <huber@mclx.com>, Mission Critical Linux, Inc.
   4  *
   5  * (C) Copyright 2002
   6  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   7  *
   8  * See file CREDITS for list of people who contributed to this
   9  * project.
  10  *
  11  * This program is free software; you can redistribute it and/or
  12  * modify it under the terms of the GNU General Public License as
  13  * published by the Free Software Foundation; either version 2 of
  14  * the License, or (at your option) any later version.
  15  *
  16  * This program is distributed in the hope that it will be useful,
  17  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19  * GNU General Public License for more details.
  20  *
  21  * You should have received a copy of the GNU General Public License
  22  * along with this program; if not, write to the Free Software
  23  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24  * MA 02111-1307 USA
  25  */
  26
  27 /*
  28  * u-boot.lds - linker script for U-Boot on the AmigaOneG3SE Board.
  29  */
  30
  31 OUTPUT_ARCH(powerpc)
  32 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  33 /* Do we need any of these for elf?
  34    __DYNAMIC = 0;    */
  35 SECTIONS
  36 {
  37   /* Read-only sections, merged into text segment: */
  38   . = + SIZEOF_HEADERS;
  39   .interp : { *(.interp) }
  40   .hash          : { *(.hash)           }
  41   .dynsym        : { *(.dynsym)         }
  42   .dynstr        : { *(.dynstr)         }
  43   .rel.text      : { *(.rel.text)               }
  44   .rela.text     : { *(.rela.text)      }
  45   .rel.data      : { *(.rel.data)               }
  46   .rela.data     : { *(.rela.data)      }
  47   .rel.rodata    : { *(.rel.rodata)     }
  48   .rela.rodata   : { *(.rela.rodata)    }
  49   .rel.got       : { *(.rel.got)                }
  50   .rela.got      : { *(.rela.got)               }
  51   .rel.ctors     : { *(.rel.ctors)      }
  52   .rela.ctors    : { *(.rela.ctors)     }
  53   .rel.dtors     : { *(.rel.dtors)      }
  54   .rela.dtors    : { *(.rela.dtors)     }
  55   .rel.bss       : { *(.rel.bss)                }
  56   .rela.bss      : { *(.rela.bss)               }
  57   .rel.plt       : { *(.rel.plt)                }
  58   .rela.plt      : { *(.rela.plt)               }
  59   .init          : { *(.init)   }
  60   .plt : { *(.plt) }
  61   .text      :
  62   {
  63     cpu/74xx_7xx/start.o        (.text)
  64 /* store the environment in a seperate sector in the boot flash */
  65 /*    . = env_offset; */
  66     common/environment.o(.text)
  67
  68     *(.text)
  69     *(.fixup)
  70     *(.got1)
  71   }
  72   _etext = .;
  73   PROVIDE (etext = .);
  74   .rodata    :
  75   {
  76     *(.rodata)
  77     *(.rodata1)
  78   }
  79   .fini      : { *(.fini)    } =0
  80   .ctors     : { *(.ctors)   }
  81   .dtors     : { *(.dtors)   }
  82
  83   /* Read-write section, merged into data segment: */
  84   . = (. + 0x00FF) & 0xFFFFFF00;
  85   _erotext = .;
  86   PROVIDE (erotext = .);
  87   .reloc   :
  88   {
  89     *(.got)
  90     _GOT2_TABLE_ = .;
  91     *(.got2)
  92     _FIXUP_TABLE_ = .;
  93     *(.fixup)
  94   }
  95   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  96   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  97
  98   .data    :
  99   {
 100     *(.data)
 101     *(.data1)
 102     *(.sdata)
 103     *(.sdata2)
 104     *(.dynamic)
 105     CONSTRUCTORS
 106   }
 107   _edata  =  .;
 108   PROVIDE (edata = .);
 109
 110   __start___ex_table = .;
 111   __ex_table : { *(__ex_table) }
 112   __stop___ex_table = .;
 113
 114   . = ALIGN(256);
 115   __init_begin = .;
 116   .text.init : { *(.text.init) }
 117   .data.init : { *(.data.init) }
 118   . = ALIGN(256);
 119   __init_end = .;
 120
 121   __bss_start = .;
 122   .bss       :
 123   {
 124    *(.sbss) *(.scommon)
 125    *(.dynbss)
 126    *(.bss)
 127    *(COMMON)
 128   }
 129   _end = ALIGN(4) /*.*/ ;
 130   PROVIDE (end = ALIGN(4) /*.*/);
 131 }