cpu/lh7a40x/start.S

   1 /*
   2  *  armboot - Startup Code for ARM920 CPU-core
   3  *
   4  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   5  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
   6  *  Copyright (c) 2002  Gary Jennejohn <gj@denx.de>
   7  *
   8  * See file CREDITS for list of people who contributed to this
   9  * project.
  10  *
  11  * This program is free software; you can redistribute it and/or
  12  * modify it under the terms of the GNU General Public License as
  13  * published by the Free Software Foundation; either version 2 of
  14  * the License, or (at your option) any later version.
  15  *
  16  * This program is distributed in the hope that it will be useful,
  17  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19  * GNU General Public License for more details.
  20  *
  21  * You should have received a copy of the GNU General Public License
  22  * along with this program; if not, write to the Free Software
  23  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24  * MA 02111-1307 USA
  25  */
  26
  27
  28 #include <config.h>
  29 #include <version.h>
  30
  31
  32 /*
  33  *************************************************************************
  34  *
  35  * Jump vector table as in table 3.1 in [1]
  36  *
  37  *************************************************************************
  38  */
  39
  40
  41 .globl _start
  42 _start: b       reset
  43         ldr     pc, _undefined_instruction
  44         ldr     pc, _software_interrupt
  45         ldr     pc, _prefetch_abort
  46         ldr     pc, _data_abort
  47         ldr     pc, _not_used
  48         ldr     pc, _irq
  49         ldr     pc, _fiq
  50
  51 _undefined_instruction: .word undefined_instruction
  52 _software_interrupt:    .word software_interrupt
  53 _prefetch_abort:        .word prefetch_abort
  54 _data_abort:            .word data_abort
  55 _not_used:              .word not_used
  56 _irq:                   .word irq
  57 _fiq:                   .word fiq
  58
  59         .balignl 16,0xdeadbeef
  60
  61
  62 /*
  63  *************************************************************************
  64  *
  65  * Startup Code (reset vector)
  66  *
  67  * do important init only if we don't start from memory!
  68  * relocate armboot to ram
  69  * setup stack
  70  * jump to second stage
  71  *
  72  *************************************************************************
  73  */
  74
  75 _TEXT_BASE:
  76         .word   TEXT_BASE
  77
  78 .globl _armboot_start
  79 _armboot_start:
  80         .word _start
  81
  82 /*
  83  * These are defined in the board-specific linker script.
  84  */
  85 .globl _bss_start
  86 _bss_start:
  87         .word __bss_start
  88
  89 .globl _bss_end
  90 _bss_end:
  91         .word _end
  92
  93 #ifdef CONFIG_USE_IRQ
  94 /* IRQ stack memory (calculated at run-time) */
  95 .globl IRQ_STACK_START
  96 IRQ_STACK_START:
  97         .word   0x0badc0de
  98
  99 /* IRQ stack memory (calculated at run-time) */
 100 .globl FIQ_STACK_START
 101 FIQ_STACK_START:
 102         .word 0x0badc0de
 103 #endif
 104
 105
 106 /*
 107  * the actual reset code
 108  */
 109
 110 reset:
 111         /*
 112          * set the cpu to SVC32 mode
 113          */
 114         mrs     r0,cpsr
 115         bic     r0,r0,#0x1f
 116         orr     r0,r0,#0xd3
 117         msr     cpsr,r0
 118
 119 #define pWDTCTL         0x80001400  /* Watchdog Timer control register */
 120 #define pINTENC         0x8000050C  /* Interupt-Controller enable clear register */
 121 #define pCLKSET         0x80000420  /* clock divisor register */
 122
 123         /* disable watchdog, set watchdog control register to
 124          * all zeros (default reset)
 125          */
 126         ldr     r0, =pWDTCTL
 127         mov     r1, #0x0
 128         str     r1, [r0]
 129
 130         /*
 131          * mask all IRQs by setting all bits in the INTENC register (default)
 132          */
 133         mov     r1, #0xffffffff
 134         ldr     r0, =pINTENC
 135         str     r1, [r0]
 136
 137         /* FCLK:HCLK:PCLK = 1:2:2 */
 138         /* default FCLK is 200 MHz, using 14.7456 MHz fin */
 139         ldr     r0, =pCLKSET
 140         ldr r1, =0x0004ee39
 141 @       ldr r1, =0x0005ee39     @ 1: 2: 4
 142         str     r1, [r0]
 143
 144         /*
 145          * we do sys-critical inits only at reboot,
 146          * not when booting from ram!
 147          */
 148 #ifdef CONFIG_INIT_CRITICAL
 149         bl      cpu_init_crit
 150 #endif
 151
 152 relocate:                               /* relocate U-Boot to RAM           */
 153         adr     r0, _start              /* r0 <- current position of code   */
 154         ldr     r1, _TEXT_BASE          /* test if we run from flash or RAM */
 155         cmp     r0, r1                  /* don't reloc during debug         */
 156         beq     stack_setup
 157
 158         ldr     r2, _armboot_start
 159         ldr     r3, _bss_start
 160         sub     r2, r3, r2              /* r2 <- size of armboot            */
 161         add     r2, r0, r2              /* r2 <- source end address         */
 162
 163 copy_loop:
 164         ldmia   r0!, {r3-r10}           /* copy from source address [r0]    */
 165         stmia   r1!, {r3-r10}           /* copy to   target address [r1]    */
 166         cmp     r0, r2                  /* until source end addreee [r2]    */
 167         blt     copy_loop               /* a 'ble' here actually copies     */
 168                                         /*   four bytes of bss              */
 169
 170         /* Set up the stack                                                 */
 171 stack_setup:
 172         ldr     r0, _TEXT_BASE          /* upper 128 KiB: relocated uboot   */
 173         sub     r0, r0, #CFG_MALLOC_LEN /* malloc area                      */
 174         sub     r0, r0, #CFG_GBL_DATA_SIZE /* bdinfo                        */
 175 #ifdef CONFIG_USE_IRQ
 176         sub     r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
 177 #endif
 178         sub     sp, r0, #12             /* leave 3 words for abort-stack    */
 179
 180 clear_bss:
 181         ldr     r0, _bss_start          /* find start of bss segment        */
 182         @add    r0, r0, #4              /* start at first byte of bss       */
 183                                         /*   why inc. 4 bytes past then?    */
 184         ldr     r1, _bss_end            /* stop here                        */
 185         mov     r2, #0x00000000         /* clear                            */
 186
 187 clbss_l:str     r2, [r0]                /* clear loop...                    */
 188         add     r0, r0, #4
 189         cmp     r0, r1
 190         ble     clbss_l
 191
 192         ldr     pc, _start_armboot
 193
 194 _start_armboot: .word start_armboot
 195
 196
 197 /*
 198  *************************************************************************
 199  *
 200  * CPU_init_critical registers
 201  *
 202  * setup important registers
 203  * setup memory timing
 204  *
 205  *************************************************************************
 206  */
 207
 208
 209 cpu_init_crit:
 210         /*
 211          * flush v4 I/D caches
 212          */
 213         mov     r0, #0
 214         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 215         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 216
 217         /*
 218          * disable MMU stuff and caches
 219          */
 220         mrc     p15, 0, r0, c1, c0, 0
 221         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 222         bic     r0, r0, #0x00000087     @ clear bits 7, 2:0 (B--- -CAM)
 223         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 224         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-Cache
 225         orr     r0, r0, #0x40000000     @ set bit 30 (nF) notFastBus
 226         mcr     p15, 0, r0, c1, c0, 0
 227
 228
 229         /*
 230          * before relocating, we have to setup RAM timing
 231          * because memory timing is board-dependend, you will
 232          * find a memsetup.S in your board directory.
 233          */
 234         mov     ip, lr
 235         bl      memsetup
 236         mov     lr, ip
 237
 238         mov     pc, lr
 239
 240
 241 /*
 242  *************************************************************************
 243  *
 244  * Interrupt handling
 245  *
 246  *************************************************************************
 247  */
 248
 249 @
 250 @ IRQ stack frame.
 251 @
 252 #define S_FRAME_SIZE    72
 253
 254 #define S_OLD_R0        68
 255 #define S_PSR           64
 256 #define S_PC            60
 257 #define S_LR            56
 258 #define S_SP            52
 259
 260 #define S_IP            48
 261 #define S_FP            44
 262 #define S_R10           40
 263 #define S_R9            36
 264 #define S_R8            32
 265 #define S_R7            28
 266 #define S_R6            24
 267 #define S_R5            20
 268 #define S_R4            16
 269 #define S_R3            12
 270 #define S_R2            8
 271 #define S_R1            4
 272 #define S_R0            0
 273
 274 #define MODE_SVC 0x13
 275 #define I_BIT    0x80
 276
 277 /*
 278  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 279  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 280  */
 281
 282         .macro  bad_save_user_regs
 283         sub     sp, sp, #S_FRAME_SIZE
 284         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 285         ldr     r2, _armboot_start
 286         sub     r2, r2, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 287         sub     r2, r2, #(CFG_GBL_DATA_SIZE+8)  @ set base 2 words into abort stack
 288         ldmia   r2, {r2 - r3}                   @ get pc, cpsr
 289         add     r0, sp, #S_FRAME_SIZE           @ restore sp_SVC
 290
 291         add     r5, sp, #S_SP
 292         mov     r1, lr
 293         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 294         mov     r0, sp
 295         .endm
 296
 297         .macro  irq_save_user_regs
 298         sub     sp, sp, #S_FRAME_SIZE
 299         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 300         add     r8, sp, #S_PC
 301         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 302         str     lr, [r8, #0]                    @ Save calling PC
 303         mrs     r6, spsr
 304         str     r6, [r8, #4]                    @ Save CPSR
 305         str     r0, [r8, #8]                    @ Save OLD_R0
 306         mov     r0, sp
 307         .endm
 308
 309         .macro  irq_restore_user_regs
 310         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 311         mov     r0, r0
 312         ldr     lr, [sp, #S_PC]                 @ Get PC
 313         add     sp, sp, #S_FRAME_SIZE
 314         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 315         .endm
 316
 317         .macro get_bad_stack
 318         ldr     r13, _armboot_start             @ setup our mode stack
 319         sub     r13, r13, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 320         sub     r13, r13, #(CFG_GBL_DATA_SIZE+8) @ reserved a couple spots in abort stack
 321
 322         str     lr, [r13]                       @ save caller lr / spsr
 323         mrs     lr, spsr
 324         str     lr, [r13, #4]
 325
 326         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 327         @ msr   spsr_c, r13
 328         msr     spsr, r13
 329         mov     lr, pc
 330         movs    pc, lr
 331         .endm
 332
 333         .macro get_irq_stack                    @ setup IRQ stack
 334         ldr     sp, IRQ_STACK_START
 335         .endm
 336
 337         .macro get_fiq_stack                    @ setup FIQ stack
 338         ldr     sp, FIQ_STACK_START
 339         .endm
 340
 341 /*
 342  * exception handlers
 343  */
 344         .align  5
 345 undefined_instruction:
 346         get_bad_stack
 347         bad_save_user_regs
 348         bl      do_undefined_instruction
 349
 350         .align  5
 351 software_interrupt:
 352         get_bad_stack
 353         bad_save_user_regs
 354         bl      do_software_interrupt
 355
 356         .align  5
 357 prefetch_abort:
 358         get_bad_stack
 359         bad_save_user_regs
 360         bl      do_prefetch_abort
 361
 362         .align  5
 363 data_abort:
 364         get_bad_stack
 365         bad_save_user_regs
 366         bl      do_data_abort
 367
 368         .align  5
 369 not_used:
 370         get_bad_stack
 371         bad_save_user_regs
 372         bl      do_not_used
 373
 374 #ifdef CONFIG_USE_IRQ
 375
 376         .align  5
 377 irq:
 378         get_irq_stack
 379         irq_save_user_regs
 380         bl      do_irq
 381         irq_restore_user_regs
 382
 383         .align  5
 384 fiq:
 385         get_fiq_stack
 386         /* someone ought to write a more effiction fiq_save_user_regs */
 387         irq_save_user_regs
 388         bl      do_fiq
 389         irq_restore_user_regs
 390
 391 #else
 392
 393         .align  5
 394 irq:
 395         get_bad_stack
 396         bad_save_user_regs
 397         bl      do_irq
 398
 399         .align  5
 400 fiq:
 401         get_bad_stack
 402         bad_save_user_regs
 403         bl      do_fiq
 404
 405 #endif
 406
 407         .align  5
 408 .globl reset_cpu
 409 reset_cpu:
 410         bl      disable_interrupts
 411
 412         /* Disable watchdog */
 413         ldr     r1, =pWDTCTL
 414         mov     r3, #0
 415         str     r3, [r1]
 416
 417         /* reset counter */
 418         ldr     r3, =0x00001984
 419         str     r3, [r1, #4]
 420
 421         /* Enable the watchdog */
 422         mov     r3, #1
 423         str     r3, [r1]
 424
 425 _loop_forever:
 426         b       _loop_forever