cpu/at91rm9200/start.S

   1 /*
   2  *  armboot - Startup Code for ARM720 CPU-core
   3  *
   4  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   5  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26
  27 #include "config.h"
  28 #include "version.h"
  29
  30
  31 /*
  32  *************************************************************************
  33  *
  34  * Jump vector table as in table 3.1 in [1]
  35  *
  36  *************************************************************************
  37  */
  38
  39
  40 .globl _start
  41 _start: b       reset
  42         ldr     pc, _undefined_instruction
  43         ldr     pc, _software_interrupt
  44         ldr     pc, _prefetch_abort
  45         ldr     pc, _data_abort
  46         ldr     pc, _not_used
  47         ldr     pc, _irq
  48         ldr     pc, _fiq
  49
  50 _undefined_instruction: .word undefined_instruction
  51 _software_interrupt:    .word software_interrupt
  52 _prefetch_abort:        .word prefetch_abort
  53 _data_abort:            .word data_abort
  54 _not_used:              .word not_used
  55 _irq:                   .word irq
  56 _fiq:                   .word fiq
  57
  58         .balignl 16,0xdeadbeef
  59
  60
  61 /*
  62  *************************************************************************
  63  *
  64  * Startup Code (reset vector)
  65  *
  66  * do important init only if we don't start from memory!
  67  * relocate armboot to ram
  68  * setup stack
  69  * jump to second stage
  70  *
  71  *************************************************************************
  72  */
  73
  74 _TEXT_BASE:
  75         .word   TEXT_BASE
  76
  77 .globl _armboot_start
  78 _armboot_start:
  79         .word _start
  80
  81 /*
  82  * These are defined in the board-specific linker script.
  83  */
  84 .globl _bss_start
  85 _bss_start:
  86         .word __bss_start
  87
  88 .globl _bss_end
  89 _bss_end:
  90         .word _end
  91
  92 #ifdef CONFIG_USE_IRQ
  93 /* IRQ stack memory (calculated at run-time) */
  94 .globl IRQ_STACK_START
  95 IRQ_STACK_START:
  96         .word   0x0badc0de
  97
  98 /* IRQ stack memory (calculated at run-time) */
  99 .globl FIQ_STACK_START
 100 FIQ_STACK_START:
 101         .word 0x0badc0de
 102 #endif
 103
 104
 105 /*
 106  * the actual reset code
 107  */
 108
 109 reset:
 110         /*
 111          * set the cpu to SVC32 mode
 112          */
 113         mrs     r0,cpsr
 114         bic     r0,r0,#0x1f
 115         orr     r0,r0,#0xd3 /* was 13 */
 116         msr     cpsr,r0
 117
 118 #ifdef CONFIG_BOOTBINFUNC
 119         /* scratch stack */
 120         ldr     r1, =0x00204000
 121         /* Insure word alignment */
 122         bic     r1, r1, #3
 123         /* Init stack SYS        */
 124         mov     sp, r1
 125         /*
 126          * This does a lot more than just set up the memory, which
 127          * is why it's called lowlevelinit
 128          */
 129         bl      lowlevelinit /* in lowlevel.S */
 130         bl      icache_enable;
 131         /*------------------------------------
 132           Read/modify/write CP15 control register
 133          -------------------------------------
 134           read cp15 control register (cp15 r1) in r0
 135           ------------------------------------*/
 136         mrc     p15, 0, r0, c1, c0, 0
 137         /* Reset bit :Little Endian end fast bus mode */
 138         ldr     r3, =0xC0000080
 139         /* Set bit :Asynchronous clock mode, Not Fast Bus */
 140         ldr     r4, =0xC0000000
 141         bic     r0, r0, r3
 142         orr     r0, r0, r4
 143         /* write r0 in cp15 control register (cp15 r1) */
 144         mcr     p15, 0, r0, c1, c0, 0
 145 #endif /* CONFIG_BOOTBINFUNC */
 146         /*
 147          * relocate exeception table
 148          */
 149         ldr     r0, =_start
 150         ldr     r1, =0x0
 151         mov     r2, #16
 152 copyex:
 153         subs    r2, r2, #1
 154         ldr     r3, [r0], #4
 155         str     r3, [r1], #4
 156         bne     copyex
 157
 158         /*
 159          * we do sys-critical inits only at reboot,
 160          * not when booting from ram!
 161          */
 162 #ifdef CONFIG_INIT_CRITICAL
 163         bl      cpu_init_crit
 164 #endif
 165
 166 #ifdef CONFIG_BOOTBINFUNC
 167 relocate:                               /* relocate U-Boot to RAM           */
 168         adr     r0, _start              /* r0 <- current position of code   */
 169         ldr     r1, _TEXT_BASE          /* test if we run from flash or RAM */
 170         cmp     r0, r1                  /* don't reloc during debug         */
 171         beq     stack_setup
 172
 173         ldr     r2, _armboot_start
 174         ldr     r3, _bss_start
 175         sub     r2, r3, r2              /* r2 <- size of armboot            */
 176         add     r2, r0, r2              /* r2 <- source end address         */
 177
 178 copy_loop:
 179         ldmia   r0!, {r3-r10}           /* copy from source address [r0]    */
 180         stmia   r1!, {r3-r10}           /* copy to   target address [r1]    */
 181         cmp     r0, r2                  /* until source end addreee [r2]    */
 182         ble     copy_loop
 183 #endif /* CONFIG_BOOTBINFUNC */
 184
 185         /* Set up the stack                                                 */
 186 stack_setup:
 187         ldr     r0, _TEXT_BASE          /* upper 128 KiB: relocated uboot   */
 188         sub     r0, r0, #CFG_MALLOC_LEN /* malloc area                      */
 189         sub     r0, r0, #CFG_GBL_DATA_SIZE /* bdinfo                        */
 190 #ifdef CONFIG_USE_IRQ
 191         sub     r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
 192 #endif
 193         sub     sp, r0, #12             /* leave 3 words for abort-stack    */
 194
 195 clear_bss:
 196         ldr     r0, _bss_start          /* find start of bss segment        */
 197         ldr     r1, _bss_end            /* stop here                        */
 198         mov     r2, #0x00000000         /* clear                            */
 199
 200 clbss_l:str     r2, [r0]                /* clear loop...                    */
 201         add     r0, r0, #4
 202         cmp     r0, r1
 203         ble     clbss_l
 204
 205         ldr pc,_start_armboot
 206
 207 _start_armboot: .word start_armboot
 208
 209 /*
 210  *************************************************************************
 211  *
 212  * CPU_init_critical registers
 213  *
 214  *************************************************************************
 215  */
 216
 217 cpu_init_crit:
 218         /* do nothing for now */
 219         mov     pc, lr
 220
 221
 222 /*
 223  *************************************************************************
 224  *
 225  * Interrupt handling
 226  *
 227  *************************************************************************
 228  */
 229
 230 @
 231 @ IRQ stack frame.
 232 @
 233 #define S_FRAME_SIZE    72
 234
 235 #define S_OLD_R0        68
 236 #define S_PSR           64
 237 #define S_PC            60
 238 #define S_LR            56
 239 #define S_SP            52
 240
 241 #define S_IP            48
 242 #define S_FP            44
 243 #define S_R10           40
 244 #define S_R9            36
 245 #define S_R8            32
 246 #define S_R7            28
 247 #define S_R6            24
 248 #define S_R5            20
 249 #define S_R4            16
 250 #define S_R3            12
 251 #define S_R2            8
 252 #define S_R1            4
 253 #define S_R0            0
 254
 255 #define MODE_SVC 0x13
 256 #define I_BIT    0x80
 257
 258 /*
 259  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 260  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 261  */
 262
 263         .macro  bad_save_user_regs
 264         sub     sp, sp, #S_FRAME_SIZE
 265         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 266         add     r8, sp, #S_PC
 267
 268         ldr     r2, _armboot_start
 269         sub     r2, r2, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 270         sub     r2, r2, #(CFG_GBL_DATA_SIZE+8)  @ set base 2 words into abort stack
 271         ldmia   r2, {r2 - r4}                   @ get pc, cpsr, old_r0
 272         add     r0, sp, #S_FRAME_SIZE           @ restore sp_SVC
 273
 274         add     r5, sp, #S_SP
 275         mov     r1, lr
 276         stmia   r5, {r0 - r4}                   @ save sp_SVC, lr_SVC, pc, cpsr, old_r
 277         mov     r0, sp
 278         .endm
 279
 280         .macro  irq_save_user_regs
 281         sub     sp, sp, #S_FRAME_SIZE
 282         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 283         add     r8, sp, #S_PC
 284         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 285         str     lr, [r8, #0]                    @ Save calling PC
 286         mrs     r6, spsr
 287         str     r6, [r8, #4]                    @ Save CPSR
 288         str     r0, [r8, #8]                    @ Save OLD_R0
 289         mov     r0, sp
 290         .endm
 291
 292         .macro  irq_restore_user_regs
 293         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 294         mov     r0, r0
 295         ldr     lr, [sp, #S_PC]                 @ Get PC
 296         add     sp, sp, #S_FRAME_SIZE
 297         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 298         .endm
 299
 300         .macro get_bad_stack
 301         ldr     r13, _armboot_start             @ setup our mode stack
 302         sub     r13, r13, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 303         sub     r13, r13, #(CFG_GBL_DATA_SIZE+8) @ reserved a couple spots in abort stack
 304
 305         str     lr, [r13]                       @ save caller lr / spsr
 306         mrs     lr, spsr
 307         str     lr, [r13, #4]
 308
 309         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 310         msr     spsr_c, r13
 311         mov     lr, pc
 312         movs    pc, lr
 313         .endm
 314
 315         .macro get_irq_stack                    @ setup IRQ stack
 316         ldr     sp, IRQ_STACK_START
 317         .endm
 318
 319         .macro get_fiq_stack                    @ setup FIQ stack
 320         ldr     sp, FIQ_STACK_START
 321         .endm
 322
 323 /*
 324  * exception handlers
 325  */
 326         .align  5
 327 undefined_instruction:
 328         get_bad_stack
 329         bad_save_user_regs
 330         bl      do_undefined_instruction
 331
 332         .align  5
 333 software_interrupt:
 334         get_bad_stack
 335         bad_save_user_regs
 336         bl      do_software_interrupt
 337
 338         .align  5
 339 prefetch_abort:
 340         get_bad_stack
 341         bad_save_user_regs
 342         bl      do_prefetch_abort
 343
 344         .align  5
 345 data_abort:
 346         get_bad_stack
 347         bad_save_user_regs
 348         bl      do_data_abort
 349
 350         .align  5
 351 not_used:
 352         get_bad_stack
 353         bad_save_user_regs
 354         bl      do_not_used
 355
 356 #ifdef CONFIG_USE_IRQ
 357
 358         .align  5
 359 irq:
 360         get_irq_stack
 361         irq_save_user_regs
 362         bl      do_irq
 363         irq_restore_user_regs
 364
 365         .align  5
 366 fiq:
 367         get_fiq_stack
 368         /* someone ought to write a more effiction fiq_save_user_regs */
 369         irq_save_user_regs
 370         bl      do_fiq
 371         irq_restore_user_regs
 372
 373 #else
 374
 375         .align  5
 376 irq:
 377         get_bad_stack
 378         bad_save_user_regs
 379         bl      do_irq
 380
 381         .align  5
 382 fiq:
 383         get_bad_stack
 384         bad_save_user_regs
 385         bl      do_fiq
 386
 387 #endif
 388
 389         .align  5
 390 .globl reset_cpu
 391 reset_cpu:
 392         mov     pc, r0