cpu/pxa/start.S

   1 /*
   2  *  armboot - Startup Code for XScale
   3  *
   4  *  Copyright (C) 1998  Dan Malek <dmalek@jlc.net>
   5  *  Copyright (C) 1999  Magnus Damm <kieraypc01.p.y.kie.era.ericsson.se>
   6  *  Copyright (C) 2000  Wolfgang Denk <wd@denx.de>
   7  *  Copyright (C) 2001  Alex Zuepke <azu@sysgo.de>
   8  *  Copyright (C) 2002  Kyle Harris <kharris@nexus-tech.net>
   9  *  Copyright (C) 2003  Robert Schwebel <r.schwebel@pengutronix.de>
  10  *  Copyright (C) 2003  Kai-Uwe Bloem <kai-uwe.bloem@auerswald.de>
  11  *
  12  * See file CREDITS for list of people who contributed to this
  13  * project.
  14  *
  15  * This program is free software; you can redistribute it and/or
  16  * modify it under the terms of the GNU General Public License as
  17  * published by the Free Software Foundation; either version 2 of
  18  * the License, or (at your option) any later version.
  19  *
  20  * This program is distributed in the hope that it will be useful,
  21  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  22  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23  * GNU General Public License for more details.
  24  *
  25  * You should have received a copy of the GNU General Public License
  26  * along with this program; if not, write to the Free Software
  27  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  28  * MA 02111-1307 USA
  29  */
  30
  31 #include <config.h>
  32 #include <version.h>
  33 #include <asm/arch/pxa-regs.h>
  34
  35 .globl _start
  36 _start: b       reset
  37         ldr     pc, _undefined_instruction
  38         ldr     pc, _software_interrupt
  39         ldr     pc, _prefetch_abort
  40         ldr     pc, _data_abort
  41         ldr     pc, _not_used
  42         ldr     pc, _irq
  43         ldr     pc, _fiq
  44
  45 _undefined_instruction: .word undefined_instruction
  46 _software_interrupt:    .word software_interrupt
  47 _prefetch_abort:        .word prefetch_abort
  48 _data_abort:            .word data_abort
  49 _not_used:              .word not_used
  50 _irq:                   .word irq
  51 _fiq:                   .word fiq
  52
  53         .balignl 16,0xdeadbeef
  54
  55
  56 /*
  57  * Startup Code (reset vector)
  58  *
  59  * do important init only if we don't start from RAM!
  60  * - relocate armboot to ram
  61  * - setup stack
  62  * - jump to second stage
  63  */
  64
  65 _TEXT_BASE:
  66         .word   TEXT_BASE
  67
  68 .globl _armboot_start
  69 _armboot_start:
  70         .word _start
  71
  72 /*
  73  * These are defined in the board-specific linker script.
  74  */
  75 .globl _bss_start
  76 _bss_start:
  77         .word __bss_start
  78
  79 .globl _bss_end
  80 _bss_end:
  81         .word _end
  82
  83 #ifdef CONFIG_USE_IRQ
  84 /* IRQ stack memory (calculated at run-time) */
  85 .globl IRQ_STACK_START
  86 IRQ_STACK_START:
  87         .word   0x0badc0de
  88
  89 /* IRQ stack memory (calculated at run-time) */
  90 .globl FIQ_STACK_START
  91 FIQ_STACK_START:
  92         .word 0x0badc0de
  93 #endif
  94
  95
  96 /****************************************************************************/
  97 /*                                                                          */
  98 /* the actual reset code                                                    */
  99 /*                                                                          */
 100 /****************************************************************************/
 101
 102 reset:
 103         mrs     r0,cpsr                 /* set the cpu to SVC32 mode        */
 104         bic     r0,r0,#0x1f             /* (superviser mode, M=10011)       */
 105         orr     r0,r0,#0x13
 106         msr     cpsr,r0
 107
 108         /*
 109          * we do sys-critical inits only at reboot,
 110          * not when booting from ram!
 111          */
 112 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 113         bl      cpu_init_crit           /* we do sys-critical inits         */
 114 #endif
 115
 116 #ifndef CONFIG_SKIP_RELOCATE_UBOOT
 117 relocate:                               /* relocate U-Boot to RAM           */
 118         adr     r0, _start              /* r0 <- current position of code   */
 119         ldr     r1, _TEXT_BASE          /* test if we run from flash or RAM */
 120         cmp     r0, r1                  /* don't reloc during debug         */
 121         beq     stack_setup
 122
 123         ldr     r2, _armboot_start
 124         ldr     r3, _bss_start
 125         sub     r2, r3, r2              /* r2 <- size of armboot            */
 126         add     r2, r0, r2              /* r2 <- source end address         */
 127
 128 copy_loop:
 129         ldmia   r0!, {r3-r10}           /* copy from source address [r0]    */
 130         stmia   r1!, {r3-r10}           /* copy to   target address [r1]    */
 131         cmp     r0, r2                  /* until source end addreee [r2]    */
 132         ble     copy_loop
 133 #endif  /* CONFIG_SKIP_RELOCATE_UBOOT */
 134
 135         /* Set up the stack                                                 */
 136 stack_setup:
 137         ldr     r0, _TEXT_BASE          /* upper 128 KiB: relocated uboot   */
 138         sub     r0, r0, #CFG_MALLOC_LEN /* malloc area                      */
 139         sub     r0, r0, #CFG_GBL_DATA_SIZE /* bdinfo                        */
 140 #ifdef CONFIG_USE_IRQ
 141         sub     r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
 142 #endif
 143         sub     sp, r0, #12             /* leave 3 words for abort-stack    */
 144
 145 clear_bss:
 146         ldr     r0, _bss_start          /* find start of bss segment        */
 147         ldr     r1, _bss_end            /* stop here                        */
 148         mov     r2, #0x00000000         /* clear                            */
 149
 150 clbss_l:str     r2, [r0]                /* clear loop...                    */
 151         add     r0, r0, #4
 152         cmp     r0, r1
 153         ble     clbss_l
 154
 155         ldr     pc, _start_armboot
 156
 157 _start_armboot: .word start_armboot
 158
 159
 160 /****************************************************************************/
 161 /*                                                                          */
 162 /* CPU_init_critical registers                                              */
 163 /*                                                                          */
 164 /* - setup important registers                                              */
 165 /* - setup memory timing                                                    */
 166 /*                                                                          */
 167 /****************************************************************************/
 168 /* mk@tbd: Fix this! */
 169 #ifdef CONFIG_CPU_MONAHANS
 170 #undef ICMR
 171 #undef OSMR3
 172 #undef OSCR
 173 #undef OWER
 174 #undef OIER
 175 #endif
 176
 177 /* Interrupt-Controller base address                                        */
 178 IC_BASE:           .word           0x40d00000
 179 #define ICMR    0x04
 180
 181 /* Reset-Controller */
 182 RST_BASE:       .word   0x40f00030
 183 #define RCSR    0x00
 184
 185 /* Operating System Timer */
 186 OSTIMER_BASE:   .word   0x40a00000
 187 #define OSMR3   0x0C
 188 #define OSCR    0x10
 189 #define OWER    0x18
 190 #define OIER    0x1C
 191
 192 /* Clock Manager Registers                                                  */
 193 #ifdef CONFIG_CPU_MONAHANS
 194 # ifndef CFG_MONAHANS_RUN_MODE_OSC_RATIO
 195 #  error "You have to define CFG_MONAHANS_RUN_MODE_OSC_RATIO!!"
 196 # endif
 197 # ifndef CFG_MONAHANS_TURBO_RUN_MODE_RATIO
 198 #  define CFG_MONAHANS_TURBO_RUN_MODE_RATIO 0x1
 199 # endif
 200 #else /* ! CONFIG_CPU_MONAHANS */
 201 #ifdef CFG_CPUSPEED
 202 CC_BASE:        .word   0x41300000
 203 #define CCCR    0x00
 204 cpuspeed:       .word   CFG_CPUSPEED
 205 #else
 206 #error "You have to define CFG_CPUSPEED!!"
 207 #endif
 208 #endif /* CONFIG_CPU_MONAHANS */
 209
 210         /* takes care the CP15 update has taken place */
 211         .macro CPWAIT reg
 212         mrc  p15,0,\reg,c2,c0,0
 213         mov  \reg,\reg
 214         sub  pc,pc,#4
 215         .endm
 216
 217 cpu_init_crit:
 218
 219         /* mask all IRQs                                                    */
 220 #ifndef CONFIG_CPU_MONAHANS
 221         ldr     r0, IC_BASE
 222         mov     r1, #0x00
 223         str     r1, [r0, #ICMR]
 224 #else
 225         /* Step 1 - Enable CP6 permission */
 226         mrc     p15, 0, r1, c15, c1, 0  @ read CPAR
 227         orr     r1, r1, #0x40
 228                 mcr     p15, 0, r1, c15, c1, 0
 229         CPWAIT  r1
 230
 231         /* Step 2 - Mask ICMR & ICMR2 */
 232         mov     r1, #0
 233         mcr     p6, 0, r1, c1, c0, 0    @ ICMR
 234         mcr     p6, 0, r1, c7, c0, 0    @ ICMR2
 235
 236         /* turn off all clocks but the ones we will definitly require */
 237         ldr     r1, =CKENA
 238         ldr     r2, =(CKENA_22_FFUART | CKENA_10_SRAM | CKENA_9_SMC | CKENA_8_DMC)
 239         str     r2, [r1]
 240         ldr     r1, =CKENB
 241         ldr     r2, =(CKENB_6_IRQ)
 242         str     r2, [r1]
 243 #endif
 244
 245         /* set clock speed */
 246 #ifdef CONFIG_CPU_MONAHANS
 247         ldr     r0, =ACCR
 248         /* KaRo: do not clear other clock fields, otherwise boards still running in SDRAM will crash here */
 249         ldr     r2, =~(ACCR_XN_MASK | ACCR_XL_MASK)
 250         ldr     r1, [r0]
 251         and     r2, r2, r1
 252         ldr     r1, =(((CFG_MONAHANS_TURBO_RUN_MODE_RATIO<<8) & ACCR_XN_MASK) | (CFG_MONAHANS_RUN_MODE_OSC_RATIO & ACCR_XL_MASK))
 253         orr     r2, r2, r1
 254         str     r2, [r0]
 255 #else /* ! CONFIG_CPU_MONAHANS */
 256 #ifdef CFG_CPUSPEED
 257         ldr     r0, CC_BASE
 258         ldr     r1, cpuspeed
 259         str     r1, [r0, #CCCR]
 260         mov     r0, #2
 261         mcr     p14, 0, r0, c6, c0, 0
 262
 263 setspeed_done:
 264
 265 #endif /* CFG_CPUSPEED */
 266 #endif /* CONFIG_CPU_MONAHANS */
 267
 268         /*
 269          * before relocating, we have to setup RAM timing
 270          * because memory timing is board-dependend, you will
 271          * find a lowlevel_init.S in your board directory.
 272          */
 273         mov     ip,     lr
 274         bl      lowlevel_init
 275         mov     lr,     ip
 276
 277         /* Memory interfaces are working. Disable MMU and enable I-cache.   */
 278         /* mk: hmm, this is not in the monahans docs, leave it now but
 279          *     check here if it doesn't work :-) */
 280
 281         ldr     r0, =0x2001             /* enable access to all coproc.     */
 282         mcr     p15, 0, r0, c15, c1, 0
 283         CPWAIT r0
 284
 285         mcr     p15, 0, r0, c7, c10, 4  /* drain the write & fill buffers   */
 286         CPWAIT r0
 287
 288         mcr     p15, 0, r0, c7, c7, 0   /* flush Icache, Dcache and BTB     */
 289         CPWAIT r0
 290
 291         mcr     p15, 0, r0, c8, c7, 0   /* flush instuction and data TLBs   */
 292         CPWAIT r0
 293
 294         /* Enable the Icache                                                */
 295 /*
 296         mrc     p15, 0, r0, c1, c0, 0
 297         orr     r0, r0, #0x1800
 298         mcr     p15, 0, r0, c1, c0, 0
 299         CPWAIT
 300 */
 301         mov     pc, lr
 302
 303
 304 /****************************************************************************/
 305 /*                                                                          */
 306 /* Interrupt handling                                                       */
 307 /*                                                                          */
 308 /****************************************************************************/
 309
 310 /* IRQ stack frame                                                          */
 311
 312 #define S_FRAME_SIZE    72
 313
 314 #define S_OLD_R0        68
 315 #define S_PSR           64
 316 #define S_PC            60
 317 #define S_LR            56
 318 #define S_SP            52
 319
 320 #define S_IP            48
 321 #define S_FP            44
 322 #define S_R10           40
 323 #define S_R9            36
 324 #define S_R8            32
 325 #define S_R7            28
 326 #define S_R6            24
 327 #define S_R5            20
 328 #define S_R4            16
 329 #define S_R3            12
 330 #define S_R2            8
 331 #define S_R1            4
 332 #define S_R0            0
 333
 334 #define MODE_SVC 0x13
 335
 336         /* use bad_save_user_regs for abort/prefetch/undef/swi ...          */
 337
 338         .macro  bad_save_user_regs
 339         sub     sp, sp, #S_FRAME_SIZE
 340         stmia   sp, {r0 - r12}                  /* Calling r0-r12           */
 341         add     r8, sp, #S_PC
 342
 343         ldr     r2, _armboot_start
 344         sub     r2, r2, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 345         sub     r2, r2, #(CFG_GBL_DATA_SIZE+8)  @ set base 2 words into abort stack
 346         ldmia   r2, {r2 - r4}                   /* get pc, cpsr, old_r0     */
 347         add     r0, sp, #S_FRAME_SIZE           /* restore sp_SVC           */
 348
 349         add     r5, sp, #S_SP
 350         mov     r1, lr
 351         stmia   r5, {r0 - r4}                   /* save sp_SVC, lr_SVC, pc, cpsr, old_r */
 352         mov     r0, sp
 353         .endm
 354
 355
 356         /* use irq_save_user_regs / irq_restore_user_regs for                */
 357         /* IRQ/FIQ handling                                                  */
 358
 359         .macro  irq_save_user_regs
 360         sub     sp, sp, #S_FRAME_SIZE
 361         stmia   sp, {r0 - r12}                  /* Calling r0-r12            */
 362         add     r8, sp, #S_PC
 363         stmdb   r8, {sp, lr}^                   /* Calling SP, LR            */
 364         str     lr, [r8, #0]                    /* Save calling PC           */
 365         mrs     r6, spsr
 366         str     r6, [r8, #4]                    /* Save CPSR                 */
 367         str     r0, [r8, #8]                    /* Save OLD_R0               */
 368         mov     r0, sp
 369         .endm
 370
 371         .macro  irq_restore_user_regs
 372         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 373         mov     r0, r0
 374         ldr     lr, [sp, #S_PC]                 @ Get PC
 375         add     sp, sp, #S_FRAME_SIZE
 376         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 377         .endm
 378
 379         .macro get_bad_stack
 380         ldr     r13, _armboot_start             @ setup our mode stack
 381         sub     r13, r13, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 382         sub     r13, r13, #(CFG_GBL_DATA_SIZE+8) @ reserved a couple spots in abort stack
 383
 384         str     lr, [r13]                       @ save caller lr / spsr
 385         mrs     lr, spsr
 386         str     lr, [r13, #4]
 387
 388         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 389         msr     spsr_c, r13
 390         mov     lr, pc
 391         movs    pc, lr
 392         .endm
 393
 394         .macro get_irq_stack                    @ setup IRQ stack
 395         ldr     sp, IRQ_STACK_START
 396         .endm
 397
 398         .macro get_fiq_stack                    @ setup FIQ stack
 399         ldr     sp, FIQ_STACK_START
 400         .endm
 401
 402
 403 /****************************************************************************/
 404 /*                                                                          */
 405 /* exception handlers                                                       */
 406 /*                                                                          */
 407 /****************************************************************************/
 408
 409         .align  5
 410 undefined_instruction:
 411         get_bad_stack
 412         bad_save_user_regs
 413         bl      do_undefined_instruction
 414
 415         .align  5
 416 software_interrupt:
 417         get_bad_stack
 418         bad_save_user_regs
 419         bl      do_software_interrupt
 420
 421         .align  5
 422 prefetch_abort:
 423         get_bad_stack
 424         bad_save_user_regs
 425         bl      do_prefetch_abort
 426
 427         .align  5
 428 data_abort:
 429         get_bad_stack
 430         bad_save_user_regs
 431         bl      do_data_abort
 432
 433         .align  5
 434 not_used:
 435         get_bad_stack
 436         bad_save_user_regs
 437         bl      do_not_used
 438
 439 #ifdef CONFIG_USE_IRQ
 440
 441         .align  5
 442 irq:
 443         get_irq_stack
 444         irq_save_user_regs
 445         bl      do_irq
 446         irq_restore_user_regs
 447
 448         .align  5
 449 fiq:
 450         get_fiq_stack
 451         irq_save_user_regs              /* someone ought to write a more    */
 452         bl      do_fiq                  /* effiction fiq_save_user_regs     */
 453         irq_restore_user_regs
 454
 455 #else
 456
 457         .align  5
 458 irq:
 459         get_bad_stack
 460         bad_save_user_regs
 461         bl      do_irq
 462
 463         .align  5
 464 fiq:
 465         get_bad_stack
 466         bad_save_user_regs
 467         bl      do_fiq
 468
 469 #endif
 470
 471 /****************************************************************************/
 472 /*                                                                          */
 473 /* Reset function: the PXA250 doesn't have a reset function, so we have to  */
 474 /* perform a watchdog timeout for a soft reset.                             */
 475 /*                                                                          */
 476 /****************************************************************************/
 477
 478         .align  5
 479 .globl reset_cpu
 480
 481         /* FIXME: this code is PXA250 specific. How is this handled on      */
 482         /*        other XScale processors?                                  */
 483
 484 reset_cpu:
 485
 486         /* We set OWE:WME (watchdog enable) and wait until timeout happens  */
 487
 488         ldr     r0, OSTIMER_BASE
 489         ldr     r1, [r0, #OWER]
 490         orr     r1, r1, #0x0001                 /* bit0: WME                */
 491         str     r1, [r0, #OWER]
 492
 493         /* OS timer does only wrap every 1165 seconds, so we have to set    */
 494         /* the match register as well.                                      */
 495
 496         ldr     r1, [r0, #OSCR]                 /* read OS timer            */
 497         add     r1, r1, #0x800                  /* let OSMR3 match after    */
 498         add     r1, r1, #0x800                  /* 4096*(1/3.6864MHz)=1ms   */
 499         str     r1, [r0, #OSMR3]
 500
 501 reset_endless:
 502
 503         b       reset_endless