packages/hal/synth/arch/v2_0/src/synth.ld

   1 //==========================================================================
   2 //
   3 //      synth.ld
   4 //
   5 //      Linker script for the synthetic target
   6 //
   7 //==========================================================================
   8 //####ECOSGPLCOPYRIGHTBEGIN####
   9 // -------------------------------------------
  10 // This file is part of eCos, the Embedded Configurable Operating System.
  11 // Copyright (C) 1998, 1999, 2000, 2001, 2002 Red Hat, Inc.
  12 //
  13 // eCos is free software; you can redistribute it and/or modify it under
  14 // the terms of the GNU General Public License as published by the Free
  15 // Software Foundation; either version 2 or (at your option) any later version.
  16 //
  17 // eCos is distributed in the hope that it will be useful, but WITHOUT ANY
  18 // WARRANTY; without even the implied warranty of MERCHANTABILITY or
  19 // FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  20 // for more details.
  21 //
  22 // You should have received a copy of the GNU General Public License along
  23 // with eCos; if not, write to the Free Software Foundation, Inc.,
  24 // 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  25 //
  26 // As a special exception, if other files instantiate templates or use macros
  27 // or inline functions from this file, or you compile this file and link it
  28 // with other works to produce a work based on this file, this file does not
  29 // by itself cause the resulting work to be covered by the GNU General Public
  30 // License. However the source code for this file must still be made available
  31 // in accordance with section (3) of the GNU General Public License.
  32 //
  33 // This exception does not invalidate any other reasons why a work based on
  34 // this file might be covered by the GNU General Public License.
  35 //
  36 // Alternative licenses for eCos may be arranged by contacting Red Hat, Inc.
  37 // at http://sources.redhat.com/ecos/ecos-license/
  38 // -------------------------------------------
  39 //####ECOSGPLCOPYRIGHTEND####
  40 //==========================================================================
  41 //#####DESCRIPTIONBEGIN####
  42 //
  43 // Author(s):   jskov
  44 // Contributors:jskov, bartv
  45 // Date:        1999-01-18
  46 // Purpose:     synthetic target linker script
  47 //
  48 //####DESCRIPTIONEND####
  49 //
  50 //==========================================================================
  51 STARTUP(vectors.o)
  52 ENTRY(_start)
  53 #ifdef EXTRAS
  54 INPUT(extras.o)
  55 #endif
  56 #if (__GNUC__ >= 3)
  57 GROUP(libtarget.a libgcc.a libsupc++.a libgcc_eh.a)
  58 #else
  59 GROUP(libtarget.a libgcc.a)
  60 #endif
  61
  62 #define ALIGN_LMA 8
  63 #define FOLLOWING(_section_) AT ((LOADADDR (_section_) + SIZEOF (_section_) + ALIGN_LMA - 1) & ~ (ALIGN_LMA - 1))
  64 #define LMA_EQ_VMA
  65 #define FORCE_OUTPUT . = .
  66
  67
  68 #define SECTIONS_BEGIN
  69
  70 #define SECTION_vectors(_region_, _vma_, _lma_)         \
  71   .vectors _vma_ : _lma_                                \
  72   { FORCE_OUTPUT; KEEP(*(.vectors)) }                   \
  73   > _region_
  74
  75 #define SECTION_text(_region_, _vma_, _lma_)                    \
  76   .text _vma_ : _lma_                                           \
  77   { _stext = .;                                                 \
  78     *(.text*) *(.gnu.warning) *(.gnu.linkonce.t.*) *(.init) }   \
  79   > _region_                                                    \
  80   _etext = .;  PROVIDE (etext = .);
  81
  82 #define SECTION_fini(_region_, _vma_, _lma_)                    \
  83     .fini _vma_ : _lma_                                         \
  84     { FORCE_OUTPUT; *(.fini) }                                  \
  85     > _region_
  86
  87 #define SECTION_rodata1(_region_, _vma_, _lma_)                 \
  88     .rodata1 _vma_ : _lma_                                      \
  89     { FORCE_OUTPUT; *(.rodata1) }                               \
  90     > _region_
  91
  92 #define SECTION_rodata(_region_, _vma_, _lma_)                  \
  93     .rodata _vma_ : _lma_                                       \
  94     { FORCE_OUTPUT; *(.rodata*) *(.gnu.linkonce.r.*) }          \
  95     > _region_
  96
  97 #define SECTION_fixup(_region_, _vma_, _lma_)                                   \
  98     .fixup _vma_ : _lma_                                                        \
  99     { _FIXUP_START_ = ABSOLUTE(.); *(.fixup) _FIXUP_END_ = ABSOLUTE(.);}        \
 100     > _region_
 101
 102 #define SECTION_gcc_except_table(_region_, _vma_, _lma_)                        \
 103     .gcc_except_table _vma_ : _lma_                                             \
 104     { _EXCEPT_START_ = ABSOLUTE(.); *(.gcc_except_table)                        \
 105       _EXCEPT_END_ = ABSOLUTE(.);}                                              \
 106     > _region_
 107
 108 #define SECTION_eh_frame(_region_, _vma_, _lma_)      \
 109   .eh_frame _vma_ : _lma_                             \
 110     {                                                 \
 111        FORCE_OUTPUT;  __EH_FRAME_BEGIN__ = .;         \
 112        KEEP(*(.eh_frame))                             \
 113        __FRAME_END__ = .;                             \
 114        . = . + 8;                                     \
 115     } > _region_ = 0
 116
 117 #define SECTION_RELOCS(_region_, _vma_, _lma_)                              \
 118   .rel.text      :                                                          \
 119     {                                                                       \
 120       *(.rel.text)                                                          \
 121       *(.rel.text.*)                                                        \
 122       *(.rel.gnu.linkonce.t*)                                               \
 123     } > _region_                                                            \
 124   .rela.text     :                                                          \
 125     {                                                                       \
 126       *(.rela.text)                                                         \
 127       *(.rela.text.*)                                                       \
 128       *(.rela.gnu.linkonce.t*)                                              \
 129     } > _region_                                                            \
 130   .rel.data      :                                                          \
 131     {                                                                       \
 132       *(.rel.data)                                                          \
 133       *(.rel.data.*)                                                        \
 134       *(.rel.gnu.linkonce.d*)                                               \
 135     } > _region_                                                            \
 136   .rela.data     :                                                          \
 137     {                                                                       \
 138       *(.rela.data)                                                         \
 139       *(.rela.data.*)                                                       \
 140       *(.rela.gnu.linkonce.d*)                                              \
 141     } > _region_                                                            \
 142   .rel.rodata    :                                                          \
 143     {                                                                       \
 144       *(.rel.rodata)                                                        \
 145       *(.rel.rodata.*)                                                      \
 146       *(.rel.gnu.linkonce.r*)                                               \
 147     } > _region_                                                            \
 148   .rela.rodata   :                                                          \
 149     {                                                                       \
 150       *(.rela.rodata)                                                       \
 151       *(.rela.rodata.*)                                                     \
 152       *(.rela.gnu.linkonce.r*)                                              \
 153     } > _region_                                                            \
 154   .rel.got       :   { *(.rel.got)    } > _region_                          \
 155   .rela.got      :   { *(.rela.got)   } > _region_                          \
 156   .rel.ctors     :   { *(.rel.ctors)  } > _region_                          \
 157   .rela.ctors    :   { *(.rela.ctors) } > _region_                          \
 158   .rel.dtors     :   { *(.rel.dtors)  } > _region_                          \
 159   .rela.dtors    :   { *(.rela.dtors) } > _region_                          \
 160   .rel.init      :   { *(.rel.init)   } > _region_                          \
 161   .rela.init     :   { *(.rela.init)  } > _region_                          \
 162   .rel.fini      :   { *(.rel.fini)   } > _region_                          \
 163   .rela.fini     :   { *(.rela.fini)  } > _region_                          \
 164   .rel.bss       :   { *(.rel.bss)    } > _region_                          \
 165   .rela.bss      :   { *(.rela.bss)   } > _region_                          \
 166   .rel.plt       :   { *(.rel.plt)    } > _region_                          \
 167   .rela.plt      :   { *(.rela.plt)   } > _region_                          \
 168   .rel.dyn       :   { *(.rel.dyn)    } > _region_
 169
 170 // Note: The __ in the name is an encoding of the .
 171 #define SECTION_rel__got(_region_, _vma_, _lma_)                                \
 172     .rel.got _vma_ : _lma_                                                      \
 173     { *(.rel.got)      }                                                        \
 174     > _region_
 175
 176 #define SECTION_data(_region_, _vma_, _lma_)                                    \
 177     .data _vma_ : _lma_                                                         \
 178     { __ram_data_start = ABSOLUTE(.); *(.data*) *(.gnu.linkonce.d.*)            \
 179     _GOT1_START_ = ABSOLUTE(.); *(.got1) _GOT1_END_ = ABSOLUTE(.);              \
 180       /* Put .ctors and .dtors next to the .got2 section, so that */            \
 181       /* the pointers get relocated with -mrelocatable.           */            \
 182      . = ALIGN(8); __CTOR_LIST__ = ABSOLUTE(.);                                 \
 183       KEEP(*(SORT(.ctors*))) __CTOR_END__ = ABSOLUTE(.);                        \
 184      __DTOR_LIST__ = ABSOLUTE(.);                                               \
 185        KEEP(*(SORT(.dtors*))) __DTOR_END__ = ABSOLUTE(.);                       \
 186     . = ALIGN(32);                                                              \
 187     KEEP(*( SORT (.ecos.table.*)));                                             \
 188     _GOT2_START_ = ABSOLUTE(.); *(.got2) _GOT2_END_ = ABSOLUTE(.);              \
 189     _GOT_START_ = ABSOLUTE(.); _GLOBAL_OFFSET_TABLE_ = ABSOLUTE(. + 32768);     \
 190     _SDA_BASE_ = ABSOLUTE(.); *(.got.plt) *(.got)                               \
 191     _GOT_END_ = ABSOLUTE(.);  *(.dynamic)                                       \
 192       /* We want the small data sections together, so single-instruction */     \
 193       /* offsets can access them all, and initialized data all before    */     \
 194       /* uninitialized, so we can shorten the on-disk segment size.      */     \
 195     _SDATA_START_ = ABSOLUTE(.); *(.sdata*) *(.gnu.linkonce.s.*) }              \
 196     > _region_                                                                  \
 197     __rom_data_start = LOADADDR(.data);                                         \
 198     __ram_data_end = .; PROVIDE(__ram_data_end = .);                            \
 199     _edata = .; PROVIDE (edata = .);
 200
 201 #define SECTION_sbss(_region_, _vma_, _lma_)                                    \
 202     .sbss _vma_ : _lma_                                                         \
 203     { __bss_start = ABSOLUTE (.);                                               \
 204     _SBSS_START_ = ABSOLUTE(.); *(.sbss*) *(.gnu.linkonce.sb.*)                 \
 205     _SBSS_END_ = ABSOLUTE(.);                                                   \
 206     *(.scommon*) }                                                              \
 207     > _region_
 208
 209 #define SECTION_bss(_region_, _vma_, _lma_)                                     \
 210     .bss _vma_ : _lma_                                                          \
 211     { FORCE_OUTPUT; *(.dynbss*) *(.bss*) *(COMMON) *(.gnu.linkonce.b.*) }       \
 212     > _region_                                                                  \
 213     __bss_end = .;
 214
 215 #define SECTIONS_END . = ALIGN(4); _end = .; PROVIDE (end = .);
 216
 217 #include <pkgconf/system.h>
 218 #include CYGHWR_MEMORY_LAYOUT_LDI