board/sbc8560/u-boot.lds

   1 /*
   2  * (C) Copyright 2002,2003,Motorola,Inc.
   3  * Xianghua Xiao, X.Xiao@motorola.com.
   4  *
   5  * (C) Copyright 2004 Wind River Systems Inc <www.windriver.com>.
   6  * Added support for Wind River SBC8560 board
   7  *
   8  * See file CREDITS for list of people who contributed to this
   9  * project.
  10  *
  11  * This program is free software; you can redistribute it and/or
  12  * modify it under the terms of the GNU General Public License as
  13  * published by the Free Software Foundation; either version 2 of
  14  * the License, or (at your option) any later version.
  15  *
  16  * This program is distributed in the hope that it will be useful,
  17  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19  * GNU General Public License for more details.
  20  *
  21  * You should have received a copy of the GNU General Public License
  22  * along with this program; if not, write to the Free Software
  23  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24  * MA 02111-1307 USA
  25  */
  26
  27 OUTPUT_ARCH(powerpc)
  28 /* Do we need any of these for elf?
  29    __DYNAMIC = 0;    */
  30 SECTIONS
  31 {
  32   .resetvec 0xFFFFFFFC :
  33   {
  34     *(.resetvec)
  35   } = 0xffff
  36
  37   .bootpg 0xFFFFF000 :
  38   {
  39     cpu/mpc85xx/start.o (.bootpg)
  40   } = 0xffff
  41
  42   /* Read-only sections, merged into text segment: */
  43   . = + SIZEOF_HEADERS;
  44   .interp : { *(.interp) }
  45   .hash          : { *(.hash)           }
  46   .dynsym        : { *(.dynsym)         }
  47   .dynstr        : { *(.dynstr)         }
  48   .rel.text      : { *(.rel.text)               }
  49   .rela.text     : { *(.rela.text)      }
  50   .rel.data      : { *(.rel.data)               }
  51   .rela.data     : { *(.rela.data)      }
  52   .rel.rodata    : { *(.rel.rodata)     }
  53   .rela.rodata   : { *(.rela.rodata)    }
  54   .rel.got       : { *(.rel.got)                }
  55   .rela.got      : { *(.rela.got)               }
  56   .rel.ctors     : { *(.rel.ctors)      }
  57   .rela.ctors    : { *(.rela.ctors)     }
  58   .rel.dtors     : { *(.rel.dtors)      }
  59   .rela.dtors    : { *(.rela.dtors)     }
  60   .rel.bss       : { *(.rel.bss)                }
  61   .rela.bss      : { *(.rela.bss)               }
  62   .rel.plt       : { *(.rel.plt)                }
  63   .rela.plt      : { *(.rela.plt)               }
  64   .init          : { *(.init)   }
  65   .plt : { *(.plt) }
  66   .text      :
  67   {
  68     cpu/mpc85xx/start.o (.text)
  69     cpu/mpc85xx/commproc.o (.text)
  70     cpu/mpc85xx/traps.o (.text)
  71     cpu/mpc85xx/interrupts.o (.text)
  72     cpu/mpc85xx/serial_scc.o (.text)
  73     cpu/mpc85xx/ether_fcc.o (.text)
  74     cpu/mpc85xx/cpu_init.o (.text)
  75     cpu/mpc85xx/cpu.o (.text)
  76     cpu/mpc85xx/speed.o (.text)
  77     common/dlmalloc.o (.text)
  78     lib_generic/crc32.o (.text)
  79     lib_ppc/extable.o (.text)
  80     lib_generic/zlib.o (.text)
  81     *(.text)
  82     *(.fixup)
  83     *(.got1)
  84    }
  85     _etext = .;
  86     PROVIDE (etext = .);
  87     .rodata    :
  88    {
  89     *(.rodata)
  90     *(.rodata1)
  91     *(.rodata.str1.4)
  92     *(.eh_frame)
  93   }
  94   .fini      : { *(.fini)    } =0
  95   .ctors     : { *(.ctors)   }
  96   .dtors     : { *(.dtors)   }
  97
  98   /* Read-write section, merged into data segment: */
  99   . = (. + 0x00FF) & 0xFFFFFF00;
 100   _erotext = .;
 101   PROVIDE (erotext = .);
 102   .reloc   :
 103   {
 104     *(.got)
 105     _GOT2_TABLE_ = .;
 106     *(.got2)
 107     _FIXUP_TABLE_ = .;
 108     *(.fixup)
 109   }
 110   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
 111   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
 112
 113   .data    :
 114   {
 115     *(.data)
 116     *(.data1)
 117     *(.sdata)
 118     *(.sdata2)
 119     *(.dynamic)
 120     CONSTRUCTORS
 121   }
 122   _edata  =  .;
 123   PROVIDE (edata = .);
 124
 125   . = .;
 126   __u_boot_cmd_start = .;
 127   .u_boot_cmd : { *(.u_boot_cmd) }
 128   __u_boot_cmd_end = .;
 129
 130   . = .;
 131   __start___ex_table = .;
 132   __ex_table : { *(__ex_table) }
 133   __stop___ex_table = .;
 134
 135   . = ALIGN(256);
 136   __init_begin = .;
 137   .text.init : { *(.text.init) }
 138   .data.init : { *(.data.init) }
 139   . = ALIGN(256);
 140   __init_end = .;
 141
 142   __bss_start = .;
 143   .bss (NOLOAD)       :
 144   {
 145    *(.sbss) *(.scommon)
 146    *(.dynbss)
 147    *(.bss)
 148    *(COMMON)
 149    . = ALIGN(4);
 150   }
 151   _end = . ;
 152   PROVIDE (end = .);
 153 }