arch/cris/kernel/vmlinux.lds.S

   1 /* ld script to make the Linux/CRIS kernel
   2  * Authors: Bjorn Wesen (bjornw@axis.com)
   3  *
   4  * It is VERY DANGEROUS to fiddle around with the symbols in this
   5  * script. It is for example quite vital that all generated sections
   6  * that are used are actually named here, otherwise the linker will
   7  * put them at the end, where the init stuff is which is FREED after
   8  * the kernel has booted.
   9  */
  10
  11 #include <asm-generic/vmlinux.lds.h>
  12 #include <asm/page.h>
  13
  14 #ifdef CONFIG_ETRAX_VMEM_SIZE
  15 #define __CONFIG_ETRAX_VMEM_SIZE CONFIG_ETRAX_VMEM_SIZE
  16 #else
  17 #define __CONFIG_ETRAX_VMEM_SIZE 0
  18 #endif
  19
  20
  21 jiffies = jiffies_64;
  22 SECTIONS
  23 {
  24         . = DRAM_VIRTUAL_BASE;
  25         dram_start = .;
  26 #ifdef CONFIG_ETRAX_ARCH_V10
  27         ibr_start = .;
  28 #else
  29         ebp_start = .;
  30         /* The boot section is only necessary until the VCS top */
  31         /* level testbench includes both flash and DRAM. */
  32         .boot : { *(.boot) }
  33 #endif
  34
  35         /* see head.S and pages reserved at the start */
  36         . = DRAM_VIRTUAL_BASE + 0x4000;
  37
  38         _text = .;                      /* Text and read-only data. */
  39         text_start = .;                 /* Lots of aliases. */
  40         _stext = .;
  41         __stext = .;
  42         .text : {
  43                 TEXT_TEXT
  44                 SCHED_TEXT
  45                 LOCK_TEXT
  46                 *(.fixup)
  47                 *(.text.__*)
  48         }
  49
  50         _etext = . ;                    /* End of text section. */
  51         __etext = .;
  52
  53         EXCEPTION_TABLE(4)
  54
  55         RODATA
  56
  57         . = ALIGN (4);
  58         ___data_start = . ;
  59         __Sdata = . ;
  60         .data : {                       /* Data */
  61                 CACHELINE_ALIGNED_DATA(32)
  62                 READ_MOSTLY_DATA(32)
  63                 DATA_DATA
  64         }
  65         __edata = . ;                   /* End of data section. */
  66         _edata = . ;
  67
  68         INIT_TASK_DATA_SECTION(PAGE_SIZE)
  69
  70         . = ALIGN(PAGE_SIZE);           /* Init code and data. */
  71         __init_begin = .;
  72         INIT_TEXT_SECTION(PAGE_SIZE)
  73         .init.data : { INIT_DATA }
  74         .init.setup : { INIT_SETUP(16) }
  75 #ifdef CONFIG_ETRAX_ARCH_V32
  76         __start___param = .;
  77         __param : { *(__param) }
  78         __stop___param = .;
  79 #endif
  80         .initcall.init : {
  81                 INIT_CALLS
  82         }
  83
  84         .con_initcall.init : {
  85                 CON_INITCALL
  86         }
  87         SECURITY_INIT
  88
  89         /* .exit.text is discarded at runtime, not link time,
  90          * to deal with references from __bug_table
  91          */
  92         .exit.text : {
  93                 EXIT_TEXT
  94         }
  95         .exit.data : {
  96                 EXIT_DATA
  97         }
  98
  99 #ifdef CONFIG_ETRAX_ARCH_V10
 100 #ifdef CONFIG_BLK_DEV_INITRD
 101         .init.ramfs : {
 102                 __initramfs_start = .;
 103                 *(.init.ramfs)
 104                 __initramfs_end = .;
 105         }
 106 #endif
 107 #endif
 108         __vmlinux_end = .;              /* Last address of the physical file. */
 109 #ifdef CONFIG_ETRAX_ARCH_V32
 110         PERCPU(PAGE_SIZE)
 111
 112         .init.ramfs : {
 113                 INIT_RAM_FS
 114         }
 115 #endif
 116
 117         /*
 118          * We fill to the next page, so we can discard all init
 119          * pages without needing to consider what payload might be
 120          * appended to the kernel image.
 121          */
 122         . = ALIGN(PAGE_SIZE);
 123
 124         __init_end = .;
 125
 126         __data_end = . ;                /* Move to _edata ? */
 127         BSS_SECTION(1, 1, 1)
 128
 129         . =  ALIGN (0x20);
 130         _end = .;
 131         __end = .;
 132
 133         dram_end = dram_start + (CONFIG_ETRAX_DRAM_SIZE - __CONFIG_ETRAX_VMEM_SIZE)*1024*1024;
 134
 135         DISCARDS
 136 }