aclocal.m4

   1 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
   2 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
   3 dnl also defines GSTUFF_PKG_ERRORS on error
   4 AC_DEFUN(PKG_CHECK_MODULES, [
   5   succeeded=no
   6
   7   if test -z "$PKG_CONFIG"; then
   8     AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
   9   fi
  10
  11   if test "$PKG_CONFIG" = "no" ; then
  12      echo "*** The pkg-config script could not be found. Make sure it is"
  13      echo "*** in your path, or set the PKG_CONFIG environment variable"
  14      echo "*** to the full path to pkg-config."
  15      echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
  16   else
  17      PKG_CONFIG_MIN_VERSION=0.9.0
  18      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
  19         AC_MSG_CHECKING(for $2)
  20
  21         if $PKG_CONFIG --exists "$2" ; then
  22             AC_MSG_RESULT(yes)
  23             succeeded=yes
  24
  25             AC_MSG_CHECKING($1_CFLAGS)
  26             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
  27             AC_MSG_RESULT($$1_CFLAGS)
  28
  29             AC_MSG_CHECKING($1_LIBS)
  30             $1_LIBS=`$PKG_CONFIG --libs "$2"`
  31             AC_MSG_RESULT($$1_LIBS)
  32         else
  33             $1_CFLAGS=""
  34             $1_LIBS=""
  35             ## If we have a custom action on failure, don't print errors, but
  36             ## do set a variable so people can do so.
  37             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
  38             ifelse([$4], ,echo $$1_PKG_ERRORS,)
  39         fi
  40
  41         AC_SUBST($1_CFLAGS)
  42         AC_SUBST($1_LIBS)
  43      else
  44         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
  45         echo "*** See http://www.freedesktop.org/software/pkgconfig"
  46      fi
  47   fi
  48
  49   if test $succeeded = yes; then
  50      ifelse([$3], , :, [$3])
  51   else
  52      ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
  53   fi
  54 ])
  55
  56