tools/perf/util/parse-events.l

   1
   2 %option prefix="parse_events_"
   3
   4 %{
   5 #include <errno.h>
   6 #include "../perf.h"
   7 #include "parse-events-bison.h"
   8 #include "parse-events.h"
   9
  10 static int __value(char *str, int base, int token)
  11 {
  12         long num;
  13
  14         errno = 0;
  15         num = strtoul(str, NULL, base);
  16         if (errno)
  17                 return PE_ERROR;
  18
  19         parse_events_lval.num = num;
  20         return token;
  21 }
  22
  23 static int value(int base)
  24 {
  25         return __value(parse_events_text, base, PE_VALUE);
  26 }
  27
  28 static int raw(void)
  29 {
  30         return __value(parse_events_text + 1, 16, PE_RAW);
  31 }
  32
  33 static int str(int token)
  34 {
  35         parse_events_lval.str = strdup(parse_events_text);
  36         return token;
  37 }
  38
  39 static int sym(int type, int config)
  40 {
  41         parse_events_lval.num = (type << 16) + config;
  42         return PE_VALUE_SYM;
  43 }
  44
  45 static int term(int type)
  46 {
  47         parse_events_lval.num = type;
  48         return PE_TERM;
  49 }
  50
  51 %}
  52
  53 num_dec         [0-9]+
  54 num_hex         0x[a-fA-F0-9]+
  55 num_raw_hex     [a-fA-F0-9]+
  56 name            [a-zA-Z_*?][a-zA-Z0-9_*?]*
  57 modifier_event  [ukhp]{1,5}
  58 modifier_bp     [rwx]
  59
  60 %%
  61 cpu-cycles|cycles                               { return sym(PERF_TYPE_HARDWARE, PERF_COUNT_HW_CPU_CYCLES); }
  62 stalled-cycles-frontend|idle-cycles-frontend    { return sym(PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_FRONTEND); }
  63 stalled-cycles-backend|idle-cycles-backend      { return sym(PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_BACKEND); }
  64 instructions                                    { return sym(PERF_TYPE_HARDWARE, PERF_COUNT_HW_INSTRUCTIONS); }
  65 cache-references                                { return sym(PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_REFERENCES); }
  66 cache-misses                                    { return sym(PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_MISSES); }
  67 branch-instructions|branches                    { return sym(PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_INSTRUCTIONS); }
  68 branch-misses                                   { return sym(PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_MISSES); }
  69 bus-cycles                                      { return sym(PERF_TYPE_HARDWARE, PERF_COUNT_HW_BUS_CYCLES); }
  70 cpu-clock                                       { return sym(PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_CLOCK); }
  71 task-clock                                      { return sym(PERF_TYPE_SOFTWARE, PERF_COUNT_SW_TASK_CLOCK); }
  72 page-faults|faults                              { return sym(PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS); }
  73 minor-faults                                    { return sym(PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MIN); }
  74 major-faults                                    { return sym(PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MAJ); }
  75 context-switches|cs                             { return sym(PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CONTEXT_SWITCHES); }
  76 cpu-migrations|migrations                       { return sym(PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_MIGRATIONS); }
  77 alignment-faults                                { return sym(PERF_TYPE_SOFTWARE, PERF_COUNT_SW_ALIGNMENT_FAULTS); }
  78 emulation-faults                                { return sym(PERF_TYPE_SOFTWARE, PERF_COUNT_SW_EMULATION_FAULTS); }
  79
  80 L1-dcache|l1-d|l1d|L1-data              |
  81 L1-icache|l1-i|l1i|L1-instruction       |
  82 LLC|L2                                  |
  83 dTLB|d-tlb|Data-TLB                     |
  84 iTLB|i-tlb|Instruction-TLB              |
  85 branch|branches|bpu|btb|bpc             |
  86 node                                    { return str(PE_NAME_CACHE_TYPE); }
  87
  88 load|loads|read                         |
  89 store|stores|write                      |
  90 prefetch|prefetches                     |
  91 speculative-read|speculative-load       |
  92 refs|Reference|ops|access               |
  93 misses|miss                             { return str(PE_NAME_CACHE_OP_RESULT); }
  94
  95         /*
  96          * These are event config hardcoded term names to be specified
  97          * within xxx/.../ syntax. So far we dont clash with other names,
  98          * so we can put them here directly. In case the we have a conflict
  99          * in future, this needs to go into '//' condition block.
 100          */
 101 config                  { return term(PARSE_EVENTS__TERM_TYPE_CONFIG); }
 102 config1                 { return term(PARSE_EVENTS__TERM_TYPE_CONFIG1); }
 103 config2                 { return term(PARSE_EVENTS__TERM_TYPE_CONFIG2); }
 104 period                  { return term(PARSE_EVENTS__TERM_TYPE_SAMPLE_PERIOD); }
 105 branch_type             { return term(PARSE_EVENTS__TERM_TYPE_BRANCH_SAMPLE_TYPE); }
 106
 107 mem:                    { return PE_PREFIX_MEM; }
 108 r{num_raw_hex}          { return raw(); }
 109 {num_dec}               { return value(10); }
 110 {num_hex}               { return value(16); }
 111
 112 {modifier_event}        { return str(PE_MODIFIER_EVENT); }
 113 {modifier_bp}           { return str(PE_MODIFIER_BP); }
 114 {name}                  { return str(PE_NAME); }
 115 "/"                     { return '/'; }
 116 -                       { return '-'; }
 117 ,                       { return ','; }
 118 :                       { return ':'; }
 119 =                       { return '='; }
 120
 121 %%
 122
 123 int parse_events_wrap(void)
 124 {
 125         return 1;
 126 }