board/sbc8560/u-boot.lds

   1 /*
   2  * (C) Copyright 2002,2003,Motorola,Inc.
   3  * Xianghua Xiao, X.Xiao@motorola.com.
   4  *
   5  * (C) Copyright 2004 Wind River Systems Inc <www.windriver.com>.
   6  * Added support for Wind River SBC8560 board
   7  *
   8  * See file CREDITS for list of people who contributed to this
   9  * project.
  10  *
  11  * This program is free software; you can redistribute it and/or
  12  * modify it under the terms of the GNU General Public License as
  13  * published by the Free Software Foundation; either version 2 of
  14  * the License, or (at your option) any later version.
  15  *
  16  * This program is distributed in the hope that it will be useful,
  17  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19  * GNU General Public License for more details.
  20  *
  21  * You should have received a copy of the GNU General Public License
  22  * along with this program; if not, write to the Free Software
  23  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24  * MA 02111-1307 USA
  25  */
  26
  27 OUTPUT_ARCH(powerpc)
  28 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  29 /* Do we need any of these for elf?
  30    __DYNAMIC = 0;    */
  31 SECTIONS
  32 {
  33   .resetvec 0xFFFFFFFC :
  34   {
  35     *(.resetvec)
  36   } = 0xffff
  37
  38   .bootpg 0xFFFFF000 :
  39   {
  40     cpu/mpc85xx/start.o (.bootpg)
  41   } = 0xffff
  42
  43   /* Read-only sections, merged into text segment: */
  44   . = + SIZEOF_HEADERS;
  45   .interp : { *(.interp) }
  46   .hash          : { *(.hash)           }
  47   .dynsym        : { *(.dynsym)         }
  48   .dynstr        : { *(.dynstr)         }
  49   .rel.text      : { *(.rel.text)               }
  50   .rela.text     : { *(.rela.text)      }
  51   .rel.data      : { *(.rel.data)               }
  52   .rela.data     : { *(.rela.data)      }
  53   .rel.rodata    : { *(.rel.rodata)     }
  54   .rela.rodata   : { *(.rela.rodata)    }
  55   .rel.got       : { *(.rel.got)                }
  56   .rela.got      : { *(.rela.got)               }
  57   .rel.ctors     : { *(.rel.ctors)      }
  58   .rela.ctors    : { *(.rela.ctors)     }
  59   .rel.dtors     : { *(.rel.dtors)      }
  60   .rela.dtors    : { *(.rela.dtors)     }
  61   .rel.bss       : { *(.rel.bss)                }
  62   .rela.bss      : { *(.rela.bss)               }
  63   .rel.plt       : { *(.rel.plt)                }
  64   .rela.plt      : { *(.rela.plt)               }
  65   .init          : { *(.init)   }
  66   .plt : { *(.plt) }
  67   .text      :
  68   {
  69     cpu/mpc85xx/start.o (.text)
  70     cpu/mpc85xx/commproc.o (.text)
  71     cpu/mpc85xx/traps.o (.text)
  72     cpu/mpc85xx/interrupts.o (.text)
  73     cpu/mpc85xx/serial_scc.o (.text)
  74     cpu/mpc85xx/ether_fcc.o (.text)
  75     cpu/mpc85xx/cpu_init.o (.text)
  76     cpu/mpc85xx/cpu.o (.text)
  77     cpu/mpc85xx/speed.o (.text)
  78     cpu/mpc85xx/spd_sdram.o (.text)
  79     common/dlmalloc.o (.text)
  80     lib_generic/crc32.o (.text)
  81     lib_ppc/extable.o (.text)
  82     lib_generic/zlib.o (.text)
  83     *(.text)
  84     *(.fixup)
  85     *(.got1)
  86    }
  87     _etext = .;
  88     PROVIDE (etext = .);
  89     .rodata    :
  90    {
  91     *(.rodata)
  92     *(.rodata1)
  93     *(.rodata.str1.4)
  94     *(.eh_frame)
  95   }
  96   .fini      : { *(.fini)    } =0
  97   .ctors     : { *(.ctors)   }
  98   .dtors     : { *(.dtors)   }
  99
 100   /* Read-write section, merged into data segment: */
 101   . = (. + 0x00FF) & 0xFFFFFF00;
 102   _erotext = .;
 103   PROVIDE (erotext = .);
 104   .reloc   :
 105   {
 106     *(.got)
 107     _GOT2_TABLE_ = .;
 108     *(.got2)
 109     _FIXUP_TABLE_ = .;
 110     *(.fixup)
 111   }
 112   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
 113   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
 114
 115   .data    :
 116   {
 117     *(.data)
 118     *(.data1)
 119     *(.sdata)
 120     *(.sdata2)
 121     *(.dynamic)
 122     CONSTRUCTORS
 123   }
 124   _edata  =  .;
 125   PROVIDE (edata = .);
 126
 127   . = .;
 128   __u_boot_cmd_start = .;
 129   .u_boot_cmd : { *(.u_boot_cmd) }
 130   __u_boot_cmd_end = .;
 131
 132   . = .;
 133   __start___ex_table = .;
 134   __ex_table : { *(__ex_table) }
 135   __stop___ex_table = .;
 136
 137   . = ALIGN(256);
 138   __init_begin = .;
 139   .text.init : { *(.text.init) }
 140   .data.init : { *(.data.init) }
 141   . = ALIGN(256);
 142   __init_end = .;
 143
 144   __bss_start = .;
 145   .bss (NOLOAD)       :
 146   {
 147    *(.sbss) *(.scommon)
 148    *(.dynbss)
 149    *(.bss)
 150    *(COMMON)
 151   }
 152   _end = . ;
 153   PROVIDE (end = .);
 154 }