board/ip860/u-boot.lds

   1 /*
   2  * (C) Copyright 2000
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  26 /* Do we need any of these for elf?
  27    __DYNAMIC = 0;    */
  28 SECTIONS
  29 {
  30   /* Read-only sections, merged into text segment: */
  31   . = + SIZEOF_HEADERS;
  32   .interp : { *(.interp) }
  33   .hash          : { *(.hash)           }
  34   .dynsym        : { *(.dynsym)         }
  35   .dynstr        : { *(.dynstr)         }
  36   .rel.text      : { *(.rel.text)               }
  37   .rela.text     : { *(.rela.text)      }
  38   .rel.data      : { *(.rel.data)               }
  39   .rela.data     : { *(.rela.data)      }
  40   .rel.rodata    : { *(.rel.rodata)     }
  41   .rela.rodata   : { *(.rela.rodata)    }
  42   .rel.got       : { *(.rel.got)                }
  43   .rela.got      : { *(.rela.got)               }
  44   .rel.ctors     : { *(.rel.ctors)      }
  45   .rela.ctors    : { *(.rela.ctors)     }
  46   .rel.dtors     : { *(.rel.dtors)      }
  47   .rela.dtors    : { *(.rela.dtors)     }
  48   .rel.bss       : { *(.rel.bss)                }
  49   .rela.bss      : { *(.rela.bss)               }
  50   .rel.plt       : { *(.rel.plt)                }
  51   .rela.plt      : { *(.rela.plt)               }
  52   .init          : { *(.init)   }
  53   .plt : { *(.plt) }
  54   .text      :
  55   {
  56     /* WARNING - the following is hand-optimized to fit within  */
  57     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  58
  59     cpu/mpc8xx/start.o  (.text)
  60     common/dlmalloc.o   (.text)
  61     lib_ppc/ppcstring.o (.text)
  62     cpu/mpc8xx/interrupts.o (.text)
  63     lib_ppc/time.o              (.text)
  64     lib_ppc/ticks.o             (.text)
  65 /**
  66     . = env_offset;
  67     common/environment.o(.text)
  68 **/
  69     *(.text)
  70     *(.fixup)
  71     *(.got1)
  72   }
  73   _etext = .;
  74   PROVIDE (etext = .);
  75   .rodata    :
  76   {
  77     *(.rodata)
  78     *(.rodata1)
  79     *(.rodata.str1.4)
  80     *(.eh_frame)
  81   }
  82   .fini      : { *(.fini)    } =0
  83   .ctors     : { *(.ctors)   }
  84   .dtors     : { *(.dtors)   }
  85
  86   /* Read-write section, merged into data segment: */
  87   . = (. + 0x00FF) & 0xFFFFFF00;
  88   _erotext = .;
  89   PROVIDE (erotext = .);
  90   .reloc   :
  91   {
  92     *(.got)
  93     _GOT2_TABLE_ = .;
  94     *(.got2)
  95     _FIXUP_TABLE_ = .;
  96     *(.fixup)
  97   }
  98   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  99   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
 100
 101   .data    :
 102   {
 103     *(.data)
 104     *(.data1)
 105     *(.sdata)
 106     *(.sdata2)
 107     *(.dynamic)
 108     CONSTRUCTORS
 109   }
 110   _edata  =  .;
 111   PROVIDE (edata = .);
 112
 113   . = .;
 114   __u_boot_cmd_start = .;
 115   .u_boot_cmd : { *(.u_boot_cmd) }
 116   __u_boot_cmd_end = .;
 117
 118
 119   . = .;
 120   __start___ex_table = .;
 121   __ex_table : { *(__ex_table) }
 122   __stop___ex_table = .;
 123
 124   . = ALIGN(256);
 125   __init_begin = .;
 126   .text.init : { *(.text.init) }
 127   .data.init : { *(.data.init) }
 128   . = ALIGN(256);
 129   __init_end = .;
 130
 131   __bss_start = .;
 132   .bss (NOLOAD)       :
 133   {
 134    *(.sbss) *(.scommon)
 135    *(.dynbss)
 136    *(.bss)
 137    *(COMMON)
 138   }
 139   _end = . ;
 140   PROVIDE (end = .);
 141 }