board/rbc823/u-boot.lds

   1 /*
   2  * (C) Copyright 2000-2010
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25
  26 SECTIONS
  27 {
  28   /* Read-only sections, merged into text segment: */
  29   . = + SIZEOF_HEADERS;
  30   .text      :
  31   {
  32     /* WARNING - the following is hand-optimized to fit within  */
  33     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  34
  35     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  36     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  37
  38     lib/libgeneric.o                    (.text*)
  39     net/libnet.o                        (.text*)
  40     arch/powerpc/cpu/mpc8xx/libmpc8xx.o (.text*)
  41     arch/powerpc/lib/libpowerpc.o       (.text*)
  42
  43     . = env_offset;
  44     common/env_embedded.o               (.text*)
  45
  46     *(.text*)
  47   }
  48   _etext = .;
  49   PROVIDE (etext = .);
  50   .rodata    :
  51   {
  52     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  53   }
  54
  55   /* Read-write section, merged into data segment: */
  56   . = (. + 0x00FF) & 0xFFFFFF00;
  57   _erotext = .;
  58   PROVIDE (erotext = .);
  59   .reloc   :
  60   {
  61     KEEP(*(.got))
  62     _GOT2_TABLE_ = .;
  63     KEEP(*(.got2))
  64     _FIXUP_TABLE_ = .;
  65     KEEP(*(.fixup))
  66   }
  67   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  68   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  69
  70   .data    :
  71   {
  72     *(.data*)
  73     *(.sdata*)
  74   }
  75   _edata  =  .;
  76   PROVIDE (edata = .);
  77
  78   . = .;
  79   __u_boot_cmd_start = .;
  80   .u_boot_cmd : { *(.u_boot_cmd) }
  81   __u_boot_cmd_end = .;
  82
  83   . = .;
  84   __start___ex_table = .;
  85   __ex_table : { *(__ex_table) }
  86   __stop___ex_table = .;
  87
  88   . = ALIGN(256);
  89   __init_begin = .;
  90   .text.init : { *(.text.init) }
  91   .data.init : { *(.data.init) }
  92   . = ALIGN(256);
  93   __init_end = .;
  94
  95   __bss_start = .;
  96   .bss (NOLOAD)       :
  97   {
  98    *(.bss*)
  99    *(.sbss*)
 100    *(COMMON)
 101    . = ALIGN(4);
 102   }
 103   _end = . ;
 104   PROVIDE (end = .);
 105 }