scripts/checkpatch.pl

   1 #!/usr/bin/perl -w
   2 # (c) 2001, Dave Jones. (the file handling bit)
   3 # (c) 2005, Joel Schopp <jschopp@austin.ibm.com> (the ugly bit)
   4 # (c) 2007,2008, Andy Whitcroft <apw@uk.ibm.com> (new conditions, test suite)
   5 # (c) 2008,2009, Andy Whitcroft <apw@canonical.com>
   6 # Licensed under the terms of the GNU GPL License version 2
   7
   8 use strict;
   9
  10 my $P = $0;
  11 $P =~ s@.*/@@g;
  12
  13 my $V = '0.30';
  14
  15 use Getopt::Long qw(:config no_auto_abbrev);
  16
  17 my $quiet = 0;
  18 my $tree = 1;
  19 my $chk_signoff = 1;
  20 my $chk_patch = 1;
  21 my $tst_only;
  22 my $emacs = 0;
  23 my $terse = 0;
  24 my $file = 0;
  25 my $check = 0;
  26 my $summary = 1;
  27 my $mailback = 0;
  28 my $summary_file = 0;
  29 my $root;
  30 my %debug;
  31 my $help = 0;
  32
  33 sub help {
  34         my ($exitcode) = @_;
  35
  36         print << "EOM";
  37 Usage: $P [OPTION]... [FILE]...
  38 Version: $V
  39
  40 Options:
  41   -q, --quiet                quiet
  42   --no-tree                  run without a kernel tree
  43   --no-signoff               do not check for 'Signed-off-by' line
  44   --patch                    treat FILE as patchfile (default)
  45   --emacs                    emacs compile window format
  46   --terse                    one line per report
  47   -f, --file                 treat FILE as regular source file
  48   --subjective, --strict     enable more subjective tests
  49   --root=PATH                PATH to the kernel tree root
  50   --no-summary               suppress the per-file summary
  51   --mailback                 only produce a report in case of warnings/errors
  52   --summary-file             include the filename in summary
  53   --debug KEY=[0|1]          turn on/off debugging of KEY, where KEY is one of
  54                              'values', 'possible', 'type', and 'attr' (default
  55                              is all off)
  56   --test-only=WORD           report only warnings/errors containing WORD
  57                              literally
  58   -h, --help, --version      display this help and exit
  59
  60 When FILE is - read standard input.
  61 EOM
  62
  63         exit($exitcode);
  64 }
  65
  66 GetOptions(
  67         'q|quiet+'      => \$quiet,
  68         'tree!'         => \$tree,
  69         'signoff!'      => \$chk_signoff,
  70         'patch!'        => \$chk_patch,
  71         'emacs!'        => \$emacs,
  72         'terse!'        => \$terse,
  73         'f|file!'       => \$file,
  74         'subjective!'   => \$check,
  75         'strict!'       => \$check,
  76         'root=s'        => \$root,
  77         'summary!'      => \$summary,
  78         'mailback!'     => \$mailback,
  79         'summary-file!' => \$summary_file,
  80
  81         'debug=s'       => \%debug,
  82         'test-only=s'   => \$tst_only,
  83         'h|help'        => \$help,
  84         'version'       => \$help
  85 ) or help(1);
  86
  87 help(0) if ($help);
  88
  89 my $exit = 0;
  90
  91 if ($#ARGV < 0) {
  92         print "$P: no input files\n";
  93         exit(1);
  94 }
  95
  96 my $dbg_values = 0;
  97 my $dbg_possible = 0;
  98 my $dbg_type = 0;
  99 my $dbg_attr = 0;
 100 for my $key (keys %debug) {
 101         ## no critic
 102         eval "\${dbg_$key} = '$debug{$key}';";
 103         die "$@" if ($@);
 104 }
 105
 106 if ($terse) {
 107         $emacs = 1;
 108         $quiet++;
 109 }
 110
 111 if ($tree) {
 112         if (defined $root) {
 113                 if (!top_of_kernel_tree($root)) {
 114                         die "$P: $root: --root does not point at a valid tree\n";
 115                 }
 116         } else {
 117                 if (top_of_kernel_tree('.')) {
 118                         $root = '.';
 119                 } elsif ($0 =~ m@(.*)/scripts/[^/]*$@ &&
 120                                                 top_of_kernel_tree($1)) {
 121                         $root = $1;
 122                 }
 123         }
 124
 125         if (!defined $root) {
 126                 print "Must be run from the top-level dir. of a kernel tree\n";
 127                 exit(2);
 128         }
 129 }
 130
 131 my $emitted_corrupt = 0;
 132
 133 our $Ident      = qr{
 134                         [A-Za-z_][A-Za-z\d_]*
 135                         (?:\s*\#\#\s*[A-Za-z_][A-Za-z\d_]*)*
 136                 }x;
 137 our $Storage    = qr{extern|static|asmlinkage};
 138 our $Sparse     = qr{
 139                         __user|
 140                         __kernel|
 141                         __force|
 142                         __iomem|
 143                         __must_check|
 144                         __init_refok|
 145                         __kprobes|
 146                         __ref
 147                 }x;
 148
 149 # Notes to $Attribute:
 150 # We need \b after 'init' otherwise 'initconst' will cause a false positive in a check
 151 our $Attribute  = qr{
 152                         const|
 153                         __read_mostly|
 154                         __kprobes|
 155                         __(?:mem|cpu|dev|)(?:initdata|initconst|init\b)|
 156                         ____cacheline_aligned|
 157                         ____cacheline_aligned_in_smp|
 158                         ____cacheline_internodealigned_in_smp|
 159                         __weak
 160                   }x;
 161 our $Modifier;
 162 our $Inline     = qr{inline|__always_inline|noinline};
 163 our $Member     = qr{->$Ident|\.$Ident|\[[^]]*\]};
 164 our $Lval       = qr{$Ident(?:$Member)*};
 165
 166 our $Constant   = qr{(?:[0-9]+|0x[0-9a-fA-F]+)[UL]*};
 167 our $Assignment = qr{(?:\*\=|/=|%=|\+=|-=|<<=|>>=|&=|\^=|\|=|=)};
 168 our $Compare    = qr{<=|>=|==|!=|<|>};
 169 our $Operators  = qr{
 170                         <=|>=|==|!=|
 171                         =>|->|<<|>>|<|>|!|~|
 172                         &&|\|\||,|\^|\+\+|--|&|\||\+|-|\*|\/|%
 173                   }x;
 174
 175 our $NonptrType;
 176 our $Type;
 177 our $Declare;
 178
 179 our $UTF8       = qr {
 180         [\x09\x0A\x0D\x20-\x7E]              # ASCII
 181         | [\xC2-\xDF][\x80-\xBF]             # non-overlong 2-byte
 182         |  \xE0[\xA0-\xBF][\x80-\xBF]        # excluding overlongs
 183         | [\xE1-\xEC\xEE\xEF][\x80-\xBF]{2}  # straight 3-byte
 184         |  \xED[\x80-\x9F][\x80-\xBF]        # excluding surrogates
 185         |  \xF0[\x90-\xBF][\x80-\xBF]{2}     # planes 1-3
 186         | [\xF1-\xF3][\x80-\xBF]{3}          # planes 4-15
 187         |  \xF4[\x80-\x8F][\x80-\xBF]{2}     # plane 16
 188 }x;
 189
 190 our $typeTypedefs = qr{(?x:
 191         (?:__)?(?:u|s|be|le)(?:8|16|32|64)|
 192         atomic_t
 193 )};
 194
 195 our $logFunctions = qr{(?x:
 196         printk|
 197         pr_(debug|dbg|vdbg|devel|info|warning|err|notice|alert|crit|emerg|cont)|
 198         dev_(printk|dbg|vdbg|info|warn|err|notice|alert|crit|emerg|WARN)|
 199         WARN|
 200         panic
 201 )};
 202
 203 our @typeList = (
 204         qr{void},
 205         qr{(?:unsigned\s+)?char},
 206         qr{(?:unsigned\s+)?short},
 207         qr{(?:unsigned\s+)?int},
 208         qr{(?:unsigned\s+)?long},
 209         qr{(?:unsigned\s+)?long\s+int},
 210         qr{(?:unsigned\s+)?long\s+long},
 211         qr{(?:unsigned\s+)?long\s+long\s+int},
 212         qr{unsigned},
 213         qr{float},
 214         qr{double},
 215         qr{bool},
 216         qr{struct\s+$Ident},
 217         qr{union\s+$Ident},
 218         qr{enum\s+$Ident},
 219         qr{${Ident}_t},
 220         qr{${Ident}_handler},
 221         qr{${Ident}_handler_fn},
 222 );
 223 our @modifierList = (
 224         qr{fastcall},
 225 );
 226
 227 sub build_types {
 228         my $mods = "(?x:  \n" . join("|\n  ", @modifierList) . "\n)";
 229         my $all = "(?x:  \n" . join("|\n  ", @typeList) . "\n)";
 230         $Modifier       = qr{(?:$Attribute|$Sparse|$mods)};
 231         $NonptrType     = qr{
 232                         (?:$Modifier\s+|const\s+)*
 233                         (?:
 234                                 (?:typeof|__typeof__)\s*\(\s*\**\s*$Ident\s*\)|
 235                                 (?:$typeTypedefs\b)|
 236                                 (?:${all}\b)
 237                         )
 238                         (?:\s+$Modifier|\s+const)*
 239                   }x;
 240         $Type   = qr{
 241                         $NonptrType
 242                         (?:[\s\*]+\s*const|[\s\*]+|(?:\s*\[\s*\])+)?
 243                         (?:\s+$Inline|\s+$Modifier)*
 244                   }x;
 245         $Declare        = qr{(?:$Storage\s+)?$Type};
 246 }
 247 build_types();
 248
 249 $chk_signoff = 0 if ($file);
 250
 251 my @dep_includes = ();
 252 my @dep_functions = ();
 253 my $removal = "Documentation/feature-removal-schedule.txt";
 254 if ($tree && -f "$root/$removal") {
 255         open(my $REMOVE, '<', "$root/$removal") ||
 256                                 die "$P: $removal: open failed - $!\n";
 257         while (<$REMOVE>) {
 258                 if (/^Check:\s+(.*\S)/) {
 259                         for my $entry (split(/[, ]+/, $1)) {
 260                                 if ($entry =~ m@include/(.*)@) {
 261                                         push(@dep_includes, $1);
 262
 263                                 } elsif ($entry !~ m@/@) {
 264                                         push(@dep_functions, $entry);
 265                                 }
 266                         }
 267                 }
 268         }
 269         close($REMOVE);
 270 }
 271
 272 my @rawlines = ();
 273 my @lines = ();
 274 my $vname;
 275 for my $filename (@ARGV) {
 276         my $FILE;
 277         if ($file) {
 278                 open($FILE, '-|', "diff -u /dev/null $filename") ||
 279                         die "$P: $filename: diff failed - $!\n";
 280         } elsif ($filename eq '-') {
 281                 open($FILE, '<&STDIN');
 282         } else {
 283                 open($FILE, '<', "$filename") ||
 284                         die "$P: $filename: open failed - $!\n";
 285         }
 286         if ($filename eq '-') {
 287                 $vname = 'Your patch';
 288         } else {
 289                 $vname = $filename;
 290         }
 291         while (<$FILE>) {
 292                 chomp;
 293                 push(@rawlines, $_);
 294         }
 295         close($FILE);
 296         if (!process($filename)) {
 297                 $exit = 1;
 298         }
 299         @rawlines = ();
 300         @lines = ();
 301 }
 302
 303 exit($exit);
 304
 305 sub top_of_kernel_tree {
 306         my ($root) = @_;
 307
 308         my @tree_check = (
 309                 "COPYING", "CREDITS", "Kbuild", "MAINTAINERS", "Makefile",
 310                 "README", "Documentation", "arch", "include", "drivers",
 311                 "fs", "init", "ipc", "kernel", "lib", "scripts",
 312         );
 313
 314         foreach my $check (@tree_check) {
 315                 if (! -e $root . '/' . $check) {
 316                         return 0;
 317                 }
 318         }
 319         return 1;
 320 }
 321
 322 sub expand_tabs {
 323         my ($str) = @_;
 324
 325         my $res = '';
 326         my $n = 0;
 327         for my $c (split(//, $str)) {
 328                 if ($c eq "\t") {
 329                         $res .= ' ';
 330                         $n++;
 331                         for (; ($n % 8) != 0; $n++) {
 332                                 $res .= ' ';
 333                         }
 334                         next;
 335                 }
 336                 $res .= $c;
 337                 $n++;
 338         }
 339
 340         return $res;
 341 }
 342 sub copy_spacing {
 343         (my $res = shift) =~ tr/\t/ /c;
 344         return $res;
 345 }
 346
 347 sub line_stats {
 348         my ($line) = @_;
 349
 350         # Drop the diff line leader and expand tabs
 351         $line =~ s/^.//;
 352         $line = expand_tabs($line);
 353
 354         # Pick the indent from the front of the line.
 355         my ($white) = ($line =~ /^(\s*)/);
 356
 357         return (length($line), length($white));
 358 }
 359
 360 my $sanitise_quote = '';
 361
 362 sub sanitise_line_reset {
 363         my ($in_comment) = @_;
 364
 365         if ($in_comment) {
 366                 $sanitise_quote = '*/';
 367         } else {
 368                 $sanitise_quote = '';
 369         }
 370 }
 371 sub sanitise_line {
 372         my ($line) = @_;
 373
 374         my $res = '';
 375         my $l = '';
 376
 377         my $qlen = 0;
 378         my $off = 0;
 379         my $c;
 380
 381         # Always copy over the diff marker.
 382         $res = substr($line, 0, 1);
 383
 384         for ($off = 1; $off < length($line); $off++) {
 385                 $c = substr($line, $off, 1);
 386
 387                 # Comments we are wacking completly including the begin
 388                 # and end, all to $;.
 389                 if ($sanitise_quote eq '' && substr($line, $off, 2) eq '/*') {
 390                         $sanitise_quote = '*/';
 391
 392                         substr($res, $off, 2, "$;$;");
 393                         $off++;
 394                         next;
 395                 }
 396                 if ($sanitise_quote eq '*/' && substr($line, $off, 2) eq '*/') {
 397                         $sanitise_quote = '';
 398                         substr($res, $off, 2, "$;$;");
 399                         $off++;
 400                         next;
 401                 }
 402                 if ($sanitise_quote eq '' && substr($line, $off, 2) eq '//') {
 403                         $sanitise_quote = '//';
 404
 405                         substr($res, $off, 2, $sanitise_quote);
 406                         $off++;
 407                         next;
 408                 }
 409
 410                 # A \ in a string means ignore the next character.
 411                 if (($sanitise_quote eq "'" || $sanitise_quote eq '"') &&
 412                     $c eq "\\") {
 413                         substr($res, $off, 2, 'XX');
 414                         $off++;
 415                         next;
 416                 }
 417                 # Regular quotes.
 418                 if ($c eq "'" || $c eq '"') {
 419                         if ($sanitise_quote eq '') {
 420                                 $sanitise_quote = $c;
 421
 422                                 substr($res, $off, 1, $c);
 423                                 next;
 424                         } elsif ($sanitise_quote eq $c) {
 425                                 $sanitise_quote = '';
 426                         }
 427                 }
 428
 429                 #print "c<$c> SQ<$sanitise_quote>\n";
 430                 if ($off != 0 && $sanitise_quote eq '*/' && $c ne "\t") {
 431                         substr($res, $off, 1, $;);
 432                 } elsif ($off != 0 && $sanitise_quote eq '//' && $c ne "\t") {
 433                         substr($res, $off, 1, $;);
 434                 } elsif ($off != 0 && $sanitise_quote && $c ne "\t") {
 435                         substr($res, $off, 1, 'X');
 436                 } else {
 437                         substr($res, $off, 1, $c);
 438                 }
 439         }
 440
 441         if ($sanitise_quote eq '//') {
 442                 $sanitise_quote = '';
 443         }
 444
 445         # The pathname on a #include may be surrounded by '<' and '>'.
 446         if ($res =~ /^.\s*\#\s*include\s+\<(.*)\>/) {
 447                 my $clean = 'X' x length($1);
 448                 $res =~ s@\<.*\>@<$clean>@;
 449
 450         # The whole of a #error is a string.
 451         } elsif ($res =~ /^.\s*\#\s*(?:error|warning)\s+(.*)\b/) {
 452                 my $clean = 'X' x length($1);
 453                 $res =~ s@(\#\s*(?:error|warning)\s+).*@$1$clean@;
 454         }
 455
 456         return $res;
 457 }
 458
 459 sub ctx_statement_block {
 460         my ($linenr, $remain, $off) = @_;
 461         my $line = $linenr - 1;
 462         my $blk = '';
 463         my $soff = $off;
 464         my $coff = $off - 1;
 465         my $coff_set = 0;
 466
 467         my $loff = 0;
 468
 469         my $type = '';
 470         my $level = 0;
 471         my @stack = ();
 472         my $p;
 473         my $c;
 474         my $len = 0;
 475
 476         my $remainder;
 477         while (1) {
 478                 @stack = (['', 0]) if ($#stack == -1);
 479
 480                 #warn "CSB: blk<$blk> remain<$remain>\n";
 481                 # If we are about to drop off the end, pull in more
 482                 # context.
 483                 if ($off >= $len) {
 484                         for (; $remain > 0; $line++) {
 485                                 last if (!defined $lines[$line]);
 486                                 next if ($lines[$line] =~ /^-/);
 487                                 $remain--;
 488                                 $loff = $len;
 489                                 $blk .= $lines[$line] . "\n";
 490                                 $len = length($blk);
 491                                 $line++;
 492                                 last;
 493                         }
 494                         # Bail if there is no further context.
 495                         #warn "CSB: blk<$blk> off<$off> len<$len>\n";
 496                         if ($off >= $len) {
 497                                 last;
 498                         }
 499                 }
 500                 $p = $c;
 501                 $c = substr($blk, $off, 1);
 502                 $remainder = substr($blk, $off);
 503
 504                 #warn "CSB: c<$c> type<$type> level<$level> remainder<$remainder> coff_set<$coff_set>\n";
 505
 506                 # Handle nested #if/#else.
 507                 if ($remainder =~ /^#\s*(?:ifndef|ifdef|if)\s/) {
 508                         push(@stack, [ $type, $level ]);
 509                 } elsif ($remainder =~ /^#\s*(?:else|elif)\b/) {
 510                         ($type, $level) = @{$stack[$#stack - 1]};
 511                 } elsif ($remainder =~ /^#\s*endif\b/) {
 512                         ($type, $level) = @{pop(@stack)};
 513                 }
 514
 515                 # Statement ends at the ';' or a close '}' at the
 516                 # outermost level.
 517                 if ($level == 0 && $c eq ';') {
 518                         last;
 519                 }
 520
 521                 # An else is really a conditional as long as its not else if
 522                 if ($level == 0 && $coff_set == 0 &&
 523                                 (!defined($p) || $p =~ /(?:\s|\}|\+)/) &&
 524                                 $remainder =~ /^(else)(?:\s|{)/ &&
 525                                 $remainder !~ /^else\s+if\b/) {
 526                         $coff = $off + length($1) - 1;
 527                         $coff_set = 1;
 528                         #warn "CSB: mark coff<$coff> soff<$soff> 1<$1>\n";
 529                         #warn "[" . substr($blk, $soff, $coff - $soff + 1) . "]\n";
 530                 }
 531
 532                 if (($type eq '' || $type eq '(') && $c eq '(') {
 533                         $level++;
 534                         $type = '(';
 535                 }
 536                 if ($type eq '(' && $c eq ')') {
 537                         $level--;
 538                         $type = ($level != 0)? '(' : '';
 539
 540                         if ($level == 0 && $coff < $soff) {
 541                                 $coff = $off;
 542                                 $coff_set = 1;
 543                                 #warn "CSB: mark coff<$coff>\n";
 544                         }
 545                 }
 546                 if (($type eq '' || $type eq '{') && $c eq '{') {
 547                         $level++;
 548                         $type = '{';
 549                 }
 550                 if ($type eq '{' && $c eq '}') {
 551                         $level--;
 552                         $type = ($level != 0)? '{' : '';
 553
 554                         if ($level == 0) {
 555                                 last;
 556                         }
 557                 }
 558                 $off++;
 559         }
 560         # We are truly at the end, so shuffle to the next line.
 561         if ($off == $len) {
 562                 $loff = $len + 1;
 563                 $line++;
 564                 $remain--;
 565         }
 566
 567         my $statement = substr($blk, $soff, $off - $soff + 1);
 568         my $condition = substr($blk, $soff, $coff - $soff + 1);
 569
 570         #warn "STATEMENT<$statement>\n";
 571         #warn "CONDITION<$condition>\n";
 572
 573         #print "coff<$coff> soff<$off> loff<$loff>\n";
 574
 575         return ($statement, $condition,
 576                         $line, $remain + 1, $off - $loff + 1, $level);
 577 }
 578
 579 sub statement_lines {
 580         my ($stmt) = @_;
 581
 582         # Strip the diff line prefixes and rip blank lines at start and end.
 583         $stmt =~ s/(^|\n)./$1/g;
 584         $stmt =~ s/^\s*//;
 585         $stmt =~ s/\s*$//;
 586
 587         my @stmt_lines = ($stmt =~ /\n/g);
 588
 589         return $#stmt_lines + 2;
 590 }
 591
 592 sub statement_rawlines {
 593         my ($stmt) = @_;
 594
 595         my @stmt_lines = ($stmt =~ /\n/g);
 596
 597         return $#stmt_lines + 2;
 598 }
 599
 600 sub statement_block_size {
 601         my ($stmt) = @_;
 602
 603         $stmt =~ s/(^|\n)./$1/g;
 604         $stmt =~ s/^\s*{//;
 605         $stmt =~ s/}\s*$//;
 606         $stmt =~ s/^\s*//;
 607         $stmt =~ s/\s*$//;
 608
 609         my @stmt_lines = ($stmt =~ /\n/g);
 610         my @stmt_statements = ($stmt =~ /;/g);
 611
 612         my $stmt_lines = $#stmt_lines + 2;
 613         my $stmt_statements = $#stmt_statements + 1;
 614
 615         if ($stmt_lines > $stmt_statements) {
 616                 return $stmt_lines;
 617         } else {
 618                 return $stmt_statements;
 619         }
 620 }
 621
 622 sub ctx_statement_full {
 623         my ($linenr, $remain, $off) = @_;
 624         my ($statement, $condition, $level);
 625
 626         my (@chunks);
 627
 628         # Grab the first conditional/block pair.
 629         ($statement, $condition, $linenr, $remain, $off, $level) =
 630                                 ctx_statement_block($linenr, $remain, $off);
 631         #print "F: c<$condition> s<$statement> remain<$remain>\n";
 632         push(@chunks, [ $condition, $statement ]);
 633         if (!($remain > 0 && $condition =~ /^\s*(?:\n[+-])?\s*(?:if|else|do)\b/s)) {
 634                 return ($level, $linenr, @chunks);
 635         }
 636
 637         # Pull in the following conditional/block pairs and see if they
 638         # could continue the statement.
 639         for (;;) {
 640                 ($statement, $condition, $linenr, $remain, $off, $level) =
 641                                 ctx_statement_block($linenr, $remain, $off);
 642                 #print "C: c<$condition> s<$statement> remain<$remain>\n";
 643                 last if (!($remain > 0 && $condition =~ /^(?:\s*\n[+-])*\s*(?:else|do)\b/s));
 644                 #print "C: push\n";
 645                 push(@chunks, [ $condition, $statement ]);
 646         }
 647
 648         return ($level, $linenr, @chunks);
 649 }
 650
 651 sub ctx_block_get {
 652         my ($linenr, $remain, $outer, $open, $close, $off) = @_;
 653         my $line;
 654         my $start = $linenr - 1;
 655         my $blk = '';
 656         my @o;
 657         my @c;
 658         my @res = ();
 659
 660         my $level = 0;
 661         my @stack = ($level);
 662         for ($line = $start; $remain > 0; $line++) {
 663                 next if ($rawlines[$line] =~ /^-/);
 664                 $remain--;
 665
 666                 $blk .= $rawlines[$line];
 667
 668                 # Handle nested #if/#else.
 669                 if ($rawlines[$line] =~ /^.\s*#\s*(?:ifndef|ifdef|if)\s/) {
 670                         push(@stack, $level);
 671                 } elsif ($rawlines[$line] =~ /^.\s*#\s*(?:else|elif)\b/) {
 672                         $level = $stack[$#stack - 1];
 673                 } elsif ($rawlines[$line] =~ /^.\s*#\s*endif\b/) {
 674                         $level = pop(@stack);
 675                 }
 676
 677                 foreach my $c (split(//, $rawlines[$line])) {
 678                         ##print "C<$c>L<$level><$open$close>O<$off>\n";
 679                         if ($off > 0) {
 680                                 $off--;
 681                                 next;
 682                         }
 683
 684                         if ($c eq $close && $level > 0) {
 685                                 $level--;
 686                                 last if ($level == 0);
 687                         } elsif ($c eq $open) {
 688                                 $level++;
 689                         }
 690                 }
 691
 692                 if (!$outer || $level <= 1) {
 693                         push(@res, $rawlines[$line]);
 694                 }
 695
 696                 last if ($level == 0);
 697         }
 698
 699         return ($level, @res);
 700 }
 701 sub ctx_block_outer {
 702         my ($linenr, $remain) = @_;
 703
 704         my ($level, @r) = ctx_block_get($linenr, $remain, 1, '{', '}', 0);
 705         return @r;
 706 }
 707 sub ctx_block {
 708         my ($linenr, $remain) = @_;
 709
 710         my ($level, @r) = ctx_block_get($linenr, $remain, 0, '{', '}', 0);
 711         return @r;
 712 }
 713 sub ctx_statement {
 714         my ($linenr, $remain, $off) = @_;
 715
 716         my ($level, @r) = ctx_block_get($linenr, $remain, 0, '(', ')', $off);
 717         return @r;
 718 }
 719 sub ctx_block_level {
 720         my ($linenr, $remain) = @_;
 721
 722         return ctx_block_get($linenr, $remain, 0, '{', '}', 0);
 723 }
 724 sub ctx_statement_level {
 725         my ($linenr, $remain, $off) = @_;
 726
 727         return ctx_block_get($linenr, $remain, 0, '(', ')', $off);
 728 }
 729
 730 sub ctx_locate_comment {
 731         my ($first_line, $end_line) = @_;
 732
 733         # Catch a comment on the end of the line itself.
 734         my ($current_comment) = ($rawlines[$end_line - 1] =~ m@.*(/\*.*\*/)\s*(?:\\\s*)?$@);
 735         return $current_comment if (defined $current_comment);
 736
 737         # Look through the context and try and figure out if there is a
 738         # comment.
 739         my $in_comment = 0;
 740         $current_comment = '';
 741         for (my $linenr = $first_line; $linenr < $end_line; $linenr++) {
 742                 my $line = $rawlines[$linenr - 1];
 743                 #warn "           $line\n";
 744                 if ($linenr == $first_line and $line =~ m@^.\s*\*@) {
 745                         $in_comment = 1;
 746                 }
 747                 if ($line =~ m@/\*@) {
 748                         $in_comment = 1;
 749                 }
 750                 if (!$in_comment && $current_comment ne '') {
 751                         $current_comment = '';
 752                 }
 753                 $current_comment .= $line . "\n" if ($in_comment);
 754                 if ($line =~ m@\*/@) {
 755                         $in_comment = 0;
 756                 }
 757         }
 758
 759         chomp($current_comment);
 760         return($current_comment);
 761 }
 762 sub ctx_has_comment {
 763         my ($first_line, $end_line) = @_;
 764         my $cmt = ctx_locate_comment($first_line, $end_line);
 765
 766         ##print "LINE: $rawlines[$end_line - 1 ]\n";
 767         ##print "CMMT: $cmt\n";
 768
 769         return ($cmt ne '');
 770 }
 771
 772 sub raw_line {
 773         my ($linenr, $cnt) = @_;
 774
 775         my $offset = $linenr - 1;
 776         $cnt++;
 777
 778         my $line;
 779         while ($cnt) {
 780                 $line = $rawlines[$offset++];
 781                 next if (defined($line) && $line =~ /^-/);
 782                 $cnt--;
 783         }
 784
 785         return $line;
 786 }
 787
 788 sub cat_vet {
 789         my ($vet) = @_;
 790         my ($res, $coded);
 791
 792         $res = '';
 793         while ($vet =~ /([^[:cntrl:]]*)([[:cntrl:]]|$)/g) {
 794                 $res .= $1;
 795                 if ($2 ne '') {
 796                         $coded = sprintf("^%c", unpack('C', $2) + 64);
 797                         $res .= $coded;
 798                 }
 799         }
 800         $res =~ s/$/\$/;
 801
 802         return $res;
 803 }
 804
 805 my $av_preprocessor = 0;
 806 my $av_pending;
 807 my @av_paren_type;
 808 my $av_pend_colon;
 809
 810 sub annotate_reset {
 811         $av_preprocessor = 0;
 812         $av_pending = '_';
 813         @av_paren_type = ('E');
 814         $av_pend_colon = 'O';
 815 }
 816
 817 sub annotate_values {
 818         my ($stream, $type) = @_;
 819
 820         my $res;
 821         my $var = '_' x length($stream);
 822         my $cur = $stream;
 823
 824         print "$stream\n" if ($dbg_values > 1);
 825
 826         while (length($cur)) {
 827                 @av_paren_type = ('E') if ($#av_paren_type < 0);
 828                 print " <" . join('', @av_paren_type) .
 829                                 "> <$type> <$av_pending>" if ($dbg_values > 1);
 830                 if ($cur =~ /^(\s+)/o) {
 831                         print "WS($1)\n" if ($dbg_values > 1);
 832                         if ($1 =~ /\n/ && $av_preprocessor) {
 833                                 $type = pop(@av_paren_type);
 834                                 $av_preprocessor = 0;
 835                         }
 836
 837                 } elsif ($cur =~ /^($Type)\s*(?:$Ident|,|\)|\()/) {
 838                         print "DECLARE($1)\n" if ($dbg_values > 1);
 839                         $type = 'T';
 840
 841                 } elsif ($cur =~ /^($Modifier)\s*/) {
 842                         print "MODIFIER($1)\n" if ($dbg_values > 1);
 843                         $type = 'T';
 844
 845                 } elsif ($cur =~ /^(\#\s*define\s*$Ident)(\(?)/o) {
 846                         print "DEFINE($1,$2)\n" if ($dbg_values > 1);
 847                         $av_preprocessor = 1;
 848                         push(@av_paren_type, $type);
 849                         if ($2 ne '') {
 850                                 $av_pending = 'N';
 851                         }
 852                         $type = 'E';
 853
 854                 } elsif ($cur =~ /^(\#\s*(?:undef\s*$Ident|include\b))/o) {
 855                         print "UNDEF($1)\n" if ($dbg_values > 1);
 856                         $av_preprocessor = 1;
 857                         push(@av_paren_type, $type);
 858
 859                 } elsif ($cur =~ /^(\#\s*(?:ifdef|ifndef|if))/o) {
 860                         print "PRE_START($1)\n" if ($dbg_values > 1);
 861                         $av_preprocessor = 1;
 862
 863                         push(@av_paren_type, $type);
 864                         push(@av_paren_type, $type);
 865                         $type = 'E';
 866
 867                 } elsif ($cur =~ /^(\#\s*(?:else|elif))/o) {
 868                         print "PRE_RESTART($1)\n" if ($dbg_values > 1);
 869                         $av_preprocessor = 1;
 870
 871                         push(@av_paren_type, $av_paren_type[$#av_paren_type]);
 872
 873                         $type = 'E';
 874
 875                 } elsif ($cur =~ /^(\#\s*(?:endif))/o) {
 876                         print "PRE_END($1)\n" if ($dbg_values > 1);
 877
 878                         $av_preprocessor = 1;
 879
 880                         # Assume all arms of the conditional end as this
 881                         # one does, and continue as if the #endif was not here.
 882                         pop(@av_paren_type);
 883                         push(@av_paren_type, $type);
 884                         $type = 'E';
 885
 886                 } elsif ($cur =~ /^(\\\n)/o) {
 887                         print "PRECONT($1)\n" if ($dbg_values > 1);
 888
 889                 } elsif ($cur =~ /^(__attribute__)\s*\(?/o) {
 890                         print "ATTR($1)\n" if ($dbg_values > 1);
 891                         $av_pending = $type;
 892                         $type = 'N';
 893
 894                 } elsif ($cur =~ /^(sizeof)\s*(\()?/o) {
 895                         print "SIZEOF($1)\n" if ($dbg_values > 1);
 896                         if (defined $2) {
 897                                 $av_pending = 'V';
 898                         }
 899                         $type = 'N';
 900
 901                 } elsif ($cur =~ /^(if|while|for)\b/o) {
 902                         print "COND($1)\n" if ($dbg_values > 1);
 903                         $av_pending = 'E';
 904                         $type = 'N';
 905
 906                 } elsif ($cur =~/^(case)/o) {
 907                         print "CASE($1)\n" if ($dbg_values > 1);
 908                         $av_pend_colon = 'C';
 909                         $type = 'N';
 910
 911                 } elsif ($cur =~/^(return|else|goto|typeof|__typeof__)\b/o) {
 912                         print "KEYWORD($1)\n" if ($dbg_values > 1);
 913                         $type = 'N';
 914
 915                 } elsif ($cur =~ /^(\()/o) {
 916                         print "PAREN('$1')\n" if ($dbg_values > 1);
 917                         push(@av_paren_type, $av_pending);
 918                         $av_pending = '_';
 919                         $type = 'N';
 920
 921                 } elsif ($cur =~ /^(\))/o) {
 922                         my $new_type = pop(@av_paren_type);
 923                         if ($new_type ne '_') {
 924                                 $type = $new_type;
 925                                 print "PAREN('$1') -> $type\n"
 926                                                         if ($dbg_values > 1);
 927                         } else {
 928                                 print "PAREN('$1')\n" if ($dbg_values > 1);
 929                         }
 930
 931                 } elsif ($cur =~ /^($Ident)\s*\(/o) {
 932                         print "FUNC($1)\n" if ($dbg_values > 1);
 933                         $type = 'V';
 934                         $av_pending = 'V';
 935
 936                 } elsif ($cur =~ /^($Ident\s*):(?:\s*\d+\s*(,|=|;))?/) {
 937                         if (defined $2 && $type eq 'C' || $type eq 'T') {
 938                                 $av_pend_colon = 'B';
 939                         } elsif ($type eq 'E') {
 940                                 $av_pend_colon = 'L';
 941                         }
 942                         print "IDENT_COLON($1,$type>$av_pend_colon)\n" if ($dbg_values > 1);
 943                         $type = 'V';
 944
 945                 } elsif ($cur =~ /^($Ident|$Constant)/o) {
 946                         print "IDENT($1)\n" if ($dbg_values > 1);
 947                         $type = 'V';
 948
 949                 } elsif ($cur =~ /^($Assignment)/o) {
 950                         print "ASSIGN($1)\n" if ($dbg_values > 1);
 951                         $type = 'N';
 952
 953                 } elsif ($cur =~/^(;|{|})/) {
 954                         print "END($1)\n" if ($dbg_values > 1);
 955                         $type = 'E';
 956                         $av_pend_colon = 'O';
 957
 958                 } elsif ($cur =~/^(,)/) {
 959                         print "COMMA($1)\n" if ($dbg_values > 1);
 960                         $type = 'C';
 961
 962                 } elsif ($cur =~ /^(\?)/o) {
 963                         print "QUESTION($1)\n" if ($dbg_values > 1);
 964                         $type = 'N';
 965
 966                 } elsif ($cur =~ /^(:)/o) {
 967                         print "COLON($1,$av_pend_colon)\n" if ($dbg_values > 1);
 968
 969                         substr($var, length($res), 1, $av_pend_colon);
 970                         if ($av_pend_colon eq 'C' || $av_pend_colon eq 'L') {
 971                                 $type = 'E';
 972                         } else {
 973                                 $type = 'N';
 974                         }
 975                         $av_pend_colon = 'O';
 976
 977                 } elsif ($cur =~ /^(\[)/o) {
 978                         print "CLOSE($1)\n" if ($dbg_values > 1);
 979                         $type = 'N';
 980
 981                 } elsif ($cur =~ /^(-(?![->])|\+(?!\+)|\*|\&\&|\&)/o) {
 982                         my $variant;
 983
 984                         print "OPV($1)\n" if ($dbg_values > 1);
 985                         if ($type eq 'V') {
 986                                 $variant = 'B';
 987                         } else {
 988                                 $variant = 'U';
 989                         }
 990
 991                         substr($var, length($res), 1, $variant);
 992                         $type = 'N';
 993
 994                 } elsif ($cur =~ /^($Operators)/o) {
 995                         print "OP($1)\n" if ($dbg_values > 1);
 996                         if ($1 ne '++' && $1 ne '--') {
 997                                 $type = 'N';
 998                         }
 999
1000                 } elsif ($cur =~ /(^.)/o) {
1001                         print "C($1)\n" if ($dbg_values > 1);
1002                 }
1003                 if (defined $1) {
1004                         $cur = substr($cur, length($1));
1005                         $res .= $type x length($1);
1006                 }
1007         }
1008
1009         return ($res, $var);
1010 }
1011
1012 sub possible {
1013         my ($possible, $line) = @_;
1014         my $notPermitted = qr{(?:
1015                 ^(?:
1016                         $Modifier|
1017                         $Storage|
1018                         $Type|
1019                         DEFINE_\S+
1020                 )$|
1021                 ^(?:
1022                         goto|
1023                         return|
1024                         case|
1025                         else|
1026                         asm|__asm__|
1027                         do
1028                 )(?:\s|$)|
1029                 ^(?:typedef|struct|enum)\b
1030             )}x;
1031         warn "CHECK<$possible> ($line)\n" if ($dbg_possible > 2);
1032         if ($possible !~ $notPermitted) {
1033                 # Check for modifiers.
1034                 $possible =~ s/\s*$Storage\s*//g;
1035                 $possible =~ s/\s*$Sparse\s*//g;
1036                 if ($possible =~ /^\s*$/) {
1037
1038                 } elsif ($possible =~ /\s/) {
1039                         $possible =~ s/\s*$Type\s*//g;
1040                         for my $modifier (split(' ', $possible)) {
1041                                 if ($modifier !~ $notPermitted) {
1042                                         warn "MODIFIER: $modifier ($possible) ($line)\n" if ($dbg_possible);
1043                                         push(@modifierList, $modifier);
1044                                 }
1045                         }
1046
1047                 } else {
1048                         warn "POSSIBLE: $possible ($line)\n" if ($dbg_possible);
1049                         push(@typeList, $possible);
1050                 }
1051                 build_types();
1052         } else {
1053                 warn "NOTPOSS: $possible ($line)\n" if ($dbg_possible > 1);
1054         }
1055 }
1056
1057 my $prefix = '';
1058
1059 sub report {
1060         if (defined $tst_only && $_[0] !~ /\Q$tst_only\E/) {
1061                 return 0;
1062         }
1063         my $line = $prefix . $_[0];
1064
1065         $line = (split('\n', $line))[0] . "\n" if ($terse);
1066
1067         push(our @report, $line);
1068
1069         return 1;
1070 }
1071 sub report_dump {
1072         our @report;
1073 }
1074 sub ERROR {
1075         if (report("ERROR: $_[0]\n")) {
1076                 our $clean = 0;
1077                 our $cnt_error++;
1078         }
1079 }
1080 sub WARN {
1081         if (report("WARNING: $_[0]\n")) {
1082                 our $clean = 0;
1083                 our $cnt_warn++;
1084         }
1085 }
1086 sub CHK {
1087         if ($check && report("CHECK: $_[0]\n")) {
1088                 our $clean = 0;
1089                 our $cnt_chk++;
1090         }
1091 }
1092
1093 sub check_absolute_file {
1094         my ($absolute, $herecurr) = @_;
1095         my $file = $absolute;
1096
1097         ##print "absolute<$absolute>\n";
1098
1099         # See if any suffix of this path is a path within the tree.
1100         while ($file =~ s@^[^/]*/@@) {
1101                 if (-f "$root/$file") {
1102                         ##print "file<$file>\n";
1103                         last;
1104                 }
1105         }
1106         if (! -f _)  {
1107                 return 0;
1108         }
1109
1110         # It is, so see if the prefix is acceptable.
1111         my $prefix = $absolute;
1112         substr($prefix, -length($file)) = '';
1113
1114         ##print "prefix<$prefix>\n";
1115         if ($prefix ne ".../") {
1116                 WARN("use relative pathname instead of absolute in changelog text\n" . $herecurr);
1117         }
1118 }
1119
1120 sub process {
1121         my $filename = shift;
1122
1123         my $linenr=0;
1124         my $prevline="";
1125         my $prevrawline="";
1126         my $stashline="";
1127         my $stashrawline="";
1128
1129         my $length;
1130         my $indent;
1131         my $previndent=0;
1132         my $stashindent=0;
1133
1134         our $clean = 1;
1135         my $signoff = 0;
1136         my $is_patch = 0;
1137
1138         our @report = ();
1139         our $cnt_lines = 0;
1140         our $cnt_error = 0;
1141         our $cnt_warn = 0;
1142         our $cnt_chk = 0;
1143
1144         # Trace the real file/line as we go.
1145         my $realfile = '';
1146         my $realline = 0;
1147         my $realcnt = 0;
1148         my $here = '';
1149         my $in_comment = 0;
1150         my $comment_edge = 0;
1151         my $first_line = 0;
1152         my $p1_prefix = '';
1153
1154         my $prev_values = 'E';
1155
1156         # suppression flags
1157         my %suppress_ifbraces;
1158         my %suppress_whiletrailers;
1159         my %suppress_export;
1160
1161         # Pre-scan the patch sanitizing the lines.
1162         # Pre-scan the patch looking for any __setup documentation.
1163         #
1164         my @setup_docs = ();
1165         my $setup_docs = 0;
1166
1167         sanitise_line_reset();
1168         my $line;
1169         foreach my $rawline (@rawlines) {
1170                 $linenr++;
1171                 $line = $rawline;
1172
1173                 if ($rawline=~/^\+\+\+\s+(\S+)/) {
1174                         $setup_docs = 0;
1175                         if ($1 =~ m@Documentation/kernel-parameters.txt$@) {
1176                                 $setup_docs = 1;
1177                         }
1178                         #next;
1179                 }
1180                 if ($rawline=~/^\@\@ -\d+(?:,\d+)? \+(\d+)(,(\d+))? \@\@/) {
1181                         $realline=$1-1;
1182                         if (defined $2) {
1183                                 $realcnt=$3+1;
1184                         } else {
1185                                 $realcnt=1+1;
1186                         }
1187                         $in_comment = 0;
1188
1189                         # Guestimate if this is a continuing comment.  Run
1190                         # the context looking for a comment "edge".  If this
1191                         # edge is a close comment then we must be in a comment
1192                         # at context start.
1193                         my $edge;
1194                         my $cnt = $realcnt;
1195                         for (my $ln = $linenr + 1; $cnt > 0; $ln++) {
1196                                 next if (defined $rawlines[$ln - 1] &&
1197                                          $rawlines[$ln - 1] =~ /^-/);
1198                                 $cnt--;
1199                                 #print "RAW<$rawlines[$ln - 1]>\n";
1200                                 last if (!defined $rawlines[$ln - 1]);
1201                                 if ($rawlines[$ln - 1] =~ m@(/\*|\*/)@ &&
1202                                     $rawlines[$ln - 1] !~ m@"[^"]*(?:/\*|\*/)[^"]*"@) {
1203                                         ($edge) = $1;
1204                                         last;
1205                                 }
1206                         }
1207                         if (defined $edge && $edge eq '*/') {
1208                                 $in_comment = 1;
1209                         }
1210
1211                         # Guestimate if this is a continuing comment.  If this
1212                         # is the start of a diff block and this line starts
1213                         # ' *' then it is very likely a comment.
1214                         if (!defined $edge &&
1215                             $rawlines[$linenr] =~ m@^.\s*(?:\*\*+| \*)(?:\s|$)@)
1216                         {
1217                                 $in_comment = 1;
1218                         }
1219
1220                         ##print "COMMENT:$in_comment edge<$edge> $rawline\n";
1221                         sanitise_line_reset($in_comment);
1222
1223                 } elsif ($realcnt && $rawline =~ /^(?:\+| |$)/) {
1224                         # Standardise the strings and chars within the input to
1225                         # simplify matching -- only bother with positive lines.
1226                         $line = sanitise_line($rawline);
1227                 }
1228                 push(@lines, $line);
1229
1230                 if ($realcnt > 1) {
1231                         $realcnt-- if ($line =~ /^(?:\+| |$)/);
1232                 } else {
1233                         $realcnt = 0;
1234                 }
1235
1236                 #print "==>$rawline\n";
1237                 #print "-->$line\n";
1238
1239                 if ($setup_docs && $line =~ /^\+/) {
1240                         push(@setup_docs, $line);
1241                 }
1242         }
1243
1244         $prefix = '';
1245
1246         $realcnt = 0;
1247         $linenr = 0;
1248         foreach my $line (@lines) {
1249                 $linenr++;
1250
1251                 my $rawline = $rawlines[$linenr - 1];
1252
1253 #extract the line range in the file after the patch is applied
1254                 if ($line=~/^\@\@ -\d+(?:,\d+)? \+(\d+)(,(\d+))? \@\@/) {
1255                         $is_patch = 1;
1256                         $first_line = $linenr + 1;
1257                         $realline=$1-1;
1258                         if (defined $2) {
1259                                 $realcnt=$3+1;
1260                         } else {
1261                                 $realcnt=1+1;
1262                         }
1263                         annotate_reset();
1264                         $prev_values = 'E';
1265
1266                         %suppress_ifbraces = ();
1267                         %suppress_whiletrailers = ();
1268                         %suppress_export = ();
1269                         next;
1270
1271 # track the line number as we move through the hunk, note that
1272 # new versions of GNU diff omit the leading space on completely
1273 # blank context lines so we need to count that too.
1274                 } elsif ($line =~ /^( |\+|$)/) {
1275                         $realline++;
1276                         $realcnt-- if ($realcnt != 0);
1277
1278                         # Measure the line length and indent.
1279                         ($length, $indent) = line_stats($rawline);
1280
1281                         # Track the previous line.
1282                         ($prevline, $stashline) = ($stashline, $line);
1283                         ($previndent, $stashindent) = ($stashindent, $indent);
1284                         ($prevrawline, $stashrawline) = ($stashrawline, $rawline);
1285
1286                         #warn "line<$line>\n";
1287
1288                 } elsif ($realcnt == 1) {
1289                         $realcnt--;
1290                 }
1291
1292                 my $hunk_line = ($realcnt != 0);
1293
1294 #make up the handle for any error we report on this line
1295                 $prefix = "$filename:$realline: " if ($emacs && $file);
1296                 $prefix = "$filename:$linenr: " if ($emacs && !$file);
1297
1298                 $here = "#$linenr: " if (!$file);
1299                 $here = "#$realline: " if ($file);
1300
1301                 # extract the filename as it passes
1302                 if ($line=~/^\+\+\+\s+(\S+)/) {
1303                         $realfile = $1;
1304                         $realfile =~ s@^([^/]*)/@@;
1305
1306                         $p1_prefix = $1;
1307                         if (!$file && $tree && $p1_prefix ne '' &&
1308                             -e "$root/$p1_prefix") {
1309                                 WARN("patch prefix '$p1_prefix' exists, appears to be a -p0 patch\n");
1310                         }
1311
1312                         if ($realfile =~ m@^include/asm/@) {
1313                                 ERROR("do not modify files in include/asm, change architecture specific files in include/asm-<architecture>\n" . "$here$rawline\n");
1314                         }
1315                         next;
1316                 }
1317
1318                 $here .= "FILE: $realfile:$realline:" if ($realcnt != 0);
1319
1320                 my $hereline = "$here\n$rawline\n";
1321                 my $herecurr = "$here\n$rawline\n";
1322                 my $hereprev = "$here\n$prevrawline\n$rawline\n";
1323
1324                 $cnt_lines++ if ($realcnt != 0);
1325
1326 #check the patch for a signoff:
1327                 if ($line =~ /^\s*signed-off-by:/i) {
1328                         # This is a signoff, if ugly, so do not double report.
1329                         $signoff++;
1330                         if (!($line =~ /^\s*Signed-off-by:/)) {
1331                                 WARN("Signed-off-by: is the preferred form\n" .
1332                                         $herecurr);
1333                         }
1334                         if ($line =~ /^\s*signed-off-by:\S/i) {
1335                                 WARN("space required after Signed-off-by:\n" .
1336                                         $herecurr);
1337                         }
1338                 }
1339
1340 # Check for wrappage within a valid hunk of the file
1341                 if ($realcnt != 0 && $line !~ m{^(?:\+|-| |\\ No newline|$)}) {
1342                         ERROR("patch seems to be corrupt (line wrapped?)\n" .
1343                                 $herecurr) if (!$emitted_corrupt++);
1344                 }
1345
1346 # Check for absolute kernel paths.
1347                 if ($tree) {
1348                         while ($line =~ m{(?:^|\s)(/\S*)}g) {
1349                                 my $file = $1;
1350
1351                                 if ($file =~ m{^(.*?)(?::\d+)+:?$} &&
1352                                     check_absolute_file($1, $herecurr)) {
1353                                         #
1354                                 } else {
1355                                         check_absolute_file($file, $herecurr);
1356                                 }
1357                         }
1358                 }
1359
1360 # UTF-8 regex found at http://www.w3.org/International/questions/qa-forms-utf-8.en.php
1361                 if (($realfile =~ /^$/ || $line =~ /^\+/) &&
1362                     $rawline !~ m/^$UTF8*$/) {
1363                         my ($utf8_prefix) = ($rawline =~ /^($UTF8*)/);
1364
1365                         my $blank = copy_spacing($rawline);
1366                         my $ptr = substr($blank, 0, length($utf8_prefix)) . "^";
1367                         my $hereptr = "$hereline$ptr\n";
1368
1369                         ERROR("Invalid UTF-8, patch and commit message should be encoded in UTF-8\n" . $hereptr);
1370                 }
1371
1372 # ignore non-hunk lines and lines being removed
1373                 next if (!$hunk_line || $line =~ /^-/);
1374
1375 #trailing whitespace
1376                 if ($line =~ /^\+.*\015/) {
1377                         my $herevet = "$here\n" . cat_vet($rawline) . "\n";
1378                         ERROR("DOS line endings\n" . $herevet);
1379
1380                 } elsif ($rawline =~ /^\+.*\S\s+$/ || $rawline =~ /^\+\s+$/) {
1381                         my $herevet = "$here\n" . cat_vet($rawline) . "\n";
1382                         ERROR("trailing whitespace\n" . $herevet);
1383                 }
1384
1385 # check we are in a valid source file if not then ignore this hunk
1386                 next if ($realfile !~ /\.(h|c|s|S|pl|sh)$/);
1387
1388 #80 column limit
1389                 if ($line =~ /^\+/ && $prevrawline !~ /\/\*\*/ &&
1390                     $rawline !~ /^.\s*\*\s*\@$Ident\s/ &&
1391                     $line !~ /^\+\s*$logFunctions\s*\(\s*(?:KERN_\S+\s*)?"[X\t]*"\s*(?:,|\)\s*;)\s*$/ &&
1392                     $length > 80)
1393                 {
1394                         WARN("line over 80 characters\n" . $herecurr);
1395                 }
1396
1397 # check for adding lines without a newline.
1398                 if ($line =~ /^\+/ && defined $lines[$linenr] && $lines[$linenr] =~ /^\\ No newline at end of file/) {
1399                         WARN("adding a line without newline at end of file\n" . $herecurr);
1400                 }
1401
1402 # Blackfin: use hi/lo macros
1403                 if ($realfile =~ m@arch/blackfin/.*\.S$@) {
1404                         if ($line =~ /\.[lL][[:space:]]*=.*&[[:space:]]*0x[fF][fF][fF][fF]/) {
1405                                 my $herevet = "$here\n" . cat_vet($line) . "\n";
1406                                 ERROR("use the LO() macro, not (... & 0xFFFF)\n" . $herevet);
1407                         }
1408                         if ($line =~ /\.[hH][[:space:]]*=.*>>[[:space:]]*16/) {
1409                                 my $herevet = "$here\n" . cat_vet($line) . "\n";
1410                                 ERROR("use the HI() macro, not (... >> 16)\n" . $herevet);
1411                         }
1412                 }
1413
1414 # check we are in a valid source file C or perl if not then ignore this hunk
1415                 next if ($realfile !~ /\.(h|c|pl)$/);
1416
1417 # at the beginning of a line any tabs must come first and anything
1418 # more than 8 must use tabs.
1419                 if ($rawline =~ /^\+\s* \t\s*\S/ ||
1420                     $rawline =~ /^\+\s*        \s*/) {
1421                         my $herevet = "$here\n" . cat_vet($rawline) . "\n";
1422                         ERROR("code indent should use tabs where possible\n" . $herevet);
1423                 }
1424
1425 # check we are in a valid C source file if not then ignore this hunk
1426                 next if ($realfile !~ /\.(h|c)$/);
1427
1428 # check for RCS/CVS revision markers
1429                 if ($rawline =~ /^\+.*\$(Revision|Log|Id)(?:\$|)/) {
1430                         WARN("CVS style keyword markers, these will _not_ be updated\n". $herecurr);
1431                 }
1432
1433 # Blackfin: don't use __builtin_bfin_[cs]sync
1434                 if ($line =~ /__builtin_bfin_csync/) {
1435                         my $herevet = "$here\n" . cat_vet($line) . "\n";
1436                         ERROR("use the CSYNC() macro in asm/blackfin.h\n" . $herevet);
1437                 }
1438                 if ($line =~ /__builtin_bfin_ssync/) {
1439                         my $herevet = "$here\n" . cat_vet($line) . "\n";
1440                         ERROR("use the SSYNC() macro in asm/blackfin.h\n" . $herevet);
1441                 }
1442
1443 # Check for potential 'bare' types
1444                 my ($stat, $cond, $line_nr_next, $remain_next, $off_next,
1445                     $realline_next);
1446                 if ($realcnt && $line =~ /.\s*\S/) {
1447                         ($stat, $cond, $line_nr_next, $remain_next, $off_next) =
1448                                 ctx_statement_block($linenr, $realcnt, 0);
1449                         $stat =~ s/\n./\n /g;
1450                         $cond =~ s/\n./\n /g;
1451
1452                         # Find the real next line.
1453                         $realline_next = $line_nr_next;
1454                         if (defined $realline_next &&
1455                             (!defined $lines[$realline_next - 1] ||
1456                              substr($lines[$realline_next - 1], $off_next) =~ /^\s*$/)) {
1457                                 $realline_next++;
1458                         }
1459
1460                         my $s = $stat;
1461                         $s =~ s/{.*$//s;
1462
1463                         # Ignore goto labels.
1464                         if ($s =~ /$Ident:\*$/s) {
1465
1466                         # Ignore functions being called
1467                         } elsif ($s =~ /^.\s*$Ident\s*\(/s) {
1468
1469                         } elsif ($s =~ /^.\s*else\b/s) {
1470
1471                         # declarations always start with types
1472                         } elsif ($prev_values eq 'E' && $s =~ /^.\s*(?:$Storage\s+)?(?:$Inline\s+)?(?:const\s+)?((?:\s*$Ident)+?)\b(?:\s+$Sparse)?\s*\**\s*(?:$Ident|\(\*[^\)]*\))(?:\s*$Modifier)?\s*(?:;|=|,|\()/s) {
1473                                 my $type = $1;
1474                                 $type =~ s/\s+/ /g;
1475                                 possible($type, "A:" . $s);
1476
1477                         # definitions in global scope can only start with types
1478                         } elsif ($s =~ /^.(?:$Storage\s+)?(?:$Inline\s+)?(?:const\s+)?($Ident)\b\s*(?!:)/s) {
1479                                 possible($1, "B:" . $s);
1480                         }
1481
1482                         # any (foo ... *) is a pointer cast, and foo is a type
1483                         while ($s =~ /\(($Ident)(?:\s+$Sparse)*[\s\*]+\s*\)/sg) {
1484                                 possible($1, "C:" . $s);
1485                         }
1486
1487                         # Check for any sort of function declaration.
1488                         # int foo(something bar, other baz);
1489                         # void (*store_gdt)(x86_descr_ptr *);
1490                         if ($prev_values eq 'E' && $s =~ /^(.(?:typedef\s*)?(?:(?:$Storage|$Inline)\s*)*\s*$Type\s*(?:\b$Ident|\(\*\s*$Ident\))\s*)\(/s) {
1491                                 my ($name_len) = length($1);
1492
1493                                 my $ctx = $s;
1494                                 substr($ctx, 0, $name_len + 1, '');
1495                                 $ctx =~ s/\)[^\)]*$//;
1496
1497                                 for my $arg (split(/\s*,\s*/, $ctx)) {
1498                                         if ($arg =~ /^(?:const\s+)?($Ident)(?:\s+$Sparse)*\s*\**\s*(:?\b$Ident)?$/s || $arg =~ /^($Ident)$/s) {
1499
1500                                                 possible($1, "D:" . $s);
1501                                         }
1502                                 }
1503                         }
1504
1505                 }
1506
1507 #
1508 # Checks which may be anchored in the context.
1509 #
1510
1511 # Check for switch () and associated case and default
1512 # statements should be at the same indent.
1513                 if ($line=~/\bswitch\s*\(.*\)/) {
1514                         my $err = '';
1515                         my $sep = '';
1516                         my @ctx = ctx_block_outer($linenr, $realcnt);
1517                         shift(@ctx);
1518                         for my $ctx (@ctx) {
1519                                 my ($clen, $cindent) = line_stats($ctx);
1520                                 if ($ctx =~ /^\+\s*(case\s+|default:)/ &&
1521                                                         $indent != $cindent) {
1522                                         $err .= "$sep$ctx\n";
1523                                         $sep = '';
1524                                 } else {
1525                                         $sep = "[...]\n";
1526                                 }
1527                         }
1528                         if ($err ne '') {
1529                                 ERROR("switch and case should be at the same indent\n$hereline$err");
1530                         }
1531                 }
1532
1533 # if/while/etc brace do not go on next line, unless defining a do while loop,
1534 # or if that brace on the next line is for something else
1535                 if ($line =~ /(.*)\b((?:if|while|for|switch)\s*\(|do\b|else\b)/ && $line !~ /^.\s*\#/) {
1536                         my $pre_ctx = "$1$2";
1537
1538                         my ($level, @ctx) = ctx_statement_level($linenr, $realcnt, 0);
1539                         my $ctx_cnt = $realcnt - $#ctx - 1;
1540                         my $ctx = join("\n", @ctx);
1541
1542                         my $ctx_ln = $linenr;
1543                         my $ctx_skip = $realcnt;
1544
1545                         while ($ctx_skip > $ctx_cnt || ($ctx_skip == $ctx_cnt &&
1546                                         defined $lines[$ctx_ln - 1] &&
1547                                         $lines[$ctx_ln - 1] =~ /^-/)) {
1548                                 ##print "SKIP<$ctx_skip> CNT<$ctx_cnt>\n";
1549                                 $ctx_skip-- if (!defined $lines[$ctx_ln - 1] || $lines[$ctx_ln - 1] !~ /^-/);
1550                                 $ctx_ln++;
1551                         }
1552
1553                         #print "realcnt<$realcnt> ctx_cnt<$ctx_cnt>\n";
1554                         #print "pre<$pre_ctx>\nline<$line>\nctx<$ctx>\nnext<$lines[$ctx_ln - 1]>\n";
1555
1556                         if ($ctx !~ /{\s*/ && defined($lines[$ctx_ln -1]) && $lines[$ctx_ln - 1] =~ /^\+\s*{/) {
1557                                 ERROR("that open brace { should be on the previous line\n" .
1558                                         "$here\n$ctx\n$lines[$ctx_ln - 1]\n");
1559                         }
1560                         if ($level == 0 && $pre_ctx !~ /}\s*while\s*\($/ &&
1561                             $ctx =~ /\)\s*\;\s*$/ &&
1562                             defined $lines[$ctx_ln - 1])
1563                         {
1564                                 my ($nlength, $nindent) = line_stats($lines[$ctx_ln - 1]);
1565                                 if ($nindent > $indent) {
1566                                         WARN("trailing semicolon indicates no statements, indent implies otherwise\n" .
1567                                                 "$here\n$ctx\n$lines[$ctx_ln - 1]\n");
1568                                 }
1569                         }
1570                 }
1571
1572 # Check relative indent for conditionals and blocks.
1573                 if ($line =~ /\b(?:(?:if|while|for)\s*\(|do\b)/ && $line !~ /^.\s*#/ && $line !~ /\}\s*while\s*/) {
1574                         my ($s, $c) = ($stat, $cond);
1575
1576                         substr($s, 0, length($c), '');
1577
1578                         # Make sure we remove the line prefixes as we have
1579                         # none on the first line, and are going to readd them
1580                         # where necessary.
1581                         $s =~ s/\n./\n/gs;
1582
1583                         # Find out how long the conditional actually is.
1584                         my @newlines = ($c =~ /\n/gs);
1585                         my $cond_lines = 1 + $#newlines;
1586
1587                         # We want to check the first line inside the block
1588                         # starting at the end of the conditional, so remove:
1589                         #  1) any blank line termination
1590                         #  2) any opening brace { on end of the line
1591                         #  3) any do (...) {
1592                         my $continuation = 0;
1593                         my $check = 0;
1594                         $s =~ s/^.*\bdo\b//;
1595                         $s =~ s/^\s*{//;
1596                         if ($s =~ s/^\s*\\//) {
1597                                 $continuation = 1;
1598                         }
1599                         if ($s =~ s/^\s*?\n//) {
1600                                 $check = 1;
1601                                 $cond_lines++;
1602                         }
1603
1604                         # Also ignore a loop construct at the end of a
1605                         # preprocessor statement.
1606                         if (($prevline =~ /^.\s*#\s*define\s/ ||
1607                             $prevline =~ /\\\s*$/) && $continuation == 0) {
1608                                 $check = 0;
1609                         }
1610
1611                         my $cond_ptr = -1;
1612                         $continuation = 0;
1613                         while ($cond_ptr != $cond_lines) {
1614                                 $cond_ptr = $cond_lines;
1615
1616                                 # If we see an #else/#elif then the code
1617                                 # is not linear.
1618                                 if ($s =~ /^\s*\#\s*(?:else|elif)/) {
1619                                         $check = 0;
1620                                 }
1621
1622                                 # Ignore:
1623                                 #  1) blank lines, they should be at 0,
1624                                 #  2) preprocessor lines, and
1625                                 #  3) labels.
1626                                 if ($continuation ||
1627                                     $s =~ /^\s*?\n/ ||
1628                                     $s =~ /^\s*#\s*?/ ||
1629                                     $s =~ /^\s*$Ident\s*:/) {
1630                                         $continuation = ($s =~ /^.*?\\\n/) ? 1 : 0;
1631                                         if ($s =~ s/^.*?\n//) {
1632                                                 $cond_lines++;
1633                                         }
1634                                 }
1635                         }
1636
1637                         my (undef, $sindent) = line_stats("+" . $s);
1638                         my $stat_real = raw_line($linenr, $cond_lines);
1639
1640                         # Check if either of these lines are modified, else
1641                         # this is not this patch's fault.
1642                         if (!defined($stat_real) ||
1643                             $stat !~ /^\+/ && $stat_real !~ /^\+/) {
1644                                 $check = 0;
1645                         }
1646                         if (defined($stat_real) && $cond_lines > 1) {
1647                                 $stat_real = "[...]\n$stat_real";
1648                         }
1649
1650                         #print "line<$line> prevline<$prevline> indent<$indent> sindent<$sindent> check<$check> continuation<$continuation> s<$s> cond_lines<$cond_lines> stat_real<$stat_real> stat<$stat>\n";
1651
1652                         if ($check && (($sindent % 8) != 0 ||
1653                             ($sindent <= $indent && $s ne ''))) {
1654                                 WARN("suspect code indent for conditional statements ($indent, $sindent)\n" . $herecurr . "$stat_real\n");
1655                         }
1656                 }
1657
1658                 # Track the 'values' across context and added lines.
1659                 my $opline = $line; $opline =~ s/^./ /;
1660                 my ($curr_values, $curr_vars) =
1661                                 annotate_values($opline . "\n", $prev_values);
1662                 $curr_values = $prev_values . $curr_values;
1663                 if ($dbg_values) {
1664                         my $outline = $opline; $outline =~ s/\t/ /g;
1665                         print "$linenr > .$outline\n";
1666                         print "$linenr > $curr_values\n";
1667                         print "$linenr >  $curr_vars\n";
1668                 }
1669                 $prev_values = substr($curr_values, -1);
1670
1671 #ignore lines not being added
1672                 if ($line=~/^[^\+]/) {next;}
1673
1674 # TEST: allow direct testing of the type matcher.
1675                 if ($dbg_type) {
1676                         if ($line =~ /^.\s*$Declare\s*$/) {
1677                                 ERROR("TEST: is type\n" . $herecurr);
1678                         } elsif ($dbg_type > 1 && $line =~ /^.+($Declare)/) {
1679                                 ERROR("TEST: is not type ($1 is)\n". $herecurr);
1680                         }
1681                         next;
1682                 }
1683 # TEST: allow direct testing of the attribute matcher.
1684                 if ($dbg_attr) {
1685                         if ($line =~ /^.\s*$Modifier\s*$/) {
1686                                 ERROR("TEST: is attr\n" . $herecurr);
1687                         } elsif ($dbg_attr > 1 && $line =~ /^.+($Modifier)/) {
1688                                 ERROR("TEST: is not attr ($1 is)\n". $herecurr);
1689                         }
1690                         next;
1691                 }
1692
1693 # check for initialisation to aggregates open brace on the next line
1694                 if ($line =~ /^.\s*{/ &&
1695                     $prevline =~ /(?:^|[^=])=\s*$/) {
1696                         ERROR("that open brace { should be on the previous line\n" . $hereprev);
1697                 }
1698
1699 #
1700 # Checks which are anchored on the added line.
1701 #
1702
1703 # check for malformed paths in #include statements (uses RAW line)
1704                 if ($rawline =~ m{^.\s*\#\s*include\s+[<"](.*)[">]}) {
1705                         my $path = $1;
1706                         if ($path =~ m{//}) {
1707                                 ERROR("malformed #include filename\n" .
1708                                         $herecurr);
1709                         }
1710                 }
1711
1712 # no C99 // comments
1713                 if ($line =~ m{//}) {
1714                         ERROR("do not use C99 // comments\n" . $herecurr);
1715                 }
1716                 # Remove C99 comments.
1717                 $line =~ s@//.*@@;
1718                 $opline =~ s@//.*@@;
1719
1720 # EXPORT_SYMBOL should immediately follow the thing it is exporting, consider
1721 # the whole statement.
1722 #print "APW <$lines[$realline_next - 1]>\n";
1723                 if (defined $realline_next &&
1724                     exists $lines[$realline_next - 1] &&
1725                     !defined $suppress_export{$realline_next} &&
1726                     ($lines[$realline_next - 1] =~ /EXPORT_SYMBOL.*\((.*)\)/ ||
1727                      $lines[$realline_next - 1] =~ /EXPORT_UNUSED_SYMBOL.*\((.*)\)/)) {
1728                         my $name = $1;
1729                         if ($stat !~ /(?:
1730                                 \n.}\s*$|
1731                                 ^.DEFINE_$Ident\(\Q$name\E\)|
1732                                 ^.DECLARE_$Ident\(\Q$name\E\)|
1733                                 ^.LIST_HEAD\(\Q$name\E\)|
1734                                 ^.(?:$Storage\s+)?$Type\s*\(\s*\*\s*\Q$name\E\s*\)\s*\(|
1735                                 \b\Q$name\E(?:\s+$Attribute)*\s*(?:;|=|\[|\()
1736                             )/x) {
1737 #print "FOO A<$lines[$realline_next - 1]> stat<$stat> name<$name>\n";
1738                                 $suppress_export{$realline_next} = 2;
1739                         } else {
1740                                 $suppress_export{$realline_next} = 1;
1741                         }
1742                 }
1743                 if (!defined $suppress_export{$linenr} &&
1744                     $prevline =~ /^.\s*$/ &&
1745                     ($line =~ /EXPORT_SYMBOL.*\((.*)\)/ ||
1746                      $line =~ /EXPORT_UNUSED_SYMBOL.*\((.*)\)/)) {
1747 #print "FOO B <$lines[$linenr - 1]>\n";
1748                         $suppress_export{$linenr} = 2;
1749                 }
1750                 if (defined $suppress_export{$linenr} &&
1751                     $suppress_export{$linenr} == 2) {
1752                         WARN("EXPORT_SYMBOL(foo); should immediately follow its function/variable\n" . $herecurr);
1753                 }
1754
1755 # check for external initialisers.
1756                 if ($line =~ /^.$Type\s*$Ident\s*(?:\s+$Modifier)*\s*=\s*(0|NULL|false)\s*;/) {
1757                         ERROR("do not initialise externals to 0 or NULL\n" .
1758                                 $herecurr);
1759                 }
1760 # check for static initialisers.
1761                 if ($line =~ /\bstatic\s.*=\s*(0|NULL|false)\s*;/) {
1762                         ERROR("do not initialise statics to 0 or NULL\n" .
1763                                 $herecurr);
1764                 }
1765
1766 # check for new typedefs, only function parameters and sparse annotations
1767 # make sense.
1768                 if ($line =~ /\btypedef\s/ &&
1769                     $line !~ /\btypedef\s+$Type\s*\(\s*\*?$Ident\s*\)\s*\(/ &&
1770                     $line !~ /\btypedef\s+$Type\s+$Ident\s*\(/ &&
1771                     $line !~ /\b$typeTypedefs\b/ &&
1772                     $line !~ /\b__bitwise(?:__|)\b/) {
1773                         WARN("do not add new typedefs\n" . $herecurr);
1774                 }
1775
1776 # * goes on variable not on type
1777                 # (char*[ const])
1778                 if ($line =~ m{\($NonptrType(\s*(?:$Modifier\b\s*|\*\s*)+)\)}) {
1779                         my ($from, $to) = ($1, $1);
1780
1781                         # Should start with a space.
1782                         $to =~ s/^(\S)/ $1/;
1783                         # Should not end with a space.
1784                         $to =~ s/\s+$//;
1785                         # '*'s should not have spaces between.
1786                         while ($to =~ s/\*\s+\*/\*\*/) {
1787                         }
1788
1789                         #print "from<$from> to<$to>\n";
1790                         if ($from ne $to) {
1791                                 ERROR("\"(foo$from)\" should be \"(foo$to)\"\n" .  $herecurr);
1792                         }
1793                 } elsif ($line =~ m{\b$NonptrType(\s*(?:$Modifier\b\s*|\*\s*)+)($Ident)}) {
1794                         my ($from, $to, $ident) = ($1, $1, $2);
1795
1796                         # Should start with a space.
1797                         $to =~ s/^(\S)/ $1/;
1798                         # Should not end with a space.
1799                         $to =~ s/\s+$//;
1800                         # '*'s should not have spaces between.
1801                         while ($to =~ s/\*\s+\*/\*\*/) {
1802                         }
1803                         # Modifiers should have spaces.
1804                         $to =~ s/(\b$Modifier$)/$1 /;
1805
1806                         #print "from<$from> to<$to> ident<$ident>\n";
1807                         if ($from ne $to && $ident !~ /^$Modifier$/) {
1808                                 ERROR("\"foo${from}bar\" should be \"foo${to}bar\"\n" .  $herecurr);
1809                         }
1810                 }
1811
1812 # # no BUG() or BUG_ON()
1813 #               if ($line =~ /\b(BUG|BUG_ON)\b/) {
1814 #                       print "Try to use WARN_ON & Recovery code rather than BUG() or BUG_ON()\n";
1815 #                       print "$herecurr";
1816 #                       $clean = 0;
1817 #               }
1818
1819                 if ($line =~ /\bLINUX_VERSION_CODE\b/) {
1820                         WARN("LINUX_VERSION_CODE should be avoided, code should be for the version to which it is merged\n" . $herecurr);
1821                 }
1822
1823 # printk should use KERN_* levels.  Note that follow on printk's on the
1824 # same line do not need a level, so we use the current block context
1825 # to try and find and validate the current printk.  In summary the current
1826 # printk includes all preceeding printk's which have no newline on the end.
1827 # we assume the first bad printk is the one to report.
1828                 if ($line =~ /\bprintk\((?!KERN_)\s*"/) {
1829                         my $ok = 0;
1830                         for (my $ln = $linenr - 1; $ln >= $first_line; $ln--) {
1831                                 #print "CHECK<$lines[$ln - 1]\n";
1832                                 # we have a preceeding printk if it ends
1833                                 # with "\n" ignore it, else it is to blame
1834                                 if ($lines[$ln - 1] =~ m{\bprintk\(}) {
1835                                         if ($rawlines[$ln - 1] !~ m{\\n"}) {
1836                                                 $ok = 1;
1837                                         }
1838                                         last;
1839                                 }
1840                         }
1841                         if ($ok == 0) {
1842                                 WARN("printk() should include KERN_ facility level\n" . $herecurr);
1843                         }
1844                 }
1845
1846 # function brace can't be on same line, except for #defines of do while,
1847 # or if closed on same line
1848                 if (($line=~/$Type\s*$Ident\(.*\).*\s{/) and
1849                     !($line=~/\#\s*define.*do\s{/) and !($line=~/}/)) {
1850                         ERROR("open brace '{' following function declarations go on the next line\n" . $herecurr);
1851                 }
1852
1853 # open braces for enum, union and struct go on the same line.
1854                 if ($line =~ /^.\s*{/ &&
1855                     $prevline =~ /^.\s*(?:typedef\s+)?(enum|union|struct)(?:\s+$Ident)?\s*$/) {
1856                         ERROR("open brace '{' following $1 go on the same line\n" . $hereprev);
1857                 }
1858
1859 # check for spacing round square brackets; allowed:
1860 #  1. with a type on the left -- int [] a;
1861 #  2. at the beginning of a line for slice initialisers -- [0...10] = 5,
1862 #  3. inside a curly brace -- = { [0...10] = 5 }
1863                 while ($line =~ /(.*?\s)\[/g) {
1864                         my ($where, $prefix) = ($-[1], $1);
1865                         if ($prefix !~ /$Type\s+$/ &&
1866                             ($where != 0 || $prefix !~ /^.\s+$/) &&
1867                             $prefix !~ /{\s+$/) {
1868                                 ERROR("space prohibited before open square bracket '['\n" . $herecurr);
1869                         }
1870                 }
1871
1872 # check for spaces between functions and their parentheses.
1873                 while ($line =~ /($Ident)\s+\(/g) {
1874                         my $name = $1;
1875                         my $ctx_before = substr($line, 0, $-[1]);
1876                         my $ctx = "$ctx_before$name";
1877
1878                         # Ignore those directives where spaces _are_ permitted.
1879                         if ($name =~ /^(?:
1880                                 if|for|while|switch|return|case|
1881                                 volatile|__volatile__|
1882                                 __attribute__|format|__extension__|
1883                                 asm|__asm__)$/x)
1884                         {
1885
1886                         # cpp #define statements have non-optional spaces, ie
1887                         # if there is a space between the name and the open
1888                         # parenthesis it is simply not a parameter group.
1889                         } elsif ($ctx_before =~ /^.\s*\#\s*define\s*$/) {
1890
1891                         # cpp #elif statement condition may start with a (
1892                         } elsif ($ctx =~ /^.\s*\#\s*elif\s*$/) {
1893
1894                         # If this whole things ends with a type its most
1895                         # likely a typedef for a function.
1896                         } elsif ($ctx =~ /$Type$/) {
1897
1898                         } else {
1899                                 WARN("space prohibited between function name and open parenthesis '('\n" . $herecurr);
1900                         }
1901                 }
1902 # Check operator spacing.
1903                 if (!($line=~/\#\s*include/)) {
1904                         my $ops = qr{
1905                                 <<=|>>=|<=|>=|==|!=|
1906                                 \+=|-=|\*=|\/=|%=|\^=|\|=|&=|
1907                                 =>|->|<<|>>|<|>|=|!|~|
1908                                 &&|\|\||,|\^|\+\+|--|&|\||\+|-|\*|\/|%|
1909                                 \?|:
1910                         }x;
1911                         my @elements = split(/($ops|;)/, $opline);
1912                         my $off = 0;
1913
1914                         my $blank = copy_spacing($opline);
1915
1916                         for (my $n = 0; $n < $#elements; $n += 2) {
1917                                 $off += length($elements[$n]);
1918
1919                                 # Pick up the preceeding and succeeding characters.
1920                                 my $ca = substr($opline, 0, $off);
1921                                 my $cc = '';
1922                                 if (length($opline) >= ($off + length($elements[$n + 1]))) {
1923                                         $cc = substr($opline, $off + length($elements[$n + 1]));
1924                                 }
1925                                 my $cb = "$ca$;$cc";
1926
1927                                 my $a = '';
1928                                 $a = 'V' if ($elements[$n] ne '');
1929                                 $a = 'W' if ($elements[$n] =~ /\s$/);
1930                                 $a = 'C' if ($elements[$n] =~ /$;$/);
1931                                 $a = 'B' if ($elements[$n] =~ /(\[|\()$/);
1932                                 $a = 'O' if ($elements[$n] eq '');
1933                                 $a = 'E' if ($ca =~ /^\s*$/);
1934
1935                                 my $op = $elements[$n + 1];
1936
1937                                 my $c = '';
1938                                 if (defined $elements[$n + 2]) {
1939                                         $c = 'V' if ($elements[$n + 2] ne '');
1940                                         $c = 'W' if ($elements[$n + 2] =~ /^\s/);
1941                                         $c = 'C' if ($elements[$n + 2] =~ /^$;/);
1942                                         $c = 'B' if ($elements[$n + 2] =~ /^(\)|\]|;)/);
1943                                         $c = 'O' if ($elements[$n + 2] eq '');
1944                                         $c = 'E' if ($elements[$n + 2] =~ /^\s*\\$/);
1945                                 } else {
1946                                         $c = 'E';
1947                                 }
1948
1949                                 my $ctx = "${a}x${c}";
1950
1951                                 my $at = "(ctx:$ctx)";
1952
1953                                 my $ptr = substr($blank, 0, $off) . "^";
1954                                 my $hereptr = "$hereline$ptr\n";
1955
1956                                 # Pull out the value of this operator.
1957                                 my $op_type = substr($curr_values, $off + 1, 1);
1958
1959                                 # Get the full operator variant.
1960                                 my $opv = $op . substr($curr_vars, $off, 1);
1961
1962                                 # Ignore operators passed as parameters.
1963                                 if ($op_type ne 'V' &&
1964                                     $ca =~ /\s$/ && $cc =~ /^\s*,/) {
1965
1966 #                               # Ignore comments
1967 #                               } elsif ($op =~ /^$;+$/) {
1968
1969                                 # ; should have either the end of line or a space or \ after it
1970                                 } elsif ($op eq ';') {
1971                                         if ($ctx !~ /.x[WEBC]/ &&
1972                                             $cc !~ /^\\/ && $cc !~ /^;/) {
1973                                                 ERROR("space required after that '$op' $at\n" . $hereptr);
1974                                         }
1975
1976                                 # // is a comment
1977                                 } elsif ($op eq '//') {
1978
1979                                 # No spaces for:
1980                                 #   ->
1981                                 #   :   when part of a bitfield
1982                                 } elsif ($op eq '->' || $opv eq ':B') {
1983                                         if ($ctx =~ /Wx.|.xW/) {
1984                                                 ERROR("spaces prohibited around that '$op' $at\n" . $hereptr);
1985                                         }
1986
1987                                 # , must have a space on the right.
1988                                 } elsif ($op eq ',') {
1989                                         if ($ctx !~ /.x[WEC]/ && $cc !~ /^}/) {
1990                                                 ERROR("space required after that '$op' $at\n" . $hereptr);
1991                                         }
1992
1993                                 # '*' as part of a type definition -- reported already.
1994                                 } elsif ($opv eq '*_') {
1995                                         #warn "'*' is part of type\n";
1996
1997                                 # unary operators should have a space before and
1998                                 # none after.  May be left adjacent to another
1999                                 # unary operator, or a cast
2000                                 } elsif ($op eq '!' || $op eq '~' ||
2001                                          $opv eq '*U' || $opv eq '-U' ||
2002                                          $opv eq '&U' || $opv eq '&&U') {
2003                                         if ($ctx !~ /[WEBC]x./ && $ca !~ /(?:\)|!|~|\*|-|\&|\||\+\+|\-\-|\{)$/) {
2004                                                 ERROR("space required before that '$op' $at\n" . $hereptr);
2005                                         }
2006                                         if ($op eq '*' && $cc =~/\s*$Modifier\b/) {
2007                                                 # A unary '*' may be const
2008
2009                                         } elsif ($ctx =~ /.xW/) {
2010                                                 ERROR("space prohibited after that '$op' $at\n" . $hereptr);
2011                                         }
2012
2013                                 # unary ++ and unary -- are allowed no space on one side.
2014                                 } elsif ($op eq '++' or $op eq '--') {
2015                                         if ($ctx !~ /[WEOBC]x[^W]/ && $ctx !~ /[^W]x[WOBEC]/) {
2016                                                 ERROR("space required one side of that '$op' $at\n" . $hereptr);
2017                                         }
2018                                         if ($ctx =~ /Wx[BE]/ ||
2019                                             ($ctx =~ /Wx./ && $cc =~ /^;/)) {
2020                                                 ERROR("space prohibited before that '$op' $at\n" . $hereptr);
2021                                         }
2022                                         if ($ctx =~ /ExW/) {
2023                                                 ERROR("space prohibited after that '$op' $at\n" . $hereptr);
2024                                         }
2025
2026
2027                                 # << and >> may either have or not have spaces both sides
2028                                 } elsif ($op eq '<<' or $op eq '>>' or
2029                                          $op eq '&' or $op eq '^' or $op eq '|' or
2030                                          $op eq '+' or $op eq '-' or
2031                                          $op eq '*' or $op eq '/' or
2032                                          $op eq '%')
2033                                 {
2034                                         if ($ctx =~ /Wx[^WCE]|[^WCE]xW/) {
2035                                                 ERROR("need consistent spacing around '$op' $at\n" .
2036                                                         $hereptr);
2037                                         }
2038
2039                                 # A colon needs no spaces before when it is
2040                                 # terminating a case value or a label.
2041                                 } elsif ($opv eq ':C' || $opv eq ':L') {
2042                                         if ($ctx =~ /Wx./) {
2043                                                 ERROR("space prohibited before that '$op' $at\n" . $hereptr);
2044                                         }
2045
2046                                 # All the others need spaces both sides.
2047                                 } elsif ($ctx !~ /[EWC]x[CWE]/) {
2048                                         my $ok = 0;
2049
2050                                         # Ignore email addresses <foo@bar>
2051                                         if (($op eq '<' &&
2052                                              $cc =~ /^\S+\@\S+>/) ||
2053                                             ($op eq '>' &&
2054                                              $ca =~ /<\S+\@\S+$/))
2055                                         {
2056                                                 $ok = 1;
2057                                         }
2058
2059                                         # Ignore ?:
2060                                         if (($opv eq ':O' && $ca =~ /\?$/) ||
2061                                             ($op eq '?' && $cc =~ /^:/)) {
2062                                                 $ok = 1;
2063                                         }
2064
2065                                         if ($ok == 0) {
2066                                                 ERROR("spaces required around that '$op' $at\n" . $hereptr);
2067                                         }
2068                                 }
2069                                 $off += length($elements[$n + 1]);
2070                         }
2071                 }
2072
2073 # check for multiple assignments
2074                 if ($line =~ /^.\s*$Lval\s*=\s*$Lval\s*=(?!=)/) {
2075                         CHK("multiple assignments should be avoided\n" . $herecurr);
2076                 }
2077
2078 ## # check for multiple declarations, allowing for a function declaration
2079 ## # continuation.
2080 ##              if ($line =~ /^.\s*$Type\s+$Ident(?:\s*=[^,{]*)?\s*,\s*$Ident.*/ &&
2081 ##                  $line !~ /^.\s*$Type\s+$Ident(?:\s*=[^,{]*)?\s*,\s*$Type\s*$Ident.*/) {
2082 ##
2083 ##                      # Remove any bracketed sections to ensure we do not
2084 ##                      # falsly report the parameters of functions.
2085 ##                      my $ln = $line;
2086 ##                      while ($ln =~ s/\([^\(\)]*\)//g) {
2087 ##                      }
2088 ##                      if ($ln =~ /,/) {
2089 ##                              WARN("declaring multiple variables together should be avoided\n" . $herecurr);
2090 ##                      }
2091 ##              }
2092
2093 #need space before brace following if, while, etc
2094                 if (($line =~ /\(.*\){/ && $line !~ /\($Type\){/) ||
2095                     $line =~ /do{/) {
2096                         ERROR("space required before the open brace '{'\n" . $herecurr);
2097                 }
2098
2099 # closing brace should have a space following it when it has anything
2100 # on the line
2101                 if ($line =~ /}(?!(?:,|;|\)))\S/) {
2102                         ERROR("space required after that close brace '}'\n" . $herecurr);
2103                 }
2104
2105 # check spacing on square brackets
2106                 if ($line =~ /\[\s/ && $line !~ /\[\s*$/) {
2107                         ERROR("space prohibited after that open square bracket '['\n" . $herecurr);
2108                 }
2109                 if ($line =~ /\s\]/) {
2110                         ERROR("space prohibited before that close square bracket ']'\n" . $herecurr);
2111                 }
2112
2113 # check spacing on parentheses
2114                 if ($line =~ /\(\s/ && $line !~ /\(\s*(?:\\)?$/ &&
2115                     $line !~ /for\s*\(\s+;/) {
2116                         ERROR("space prohibited after that open parenthesis '('\n" . $herecurr);
2117                 }
2118                 if ($line =~ /(\s+)\)/ && $line !~ /^.\s*\)/ &&
2119                     $line !~ /for\s*\(.*;\s+\)/ &&
2120                     $line !~ /:\s+\)/) {
2121                         ERROR("space prohibited before that close parenthesis ')'\n" . $herecurr);
2122                 }
2123
2124 #goto labels aren't indented, allow a single space however
2125                 if ($line=~/^.\s+[A-Za-z\d_]+:(?![0-9]+)/ and
2126                    !($line=~/^. [A-Za-z\d_]+:/) and !($line=~/^.\s+default:/)) {
2127                         WARN("labels should not be indented\n" . $herecurr);
2128                 }
2129
2130 # Return is not a function.
2131                 if (defined($stat) && $stat =~ /^.\s*return(\s*)(\(.*);/s) {
2132                         my $spacing = $1;
2133                         my $value = $2;
2134
2135                         # Flatten any parentheses
2136                         $value =~ s/\)\(/\) \(/g;
2137                         while ($value =~ s/\[[^\{\}]*\]/1/ ||
2138                                $value !~ /(?:$Ident|-?$Constant)\s*
2139                                              $Compare\s*
2140                                              (?:$Ident|-?$Constant)/x &&
2141                                $value =~ s/\([^\(\)]*\)/1/) {
2142                         }
2143
2144                         if ($value =~ /^(?:$Ident|-?$Constant)$/) {
2145                                 ERROR("return is not a function, parentheses are not required\n" . $herecurr);
2146
2147                         } elsif ($spacing !~ /\s+/) {
2148                                 ERROR("space required before the open parenthesis '('\n" . $herecurr);
2149                         }
2150                 }
2151
2152 # Need a space before open parenthesis after if, while etc
2153                 if ($line=~/\b(if|while|for|switch)\(/) {
2154                         ERROR("space required before the open parenthesis '('\n" . $herecurr);
2155                 }
2156
2157 # Check for illegal assignment in if conditional -- and check for trailing
2158 # statements after the conditional.
2159                 if ($line =~ /do\s*(?!{)/) {
2160                         my ($stat_next) = ctx_statement_block($line_nr_next,
2161                                                 $remain_next, $off_next);
2162                         $stat_next =~ s/\n./\n /g;
2163                         ##print "stat<$stat> stat_next<$stat_next>\n";
2164
2165                         if ($stat_next =~ /^\s*while\b/) {
2166                                 # If the statement carries leading newlines,
2167                                 # then count those as offsets.
2168                                 my ($whitespace) =
2169                                         ($stat_next =~ /^((?:\s*\n[+-])*\s*)/s);
2170                                 my $offset =
2171                                         statement_rawlines($whitespace) - 1;
2172
2173                                 $suppress_whiletrailers{$line_nr_next +
2174                                                                 $offset} = 1;
2175                         }
2176                 }
2177                 if (!defined $suppress_whiletrailers{$linenr} &&
2178                     $line =~ /\b(?:if|while|for)\s*\(/ && $line !~ /^.\s*#/) {
2179                         my ($s, $c) = ($stat, $cond);
2180
2181                         if ($c =~ /\bif\s*\(.*[^<>!=]=[^=].*/s) {
2182                                 ERROR("do not use assignment in if condition\n" . $herecurr);
2183                         }
2184
2185                         # Find out what is on the end of the line after the
2186                         # conditional.
2187                         substr($s, 0, length($c), '');
2188                         $s =~ s/\n.*//g;
2189                         $s =~ s/$;//g;  # Remove any comments
2190                         if (length($c) && $s !~ /^\s*{?\s*\\*\s*$/ &&
2191                             $c !~ /}\s*while\s*/)
2192                         {
2193                                 # Find out how long the conditional actually is.
2194                                 my @newlines = ($c =~ /\n/gs);
2195                                 my $cond_lines = 1 + $#newlines;
2196                                 my $stat_real = '';
2197
2198                                 $stat_real = raw_line($linenr, $cond_lines)
2199                                                         . "\n" if ($cond_lines);
2200                                 if (defined($stat_real) && $cond_lines > 1) {
2201                                         $stat_real = "[...]\n$stat_real";
2202                                 }
2203
2204                                 ERROR("trailing statements should be on next line\n" . $herecurr . $stat_real);
2205                         }
2206                 }
2207
2208 # Check for bitwise tests written as boolean
2209                 if ($line =~ /
2210                         (?:
2211                                 (?:\[|\(|\&\&|\|\|)
2212                                 \s*0[xX][0-9]+\s*
2213                                 (?:\&\&|\|\|)
2214                         |
2215                                 (?:\&\&|\|\|)
2216                                 \s*0[xX][0-9]+\s*
2217                                 (?:\&\&|\|\||\)|\])
2218                         )/x)
2219                 {
2220                         WARN("boolean test with hexadecimal, perhaps just 1 \& or \|?\n" . $herecurr);
2221                 }
2222
2223 # if and else should not have general statements after it
2224                 if ($line =~ /^.\s*(?:}\s*)?else\b(.*)/) {
2225                         my $s = $1;
2226                         $s =~ s/$;//g;  # Remove any comments
2227                         if ($s !~ /^\s*(?:\sif|(?:{|)\s*\\?\s*$)/) {
2228                                 ERROR("trailing statements should be on next line\n" . $herecurr);
2229                         }
2230                 }
2231 # if should not continue a brace
2232                 if ($line =~ /}\s*if\b/) {
2233                         ERROR("trailing statements should be on next line\n" .
2234                                 $herecurr);
2235                 }
2236 # case and default should not have general statements after them
2237                 if ($line =~ /^.\s*(?:case\s*.*|default\s*):/g &&
2238                     $line !~ /\G(?:
2239                         (?:\s*$;*)(?:\s*{)?(?:\s*$;*)(?:\s*\\)?\s*$|
2240                         \s*return\s+
2241                     )/xg)
2242                 {
2243                         ERROR("trailing statements should be on next line\n" . $herecurr);
2244                 }
2245
2246                 # Check for }<nl>else {, these must be at the same
2247                 # indent level to be relevant to each other.
2248                 if ($prevline=~/}\s*$/ and $line=~/^.\s*else\s*/ and
2249                                                 $previndent == $indent) {
2250                         ERROR("else should follow close brace '}'\n" . $hereprev);
2251                 }
2252
2253                 if ($prevline=~/}\s*$/ and $line=~/^.\s*while\s*/ and
2254                                                 $previndent == $indent) {
2255                         my ($s, $c) = ctx_statement_block($linenr, $realcnt, 0);
2256
2257                         # Find out what is on the end of the line after the
2258                         # conditional.
2259                         substr($s, 0, length($c), '');
2260                         $s =~ s/\n.*//g;
2261
2262                         if ($s =~ /^\s*;/) {
2263                                 ERROR("while should follow close brace '}'\n" . $hereprev);
2264                         }
2265                 }
2266
2267 #studly caps, commented out until figure out how to distinguish between use of existing and adding new
2268 #               if (($line=~/[\w_][a-z\d]+[A-Z]/) and !($line=~/print/)) {
2269 #                   print "No studly caps, use _\n";
2270 #                   print "$herecurr";
2271 #                   $clean = 0;
2272 #               }
2273
2274 #no spaces allowed after \ in define
2275                 if ($line=~/\#\s*define.*\\\s$/) {
2276                         WARN("Whitepspace after \\ makes next lines useless\n" . $herecurr);
2277                 }
2278
2279 #warn if <asm/foo.h> is #included and <linux/foo.h> is available (uses RAW line)
2280                 if ($tree && $rawline =~ m{^.\s*\#\s*include\s*\<asm\/(.*)\.h\>}) {
2281                         my $file = "$1.h";
2282                         my $checkfile = "include/linux/$file";
2283                         if (-f "$root/$checkfile" &&
2284                             $realfile ne $checkfile &&
2285                             $1 ne 'irq')
2286                         {
2287                                 if ($realfile =~ m{^arch/}) {
2288                                         CHK("Consider using #include <linux/$file> instead of <asm/$file>\n" . $herecurr);
2289                                 } else {
2290                                         WARN("Use #include <linux/$file> instead of <asm/$file>\n" . $herecurr);
2291                                 }
2292                         }
2293                 }
2294
2295 # multi-statement macros should be enclosed in a do while loop, grab the
2296 # first statement and ensure its the whole macro if its not enclosed
2297 # in a known good container
2298                 if ($realfile !~ m@/vmlinux.lds.h$@ &&
2299                     $line =~ /^.\s*\#\s*define\s*$Ident(\()?/) {
2300                         my $ln = $linenr;
2301                         my $cnt = $realcnt;
2302                         my ($off, $dstat, $dcond, $rest);
2303                         my $ctx = '';
2304
2305                         my $args = defined($1);
2306
2307                         # Find the end of the macro and limit our statement
2308                         # search to that.
2309                         while ($cnt > 0 && defined $lines[$ln - 1] &&
2310                                 $lines[$ln - 1] =~ /^(?:-|..*\\$)/)
2311                         {
2312                                 $ctx .= $rawlines[$ln - 1] . "\n";
2313                                 $cnt-- if ($lines[$ln - 1] !~ /^-/);
2314                                 $ln++;
2315                         }
2316                         $ctx .= $rawlines[$ln - 1];
2317
2318                         ($dstat, $dcond, $ln, $cnt, $off) =
2319                                 ctx_statement_block($linenr, $ln - $linenr + 1, 0);
2320                         #print "dstat<$dstat> dcond<$dcond> cnt<$cnt> off<$off>\n";
2321                         #print "LINE<$lines[$ln-1]> len<" . length($lines[$ln-1]) . "\n";
2322
2323                         # Extract the remainder of the define (if any) and
2324                         # rip off surrounding spaces, and trailing \'s.
2325                         $rest = '';
2326                         while ($off != 0 || ($cnt > 0 && $rest =~ /\\\s*$/)) {
2327                                 #print "ADDING cnt<$cnt> $off <" . substr($lines[$ln - 1], $off) . "> rest<$rest>\n";
2328                                 if ($off != 0 || $lines[$ln - 1] !~ /^-/) {
2329                                         $rest .= substr($lines[$ln - 1], $off) . "\n";
2330                                         $cnt--;
2331                                 }
2332                                 $ln++;
2333                                 $off = 0;
2334                         }
2335                         $rest =~ s/\\\n.//g;
2336                         $rest =~ s/^\s*//s;
2337                         $rest =~ s/\s*$//s;
2338
2339                         # Clean up the original statement.
2340                         if ($args) {
2341                                 substr($dstat, 0, length($dcond), '');
2342                         } else {
2343                                 $dstat =~ s/^.\s*\#\s*define\s+$Ident\s*//;
2344                         }
2345                         $dstat =~ s/$;//g;
2346                         $dstat =~ s/\\\n.//g;
2347                         $dstat =~ s/^\s*//s;
2348                         $dstat =~ s/\s*$//s;
2349
2350                         # Flatten any parentheses and braces
2351                         while ($dstat =~ s/\([^\(\)]*\)/1/ ||
2352                                $dstat =~ s/\{[^\{\}]*\}/1/ ||
2353                                $dstat =~ s/\[[^\{\}]*\]/1/)
2354                         {
2355                         }
2356
2357                         my $exceptions = qr{
2358                                 $Declare|
2359                                 module_param_named|
2360                                 MODULE_PARAM_DESC|
2361                                 DECLARE_PER_CPU|
2362                                 DEFINE_PER_CPU|
2363                                 __typeof__\(|
2364                                 union|
2365                                 struct|
2366                                 \.$Ident\s*=\s*|
2367                                 ^\"|\"$
2368                         }x;
2369                         #print "REST<$rest> dstat<$dstat>\n";
2370                         if ($rest ne '') {
2371                                 if ($rest !~ /while\s*\(/ &&
2372                                     $dstat !~ /$exceptions/)
2373                                 {
2374                                         ERROR("Macros with multiple statements should be enclosed in a do - while loop\n" . "$here\n$ctx\n");
2375                                 }
2376
2377                         } elsif ($ctx !~ /;/) {
2378                                 if ($dstat ne '' &&
2379                                     $dstat !~ /^(?:$Ident|-?$Constant)$/ &&
2380                                     $dstat !~ /$exceptions/ &&
2381                                     $dstat !~ /^\.$Ident\s*=/ &&
2382                                     $dstat =~ /$Operators/)
2383                                 {
2384                                         ERROR("Macros with complex values should be enclosed in parenthesis\n" . "$here\n$ctx\n");
2385                                 }
2386                         }
2387                 }
2388
2389 # make sure symbols are always wrapped with VMLINUX_SYMBOL() ...
2390 # all assignments may have only one of the following with an assignment:
2391 #       .
2392 #       ALIGN(...)
2393 #       VMLINUX_SYMBOL(...)
2394                 if ($realfile eq 'vmlinux.lds.h' && $line =~ /(?:(?:^|\s)$Ident\s*=|=\s*$Ident(?:\s|$))/) {
2395                         WARN("vmlinux.lds.h needs VMLINUX_SYMBOL() around C-visible symbols\n" . $herecurr);
2396                 }
2397
2398 # check for redundant bracing round if etc
2399                 if ($line =~ /(^.*)\bif\b/ && $1 !~ /else\s*$/) {
2400                         my ($level, $endln, @chunks) =
2401                                 ctx_statement_full($linenr, $realcnt, 1);
2402                         #print "chunks<$#chunks> linenr<$linenr> endln<$endln> level<$level>\n";
2403                         #print "APW: <<$chunks[1][0]>><<$chunks[1][1]>>\n";
2404                         if ($#chunks > 0 && $level == 0) {
2405                                 my $allowed = 0;
2406                                 my $seen = 0;
2407                                 my $herectx = $here . "\n";
2408                                 my $ln = $linenr - 1;
2409                                 for my $chunk (@chunks) {
2410                                         my ($cond, $block) = @{$chunk};
2411
2412                                         # If the condition carries leading newlines, then count those as offsets.
2413                                         my ($whitespace) = ($cond =~ /^((?:\s*\n[+-])*\s*)/s);
2414                                         my $offset = statement_rawlines($whitespace) - 1;
2415
2416                                         #print "COND<$cond> whitespace<$whitespace> offset<$offset>\n";
2417
2418                                         # We have looked at and allowed this specific line.
2419                                         $suppress_ifbraces{$ln + $offset} = 1;
2420
2421                                         $herectx .= "$rawlines[$ln + $offset]\n[...]\n";
2422                                         $ln += statement_rawlines($block) - 1;
2423
2424                                         substr($block, 0, length($cond), '');
2425
2426                                         $seen++ if ($block =~ /^\s*{/);
2427
2428                                         #print "cond<$cond> block<$block> allowed<$allowed>\n";
2429                                         if (statement_lines($cond) > 1) {
2430                                                 #print "APW: ALLOWED: cond<$cond>\n";
2431                                                 $allowed = 1;
2432                                         }
2433                                         if ($block =~/\b(?:if|for|while)\b/) {
2434                                                 #print "APW: ALLOWED: block<$block>\n";
2435                                                 $allowed = 1;
2436                                         }
2437                                         if (statement_block_size($block) > 1) {
2438                                                 #print "APW: ALLOWED: lines block<$block>\n";
2439                                                 $allowed = 1;
2440                                         }
2441                                 }
2442                                 if ($seen && !$allowed) {
2443                                         WARN("braces {} are not necessary for any arm of this statement\n" . $herectx);
2444                                 }
2445                         }
2446                 }
2447                 if (!defined $suppress_ifbraces{$linenr - 1} &&
2448                                         $line =~ /\b(if|while|for|else)\b/) {
2449                         my $allowed = 0;
2450
2451                         # Check the pre-context.
2452                         if (substr($line, 0, $-[0]) =~ /(\}\s*)$/) {
2453                                 #print "APW: ALLOWED: pre<$1>\n";
2454                                 $allowed = 1;
2455                         }
2456
2457                         my ($level, $endln, @chunks) =
2458                                 ctx_statement_full($linenr, $realcnt, $-[0]);
2459
2460                         # Check the condition.
2461                         my ($cond, $block) = @{$chunks[0]};
2462                         #print "CHECKING<$linenr> cond<$cond> block<$block>\n";
2463                         if (defined $cond) {
2464                                 substr($block, 0, length($cond), '');
2465                         }
2466                         if (statement_lines($cond) > 1) {
2467                                 #print "APW: ALLOWED: cond<$cond>\n";
2468                                 $allowed = 1;
2469                         }
2470                         if ($block =~/\b(?:if|for|while)\b/) {
2471                                 #print "APW: ALLOWED: block<$block>\n";
2472                                 $allowed = 1;
2473                         }
2474                         if (statement_block_size($block) > 1) {
2475                                 #print "APW: ALLOWED: lines block<$block>\n";
2476                                 $allowed = 1;
2477                         }
2478                         # Check the post-context.
2479                         if (defined $chunks[1]) {
2480                                 my ($cond, $block) = @{$chunks[1]};
2481                                 if (defined $cond) {
2482                                         substr($block, 0, length($cond), '');
2483                                 }
2484                                 if ($block =~ /^\s*\{/) {
2485                                         #print "APW: ALLOWED: chunk-1 block<$block>\n";
2486                                         $allowed = 1;
2487                                 }
2488                         }
2489                         if ($level == 0 && $block =~ /^\s*\{/ && !$allowed) {
2490                                 my $herectx = $here . "\n";;
2491                                 my $cnt = statement_rawlines($block);
2492
2493                                 for (my $n = 0; $n < $cnt; $n++) {
2494                                         $herectx .= raw_line($linenr, $n) . "\n";;
2495                                 }
2496
2497                                 WARN("braces {} are not necessary for single statement blocks\n" . $herectx);
2498                         }
2499                 }
2500
2501 # don't include deprecated include files (uses RAW line)
2502                 for my $inc (@dep_includes) {
2503                         if ($rawline =~ m@^.\s*\#\s*include\s*\<$inc>@) {
2504                                 ERROR("Don't use <$inc>: see Documentation/feature-removal-schedule.txt\n" . $herecurr);
2505                         }
2506                 }
2507
2508 # don't use deprecated functions
2509                 for my $func (@dep_functions) {
2510                         if ($line =~ /\b$func\b/) {
2511                                 ERROR("Don't use $func(): see Documentation/feature-removal-schedule.txt\n" . $herecurr);
2512                         }
2513                 }
2514
2515 # no volatiles please
2516                 my $asm_volatile = qr{\b(__asm__|asm)\s+(__volatile__|volatile)\b};
2517                 if ($line =~ /\bvolatile\b/ && $line !~ /$asm_volatile/) {
2518                         WARN("Use of volatile is usually wrong: see Documentation/volatile-considered-harmful.txt\n" . $herecurr);
2519                 }
2520
2521 # SPIN_LOCK_UNLOCKED & RW_LOCK_UNLOCKED are deprecated
2522                 if ($line =~ /\b(SPIN_LOCK_UNLOCKED|RW_LOCK_UNLOCKED)/) {
2523                         ERROR("Use of $1 is deprecated: see Documentation/spinlocks.txt\n" . $herecurr);
2524                 }
2525
2526 # warn about #if 0
2527                 if ($line =~ /^.\s*\#\s*if\s+0\b/) {
2528                         CHK("if this code is redundant consider removing it\n" .
2529                                 $herecurr);
2530                 }
2531
2532 # check for needless kfree() checks
2533                 if ($prevline =~ /\bif\s*\(([^\)]*)\)/) {
2534                         my $expr = $1;
2535                         if ($line =~ /\bkfree\(\Q$expr\E\);/) {
2536                                 WARN("kfree(NULL) is safe this check is probably not required\n" . $hereprev);
2537                         }
2538                 }
2539 # check for needless usb_free_urb() checks
2540                 if ($prevline =~ /\bif\s*\(([^\)]*)\)/) {
2541                         my $expr = $1;
2542                         if ($line =~ /\busb_free_urb\(\Q$expr\E\);/) {
2543                                 WARN("usb_free_urb(NULL) is safe this check is probably not required\n" . $hereprev);
2544                         }
2545                 }
2546
2547 # warn about #ifdefs in C files
2548 #               if ($line =~ /^.\s*\#\s*if(|n)def/ && ($realfile =~ /\.c$/)) {
2549 #                       print "#ifdef in C files should be avoided\n";
2550 #                       print "$herecurr";
2551 #                       $clean = 0;
2552 #               }
2553
2554 # warn about spacing in #ifdefs
2555                 if ($line =~ /^.\s*\#\s*(ifdef|ifndef|elif)\s\s+/) {
2556                         ERROR("exactly one space required after that #$1\n" . $herecurr);
2557                 }
2558
2559 # check for spinlock_t definitions without a comment.
2560                 if ($line =~ /^.\s*(struct\s+mutex|spinlock_t)\s+\S+;/ ||
2561                     $line =~ /^.\s*(DEFINE_MUTEX)\s*\(/) {
2562                         my $which = $1;
2563                         if (!ctx_has_comment($first_line, $linenr)) {
2564                                 CHK("$1 definition without comment\n" . $herecurr);
2565                         }
2566                 }
2567 # check for memory barriers without a comment.
2568                 if ($line =~ /\b(mb|rmb|wmb|read_barrier_depends|smp_mb|smp_rmb|smp_wmb|smp_read_barrier_depends)\(/) {
2569                         if (!ctx_has_comment($first_line, $linenr)) {
2570                                 CHK("memory barrier without comment\n" . $herecurr);
2571                         }
2572                 }
2573 # check of hardware specific defines
2574                 if ($line =~ m@^.\s*\#\s*if.*\b(__i386__|__powerpc64__|__sun__|__s390x__)\b@ && $realfile !~ m@include/asm-@) {
2575                         CHK("architecture specific defines should be avoided\n" .  $herecurr);
2576                 }
2577
2578 # check the location of the inline attribute, that it is between
2579 # storage class and type.
2580                 if ($line =~ /\b$Type\s+$Inline\b/ ||
2581                     $line =~ /\b$Inline\s+$Storage\b/) {
2582                         ERROR("inline keyword should sit between storage class and type\n" . $herecurr);
2583                 }
2584
2585 # Check for __inline__ and __inline, prefer inline
2586                 if ($line =~ /\b(__inline__|__inline)\b/) {
2587                         WARN("plain inline is preferred over $1\n" . $herecurr);
2588                 }
2589
2590 # check for sizeof(&)
2591                 if ($line =~ /\bsizeof\s*\(\s*\&/) {
2592                         WARN("sizeof(& should be avoided\n" . $herecurr);
2593                 }
2594
2595 # check for new externs in .c files.
2596                 if ($realfile =~ /\.c$/ && defined $stat &&
2597                     $stat =~ /^.\s*(?:extern\s+)?$Type\s+($Ident)(\s*)\(/s)
2598                 {
2599                         my $function_name = $1;
2600                         my $paren_space = $2;
2601
2602                         my $s = $stat;
2603                         if (defined $cond) {
2604                                 substr($s, 0, length($cond), '');
2605                         }
2606                         if ($s =~ /^\s*;/ &&
2607                             $function_name ne 'uninitialized_var')
2608                         {
2609                                 WARN("externs should be avoided in .c files\n" .  $herecurr);
2610                         }
2611
2612                         if ($paren_space =~ /\n/) {
2613                                 WARN("arguments for function declarations should follow identifier\n" . $herecurr);
2614                         }
2615
2616                 } elsif ($realfile =~ /\.c$/ && defined $stat &&
2617                     $stat =~ /^.\s*extern\s+/)
2618                 {
2619                         WARN("externs should be avoided in .c files\n" .  $herecurr);
2620                 }
2621
2622 # checks for new __setup's
2623                 if ($rawline =~ /\b__setup\("([^"]*)"/) {
2624                         my $name = $1;
2625
2626                         if (!grep(/$name/, @setup_docs)) {
2627                                 CHK("__setup appears un-documented -- check Documentation/kernel-parameters.txt\n" . $herecurr);
2628                         }
2629                 }
2630
2631 # check for pointless casting of kmalloc return
2632                 if ($line =~ /\*\s*\)\s*k[czm]alloc\b/) {
2633                         WARN("unnecessary cast may hide bugs, see http://c-faq.com/malloc/mallocnocast.html\n" . $herecurr);
2634                 }
2635
2636 # check for gcc specific __FUNCTION__
2637                 if ($line =~ /__FUNCTION__/) {
2638                         WARN("__func__ should be used instead of gcc specific __FUNCTION__\n"  . $herecurr);
2639                 }
2640
2641 # check for semaphores used as mutexes
2642                 if ($line =~ /^.\s*(DECLARE_MUTEX|init_MUTEX)\s*\(/) {
2643                         WARN("mutexes are preferred for single holder semaphores\n" . $herecurr);
2644                 }
2645 # check for semaphores used as mutexes
2646                 if ($line =~ /^.\s*init_MUTEX_LOCKED\s*\(/) {
2647                         WARN("consider using a completion\n" . $herecurr);
2648                 }
2649 # recommend strict_strto* over simple_strto*
2650                 if ($line =~ /\bsimple_(strto.*?)\s*\(/) {
2651                         WARN("consider using strict_$1 in preference to simple_$1\n" . $herecurr);
2652                 }
2653 # check for __initcall(), use device_initcall() explicitly please
2654                 if ($line =~ /^.\s*__initcall\s*\(/) {
2655                         WARN("please use device_initcall() instead of __initcall()\n" . $herecurr);
2656                 }
2657 # check for various ops structs, ensure they are const.
2658                 my $struct_ops = qr{acpi_dock_ops|
2659                                 address_space_operations|
2660                                 backlight_ops|
2661                                 block_device_operations|
2662                                 dentry_operations|
2663                                 dev_pm_ops|
2664                                 dma_map_ops|
2665                                 extent_io_ops|
2666                                 file_lock_operations|
2667                                 file_operations|
2668                                 hv_ops|
2669                                 ide_dma_ops|
2670                                 intel_dvo_dev_ops|
2671                                 item_operations|
2672                                 iwl_ops|
2673                                 kgdb_arch|
2674                                 kgdb_io|
2675                                 kset_uevent_ops|
2676                                 lock_manager_operations|
2677                                 microcode_ops|
2678                                 mtrr_ops|
2679                                 neigh_ops|
2680                                 nlmsvc_binding|
2681                                 pci_raw_ops|
2682                                 pipe_buf_operations|
2683                                 platform_hibernation_ops|
2684                                 platform_suspend_ops|
2685                                 proto_ops|
2686                                 rpc_pipe_ops|
2687                                 seq_operations|
2688                                 snd_ac97_build_ops|
2689                                 soc_pcmcia_socket_ops|
2690                                 stacktrace_ops|
2691                                 sysfs_ops|
2692                                 tty_operations|
2693                                 usb_mon_operations|
2694                                 wd_ops}x;
2695                 if ($line !~ /\bconst\b/ &&
2696                     $line =~ /\bstruct\s+($struct_ops)\b/) {
2697                         WARN("struct $1 should normally be const\n" .
2698                                 $herecurr);
2699                 }
2700
2701 # use of NR_CPUS is usually wrong
2702 # ignore definitions of NR_CPUS and usage to define arrays as likely right
2703                 if ($line =~ /\bNR_CPUS\b/ &&
2704                     $line !~ /^.\s*\s*#\s*if\b.*\bNR_CPUS\b/ &&
2705                     $line !~ /^.\s*\s*#\s*define\b.*\bNR_CPUS\b/ &&
2706                     $line !~ /^.\s*$Declare\s.*\[[^\]]*NR_CPUS[^\]]*\]/ &&
2707                     $line !~ /\[[^\]]*\.\.\.[^\]]*NR_CPUS[^\]]*\]/ &&
2708                     $line !~ /\[[^\]]*NR_CPUS[^\]]*\.\.\.[^\]]*\]/)
2709                 {
2710                         WARN("usage of NR_CPUS is often wrong - consider using cpu_possible(), num_possible_cpus(), for_each_possible_cpu(), etc\n" . $herecurr);
2711                 }
2712
2713 # check for %L{u,d,i} in strings
2714                 my $string;
2715                 while ($line =~ /(?:^|")([X\t]*)(?:"|$)/g) {
2716                         $string = substr($rawline, $-[1], $+[1] - $-[1]);
2717                         $string =~ s/%%/__/g;
2718                         if ($string =~ /(?<!%)%L[udi]/) {
2719                                 WARN("\%Ld/%Lu are not-standard C, use %lld/%llu\n" . $herecurr);
2720                                 last;
2721                         }
2722                 }
2723
2724 # whine mightly about in_atomic
2725                 if ($line =~ /\bin_atomic\s*\(/) {
2726                         if ($realfile =~ m@^drivers/@) {
2727                                 ERROR("do not use in_atomic in drivers\n" . $herecurr);
2728                         } elsif ($realfile !~ m@^kernel/@) {
2729                                 WARN("use of in_atomic() is incorrect outside core kernel code\n" . $herecurr);
2730                         }
2731                 }
2732         }
2733
2734         # If we have no input at all, then there is nothing to report on
2735         # so just keep quiet.
2736         if ($#rawlines == -1) {
2737                 exit(0);
2738         }
2739
2740         # In mailback mode only produce a report in the negative, for
2741         # things that appear to be patches.
2742         if ($mailback && ($clean == 1 || !$is_patch)) {
2743                 exit(0);
2744         }
2745
2746         # This is not a patch, and we are are in 'no-patch' mode so
2747         # just keep quiet.
2748         if (!$chk_patch && !$is_patch) {
2749                 exit(0);
2750         }
2751
2752         if (!$is_patch) {
2753                 ERROR("Does not appear to be a unified-diff format patch\n");
2754         }
2755         if ($is_patch && $chk_signoff && $signoff == 0) {
2756                 ERROR("Missing Signed-off-by: line(s)\n");
2757         }
2758
2759         print report_dump();
2760         if ($summary && !($clean == 1 && $quiet == 1)) {
2761                 print "$filename " if ($summary_file);
2762                 print "total: $cnt_error errors, $cnt_warn warnings, " .
2763                         (($check)? "$cnt_chk checks, " : "") .
2764                         "$cnt_lines lines checked\n";
2765                 print "\n" if ($quiet == 0);
2766         }
2767
2768         if ($clean == 1 && $quiet == 0) {
2769                 print "$vname has no obvious style problems and is ready for submission.\n"
2770         }
2771         if ($clean == 0 && $quiet == 0) {
2772                 print "$vname has style problems, please review.  If any of these errors\n";
2773                 print "are false positives report them to the maintainer, see\n";
2774                 print "CHECKPATCH in MAINTAINERS.\n";
2775         }
2776
2777         return $clean;
2778 }